configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_COMMON_LIST], [ dnl
  61   -Wall dnl
  62   -Wnull-dereference dnl
  63   dnl We currently get this warning when building with Clang:
  64   dnl
  65   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  66   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  67   dnl            ^
  68   -Wno-incomplete-setjmp-declaration dnl
  69   -Wmissing-declarations dnl
  70   -Wshadow dnl
  71   -Wno-gnu-folding-constant dnl
  72   -Wsuggest-attribute=format dnl
  73   -Wformat=2 dnl
  74 ])
  75
  76 # Detect warning flags specific to the C compiler and append them to
  77 # WARN_CFLAGS.
  78 m4_define([WARN_FLAGS_C_LIST], [ dnl
  79   -Wdiscarded-qualifiers dnl
  80   -Wmissing-prototypes dnl
  81   -Wmissing-parameter-type dnl
  82 ])
  83
  84 # Pass -Werror as an extra flag during the test: this is needed to make the
  85 # -Wunknown-warning-option diagnostic fatal with clang.
  86 AC_LANG_PUSH([C])
  87 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_C_LIST], [WARN_CFLAGS], [-Werror])
  88 AC_LANG_POP([C])
  89
  90 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
  91 # written in such a way that it triggers warnings with the following warning
  92 # flags.  So they would always end up disabled if we put them there, because
  93 # the test program would not build.
  94 #
  95 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
  96 # Clang >= 3.3 (required by the project) and are only valid for C code.
  97 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
  98
  99 # Disable 'strict aliasing' if the C compiler supports it.
 100 AC_LANG_PUSH([C])
 101 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 102 AC_LANG_POP([C])
 103
 104
 105 ##                     ##
 106 ## C++ compiler checks ##
 107 ##                     ##
 108
 109 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 110 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 111
 112 # Detect warning flags specific to the C++ compiler and append them to
 113 # WARN_CXXFLAGS.
 114 m4_define([WARN_FLAGS_CXX_LIST], [ dnl
 115   dnl GCC enables this with -Wall in C++, and that generates a
 116   dnl lot of warnings that have on average a low value to fix.
 117   -Wno-sign-compare dnl
 118 ])
 119
 120 # Pass -Werror as an extra flag during the test: this is needed to make the
 121 # -Wunknown-warning-option diagnostic fatal with clang.
 122 AC_LANG_PUSH([C++])
 123 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_CXX_LIST], [WARN_CXXFLAGS], [-Werror])
 124 AC_LANG_POP([C++])
 125
 126 # Disable 'strict aliasing' if the C++ compiler supports it.
 127 AC_LANG_PUSH([C++])
 128 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 129 AC_LANG_POP([C++])
 130
 131
 132 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 133 AC_ARG_ENABLE([Werror],[
 134   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 135 ])
 136
 137 AS_IF([test "x$enable_Werror" = "xyes"], [
 138   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 139   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 140 ])
 141
 142 # Checks for programs.
 143 AC_PROG_GREP
 144 AC_PROG_MAKE_SET
 145 AC_PROG_SED
 146 AC_PATH_PROG([report_fold], [fold])
 147 LT_INIT
 148
 149 # Check for objcopy, required by the base address statedump and dynamic linker tests
 150 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
 151 AS_IF([test "x$OBJCOPY" = "xno"],
 152         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 153 )
 154 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
 155
 156 # check for pgrep
 157 AC_PATH_PROG([PGREP], [pgrep], [no])
 158 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
 159
 160 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 161 # is not distributed in tarballs
 162 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 163 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 164
 165 # check for bison
 166 AC_PROG_YACC
 167 BISON=$YACC
 168 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 169
 170 AS_IF([test "x$have_bison" != "xyes"], [
 171   AS_IF([test "x$in_git_repo" = "xyes"], [
 172     AC_MSG_FAILURE([
 173 Bison >= 2.4 is required when building from the Git repository. You can
 174 set the YACC variable to override automatic detection.
 175     ])
 176   ], [
 177     AC_MSG_WARN([
 178 Missing Bison >= 2.4. Note that the parser files are already built in
 179 this distribution tarball, so Bison is only needed if you intend to
 180 modify their sources. You can set the YACC variable to override automatic
 181 detection.
 182     ])
 183   ])
 184 ])
 185 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 186
 187 # check for flex
 188 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 189 # problem since the argument is silently ignored by older versions.
 190 AC_PROG_LEX([noyywrap])
 191 FLEX=$LEX
 192 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 193
 194 AS_IF([test "x$have_flex" != "xyes"], [
 195   AS_IF([test "x$in_git_repo" = "xyes"], [
 196     AC_MSG_FAILURE([
 197 Flex >= 2.5.35 is required when building from the Git repository. You can
 198 set the LEX variable to override automatic detection.
 199     ])
 200   ], [
 201     AC_MSG_WARN([
 202 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 203 this distribution tarball, so Flex is only needed if you intend to
 204 modify their sources. You can set the LEX variable to override automatic
 205 detection.
 206     ])
 207   ])
 208 ])
 209 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 210
 211
 212
 213 # Check if linker has the -no-pie option.
 214 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 215 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 216
 217 AX_LIB_SOCKET_NSL
 218
 219 LT_NO_UNDEFINED=""
 220 AS_CASE([$host_os],
 221   [cygwin*],
 222     [
 223       LT_NO_UNDEFINED="-no-undefined"
 224     ],
 225   [cygwin*|darwin*|mingw*|solaris*],
 226     [
 227       # On platforms where we only support the relayd, disable the other binaries by default
 228       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 229       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 230       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 231       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 232       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 233       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 234     ]
 235 )
 236
 237 AC_SUBST(LT_NO_UNDEFINED)
 238
 239 # Compute minor/major/patchlevel version numbers
 240 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 241 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 242 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 243
 244 AC_SUBST([MAJOR_VERSION], [$major_version])
 245 AC_SUBST([MINOR_VERSION], [$minor_version])
 246 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 247 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 248 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 249 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 250
 251 version_name="O-Beer"
 252 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 253 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 254
 255 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 256 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 257
 258 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 259 AC_ARG_ENABLE(libtool-linkdep-fixup,
 260         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 261                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 262         libtool_fixup=$enableval,
 263         libtool_fixup=yes)
 264
 265 AS_IF([test "x$libtool_fixup" = "xyes"],
 266             [
 267             libtool_m4="$srcdir/m4/libtool.m4"
 268             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 269             AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4])
 270             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 271             AS_IF([test $libtool_flag_pattern_count -ne 0],
 272             [
 273                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 274                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 275                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 276                   ],
 277                   [
 278                   AC_MSG_RESULT([none])
 279                   ])
 280             ])
 281
 282 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 283
 284 AC_CHECK_HEADERS([ \
 285         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 286         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 287         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 288         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 289         sys/mount.h sys/param.h sys/time.h elf.h
 290 ])
 291
 292 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 293
 294 # Basic functions check
 295 AC_CHECK_FUNCS([ \
 296         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 297         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 298         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 299         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 300         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 301         sched_getcpu sysconf sync_file_range
 302 ])
 303
 304 # Check for pthread_setname_np and pthread_getname_np
 305 LTTNG_PTHREAD_SETNAME_NP
 306 LTTNG_PTHREAD_GETNAME_NP
 307
 308 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 309 # add -lrt to LIBS
 310 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 311
 312 # Checks for dl.
 313 AC_CHECK_LIB([dl], [dlopen], [
 314         have_libdl=yes
 315         libdl_name=dl
 316         DL_LIBS="-ldl"
 317 ], [
 318         # libdl not found, check for dlopen in libc.
 319         AC_CHECK_LIB([c], [dlopen], [
 320                 have_libc_dl=yes
 321                 libdl_name=c
 322                 DL_LIBS="-lc"
 323         ], [
 324                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 325         ])
 326 ])
 327 AC_SUBST(DL_LIBS)
 328
 329 # Check if libdl has dlmopen support.
 330 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 331 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 332         AC_DEFINE([HAVE_DLMOPEN], [1])
 333         HAVE_DLMOPEN=1
 334 ], [
 335         HAVE_DLMOPEN=0
 336 ])
 337 AC_SUBST(HAVE_DLMOPEN)
 338
 339 # Babeltrace viewer check
 340 AC_ARG_WITH([babeltrace-bin],
 341         AS_HELP_STRING([--with-babeltrace-bin],
 342         [Location of the babeltrace viewer executable (including the filename)]),
 343         [BABELTRACE_BIN="$withval"],
 344         [BABELTRACE_BIN=''])
 345 AC_SUBST([BABELTRACE_BIN])
 346
 347 AC_ARG_WITH([babeltrace2-bin],
 348         AS_HELP_STRING([--with-babeltrace2-bin],
 349         [Location of the babeltrace2 viewer executable (including the filename)]),
 350         [BABELTRACE2_BIN="$withval"],
 351         [BABELTRACE2_BIN=''])
 352 AC_SUBST([BABELTRACE2_BIN])
 353
 354 AC_ARG_WITH([consumerd32-bin],
 355         AS_HELP_STRING([--with-consumerd32-bin],
 356         [Location of the 32-bit consumerd executable (including the filename)]),
 357         [CONSUMERD32_BIN="$withval"],
 358         [CONSUMERD32_BIN=''])
 359 AC_SUBST([CONSUMERD32_BIN])
 360
 361 AC_ARG_WITH([consumerd64-bin],
 362         AS_HELP_STRING([--with-consumerd64-bin],
 363         [Location of the 64-bit consumerd executable (including the filename)]),
 364         [CONSUMERD64_BIN="$withval"],
 365         [CONSUMERD64_BIN=''])
 366 AC_SUBST([CONSUMERD64_BIN])
 367
 368 AC_ARG_WITH([consumerd32-libdir],
 369         AS_HELP_STRING([--with-consumerd32-libdir],
 370         [Directory containing the 32-bit consumerd libraries]),
 371         [CONSUMERD32_LIBDIR="$withval"],
 372         [CONSUMERD32_LIBDIR=''])
 373 AC_SUBST([CONSUMERD32_LIBDIR])
 374
 375 AC_ARG_WITH([consumerd64-libdir],
 376         AS_HELP_STRING([--with-consumerd64-libdir],
 377         [Directory containing the 64-bit consumerd libraries]),
 378         [CONSUMERD64_LIBDIR="$withval"],
 379         [CONSUMERD64_LIBDIR=''])
 380 AC_SUBST([CONSUMERD64_LIBDIR])
 381
 382 AC_ARG_WITH([sessiond-bin],
 383         AS_HELP_STRING([--with-sessiond-bin],
 384         [Location of the sessiond executable (including the filename)]),
 385         [SESSIOND_BIN="$withval"],
 386         [SESSIOND_BIN=''])
 387 AC_SUBST([SESSIOND_BIN])
 388
 389 AC_ARG_WITH([lttng-system-rundir],
 390         AS_HELP_STRING([--with-lttng-system-rundir],
 391         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 392         [LTTNG_SYSTEM_RUNDIR="$withval"],
 393         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 394 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 395
 396 AC_ARG_ENABLE([test-java-agent-jul],
 397         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 398         [test_java_agent_jul=$enableval],
 399         [test_java_agent_jul=no]
 400 )
 401
 402 AC_ARG_ENABLE([test-java-agent-log4j],
 403         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])],
 404         [test_java_agent_log4j=$enableval],
 405         [test_java_agent_log4j=no]
 406 )
 407
 408 AC_ARG_ENABLE([test-java-agent-log4j2],
 409         [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])],
 410         [test_java_agent_log4j2=$enableval],
 411         [test_java_agent_log4j2=no]
 412 )
 413
 414 AC_ARG_ENABLE([test-java-agent-all],
 415         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 416         [test_java_agent_jul=$enableval
 417          test_java_agent_log4j=$enableval
 418          test_java_agent_log4j2=$enableval],
 419         [:]
 420 )
 421
 422 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 423 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 424 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 425 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 426 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 427 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 428 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 429 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 430
 431 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 432         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 433         $1="$2"
 434         AC_SUBST([$1])
 435 ])
 436
 437 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 438         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 439         $1="$2"
 440         AC_SUBST([$1])
 441 ])
 442
 443 # Default values
 444 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 445 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 446 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 447 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 448 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 449 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 450 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 451 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 452 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 453 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 454 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 455 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 456 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 457 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 458 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 459 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 460 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 461 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 462 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 463 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 464 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 465 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 466 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 467 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 468 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 469 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 470 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 471 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 472 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 473 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 474 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 475 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 476 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 477 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 478 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 479 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 480 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 481 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 482 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 483 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 484 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 485 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 486 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 487 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 488 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 489 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 490 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 491 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 492 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 493 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 494
 495 # Command short descriptions
 496 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 497 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 498 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 499 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 500 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 501 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 502 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 503 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 504 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 505 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 506 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 507 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 508 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 509 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 510 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 511 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 512 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 513 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 514 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 515 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 516 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 517 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 518 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 519 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 520 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 521 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 522 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 523 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 524
 525 if test "x$prefix" = "xNONE"; then
 526         prefix=$ac_default_prefix
 527 fi
 528 CONFDIR=`eval echo $sysconfdir`
 529 AC_SUBST(CONFDIR)
 530 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 531
 532 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 533
 534 # Check libpopt
 535 PKG_CHECK_MODULES([POPT], [popt],
 536   [
 537     dnl PKG_CHECK_MODULES defines POPT_LIBS
 538   ],
 539   [
 540     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 541     AC_MSG_WARN([Finding libpopt without pkg-config.])
 542     AC_CHECK_LIB([popt],
 543       [poptGetContext],
 544       [POPT_LIBS="-lpopt"],
 545       [
 546         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 547       ]
 548     )
 549   ]
 550 )
 551 AC_SUBST(POPT_LIBS)
 552
 553 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 554
 555 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 556
 557 # URCU library version needed or newer
 558 PKG_CHECK_MODULES([URCU], [liburcu >= 0.11])
 559 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11])
 560 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 561
 562 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 563 # it can be explicitly disabled with --without-kmod
 564 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 565 AC_ARG_WITH([kmod],
 566   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 567   [],
 568   [with_kmod=check]
 569 )
 570
 571 AS_IF([test "x$with_kmod" != "xno"],
 572   [
 573     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 574       [
 575         AC_DEFINE([HAVE_KMOD], [1])
 576         KMOD_LIBS="-lkmod"
 577       ],
 578       [
 579         if test "x$with_kmod" != xcheck; then
 580           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 581         else
 582           with_kmod=no
 583         fi
 584       ]
 585     )
 586   ]
 587 )
 588 AC_SUBST(KMOD_LIBS)
 589
 590 # Check for liblttng-ust-ctl, fail if it's not found,
 591 # it can be explicitly disabled with --without-lttng-ust
 592 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 593 AC_ARG_WITH([lttng-ust],
 594   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 595   [],
 596   [with_lttng_ust=yes]
 597 )
 598
 599 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 600   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 601
 602   # Check for liblttng-ust
 603   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 604
 605   # Check for liblttng-ust-ctl
 606   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 607
 608   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 609 ])
 610
 611 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 612
 613
 614 # Check for fmemopen
 615 AC_CHECK_LIB([c], [fmemopen],
 616 [
 617         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 618 ]
 619 )
 620
 621 # check for libpfm
 622 AC_CHECK_LIB([pfm], [pfm_initialize],
 623              [
 624               have_libpfm=yes
 625               ])
 626 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 627
 628 # For Python
 629 # SWIG version needed or newer:
 630 swig_version=2.0.0
 631
 632 AC_ARG_ENABLE([python-bindings],
 633               [AS_HELP_STRING([--enable-python-bindings],
 634                               [compile Python bindings])],
 635               [enable_python_binding=$enableval], [enable_python_binding=no])
 636
 637 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 638
 639 if test "x$enable_python_binding" = xyes; then
 640   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 641   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 642   AM_PATH_PYTHON([3.0])
 643
 644   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 645   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 646   AS_IF([test -z "$PYTHON_INCLUDE"], [
 647     AS_IF([test -z "$PYTHON_CONFIG"], [
 648       AC_PATH_PROGS([PYTHON_CONFIG],
 649                     [python$PYTHON_VERSION-config python-config],
 650                     [no],
 651                     [`dirname $PYTHON`])
 652       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 653     ])
 654     AC_MSG_CHECKING([python include flags])
 655     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 656     AC_MSG_RESULT([$PYTHON_INCLUDE])
 657   ])
 658
 659 else
 660     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 661 [if you want Python bindings.])
 662
 663 fi
 664
 665 # Epoll check. If not present, the build will fallback on poll() API
 666 AX_HAVE_EPOLL(
 667         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 668         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 669 )
 670 AX_CONFIG_FEATURE(
 671         [epoll], [This platform supports epoll(7)],
 672         [HAVE_EPOLL], [This platform supports epoll(7).]
 673 )
 674
 675 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 676         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 677         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 678 )
 679 AX_CONFIG_FEATURE(
 680         [dirfd], [Use directory file descriptors],
 681         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 682 )
 683
 684 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 685 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 686 AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"])
 687
 688 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then
 689         AX_JAVA_OPTIONS
 690         AX_PROG_JAVAC
 691         AX_PROG_JAVA
 692         AX_PROG_JAR
 693
 694         AX_CHECK_CLASSPATH
 695
 696         # Check for Java UST agent common class first
 697         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 698         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 699                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 700         fi
 701
 702         if test "x$test_java_agent_jul" = "xyes"; then
 703                 # Check for JUL agent class
 704                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 705                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 706                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 707                 fi
 708         fi
 709
 710         if test "x$test_java_agent_log4j" = "xyes"; then
 711                 # Check for Log4j agent class
 712                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 713                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 714                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 715                 fi
 716
 717                 # Check for Log4j class
 718                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 719                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 720                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 721                 fi
 722         fi
 723
 724         if test "x$test_java_agent_log4j2" = "xyes"; then
 725                 # Check for Log4j2 agent class
 726                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender)
 727                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then
 728                         AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"])
 729                 fi
 730
 731                 # Check for Log4j 2.x classes
 732                 AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 733                 AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 734                 if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then
 735                         AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"])
 736                 fi
 737         fi
 738 fi
 739
 740 # enable building man pages (user's intention)
 741 AC_ARG_ENABLE(
 742         man-pages,
 743         AS_HELP_STRING(
 744                 [--disable-man-pages],
 745                 [Do not build and install man pages (already built in a distributed tarball)]
 746         ),
 747         [man_pages_opt=$enableval],
 748         [man_pages_opt=yes]
 749 )
 750
 751 # check for asciidoc and xmlto if we enabled building the man pages
 752 have_asciidoc_xmlto=no
 753 warn_prebuilt_man_pages=no
 754
 755 AS_IF([test "x$man_pages_opt" = "xyes"], [
 756         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 757         AC_PATH_PROG([XMLTO], [xmlto], [no])
 758
 759         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 760                 AS_IF([test "x$in_git_repo" = "xyes"], [
 761                         # this is an error because we're in the Git repo, which
 762                         # means the man pages are not already generated for us,
 763                         # thus asciidoc/xmlto are required because we were asked
 764                         # to build the man pages
 765                         AC_MSG_ERROR([
 766 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 767 --disable-man-pages to disable building the man pages, in which case
 768 they will not be installed.
 769                         ])
 770                 ], [
 771                         # only warn here: since we're in the tarball, the man
 772                         # pages should already be generated at this point, thus
 773                         # asciidoc/xmlto are not strictly required
 774                         warn_prebuilt_man_pages=yes
 775                 ])
 776         ], [
 777                 have_asciidoc_xmlto=yes
 778         ])
 779 ])
 780
 781 # export man page build condition: build the man pages if the user
 782 # asked for it, and if the tools are available
 783 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 784 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 785
 786 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 787
 788 # embedded --help message
 789 AC_ARG_ENABLE(
 790         [embedded-help],
 791         AS_HELP_STRING(
 792                 [--enable-embedded-help],
 793                 [Embed the --help messages in the executable files]
 794         ),
 795         [embedded_help=$enableval],
 796         [embedded_help=no]
 797 )
 798 AS_IF([test "x$embedded_help" = "xyes"], [
 799         AS_IF([test "x$man_pages_opt" = "xno"], [
 800                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 801         ])
 802         AC_PATH_PROG([man_prog_path], [man], [no])
 803         AS_IF([test "x$man_prog_path" = "xno"], [
 804                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 805         ])
 806         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 807         AC_SUBST([MANPROG], [$man_prog_path])
 808 ])
 809 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 810
 811 # Python agent test
 812 UST_PYTHON_AGENT="lttngust"
 813
 814 AC_ARG_ENABLE(test-python2-agent,
 815         AS_HELP_STRING([--enable-test-python2-agent],
 816                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 817         ),[:],[test_python2_agent_autodetect=yes]
 818 )
 819
 820 AC_ARG_ENABLE(test-python3-agent,
 821         AS_HELP_STRING([--enable-test-python3-agent],
 822                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 823         ),[:],[test_python3_agent_autodetect=yes]
 824 )
 825
 826 AC_ARG_ENABLE(test-python-agent-all,
 827         AS_HELP_STRING([--enable-test-python-agent-all],
 828                 [enable test for all python{2/3} agent.]
 829         ),
 830 )
 831
 832 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 833        unset test_python2_agent_autodetect
 834        unset test_python3_agent_autodetect
 835 ])
 836
 837 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 838        enable_test_python2_agent=yes
 839        enable_test_python3_agent=yes
 840 ])
 841
 842 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 843        enable_test_python2_agent=no
 844        enable_test_python3_agent=no
 845 ])
 846
 847
 848 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 849         AS_IF([test -z "$PYTHON2"], [
 850                         PYTHON2=python2
 851                 ], [
 852                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 853         ])
 854
 855         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 856         AS_IF([test -z "$PYTHON2_BIN"], [
 857                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 858                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 859                 ])
 860         ], [
 861                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 862                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 863                         PYTHON2_AGENT=$PYTHON2_BIN
 864                         AC_MSG_RESULT([yes])
 865                         RUN_PYTHON_AGENT_TEST=yes
 866                 ], [
 867                         AC_MSG_RESULT([no])
 868                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 869                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 870                         ])
 871                 ])
 872
 873         ])
 874
 875 ])
 876
 877 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 878         AS_IF([test -z "$PYTHON3"], [
 879                 PYTHON3=python3
 880         ], [
 881                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 882         ])
 883
 884         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 885         AS_IF([test -z "$PYTHON3_BIN"], [
 886                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 887                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 888                 ])
 889         ], [
 890                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 891                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 892                         PYTHON3_AGENT=$PYTHON3_BIN
 893                         AC_MSG_RESULT([yes])
 894                         RUN_PYTHON_AGENT_TEST=yes
 895                 ], [
 896                         AC_MSG_RESULT([no])
 897                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 898                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 899                         ])
 900                 ])
 901
 902         ])
 903 ])
 904 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 905 AC_SUBST([PYTHON2_AGENT])
 906 AC_SUBST([PYTHON3_AGENT])
 907
 908 AC_ARG_ENABLE([test-sdt-uprobe],
 909   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 910   [test_sdt_uprobe="$enableval"],
 911   [test_sdt_uprobe=autodetect]
 912 )
 913
 914 AS_IF([test "$test_sdt_uprobe" != "no"], [
 915   LTTNG_CHECK_SDT_WORKS
 916   AC_PATH_PROG([DTRACE], [dtrace])
 917 ])
 918
 919 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 920   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 921     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 922   ])
 923   AS_IF([test "x$DTRACE" = "x"], [
 924     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 925   ])
 926 ])
 927
 928 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 929   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 930     AS_IF([test "x$DTRACE" != "x"], [
 931       test_sdt_uprobe=yes
 932     ])
 933   ])
 934 ])
 935
 936 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 937
 938 # Arguments for binaries build exclusion
 939 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 940 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 941               [Disable the build of lttng-consumerd binaries]))
 942 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 943 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 944               [Disable the build of lttng-relayd binaries]))
 945 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 946               [Disable the build of lttng-sessiond binaries]))
 947 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 948               [Disable the build of the extra components]))
 949
 950
 951 build_lib_consumer=no
 952 build_lib_health=no
 953 build_lib_index=no
 954 build_lib_kernel_consumer=no
 955 build_lib_kernel_ctl=no
 956 build_lib_lttng_ctl=no
 957 build_lib_relayd=no
 958 build_lib_sessiond_comm=no
 959 build_lib_testpoint=no
 960 build_lib_ust_consumer=no
 961
 962 # There is an overlap for enabled dependencies, but this makes everything
 963 # simpler. libcommon and libconfig are always compiled so they are not repeated
 964 # here.
 965
 966 # Enable binary dependencies.
 967 AS_IF([test x$enable_bin_lttng != xno],
 968       [
 969        build_lib_lttng_ctl=yes
 970       ]
 971 )
 972
 973 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 974       [
 975        build_lib_consumer=yes
 976        build_lib_sessiond_comm=yes
 977        build_lib_index=yes
 978        build_lib_health=yes
 979        build_lib_testpoint=yes
 980       ]
 981 )
 982
 983 AS_IF([test x$enable_bin_lttng_crash != xno],
 984       # Do nothing since libconfig and libcommon are built by default.
 985       []
 986 )
 987
 988 AS_IF([test x$enable_bin_lttng_relayd != xno],
 989       [
 990        build_lib_sessiond_comm=yes
 991        build_lib_index=yes
 992        build_lib_health=yes
 993        build_lib_testpoint=yes
 994       ]
 995 )
 996 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 997       [
 998        build_lib_lttng_ctl=yes
 999        build_lib_sessiond_comm=yes
1000        build_lib_kernel_ctl=yes
1001        build_lib_relayd=yes
1002        build_lib_testpoint=yes
1003        build_lib_health=yes
1004       ]
1005 )
1006
1007 # Libraries dependencies enabling
1008 AS_IF([test x$build_lib_lttng_ctl = xyes],
1009       [
1010        build_lib_sessiond_comm=yes
1011       ]
1012 )
1013
1014 AS_IF([test x$build_lib_consumer = xyes],
1015       [
1016        build_lib_sessiond_comm=yes
1017        build_lib_kernel_consumer=yes
1018        build_lib_relayd=yes
1019        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
1020       ]
1021 )
1022
1023 AS_IF([test x$build_lib_kernel_consumer = xyes],
1024       [
1025        build_lib_kernel_ctl=yes
1026        build_lib_relayd=yes
1027       ]
1028 )
1029
1030 AS_IF([test x$build_lib_relayd = xyes],
1031       [
1032        build_lib_sessiond_comm=yes
1033       ]
1034 )
1035
1036 # Find arch type
1037 AS_CASE([$host_cpu],
1038         [k1om], [ARCHTYPE="x86"],
1039         [i386], [ARCHTYPE="x86"],
1040         [i486], [ARCHTYPE="x86"],
1041         [i586], [ARCHTYPE="x86"],
1042         [i686], [ARCHTYPE="x86"],
1043         [amd64], [ARCHTYPE="x86"],
1044         [x86_64], [ARCHTYPE="x86"],
1045         [powerpc], [ARCHTYPE="ppc"],
1046         [ppc64], [ARCHTYPE="ppc"],
1047         [powerpc64], [ARCHTYPE="ppc"],
1048         [powerpc64le], [ARCHTYPE="ppc"],
1049         [ppc], [ARCHTYPE="ppc"],
1050         [s390], [ARCHTYPE="s390"],
1051         [s390x], [ARCHTYPE="s390"],
1052         [sparc], [ARCHTYPE="sparc64"],
1053         [sparc64], [ARCHTYPE="sparc64"],
1054         [alpha*], [ARCHTYPE="alpha"],
1055         [ia64], [ARCHTYPE="ia64"],
1056         [arm*], [ARCHTYPE="arm"],
1057         [aarch64*], [ARCHTYPE="aarch64"],
1058         [mips*], [ARCHTYPE="mips"],
1059         [nios2*], [ARCHTYPE="nios2"],
1060         [tile*], [ARCHTYPE="tile"],
1061         [hppa*], [ARCHTYPE="hppa"],
1062         [m68k], [ARCHTYPE="m68k"],
1063         [riscv*], [ARCHTYPE="riscv"],
1064         [ARCHTYPE="unknown"]
1065 )
1066
1067 AC_SUBST(ARCHTYPE)
1068
1069 AS_CASE([$host_os],
1070         [linux*], [OSTYPE="linux"],
1071         [freebsd*], [OSTYPE="freebsd"],
1072         [solaris*], [OSTYPE="solaris"],
1073         [cygwin*], [OSTYPE="cygwin"],
1074         [mingw*], [OSTYPE="mingw"],
1075         [OSTYPE="unknown"]
1076 )
1077 AC_SUBST(OSTYPE)
1078 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1079
1080
1081
1082 # Userspace callstack capture is only supported by the Linux kernel on x86.
1083 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1084 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1085         have_modules_userspace_callstack_context=yes
1086         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1087 ])
1088 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1089
1090 # Export binaries build conditions.
1091 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1092 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1093 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1094 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1095 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1096
1097 # Export the tests and extras build conditions.
1098 AS_IF([\
1099 test "x$enable_bin_lttng" != "xno" && \
1100 test "x$enable_bin_lttng_consumerd" != "xno" && \
1101 test "x$enable_bin_lttng_crash" != "xno" && \
1102 test "x$enable_bin_lttng_relayd" != "xno" && \
1103 test "x$enable_bin_lttng_sessiond" != "xno"],
1104 [build_tests=yes],
1105 [build_tests=no]
1106 )
1107
1108 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1109 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1110
1111 # Export libraries build conditions.
1112 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1113 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1114 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1115 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1116 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1117 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1118 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1119 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1120 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1121 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1122
1123 AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1124 AC_SUBST(AM_CFLAGS)
1125
1126 AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1127 AC_SUBST(AM_CXXFLAGS)
1128
1129 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1130 AM_LDFLAGS=""
1131 AC_SUBST(AM_LDFLAGS)
1132
1133 # The order in which the include folders are searched is important.
1134 # The top_builddir should always be searched first in the event that a build
1135 # time generated file is included. An example of this is the "version.i" file.
1136 # In a scenario where lttng-tools is built from a distribution tarball and in a
1137 # out-of-tree manner, the generated "version.i" has priority on the one from
1138 # the source (distribution tarball) and must be found first.
1139 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1140 AC_SUBST(AM_CPPFLAGS)
1141
1142 lttngincludedir="${includedir}/lttng"
1143 AC_SUBST(lttngincludedir)
1144
1145 lttngactionincludedir="${includedir}/lttng/action"
1146 AC_SUBST(lttngactionincludedir)
1147
1148 lttngconditionincludedir="${includedir}/lttng/condition"
1149 AC_SUBST(lttngconditionincludedir)
1150
1151 lttngnotificationincludedir="${includedir}/lttng/notification"
1152 AC_SUBST(lttngnotificationincludedir)
1153
1154 lttngtriggerincludedir="${includedir}/lttng/trigger"
1155 AC_SUBST(lttngtriggerincludedir)
1156
1157 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1158 AC_SUBST(lttngeventruleincludedir)
1159
1160 lttnglibexecdir="${libdir}/lttng/libexec"
1161 AC_SUBST(lttnglibexecdir)
1162
1163 AC_CONFIG_FILES([
1164         Makefile
1165         doc/Makefile
1166         doc/examples/Makefile
1167         doc/examples/rotation/Makefile
1168         doc/examples/trigger-condition-event-matches/Makefile
1169         doc/man/Makefile
1170         doc/man/asciidoc-attrs.conf
1171         include/Makefile
1172         extras/Makefile
1173         extras/bindings/Makefile
1174         extras/bindings/swig/Makefile
1175         extras/bindings/swig/python/Makefile
1176         extras/core-handler/Makefile
1177         src/Makefile
1178         src/common/Makefile
1179         src/lib/Makefile
1180         src/lib/lttng-ctl/Makefile
1181         src/lib/lttng-ctl/lttng-ctl.pc
1182         src/bin/Makefile
1183         src/bin/lttng-consumerd/Makefile
1184         src/bin/lttng-sessiond/Makefile
1185         src/bin/lttng-relayd/Makefile
1186         src/bin/lttng/Makefile
1187         src/bin/lttng-crash/Makefile
1188         src/vendor/Makefile
1189         src/vendor/msgpack/Makefile
1190         tests/Makefile
1191         tests/destructive/Makefile
1192         tests/regression/Makefile
1193         tests/regression/kernel/Makefile
1194         tests/regression/tools/Makefile
1195         tests/regression/tools/streaming/Makefile
1196         tests/regression/tools/filtering/Makefile
1197         tests/regression/tools/health/Makefile
1198         tests/regression/tools/tracefile-limits/Makefile
1199         tests/regression/tools/snapshots/Makefile
1200         tests/regression/tools/live/Makefile
1201         tests/regression/tools/exclusion/Makefile
1202         tests/regression/tools/save-load/Makefile
1203         tests/regression/tools/save-load/configuration/Makefile
1204         tests/regression/tools/mi/Makefile
1205         tests/regression/tools/wildcard/Makefile
1206         tests/regression/tools/channel/Makefile
1207         tests/regression/tools/crash/Makefile
1208         tests/regression/tools/regen-metadata/Makefile
1209         tests/regression/tools/regen-statedump/Makefile
1210         tests/regression/tools/notification/Makefile
1211         tests/regression/tools/rotation/Makefile
1212         tests/regression/tools/base-path/Makefile
1213         tests/regression/tools/metadata/Makefile
1214         tests/regression/tools/tracker/Makefile
1215         tests/regression/tools/working-directory/Makefile
1216         tests/regression/tools/relayd-grouping/Makefile
1217         tests/regression/tools/clear/Makefile
1218         tests/regression/tools/trigger/Makefile
1219         tests/regression/tools/trigger/rate-policy/Makefile
1220         tests/regression/tools/trigger/start-stop/Makefile
1221         tests/regression/tools/trigger/utils/Makefile
1222         tests/regression/tools/trigger/name/Makefile
1223         tests/regression/tools/trigger/hidden/Makefile
1224         tests/regression/ust/Makefile
1225         tests/regression/ust/nprocesses/Makefile
1226         tests/regression/ust/high-throughput/Makefile
1227         tests/regression/ust/low-throughput/Makefile
1228         tests/regression/ust/before-after/Makefile
1229         tests/regression/ust/buffers-pid/Makefile
1230         tests/regression/ust/periodical-metadata-flush/Makefile
1231         tests/regression/ust/multi-session/Makefile
1232         tests/regression/ust/multi-lib/Makefile
1233         tests/regression/ust/overlap/Makefile
1234         tests/regression/ust/overlap/demo/Makefile
1235         tests/regression/ust/linking/Makefile
1236         tests/regression/ust/daemon/Makefile
1237         tests/regression/ust/exit-fast/Makefile
1238         tests/regression/ust/fork/Makefile
1239         tests/regression/ust/libc-wrapper/Makefile
1240         tests/regression/ust/baddr-statedump/Makefile
1241         tests/regression/ust/ust-dl/Makefile
1242         tests/regression/ust/java-jul/Makefile
1243         tests/regression/ust/java-log4j/Makefile
1244         tests/regression/ust/java-log4j2/Makefile
1245         tests/regression/ust/getcpu-override/Makefile
1246         tests/regression/ust/clock-override/Makefile
1247         tests/regression/ust/type-declarations/Makefile
1248         tests/regression/ust/rotation-destroy-flush/Makefile
1249         tests/regression/ust/blocking/Makefile
1250         tests/regression/ust/namespaces/Makefile
1251         tests/stress/Makefile
1252         tests/unit/Makefile
1253         tests/unit/ini_config/Makefile
1254         tests/perf/Makefile
1255         tests/utils/Makefile
1256         tests/utils/tap/Makefile
1257         tests/utils/testapp/Makefile
1258         tests/utils/testapp/gen-ns-events/Makefile
1259         tests/utils/testapp/gen-kernel-test-events/Makefile
1260         tests/utils/testapp/gen-py-events/Makefile
1261         tests/utils/testapp/gen-ust-events/Makefile
1262         tests/utils/testapp/gen-ust-events-ns/Makefile
1263         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1264         tests/utils/testapp/gen-ust-nevents/Makefile
1265         tests/utils/testapp/gen-ust-nevents-str/Makefile
1266         tests/utils/testapp/gen-syscall-events/Makefile
1267         tests/utils/testapp/gen-ust-tracef/Makefile
1268         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1269         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1270         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1271         tests/utils/xml-utils/Makefile
1272 ])
1273
1274 # Inject variable into python test script.
1275 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1276 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1277 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1278 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1279
1280 AC_OUTPUT
1281
1282 #
1283 # Mini-report on what will be built.
1284 #
1285
1286 PPRINT_INIT
1287 PPRINT_SET_INDENT(1)
1288 PPRINT_SET_TS(38)
1289
1290 AS_ECHO
1291 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1292 AS_ECHO
1293
1294 AS_IF([test -n "$report_fold"], [
1295         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1296 ], [
1297         AS_ECHO("$version_description")
1298 ])
1299
1300 AS_ECHO
1301 PPRINT_SUBTITLE([Features])
1302
1303 # Target architecture we're building for.
1304 target_arch=$host_cpu
1305 [
1306 for f in $CFLAGS; do
1307         if test $f = "-m32"; then
1308                         target_arch="32-bit"
1309         elif test $f = "-m64"; then
1310                         target_arch="64-bit"
1311         fi
1312 done
1313 ]
1314 PPRINT_PROP_STRING([Target architecture], $target_arch)
1315
1316 # kmod enabled/disabled
1317 test "x$with_kmod" != "xno" && value=1 || value=0
1318 PPRINT_PROP_BOOL([libkmod support], $value)
1319
1320 # LTTng-UST enabled/disabled
1321 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1322 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1323
1324 AS_ECHO
1325 PPRINT_SUBTITLE([Binaries])
1326
1327 # List binaries to be built
1328 test x$enable_bin_lttng != xno && value=1 || value=0
1329 PPRINT_PROP_BOOL([lttng], $value)
1330
1331 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1332 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1333
1334 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1335 PPRINT_PROP_BOOL([lttng-crash], $value)
1336
1337 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1338 PPRINT_PROP_BOOL([lttng-relayd], $value)
1339
1340 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1341 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1342
1343 # Extras
1344 test x$enable_extras != xno && value=1 || value=0
1345 AS_ECHO
1346 PPRINT_SET_INDENT(0)
1347 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1348 PPRINT_SET_INDENT(1)
1349
1350 AS_ECHO
1351 PPRINT_SUBTITLE([Tests])
1352
1353 # Print clear message that tests won't be built
1354 AS_IF([test "x$build_tests" = "xno"],[
1355         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1356 ])
1357
1358 # LTTng UST Java agent JUL tests enabled/disabled
1359 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1360 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1361
1362 # LTTng UST Java agent Log4j 1.x tests enabled/disabled
1363 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1364 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value)
1365
1366 # LTTng UST Java agent Log4j 2.x tests enabled/disabled
1367 test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0
1368 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value)
1369
1370 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1371 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1372
1373 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1374 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1375
1376 # userspace-probe SDT instrumentation tests enabled/disabled
1377 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1378 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1379
1380 #Python binding enabled/disabled
1381 test "x$enable_python_binding" = xyes && value=1 || value=0
1382 AS_ECHO
1383 PPRINT_SET_INDENT(0)
1384 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1385
1386 # man pages build enabled/disabled
1387 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1388
1389 AS_IF([test "x$man_pages_opt" != "xno"], [
1390         AS_IF([test "x$in_git_repo" = "xyes"], [
1391                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1392         ], [
1393                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1394                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1395                 ], [
1396                         PPRINT_PROP_STRING([build_man_pages_msg],
1397                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1398                                 $PPRINT_COLOR_SUBTITLE)
1399                 ])
1400         ])
1401 ], [
1402         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1403 ])
1404
1405 m4_popdef([build_man_pages_msg])
1406
1407 test "x$embedded_help" = xyes && value=1 || value=0
1408 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1409
1410 PPRINT_SET_INDENT(1)
1411
1412 report_bindir="`eval eval echo $bindir`"
1413 report_libdir="`eval eval echo $libdir`"
1414
1415 # Print the bindir and libdir this `make install' will install into.
1416 AS_ECHO
1417 PPRINT_SUBTITLE([Install directories])
1418 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1419 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1420
1421 AS_ECHO
1422 PPRINT_SUBTITLE([Search directories])
1423
1424 # If we build the sessiond, print the paths it will use
1425 AS_IF([test "$SESSIOND_BIN" = ""],[
1426         path="$report_bindir/lttng-sessiond"
1427 ],[
1428         path="$SESSIOND_BIN"
1429 ])
1430 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1431
1432 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1433         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1434 ],[
1435         path="$CONSUMERD32_BIN"
1436 ])
1437 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1438
1439 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1440         path="`eval eval echo $libdir`"
1441 ],[
1442         path="$CONSUMERD32_LIBDIR"
1443 ])
1444 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1445
1446 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1447         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1448 ],[
1449         path="$CONSUMERD64_BIN"
1450 ])
1451 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1452
1453 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1454         path="`eval eval echo $libdir`"
1455 ],[
1456         path="$CONSUMERD64_LIBDIR"
1457 ])
1458 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1459 PPRINT_SET_INDENT(0)
1460
1461 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1462         AS_ECHO
1463         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1464
1465 Note that the man pages are already built in this distribution tarball,
1466 therefore asciidoc and xmlto are only needed if you intend to modify
1467 their sources.
1468
1469 Also note that the installed man pages will contain the project's
1470 default command-line option and environment variable values.
1471
1472 Use --disable-man-pages to completely disable building and installing
1473 the man pages.])
1474 ])