configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc subdir-objects])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_COMMON_LIST], [ dnl
  61   -Wall dnl
  62   -Wextra dnl
  63   -Wmissing-declarations dnl
  64   -Wnull-dereference dnl
  65   -Wundef dnl
  66   -Wredundant-decls dnl
  67   -Wshadow dnl
  68   -Wsuggest-attribute=format dnl
  69   -Wtautological-constant-out-of-range-compare dnl Clang specific
  70   -Wwrite-strings dnl
  71   -Wformat=2 dnl
  72   -Wstrict-aliasing dnl
  73   -Wmissing-noreturn dnl
  74   -Wduplicated-cond dnl
  75   -Wduplicated-branches dnl
  76   -Wlogical-op dnl
  77   -Winit-self dnl
  78   dnl We currently get this warning when building with Clang:
  79   dnl
  80   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  81   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  82   dnl            ^
  83   -Wno-incomplete-setjmp-declaration dnl
  84   -Wno-gnu-folding-constant dnl Clang specific
  85 ])
  86
  87 # Detect warning flags specific to the C compiler and append them to
  88 # WARN_CFLAGS.
  89 m4_define([WARN_FLAGS_C_LIST], [ dnl
  90   -Wdiscarded-qualifiers dnl
  91   -Wmissing-prototypes dnl
  92   -Wmissing-parameter-type dnl
  93   -Wsuggest-final-types dnl
  94   -Wsuggest-final-methods dnl
  95   -Wsuggest-override dnl
  96 ])
  97
  98 # Pass -Werror as an extra flag during the test: this is needed to make the
  99 # -Wunknown-warning-option diagnostic fatal with clang.
 100 AC_LANG_PUSH([C])
 101 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_C_LIST], [WARN_CFLAGS], [-Werror])
 102 AC_LANG_POP([C])
 103
 104 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 105 # written in such a way that it triggers warnings with the following warning
 106 # flags.  So they would always end up disabled if we put them there, because
 107 # the test program would not build.
 108 #
 109 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 110 # Clang >= 3.3 (required by the project) and are only valid for C code.
 111 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 112
 113 # Disable 'strict aliasing' if the C compiler supports it.
 114 AC_LANG_PUSH([C])
 115 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 116 AC_LANG_POP([C])
 117
 118
 119 ##                     ##
 120 ## C++ compiler checks ##
 121 ##                     ##
 122
 123 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 124 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 125
 126 # Detect warning flags specific to the C++ compiler and append them to
 127 # WARN_CXXFLAGS.
 128 m4_define([WARN_FLAGS_CXX_LIST], [ dnl
 129   dnl GCC enables this with -Wall in C++, and that generates a
 130   dnl lot of warnings that have on average a low value to fix.
 131   -Wno-sign-compare dnl
 132 ])
 133
 134 # Pass -Werror as an extra flag during the test: this is needed to make the
 135 # -Wunknown-warning-option diagnostic fatal with clang.
 136 AC_LANG_PUSH([C++])
 137 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_CXX_LIST], [WARN_CXXFLAGS], [-Werror])
 138 AC_LANG_POP([C++])
 139
 140 # Disable 'strict aliasing' if the C++ compiler supports it.
 141 AC_LANG_PUSH([C++])
 142 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 143 AC_LANG_POP([C++])
 144
 145
 146 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 147 AC_ARG_ENABLE([Werror],[
 148   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 149 ])
 150
 151 AS_IF([test "x$enable_Werror" = "xyes"], [
 152   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 153   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 154 ])
 155
 156 # Checks for programs.
 157 AC_PROG_GREP
 158 AC_PROG_MAKE_SET
 159 AC_PROG_SED
 160 AC_PROG_MKDIR_P
 161 AC_PATH_PROG([report_fold], [fold])
 162 LT_INIT
 163
 164 # Check for objcopy, required by the base address statedump and dynamic linker tests
 165 AC_CHECK_TOOL([OBJCOPY], [objcopy])
 166 AS_IF([test "x$OBJCOPY" = "x"],
 167         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 168 )
 169 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != "x"])
 170
 171 # check for pgrep
 172 AC_PATH_PROG([PGREP], [pgrep])
 173 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "x"])
 174
 175 AC_PATH_PROG([SHELLCHECK], [shellcheck])
 176 AM_CONDITIONAL([HAVE_SHELLCHECK], [test "x$SHELLCHECK" != "x"])
 177
 178 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 179 # is not distributed in tarballs
 180 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 181 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 182
 183 # check for bison
 184 AC_PROG_YACC
 185 BISON=$YACC
 186 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 187
 188 AS_IF([test "x$have_bison" != "xyes"], [
 189   AS_IF([test "x$in_git_repo" = "xyes"], [
 190     AC_MSG_FAILURE([
 191 Bison >= 2.4 is required when building from the Git repository. You can
 192 set the YACC variable to override automatic detection.
 193     ])
 194   ], [
 195     AC_MSG_WARN([
 196 Missing Bison >= 2.4. Note that the parser files are already built in
 197 this distribution tarball, so Bison is only needed if you intend to
 198 modify their sources. You can set the YACC variable to override automatic
 199 detection.
 200     ])
 201   ])
 202 ])
 203 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 204
 205 # check for flex
 206 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 207 # problem since the argument is silently ignored by older versions.
 208 AC_PROG_LEX([noyywrap])
 209 FLEX=$LEX
 210 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 211
 212 AS_IF([test "x$have_flex" != "xyes"], [
 213   AS_IF([test "x$in_git_repo" = "xyes"], [
 214     AC_MSG_FAILURE([
 215 Flex >= 2.5.35 is required when building from the Git repository. You can
 216 set the LEX variable to override automatic detection.
 217     ])
 218   ], [
 219     AC_MSG_WARN([
 220 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 221 this distribution tarball, so Flex is only needed if you intend to
 222 modify their sources. You can set the LEX variable to override automatic
 223 detection.
 224     ])
 225   ])
 226 ])
 227 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 228
 229
 230
 231 # Check if linker has the -no-pie option.
 232 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 233 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 234
 235 AX_LIB_SOCKET_NSL
 236
 237 LT_NO_UNDEFINED=""
 238 AS_CASE([$host_os],
 239   [cygwin*],
 240     [
 241       LT_NO_UNDEFINED="-no-undefined"
 242     ],
 243   [cygwin*|darwin*|mingw*|solaris*],
 244     [
 245       # On platforms where we only support the relayd, disable the other binaries by default
 246       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 247       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 248       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 249       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 250       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 251       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 252     ]
 253 )
 254
 255 AC_SUBST(LT_NO_UNDEFINED)
 256
 257 # Compute minor/major/patchlevel version numbers
 258 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 259 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 260 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 261
 262 AC_SUBST([MAJOR_VERSION], [$major_version])
 263 AC_SUBST([MINOR_VERSION], [$minor_version])
 264 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 265 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 266 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 267 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 268
 269 version_name="O-Beer"
 270 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 271 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 272
 273 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 274 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 275
 276 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 277 AC_ARG_ENABLE(libtool-linkdep-fixup,
 278         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 279                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 280         libtool_fixup=$enableval,
 281         libtool_fixup=yes)
 282
 283 AS_IF([test "x$libtool_fixup" = "xyes"],
 284             [
 285             libtool_m4="$srcdir/m4/libtool.m4"
 286             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 287             AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4])
 288             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 289             AS_IF([test $libtool_flag_pattern_count -ne 0],
 290             [
 291                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 292                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 293                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 294                   ],
 295                   [
 296                   AC_MSG_RESULT([none])
 297                   ])
 298             ])
 299
 300 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 301
 302 AC_CHECK_HEADERS([ \
 303         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 304         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 305         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 306         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 307         sys/mount.h sys/param.h sys/time.h elf.h sys/random.h sys/syscall.h
 308 ])
 309
 310 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 311
 312 # Basic functions check
 313 AC_CHECK_FUNCS([ \
 314         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 315         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 316         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 317         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 318         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 319         sched_getcpu sysconf sync_file_range getrandom posix_fadvise \
 320         arc4random flock
 321 ])
 322
 323 # Check for pthread_setname_np and pthread_getname_np
 324 LTTNG_PTHREAD_SETNAME_NP
 325 LTTNG_PTHREAD_GETNAME_NP
 326
 327 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 328 # add -lrt to LIBS
 329 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 330
 331 # Checks for dl.
 332 AC_CHECK_LIB([dl], [dlopen], [
 333         have_libdl=yes
 334         libdl_name=dl
 335         DL_LIBS="-ldl"
 336 ], [
 337         # libdl not found, check for dlopen in libc.
 338         AC_CHECK_LIB([c], [dlopen], [
 339                 have_libc_dl=yes
 340                 libdl_name=c
 341                 DL_LIBS="-lc"
 342         ], [
 343                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 344         ])
 345 ])
 346 AC_SUBST(DL_LIBS)
 347
 348 # Check if libdl has dlmopen support.
 349 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 350 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 351         AC_DEFINE([HAVE_DLMOPEN], [1])
 352         HAVE_DLMOPEN=1
 353 ], [
 354         HAVE_DLMOPEN=0
 355 ])
 356 AC_SUBST(HAVE_DLMOPEN)
 357
 358 # Babeltrace viewer check
 359 AC_ARG_WITH([babeltrace-bin],
 360         AS_HELP_STRING([--with-babeltrace-bin],
 361         [Location of the babeltrace viewer executable (including the filename)]),
 362         [BABELTRACE_BIN="$withval"],
 363         [BABELTRACE_BIN=''])
 364 AC_SUBST([BABELTRACE_BIN])
 365
 366 AC_ARG_WITH([babeltrace2-bin],
 367         AS_HELP_STRING([--with-babeltrace2-bin],
 368         [Location of the babeltrace2 viewer executable (including the filename)]),
 369         [BABELTRACE2_BIN="$withval"],
 370         [BABELTRACE2_BIN=''])
 371 AC_SUBST([BABELTRACE2_BIN])
 372
 373 AC_ARG_WITH([consumerd32-bin],
 374         AS_HELP_STRING([--with-consumerd32-bin],
 375         [Location of the 32-bit consumerd executable (including the filename)]),
 376         [CONSUMERD32_BIN="$withval"],
 377         [CONSUMERD32_BIN=''])
 378 AC_SUBST([CONSUMERD32_BIN])
 379
 380 AC_ARG_WITH([consumerd64-bin],
 381         AS_HELP_STRING([--with-consumerd64-bin],
 382         [Location of the 64-bit consumerd executable (including the filename)]),
 383         [CONSUMERD64_BIN="$withval"],
 384         [CONSUMERD64_BIN=''])
 385 AC_SUBST([CONSUMERD64_BIN])
 386
 387 AC_ARG_WITH([consumerd32-libdir],
 388         AS_HELP_STRING([--with-consumerd32-libdir],
 389         [Directory containing the 32-bit consumerd libraries]),
 390         [CONSUMERD32_LIBDIR="$withval"],
 391         [CONSUMERD32_LIBDIR=''])
 392 AC_SUBST([CONSUMERD32_LIBDIR])
 393
 394 AC_ARG_WITH([consumerd64-libdir],
 395         AS_HELP_STRING([--with-consumerd64-libdir],
 396         [Directory containing the 64-bit consumerd libraries]),
 397         [CONSUMERD64_LIBDIR="$withval"],
 398         [CONSUMERD64_LIBDIR=''])
 399 AC_SUBST([CONSUMERD64_LIBDIR])
 400
 401 AC_ARG_WITH([sessiond-bin],
 402         AS_HELP_STRING([--with-sessiond-bin],
 403         [Location of the sessiond executable (including the filename)]),
 404         [SESSIOND_BIN="$withval"],
 405         [SESSIOND_BIN=''])
 406 AC_SUBST([SESSIOND_BIN])
 407
 408 AC_ARG_WITH([lttng-system-rundir],
 409         AS_HELP_STRING([--with-lttng-system-rundir],
 410         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 411         [LTTNG_SYSTEM_RUNDIR="$withval"],
 412         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 413 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 414
 415 AC_ARG_ENABLE([test-java-agent-jul],
 416         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 417         [test_java_agent_jul=$enableval],
 418         [test_java_agent_jul=no]
 419 )
 420
 421 AC_ARG_ENABLE([test-java-agent-log4j],
 422         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])],
 423         [test_java_agent_log4j=$enableval],
 424         [test_java_agent_log4j=no]
 425 )
 426
 427 AC_ARG_ENABLE([test-java-agent-log4j2],
 428         [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])],
 429         [test_java_agent_log4j2=$enableval],
 430         [test_java_agent_log4j2=no]
 431 )
 432
 433 AC_ARG_ENABLE([test-java-agent-all],
 434         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 435         [test_java_agent_jul=$enableval
 436          test_java_agent_log4j=$enableval
 437          test_java_agent_log4j2=$enableval],
 438         [:]
 439 )
 440
 441 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 442 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 443 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 444 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 445 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 446 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 447 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 448 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 449
 450 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 451         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 452         $1="$2"
 453         AC_SUBST([$1])
 454 ])
 455
 456 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 457         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 458         $1="$2"
 459         AC_SUBST([$1])
 460 ])
 461
 462 # Default values
 463 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 464 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 465 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 466 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 467 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 468 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 469 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 470 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 471 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 472 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 473 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 474 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 475 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 476 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 477 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 478 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 479 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 480 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 481 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 482 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 483 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 484 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 485 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 486 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 487 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 488 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 489 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 490 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 491 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 492 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 493 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 494 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 495 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 496 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 497 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 498 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 499 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 500 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 501 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 502 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 503 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 504 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 505 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 506 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 507 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 508 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 509 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 510 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 511 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 512 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 513
 514 # Command short descriptions
 515 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 516 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 517 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 518 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 519 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 520 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 521 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 522 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 523 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 524 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 525 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 526 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 527 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 528 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 529 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 530 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 531 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 532 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 533 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 534 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 535 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 536 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 537 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 538 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 539 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 540 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 541 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 542 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 543
 544 if test "x$prefix" = "xNONE"; then
 545         prefix=$ac_default_prefix
 546 fi
 547 CONFDIR=`eval echo $sysconfdir`
 548 AC_SUBST(CONFDIR)
 549 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 550
 551 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 552
 553 # Check libpopt
 554 PKG_CHECK_MODULES([POPT], [popt],
 555   [
 556     dnl PKG_CHECK_MODULES defines POPT_LIBS
 557   ],
 558   [
 559     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 560     AC_MSG_WARN([Finding libpopt without pkg-config.])
 561     AC_CHECK_LIB([popt],
 562       [poptGetContext],
 563       [POPT_LIBS="-lpopt"],
 564       [
 565         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 566       ]
 567     )
 568   ]
 569 )
 570 AC_SUBST(POPT_LIBS)
 571
 572 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 573
 574 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 575
 576 # URCU library version needed or newer
 577 PKG_CHECK_MODULES([URCU], [liburcu >= 0.14])
 578 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.14])
 579 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 580
 581 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 582 # it can be explicitly disabled with --without-kmod
 583 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 584 AC_ARG_WITH([kmod],
 585   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 586   [],
 587   [with_kmod=check]
 588 )
 589
 590 AS_IF([test "x$with_kmod" != "xno"],
 591   [
 592     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 593       [
 594         AC_DEFINE([HAVE_KMOD], [1])
 595         KMOD_LIBS="-lkmod"
 596       ],
 597       [
 598         if test "x$with_kmod" != xcheck; then
 599           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 600         else
 601           with_kmod=no
 602         fi
 603       ]
 604     )
 605   ]
 606 )
 607 AC_SUBST(KMOD_LIBS)
 608
 609 # Check for liblttng-ust-ctl, fail if it's not found,
 610 # it can be explicitly disabled with --without-lttng-ust
 611 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 612 AC_ARG_WITH([lttng-ust],
 613   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 614   [],
 615   [with_lttng_ust=yes]
 616 )
 617
 618 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 619   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 620
 621   # Check for liblttng-ust
 622   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 623
 624   # Check for liblttng-ust-ctl
 625   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 626
 627   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 628 ])
 629
 630 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 631
 632
 633 # Check for fmemopen
 634 AC_CHECK_LIB([c], [fmemopen],
 635 [
 636         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 637 ]
 638 )
 639
 640 # check for libpfm
 641 AC_CHECK_LIB([pfm], [pfm_initialize],
 642              [
 643               have_libpfm=yes
 644               ])
 645 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 646
 647 # For Python
 648 # SWIG version needed or newer:
 649 swig_version=2.0.0
 650
 651 AC_ARG_ENABLE([python-bindings],
 652               [AS_HELP_STRING([--enable-python-bindings],
 653                               [compile Python bindings])],
 654               [enable_python_binding=$enableval], [enable_python_binding=no])
 655
 656 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 657
 658 if test "x$enable_python_binding" = xyes; then
 659   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 660   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 661   AM_PATH_PYTHON([3.4])
 662
 663   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 664   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 665   AS_IF([test -z "$PYTHON_INCLUDE"], [
 666     AS_IF([test -z "$PYTHON_CONFIG"], [
 667       AC_PATH_PROGS([PYTHON_CONFIG],
 668                     [python$PYTHON_VERSION-config python-config],
 669                     [],
 670                     [`dirname $PYTHON`])
 671       AS_IF([test "x$PYTHON_CONFIG" = "x"], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 672     ])
 673     AC_MSG_CHECKING([python include flags])
 674     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 675     AC_MSG_RESULT([$PYTHON_INCLUDE])
 676   ])
 677
 678 else
 679     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 680 [if you want Python bindings.])
 681
 682 fi
 683
 684 # Epoll check. If not present, the build will fallback on poll() API
 685 AX_HAVE_EPOLL(
 686         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 687         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 688 )
 689 AX_CONFIG_FEATURE(
 690         [epoll], [This platform supports epoll(7)],
 691         [HAVE_EPOLL], [This platform supports epoll(7).]
 692 )
 693
 694 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 695         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 696         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 697 )
 698 AX_CONFIG_FEATURE(
 699         [dirfd], [Use directory file descriptors],
 700         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 701 )
 702
 703 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 704 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 705 AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"])
 706
 707 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then
 708         AX_JAVA_OPTIONS
 709         AX_PROG_JAVAC
 710         AX_PROG_JAVA
 711         AX_PROG_JAR
 712
 713         AX_CHECK_CLASSPATH
 714
 715         # Check for Java UST agent common class first
 716         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 717         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 718                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 719         fi
 720
 721         if test "x$test_java_agent_jul" = "xyes"; then
 722                 # Check for JUL agent class
 723                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 724                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 725                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 726                 fi
 727         fi
 728
 729         if test "x$test_java_agent_log4j" = "xyes"; then
 730                 # Check for Log4j agent class
 731                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 732                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 733                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 734                 fi
 735
 736                 # Check for Log4j class
 737                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 738                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 739                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 740                 fi
 741         fi
 742
 743         if test "x$test_java_agent_log4j2" = "xyes"; then
 744                 # Check for Log4j2 agent class
 745                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender)
 746                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then
 747                         AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"])
 748                 fi
 749
 750                 # Check for Log4j 2.x classes
 751                 AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 752                 AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 753                 if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then
 754                         AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"])
 755                 fi
 756         fi
 757 fi
 758
 759 # API documentation using Doxygen
 760 AC_ARG_ENABLE([api-doc], [
 761         AS_HELP_STRING([--enable-api-doc], [build HTML API documentation])
 762 ], [api_doc=$enableval], [api_doc=no])
 763
 764 AS_IF([test "x$api_doc" = xyes], [
 765         DX_DOXYGEN_FEATURE(ON)
 766         DX_DOT_FEATURE(OFF)
 767         DX_HTML_FEATURE(ON)
 768         DX_CHM_FEATURE(OFF)
 769         DX_CHI_FEATURE(OFF)
 770         DX_MAN_FEATURE(OFF)
 771         DX_RTF_FEATURE(OFF)
 772         DX_XML_FEATURE(OFF)
 773         DX_PDF_FEATURE(OFF)
 774         DX_PS_FEATURE(OFF)
 775         DX_INIT_DOXYGEN(["LTTng control library"], [$(builddir)/Doxyfile], [output])
 776
 777         AS_IF([test -z "$DX_DOXYGEN"], [
 778                 AC_MSG_ERROR([You need Doxygen to build the liblttng-ctl API documentation])
 779         ])
 780 ])
 781
 782 AM_CONDITIONAL([API_DOC], [test "x$api_doc" = xyes])
 783
 784 # enable building man pages (user's intention)
 785 AC_ARG_ENABLE(
 786         man-pages,
 787         AS_HELP_STRING(
 788                 [--disable-man-pages],
 789                 [Do not build and install man pages (already built in a distributed tarball)]
 790         ),
 791         [man_pages_opt=$enableval],
 792         [man_pages_opt=yes]
 793 )
 794
 795 # check for asciidoc and xmlto if we enabled building the man pages
 796 have_asciidoc_xmlto=no
 797 warn_prebuilt_man_pages=no
 798
 799 AS_IF([test "x$man_pages_opt" = "xyes"], [
 800         AC_PATH_PROG([ASCIIDOC], [asciidoc])
 801         AC_PATH_PROG([XMLTO], [xmlto])
 802
 803         AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 804                 AS_IF([test "x$in_git_repo" = "xyes"], [
 805                         # this is an error because we're in the Git repo, which
 806                         # means the man pages are not already generated for us,
 807                         # thus asciidoc/xmlto are required because we were asked
 808                         # to build the man pages
 809                         AC_MSG_ERROR([
 810 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 811 --disable-man-pages to disable building the man pages, in which case
 812 they will not be installed.
 813                         ])
 814                 ], [
 815                         # only warn here: since we're in the tarball, the man
 816                         # pages should already be generated at this point, thus
 817                         # asciidoc/xmlto are not strictly required
 818                         warn_prebuilt_man_pages=yes
 819                 ])
 820         ], [
 821                 have_asciidoc_xmlto=yes
 822         ])
 823 ])
 824
 825 # export man page build condition: build the man pages if the user
 826 # asked for it, and if the tools are available
 827 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 828 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 829
 830 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 831
 832 # embedded --help message
 833 AC_ARG_ENABLE(
 834         [embedded-help],
 835         AS_HELP_STRING(
 836                 [--enable-embedded-help],
 837                 [Embed the --help messages in the executable files]
 838         ),
 839         [embedded_help=$enableval],
 840         [embedded_help=no]
 841 )
 842 AS_IF([test "x$embedded_help" = "xyes"], [
 843         AS_IF([test "x$man_pages_opt" = "xno"], [
 844                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 845         ])
 846         AC_PATH_PROG([man_prog_path], [man])
 847         AS_IF([test "x$man_prog_path" = "x"], [
 848                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 849         ])
 850         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 851         AC_SUBST([MANPROG], [$man_prog_path])
 852 ])
 853 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 854
 855 # Python agent test
 856 UST_PYTHON_AGENT="lttngust"
 857
 858 AC_ARG_ENABLE(test-python2-agent,
 859         AS_HELP_STRING([--enable-test-python2-agent],
 860                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 861         ),[:],[test_python2_agent_autodetect=yes]
 862 )
 863
 864 AC_ARG_ENABLE(test-python3-agent,
 865         AS_HELP_STRING([--enable-test-python3-agent],
 866                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 867         ),[:],[test_python3_agent_autodetect=yes]
 868 )
 869
 870 AC_ARG_ENABLE(test-python-agent-all,
 871         AS_HELP_STRING([--enable-test-python-agent-all],
 872                 [enable test for all python{2/3} agent.]
 873         ),
 874 )
 875
 876 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 877        unset test_python2_agent_autodetect
 878        unset test_python3_agent_autodetect
 879 ])
 880
 881 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 882        enable_test_python2_agent=yes
 883        enable_test_python3_agent=yes
 884 ])
 885
 886 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 887        enable_test_python2_agent=no
 888        enable_test_python3_agent=no
 889 ])
 890
 891
 892 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 893         AS_IF([test -z "$PYTHON2"], [
 894                         PYTHON2=python2
 895                 ], [
 896                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 897         ])
 898
 899         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 900         AS_IF([test -z "$PYTHON2_BIN"], [
 901                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 902                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 903                 ])
 904         ], [
 905                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 906                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 907                         PYTHON2_AGENT=$PYTHON2_BIN
 908                         AC_MSG_RESULT([yes])
 909                         RUN_PYTHON_AGENT_TEST=yes
 910                 ], [
 911                         AC_MSG_RESULT([no])
 912                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 913                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 914                         ])
 915                 ])
 916
 917         ])
 918
 919 ])
 920
 921 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 922         AS_IF([test -z "$PYTHON3"], [
 923                 PYTHON3=python3
 924         ], [
 925                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 926         ])
 927
 928         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 929         AS_IF([test -z "$PYTHON3_BIN"], [
 930                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 931                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 932                 ])
 933         ], [
 934                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 935                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 936                         PYTHON3_AGENT=$PYTHON3_BIN
 937                         AC_MSG_RESULT([yes])
 938                         RUN_PYTHON_AGENT_TEST=yes
 939                 ], [
 940                         AC_MSG_RESULT([no])
 941                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 942                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 943                         ])
 944                 ])
 945
 946         ])
 947 ])
 948 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 949 AC_SUBST([PYTHON2_AGENT])
 950 AC_SUBST([PYTHON3_AGENT])
 951
 952 AC_ARG_ENABLE([test-sdt-uprobe],
 953   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 954   [test_sdt_uprobe="$enableval"],
 955   [test_sdt_uprobe=autodetect]
 956 )
 957
 958 AS_IF([test "$test_sdt_uprobe" != "no"], [
 959   LTTNG_CHECK_SDT_WORKS
 960   AC_PATH_PROG([DTRACE], [dtrace])
 961 ])
 962
 963 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 964   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 965     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 966   ])
 967   AS_IF([test "x$DTRACE" = "x"], [
 968     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 969   ])
 970 ])
 971
 972 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 973   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 974     AS_IF([test "x$DTRACE" != "x"], [
 975       test_sdt_uprobe=yes
 976     ])
 977   ])
 978 ])
 979
 980 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 981
 982 AC_ARG_ENABLE(
 983         [precious-tests],
 984         AS_HELP_STRING(
 985                 [--disable-precious-tests],
 986                 [Delete log files for interrupted tests]
 987         ),
 988         [precious_tests=$enableval],
 989         [precious_tests=yes]
 990 )
 991
 992 AM_CONDITIONAL([PRECIOUS_TESTS], [test x$precious_tests = xyes])
 993
 994 AC_ARG_ENABLE([lib-lttng-ctl], AS_HELP_STRING([--disable-lib-lttng-ctl],
 995         [Disable the build of liblttng-ctl (only possible if no binaries that depend on it are built)]))
 996
 997 # Arguments for binaries build exclusion
 998 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 999 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
1000               [Disable the build of lttng-consumerd binaries]))
1001 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
1002 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
1003               [Disable the build of lttng-relayd binaries]))
1004 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
1005               [Disable the build of lttng-sessiond binaries]))
1006 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
1007               [Disable the build of the extra components]))
1008
1009
1010 build_lib_consumer=no
1011 build_lib_health=no
1012 build_lib_index=no
1013 build_lib_kernel_consumer=no
1014 build_lib_kernel_ctl=no
1015 build_lib_lttng_ctl=no
1016 build_lib_relayd=no
1017 build_lib_sessiond_comm=no
1018 build_lib_testpoint=no
1019 build_lib_ust_consumer=no
1020
1021 # There is an overlap for enabled dependencies, but this makes everything
1022 # simpler. libcommon and libconfig are always compiled so they are not repeated
1023 # here.
1024
1025 # Enable binary dependencies.
1026 AS_IF([test x$enable_bin_lttng != xno],
1027       [
1028        build_lib_lttng_ctl=yes
1029       ]
1030 )
1031
1032 AS_IF([test x$enable_bin_lttng_consumerd != xno],
1033       [
1034        build_lib_consumer=yes
1035        build_lib_sessiond_comm=yes
1036        build_lib_index=yes
1037        build_lib_health=yes
1038        build_lib_testpoint=yes
1039       ]
1040 )
1041
1042 AS_IF([test x$enable_bin_lttng_crash != xno],
1043       # Do nothing since libconfig and libcommon are built by default.
1044       []
1045 )
1046
1047 AS_IF([test x$enable_bin_lttng_relayd != xno],
1048       [
1049        build_lib_sessiond_comm=yes
1050        build_lib_index=yes
1051        build_lib_health=yes
1052        build_lib_testpoint=yes
1053       ]
1054 )
1055 AS_IF([test x$enable_bin_lttng_sessiond != xno],
1056       [
1057        build_lib_lttng_ctl=yes
1058        build_lib_sessiond_comm=yes
1059        build_lib_kernel_ctl=yes
1060        build_lib_relayd=yes
1061        build_lib_testpoint=yes
1062        build_lib_health=yes
1063       ]
1064 )
1065
1066 # Libraries dependencies enabling
1067 # If we want to build liblttng-ctl
1068 AS_IF([test x$enable_lib_lttng_ctl != xno],
1069       [
1070        build_lib_lttng_ctl=yes
1071       ]
1072 )
1073 # If we need to build liblttng-ctl because a binary depends on it
1074 AS_IF([test x$build_lib_lttng_ctl = xyes],
1075       [
1076        build_lib_sessiond_comm=yes
1077       ]
1078 )
1079 # Fail if we didn't want to build liblttng-ctl but need to build it anyway
1080 AS_IF([test "x$build_lib_lttng_ctl" = "xyes" -a "x$enable_lib_lttng_ctl" = "xno"],[
1081         AC_MSG_FAILURE(
1082                 [liblttng-ctl must be built, because at least one binary that depends on it is enabled])
1083 ])
1084
1085 AS_IF([test x$build_lib_consumer = xyes],
1086       [
1087        build_lib_sessiond_comm=yes
1088        build_lib_kernel_consumer=yes
1089        build_lib_relayd=yes
1090        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
1091       ]
1092 )
1093
1094 AS_IF([test x$build_lib_kernel_consumer = xyes],
1095       [
1096        build_lib_kernel_ctl=yes
1097        build_lib_relayd=yes
1098       ]
1099 )
1100
1101 AS_IF([test x$build_lib_relayd = xyes],
1102       [
1103        build_lib_sessiond_comm=yes
1104       ]
1105 )
1106
1107 # Find arch type
1108 AS_CASE([$host_cpu],
1109         [k1om], [ARCHTYPE="x86"],
1110         [i386], [ARCHTYPE="x86"],
1111         [i486], [ARCHTYPE="x86"],
1112         [i586], [ARCHTYPE="x86"],
1113         [i686], [ARCHTYPE="x86"],
1114         [amd64], [ARCHTYPE="x86"],
1115         [x86_64], [ARCHTYPE="x86"],
1116         [powerpc], [ARCHTYPE="ppc"],
1117         [ppc64], [ARCHTYPE="ppc"],
1118         [powerpc64], [ARCHTYPE="ppc"],
1119         [powerpc64le], [ARCHTYPE="ppc"],
1120         [ppc], [ARCHTYPE="ppc"],
1121         [s390], [ARCHTYPE="s390"],
1122         [s390x], [ARCHTYPE="s390"],
1123         [sparc], [ARCHTYPE="sparc64"],
1124         [sparc64], [ARCHTYPE="sparc64"],
1125         [alpha*], [ARCHTYPE="alpha"],
1126         [ia64], [ARCHTYPE="ia64"],
1127         [arm*], [ARCHTYPE="arm"],
1128         [aarch64*], [ARCHTYPE="aarch64"],
1129         [mips*], [ARCHTYPE="mips"],
1130         [nios2*], [ARCHTYPE="nios2"],
1131         [tile*], [ARCHTYPE="tile"],
1132         [hppa*], [ARCHTYPE="hppa"],
1133         [m68k], [ARCHTYPE="m68k"],
1134         [riscv*], [ARCHTYPE="riscv"],
1135         [ARCHTYPE="unknown"]
1136 )
1137
1138 AC_SUBST(ARCHTYPE)
1139
1140 AS_CASE([$host_os],
1141         [linux*], [OSTYPE="linux"],
1142         [freebsd*], [OSTYPE="freebsd"],
1143         [solaris*], [OSTYPE="solaris"],
1144         [cygwin*], [OSTYPE="cygwin"],
1145         [mingw*], [OSTYPE="mingw"],
1146         [OSTYPE="unknown"]
1147 )
1148 AC_SUBST(OSTYPE)
1149 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1150
1151
1152
1153 # Userspace callstack capture is only supported by the Linux kernel on x86.
1154 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1155 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1156         have_modules_userspace_callstack_context=yes
1157         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1158 ])
1159 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1160
1161 # Export binaries build conditions.
1162 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1163 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1164 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1165 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1166 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1167
1168 # Export the tests and extras build conditions.
1169 AS_IF([\
1170 test "x$enable_bin_lttng" != "xno" && \
1171 test "x$enable_bin_lttng_consumerd" != "xno" && \
1172 test "x$enable_bin_lttng_crash" != "xno" && \
1173 test "x$enable_bin_lttng_relayd" != "xno" && \
1174 test "x$enable_bin_lttng_sessiond" != "xno"],
1175 [build_tests=yes],
1176 [build_tests=no]
1177 )
1178
1179 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1180
1181 AS_IF([test "x$build_tests" = "xyes"],
1182   [
1183     PKG_CHECK_MODULES([babeltrace2], [babeltrace2])
1184   ]
1185 )
1186
1187 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1188
1189 # Export libraries build conditions.
1190 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1191 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1192 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1193 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1194 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1195 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1196 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1197 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1198 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1199 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1200
1201 AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1202 AC_SUBST(AM_CFLAGS)
1203
1204 AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1205 AC_SUBST(AM_CXXFLAGS)
1206
1207 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1208 AM_LDFLAGS=""
1209 AC_SUBST(AM_LDFLAGS)
1210
1211 # The order in which the include folders are searched is important.
1212 # The top_builddir should always be searched first in the event that a build
1213 # time generated file is included. An example of this is the "version.i" file.
1214 # In a scenario where lttng-tools is built from a distribution tarball and in a
1215 # out-of-tree manner, the generated "version.i" has priority on the one from
1216 # the source (distribution tarball) and must be found first.
1217 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1218 AC_SUBST(AM_CPPFLAGS)
1219
1220 lttngincludedir="${includedir}/lttng"
1221 AC_SUBST(lttngincludedir)
1222
1223 lttngactionincludedir="${includedir}/lttng/action"
1224 AC_SUBST(lttngactionincludedir)
1225
1226 lttngconditionincludedir="${includedir}/lttng/condition"
1227 AC_SUBST(lttngconditionincludedir)
1228
1229 lttngnotificationincludedir="${includedir}/lttng/notification"
1230 AC_SUBST(lttngnotificationincludedir)
1231
1232 lttngtriggerincludedir="${includedir}/lttng/trigger"
1233 AC_SUBST(lttngtriggerincludedir)
1234
1235 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1236 AC_SUBST(lttngeventruleincludedir)
1237
1238 lttnglibexecdir="${libdir}/lttng/libexec"
1239 AC_SUBST(lttnglibexecdir)
1240
1241 AC_CONFIG_FILES([
1242         Makefile
1243         doc/Makefile
1244         doc/api/Makefile
1245         doc/api/liblttng-ctl/Doxyfile
1246         doc/api/liblttng-ctl/Makefile
1247         doc/examples/Makefile
1248         doc/examples/rotation/Makefile
1249         doc/examples/trigger-condition-event-matches/Makefile
1250         doc/man/Makefile
1251         doc/man/asciidoc-attrs.conf
1252         include/Makefile
1253         extras/Makefile
1254         extras/bindings/Makefile
1255         extras/bindings/swig/Makefile
1256         extras/bindings/swig/python/Makefile
1257         extras/core-handler/Makefile
1258         src/Makefile
1259         src/common/Makefile
1260         src/lib/Makefile
1261         src/lib/lttng-ctl/Makefile
1262         src/lib/lttng-ctl/lttng-ctl.pc
1263         src/bin/Makefile
1264         src/bin/lttng-consumerd/Makefile
1265         src/bin/lttng-sessiond/Makefile
1266         src/bin/lttng-relayd/Makefile
1267         src/bin/lttng/Makefile
1268         src/bin/lttng-crash/Makefile
1269         src/vendor/Makefile
1270         src/vendor/msgpack/Makefile
1271         src/vendor/fmt/Makefile
1272         tests/Makefile
1273         tests/destructive/Makefile
1274         tests/meta/Makefile
1275         tests/regression/Makefile
1276         tests/regression/kernel/Makefile
1277         tests/regression/tools/Makefile
1278         tests/regression/tools/streaming/Makefile
1279         tests/regression/tools/filtering/Makefile
1280         tests/regression/tools/health/Makefile
1281         tests/regression/tools/tracefile-limits/Makefile
1282         tests/regression/tools/snapshots/Makefile
1283         tests/regression/tools/lttng-ctl/Makefile
1284         tests/regression/tools/live/Makefile
1285         tests/regression/tools/exclusion/Makefile
1286         tests/regression/tools/save-load/Makefile
1287         tests/regression/tools/save-load/configuration/Makefile
1288         tests/regression/tools/mi/Makefile
1289         tests/regression/tools/wildcard/Makefile
1290         tests/regression/tools/channel/Makefile
1291         tests/regression/tools/crash/Makefile
1292         tests/regression/tools/regen-metadata/Makefile
1293         tests/regression/tools/regen-statedump/Makefile
1294         tests/regression/tools/notification/Makefile
1295         tests/regression/tools/rotation/Makefile
1296         tests/regression/tools/base-path/Makefile
1297         tests/regression/tools/metadata/Makefile
1298         tests/regression/tools/tracker/Makefile
1299         tests/regression/tools/working-directory/Makefile
1300         tests/regression/tools/relayd-grouping/Makefile
1301         tests/regression/tools/clear/Makefile
1302         tests/regression/tools/trigger/Makefile
1303         tests/regression/tools/trigger/rate-policy/Makefile
1304         tests/regression/tools/trigger/start-stop/Makefile
1305         tests/regression/tools/trigger/utils/Makefile
1306         tests/regression/tools/trigger/name/Makefile
1307         tests/regression/tools/trigger/hidden/Makefile
1308         tests/regression/tools/context/Makefile
1309         tests/regression/tools/client/Makefile
1310         tests/regression/ust/Makefile
1311         tests/regression/ust/nprocesses/Makefile
1312         tests/regression/ust/high-throughput/Makefile
1313         tests/regression/ust/low-throughput/Makefile
1314         tests/regression/ust/before-after/Makefile
1315         tests/regression/ust/buffers-pid/Makefile
1316         tests/regression/ust/periodical-metadata-flush/Makefile
1317         tests/regression/ust/multi-session/Makefile
1318         tests/regression/ust/multi-lib/Makefile
1319         tests/regression/ust/overlap/Makefile
1320         tests/regression/ust/overlap/demo/Makefile
1321         tests/regression/ust/linking/Makefile
1322         tests/regression/ust/daemon/Makefile
1323         tests/regression/ust/exit-fast/Makefile
1324         tests/regression/ust/fork/Makefile
1325         tests/regression/ust/libc-wrapper/Makefile
1326         tests/regression/ust/baddr-statedump/Makefile
1327         tests/regression/ust/ust-dl/Makefile
1328         tests/regression/ust/java-jul/Makefile
1329         tests/regression/ust/java-log4j/Makefile
1330         tests/regression/ust/java-log4j2/Makefile
1331         tests/regression/ust/getcpu-override/Makefile
1332         tests/regression/ust/clock-override/Makefile
1333         tests/regression/ust/type-declarations/Makefile
1334         tests/regression/ust/rotation-destroy-flush/Makefile
1335         tests/regression/ust/blocking/Makefile
1336         tests/regression/ust/namespaces/Makefile
1337         tests/regression/ust/ust-app-ctl-paths/Makefile
1338         tests/regression/ust/ust-constructor/Makefile
1339         tests/stress/Makefile
1340         tests/unit/Makefile
1341         tests/unit/ini_config/Makefile
1342         tests/perf/Makefile
1343         tests/utils/Makefile
1344         tests/utils/bt2_plugins/Makefile
1345         tests/utils/bt2_plugins/event_name/Makefile
1346         tests/utils/bt2_plugins/field_stats/Makefile
1347         tests/utils/lttngtest/Makefile
1348         tests/utils/tap/Makefile
1349         tests/utils/testapp/Makefile
1350         tests/utils/testapp/gen-data-pending/Makefile
1351         tests/utils/testapp/gen-ns-events/Makefile
1352         tests/utils/testapp/gen-kernel-test-events/Makefile
1353         tests/utils/testapp/gen-py-events/Makefile
1354         tests/utils/testapp/gen-ust-events/Makefile
1355         tests/utils/testapp/gen-ust-events-constructor/Makefile
1356         tests/utils/testapp/gen-ust-events-ns/Makefile
1357         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1358         tests/utils/testapp/gen-ust-nevents/Makefile
1359         tests/utils/testapp/gen-ust-nevents-str/Makefile
1360         tests/utils/testapp/gen-syscall-events/Makefile
1361         tests/utils/testapp/gen-ust-tracef/Makefile
1362         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1363         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1364         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1365         tests/utils/xml-utils/Makefile
1366 ])
1367
1368 # Inject variable into python test script.
1369 AC_CONFIG_FILES([tests/regression/tools/config-directory/test_config.py],[chmod +x tests/regression/tools/config-directory/test_config.py])
1370 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1371 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1372 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1373 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1374 AC_CONFIG_FILES([pre-inst-env],[chmod +x pre-inst-env])
1375
1376 AC_OUTPUT
1377
1378 #
1379 # Mini-report on what will be built.
1380 #
1381
1382 PPRINT_INIT
1383 PPRINT_SET_INDENT(1)
1384 PPRINT_SET_TS(38)
1385
1386 AS_ECHO
1387 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1388 AS_ECHO
1389
1390 AS_IF([test -n "$report_fold"], [
1391         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1392 ], [
1393         AS_ECHO("$version_description")
1394 ])
1395
1396 AS_ECHO
1397 PPRINT_SUBTITLE([Features])
1398
1399 # Target architecture we're building for.
1400 target_arch=$host_cpu
1401 [
1402 for f in $CFLAGS; do
1403         if test $f = "-m32"; then
1404                         target_arch="32-bit"
1405         elif test $f = "-m64"; then
1406                         target_arch="64-bit"
1407         fi
1408 done
1409 ]
1410 PPRINT_PROP_STRING([Target architecture], $target_arch)
1411
1412 # kmod enabled/disabled
1413 test "x$with_kmod" != "xno" && value=1 || value=0
1414 PPRINT_PROP_BOOL([libkmod support], $value)
1415
1416 # LTTng-UST enabled/disabled
1417 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1418 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1419
1420 AS_ECHO
1421 PPRINT_SUBTITLE([Libraries])
1422
1423 # liblttng-ctl enabled/disabled
1424 test x$build_lib_lttng_ctl != xno && value=1 || value=0
1425 PPRINT_PROP_BOOL([liblttng-ctl], $value)
1426
1427 AS_ECHO
1428 PPRINT_SUBTITLE([Binaries])
1429
1430 # List binaries to be built
1431 test x$enable_bin_lttng != xno && value=1 || value=0
1432 PPRINT_PROP_BOOL([lttng], $value)
1433
1434 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1435 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1436
1437 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1438 PPRINT_PROP_BOOL([lttng-crash], $value)
1439
1440 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1441 PPRINT_PROP_BOOL([lttng-relayd], $value)
1442
1443 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1444 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1445
1446 # Extras
1447 test x$enable_extras != xno && value=1 || value=0
1448 AS_ECHO
1449 PPRINT_SET_INDENT(0)
1450 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1451 PPRINT_SET_INDENT(1)
1452
1453 AS_ECHO
1454 PPRINT_SUBTITLE([Tests])
1455
1456 # Print clear message that tests won't be built
1457 AS_IF([test "x$build_tests" = "xno"],[
1458         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1459 ])
1460
1461 # LTTng UST Java agent JUL tests enabled/disabled
1462 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1463 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1464
1465 # LTTng UST Java agent Log4j 1.x tests enabled/disabled
1466 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1467 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value)
1468
1469 # LTTng UST Java agent Log4j 2.x tests enabled/disabled
1470 test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0
1471 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value)
1472
1473 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1474 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1475
1476 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1477 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1478
1479 # userspace-probe SDT instrumentation tests enabled/disabled
1480 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1481 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1482
1483 #Python binding enabled/disabled
1484 test "x$enable_python_binding" = xyes && value=1 || value=0
1485 AS_ECHO
1486 PPRINT_SET_INDENT(0)
1487 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1488
1489 # man pages build enabled/disabled
1490 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1491
1492 AS_IF([test "x$man_pages_opt" != "xno"], [
1493         AS_IF([test "x$in_git_repo" = "xyes"], [
1494                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1495         ], [
1496                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1497                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1498                 ], [
1499                         PPRINT_PROP_STRING([build_man_pages_msg],
1500                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1501                                 $PPRINT_COLOR_SUBTITLE)
1502                 ])
1503         ])
1504 ], [
1505         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1506 ])
1507
1508 m4_popdef([build_man_pages_msg])
1509
1510 test "x$embedded_help" = xyes && value=1 || value=0
1511 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1512
1513 test "x$api_doc" = xyes && value=1 || value=0
1514 PPRINT_PROP_BOOL([liblttng-ctl HTML API documentation], $value, $PPRINT_COLOR_SUBTITLE)
1515
1516 PPRINT_SET_INDENT(1)
1517
1518 report_bindir="`eval eval echo $bindir`"
1519 report_libdir="`eval eval echo $libdir`"
1520
1521 # Print the bindir and libdir this `make install' will install into.
1522 AS_ECHO
1523 PPRINT_SUBTITLE([Install directories])
1524 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1525 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1526
1527 AS_ECHO
1528 PPRINT_SUBTITLE([Search directories])
1529
1530 # If we build the sessiond, print the paths it will use
1531 AS_IF([test "$SESSIOND_BIN" = ""],[
1532         path="$report_bindir/lttng-sessiond"
1533 ],[
1534         path="$SESSIOND_BIN"
1535 ])
1536 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1537
1538 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1539         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1540 ],[
1541         path="$CONSUMERD32_BIN"
1542 ])
1543 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1544
1545 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1546         path="`eval eval echo $libdir`"
1547 ],[
1548         path="$CONSUMERD32_LIBDIR"
1549 ])
1550 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1551
1552 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1553         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1554 ],[
1555         path="$CONSUMERD64_BIN"
1556 ])
1557 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1558
1559 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1560         path="`eval eval echo $libdir`"
1561 ],[
1562         path="$CONSUMERD64_LIBDIR"
1563 ])
1564 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1565 PPRINT_SET_INDENT(0)
1566
1567 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1568         AS_ECHO
1569         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1570
1571 Note that the man pages are already built in this distribution tarball,
1572 therefore asciidoc and xmlto are only needed if you intend to modify
1573 their sources.
1574
1575 Also note that the installed man pages will contain the project's
1576 default command-line option and environment variable values.
1577
1578 Use --disable-man-pages to completely disable building and installing
1579 the man pages.])
1580 ])