configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_COMMON_LIST], [ dnl
  61   -Wall dnl
  62   -Wnull-dereference dnl
  63   -Wundef dnl
  64   -Wlogical-op dnl
  65   dnl We currently get this warning when building with Clang:
  66   dnl
  67   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  68   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  69   dnl            ^
  70   -Wno-incomplete-setjmp-declaration dnl
  71   -Wmissing-declarations dnl
  72   -Wshadow dnl
  73   -Wno-gnu-folding-constant dnl
  74   -Wsuggest-attribute=format dnl
  75   -Wformat=2 dnl
  76 ])
  77
  78 # Detect warning flags specific to the C compiler and append them to
  79 # WARN_CFLAGS.
  80 m4_define([WARN_FLAGS_C_LIST], [ dnl
  81   -Wdiscarded-qualifiers dnl
  82   -Wmissing-prototypes dnl
  83   -Wmissing-parameter-type dnl
  84 ])
  85
  86 # Pass -Werror as an extra flag during the test: this is needed to make the
  87 # -Wunknown-warning-option diagnostic fatal with clang.
  88 AC_LANG_PUSH([C])
  89 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_C_LIST], [WARN_CFLAGS], [-Werror])
  90 AC_LANG_POP([C])
  91
  92 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
  93 # written in such a way that it triggers warnings with the following warning
  94 # flags.  So they would always end up disabled if we put them there, because
  95 # the test program would not build.
  96 #
  97 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
  98 # Clang >= 3.3 (required by the project) and are only valid for C code.
  99 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 100
 101 # Disable 'strict aliasing' if the C compiler supports it.
 102 AC_LANG_PUSH([C])
 103 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 104 AC_LANG_POP([C])
 105
 106
 107 ##                     ##
 108 ## C++ compiler checks ##
 109 ##                     ##
 110
 111 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 112 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 113
 114 # Detect warning flags specific to the C++ compiler and append them to
 115 # WARN_CXXFLAGS.
 116 m4_define([WARN_FLAGS_CXX_LIST], [ dnl
 117   dnl GCC enables this with -Wall in C++, and that generates a
 118   dnl lot of warnings that have on average a low value to fix.
 119   -Wno-sign-compare dnl
 120 ])
 121
 122 # Pass -Werror as an extra flag during the test: this is needed to make the
 123 # -Wunknown-warning-option diagnostic fatal with clang.
 124 AC_LANG_PUSH([C++])
 125 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_CXX_LIST], [WARN_CXXFLAGS], [-Werror])
 126 AC_LANG_POP([C++])
 127
 128 # Disable 'strict aliasing' if the C++ compiler supports it.
 129 AC_LANG_PUSH([C++])
 130 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 131 AC_LANG_POP([C++])
 132
 133
 134 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 135 AC_ARG_ENABLE([Werror],[
 136   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 137 ])
 138
 139 AS_IF([test "x$enable_Werror" = "xyes"], [
 140   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 141   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 142 ])
 143
 144 # Checks for programs.
 145 AC_PROG_GREP
 146 AC_PROG_MAKE_SET
 147 AC_PROG_SED
 148 AC_PATH_PROG([report_fold], [fold])
 149 LT_INIT
 150
 151 # Check for objcopy, required by the base address statedump and dynamic linker tests
 152 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
 153 AS_IF([test "x$OBJCOPY" = "xno"],
 154         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 155 )
 156 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
 157
 158 # check for pgrep
 159 AC_PATH_PROG([PGREP], [pgrep], [no])
 160 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
 161
 162 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 163 # is not distributed in tarballs
 164 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 165 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 166
 167 # check for bison
 168 AC_PROG_YACC
 169 BISON=$YACC
 170 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 171
 172 AS_IF([test "x$have_bison" != "xyes"], [
 173   AS_IF([test "x$in_git_repo" = "xyes"], [
 174     AC_MSG_FAILURE([
 175 Bison >= 2.4 is required when building from the Git repository. You can
 176 set the YACC variable to override automatic detection.
 177     ])
 178   ], [
 179     AC_MSG_WARN([
 180 Missing Bison >= 2.4. Note that the parser files are already built in
 181 this distribution tarball, so Bison is only needed if you intend to
 182 modify their sources. You can set the YACC variable to override automatic
 183 detection.
 184     ])
 185   ])
 186 ])
 187 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 188
 189 # check for flex
 190 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 191 # problem since the argument is silently ignored by older versions.
 192 AC_PROG_LEX([noyywrap])
 193 FLEX=$LEX
 194 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 195
 196 AS_IF([test "x$have_flex" != "xyes"], [
 197   AS_IF([test "x$in_git_repo" = "xyes"], [
 198     AC_MSG_FAILURE([
 199 Flex >= 2.5.35 is required when building from the Git repository. You can
 200 set the LEX variable to override automatic detection.
 201     ])
 202   ], [
 203     AC_MSG_WARN([
 204 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 205 this distribution tarball, so Flex is only needed if you intend to
 206 modify their sources. You can set the LEX variable to override automatic
 207 detection.
 208     ])
 209   ])
 210 ])
 211 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 212
 213
 214
 215 # Check if linker has the -no-pie option.
 216 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 217 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 218
 219 AX_LIB_SOCKET_NSL
 220
 221 LT_NO_UNDEFINED=""
 222 AS_CASE([$host_os],
 223   [cygwin*],
 224     [
 225       LT_NO_UNDEFINED="-no-undefined"
 226     ],
 227   [cygwin*|darwin*|mingw*|solaris*],
 228     [
 229       # On platforms where we only support the relayd, disable the other binaries by default
 230       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 231       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 232       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 233       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 234       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 235       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 236     ]
 237 )
 238
 239 AC_SUBST(LT_NO_UNDEFINED)
 240
 241 # Compute minor/major/patchlevel version numbers
 242 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 243 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 244 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 245
 246 AC_SUBST([MAJOR_VERSION], [$major_version])
 247 AC_SUBST([MINOR_VERSION], [$minor_version])
 248 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 249 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 250 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 251 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 252
 253 version_name="O-Beer"
 254 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 255 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 256
 257 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 258 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 259
 260 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 261 AC_ARG_ENABLE(libtool-linkdep-fixup,
 262         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 263                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 264         libtool_fixup=$enableval,
 265         libtool_fixup=yes)
 266
 267 AS_IF([test "x$libtool_fixup" = "xyes"],
 268             [
 269             libtool_m4="$srcdir/m4/libtool.m4"
 270             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 271             AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4])
 272             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 273             AS_IF([test $libtool_flag_pattern_count -ne 0],
 274             [
 275                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 276                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 277                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 278                   ],
 279                   [
 280                   AC_MSG_RESULT([none])
 281                   ])
 282             ])
 283
 284 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 285
 286 AC_CHECK_HEADERS([ \
 287         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 288         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 289         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 290         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 291         sys/mount.h sys/param.h sys/time.h elf.h
 292 ])
 293
 294 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 295
 296 # Basic functions check
 297 AC_CHECK_FUNCS([ \
 298         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 299         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 300         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 301         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 302         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 303         sched_getcpu sysconf sync_file_range
 304 ])
 305
 306 # Check for pthread_setname_np and pthread_getname_np
 307 LTTNG_PTHREAD_SETNAME_NP
 308 LTTNG_PTHREAD_GETNAME_NP
 309
 310 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 311 # add -lrt to LIBS
 312 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 313
 314 # Checks for dl.
 315 AC_CHECK_LIB([dl], [dlopen], [
 316         have_libdl=yes
 317         libdl_name=dl
 318         DL_LIBS="-ldl"
 319 ], [
 320         # libdl not found, check for dlopen in libc.
 321         AC_CHECK_LIB([c], [dlopen], [
 322                 have_libc_dl=yes
 323                 libdl_name=c
 324                 DL_LIBS="-lc"
 325         ], [
 326                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 327         ])
 328 ])
 329 AC_SUBST(DL_LIBS)
 330
 331 # Check if libdl has dlmopen support.
 332 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 333 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 334         AC_DEFINE([HAVE_DLMOPEN], [1])
 335         HAVE_DLMOPEN=1
 336 ], [
 337         HAVE_DLMOPEN=0
 338 ])
 339 AC_SUBST(HAVE_DLMOPEN)
 340
 341 # Babeltrace viewer check
 342 AC_ARG_WITH([babeltrace-bin],
 343         AS_HELP_STRING([--with-babeltrace-bin],
 344         [Location of the babeltrace viewer executable (including the filename)]),
 345         [BABELTRACE_BIN="$withval"],
 346         [BABELTRACE_BIN=''])
 347 AC_SUBST([BABELTRACE_BIN])
 348
 349 AC_ARG_WITH([babeltrace2-bin],
 350         AS_HELP_STRING([--with-babeltrace2-bin],
 351         [Location of the babeltrace2 viewer executable (including the filename)]),
 352         [BABELTRACE2_BIN="$withval"],
 353         [BABELTRACE2_BIN=''])
 354 AC_SUBST([BABELTRACE2_BIN])
 355
 356 AC_ARG_WITH([consumerd32-bin],
 357         AS_HELP_STRING([--with-consumerd32-bin],
 358         [Location of the 32-bit consumerd executable (including the filename)]),
 359         [CONSUMERD32_BIN="$withval"],
 360         [CONSUMERD32_BIN=''])
 361 AC_SUBST([CONSUMERD32_BIN])
 362
 363 AC_ARG_WITH([consumerd64-bin],
 364         AS_HELP_STRING([--with-consumerd64-bin],
 365         [Location of the 64-bit consumerd executable (including the filename)]),
 366         [CONSUMERD64_BIN="$withval"],
 367         [CONSUMERD64_BIN=''])
 368 AC_SUBST([CONSUMERD64_BIN])
 369
 370 AC_ARG_WITH([consumerd32-libdir],
 371         AS_HELP_STRING([--with-consumerd32-libdir],
 372         [Directory containing the 32-bit consumerd libraries]),
 373         [CONSUMERD32_LIBDIR="$withval"],
 374         [CONSUMERD32_LIBDIR=''])
 375 AC_SUBST([CONSUMERD32_LIBDIR])
 376
 377 AC_ARG_WITH([consumerd64-libdir],
 378         AS_HELP_STRING([--with-consumerd64-libdir],
 379         [Directory containing the 64-bit consumerd libraries]),
 380         [CONSUMERD64_LIBDIR="$withval"],
 381         [CONSUMERD64_LIBDIR=''])
 382 AC_SUBST([CONSUMERD64_LIBDIR])
 383
 384 AC_ARG_WITH([sessiond-bin],
 385         AS_HELP_STRING([--with-sessiond-bin],
 386         [Location of the sessiond executable (including the filename)]),
 387         [SESSIOND_BIN="$withval"],
 388         [SESSIOND_BIN=''])
 389 AC_SUBST([SESSIOND_BIN])
 390
 391 AC_ARG_WITH([lttng-system-rundir],
 392         AS_HELP_STRING([--with-lttng-system-rundir],
 393         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 394         [LTTNG_SYSTEM_RUNDIR="$withval"],
 395         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 396 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 397
 398 AC_ARG_ENABLE([test-java-agent-jul],
 399         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 400         [test_java_agent_jul=$enableval],
 401         [test_java_agent_jul=no]
 402 )
 403
 404 AC_ARG_ENABLE([test-java-agent-log4j],
 405         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])],
 406         [test_java_agent_log4j=$enableval],
 407         [test_java_agent_log4j=no]
 408 )
 409
 410 AC_ARG_ENABLE([test-java-agent-log4j2],
 411         [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])],
 412         [test_java_agent_log4j2=$enableval],
 413         [test_java_agent_log4j2=no]
 414 )
 415
 416 AC_ARG_ENABLE([test-java-agent-all],
 417         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 418         [test_java_agent_jul=$enableval
 419          test_java_agent_log4j=$enableval
 420          test_java_agent_log4j2=$enableval],
 421         [:]
 422 )
 423
 424 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 425 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 426 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 427 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 428 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 429 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 430 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 431 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 432
 433 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 434         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 435         $1="$2"
 436         AC_SUBST([$1])
 437 ])
 438
 439 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 440         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 441         $1="$2"
 442         AC_SUBST([$1])
 443 ])
 444
 445 # Default values
 446 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 447 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 448 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 449 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 450 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 451 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 452 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 453 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 454 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 455 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 456 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 457 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 458 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 459 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 460 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 461 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 462 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 463 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 464 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 465 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 466 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 467 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 468 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 469 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 470 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 471 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 472 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 473 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 474 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 475 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 476 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 477 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 478 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 479 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 480 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 481 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 482 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 483 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 484 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 485 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 486 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 487 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 488 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 489 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 490 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 491 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 492 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 493 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 494 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 495 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 496
 497 # Command short descriptions
 498 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 499 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 500 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 501 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 502 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 503 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 504 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 505 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 506 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 507 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 508 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 509 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 510 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 511 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 512 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 513 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 514 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 515 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 516 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 517 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 518 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 519 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 520 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 521 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 522 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 523 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 524 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 525 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 526
 527 if test "x$prefix" = "xNONE"; then
 528         prefix=$ac_default_prefix
 529 fi
 530 CONFDIR=`eval echo $sysconfdir`
 531 AC_SUBST(CONFDIR)
 532 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 533
 534 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 535
 536 # Check libpopt
 537 PKG_CHECK_MODULES([POPT], [popt],
 538   [
 539     dnl PKG_CHECK_MODULES defines POPT_LIBS
 540   ],
 541   [
 542     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 543     AC_MSG_WARN([Finding libpopt without pkg-config.])
 544     AC_CHECK_LIB([popt],
 545       [poptGetContext],
 546       [POPT_LIBS="-lpopt"],
 547       [
 548         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 549       ]
 550     )
 551   ]
 552 )
 553 AC_SUBST(POPT_LIBS)
 554
 555 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 556
 557 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 558
 559 # URCU library version needed or newer
 560 PKG_CHECK_MODULES([URCU], [liburcu >= 0.11])
 561 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11])
 562 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 563
 564 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 565 # it can be explicitly disabled with --without-kmod
 566 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 567 AC_ARG_WITH([kmod],
 568   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 569   [],
 570   [with_kmod=check]
 571 )
 572
 573 AS_IF([test "x$with_kmod" != "xno"],
 574   [
 575     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 576       [
 577         AC_DEFINE([HAVE_KMOD], [1])
 578         KMOD_LIBS="-lkmod"
 579       ],
 580       [
 581         if test "x$with_kmod" != xcheck; then
 582           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 583         else
 584           with_kmod=no
 585         fi
 586       ]
 587     )
 588   ]
 589 )
 590 AC_SUBST(KMOD_LIBS)
 591
 592 # Check for liblttng-ust-ctl, fail if it's not found,
 593 # it can be explicitly disabled with --without-lttng-ust
 594 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 595 AC_ARG_WITH([lttng-ust],
 596   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 597   [],
 598   [with_lttng_ust=yes]
 599 )
 600
 601 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 602   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 603
 604   # Check for liblttng-ust
 605   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 606
 607   # Check for liblttng-ust-ctl
 608   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 609
 610   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 611 ])
 612
 613 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 614
 615
 616 # Check for fmemopen
 617 AC_CHECK_LIB([c], [fmemopen],
 618 [
 619         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 620 ]
 621 )
 622
 623 # check for libpfm
 624 AC_CHECK_LIB([pfm], [pfm_initialize],
 625              [
 626               have_libpfm=yes
 627               ])
 628 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 629
 630 # For Python
 631 # SWIG version needed or newer:
 632 swig_version=2.0.0
 633
 634 AC_ARG_ENABLE([python-bindings],
 635               [AS_HELP_STRING([--enable-python-bindings],
 636                               [compile Python bindings])],
 637               [enable_python_binding=$enableval], [enable_python_binding=no])
 638
 639 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 640
 641 if test "x$enable_python_binding" = xyes; then
 642   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 643   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 644   AM_PATH_PYTHON([3.0])
 645
 646   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 647   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 648   AS_IF([test -z "$PYTHON_INCLUDE"], [
 649     AS_IF([test -z "$PYTHON_CONFIG"], [
 650       AC_PATH_PROGS([PYTHON_CONFIG],
 651                     [python$PYTHON_VERSION-config python-config],
 652                     [no],
 653                     [`dirname $PYTHON`])
 654       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 655     ])
 656     AC_MSG_CHECKING([python include flags])
 657     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 658     AC_MSG_RESULT([$PYTHON_INCLUDE])
 659   ])
 660
 661 else
 662     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 663 [if you want Python bindings.])
 664
 665 fi
 666
 667 # Epoll check. If not present, the build will fallback on poll() API
 668 AX_HAVE_EPOLL(
 669         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 670         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 671 )
 672 AX_CONFIG_FEATURE(
 673         [epoll], [This platform supports epoll(7)],
 674         [HAVE_EPOLL], [This platform supports epoll(7).]
 675 )
 676
 677 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 678         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 679         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 680 )
 681 AX_CONFIG_FEATURE(
 682         [dirfd], [Use directory file descriptors],
 683         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 684 )
 685
 686 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 687 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 688 AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"])
 689
 690 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then
 691         AX_JAVA_OPTIONS
 692         AX_PROG_JAVAC
 693         AX_PROG_JAVA
 694         AX_PROG_JAR
 695
 696         AX_CHECK_CLASSPATH
 697
 698         # Check for Java UST agent common class first
 699         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 700         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 701                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 702         fi
 703
 704         if test "x$test_java_agent_jul" = "xyes"; then
 705                 # Check for JUL agent class
 706                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 707                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 708                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 709                 fi
 710         fi
 711
 712         if test "x$test_java_agent_log4j" = "xyes"; then
 713                 # Check for Log4j agent class
 714                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 715                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 716                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 717                 fi
 718
 719                 # Check for Log4j class
 720                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 721                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 722                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 723                 fi
 724         fi
 725
 726         if test "x$test_java_agent_log4j2" = "xyes"; then
 727                 # Check for Log4j2 agent class
 728                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender)
 729                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then
 730                         AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"])
 731                 fi
 732
 733                 # Check for Log4j 2.x classes
 734                 AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 735                 AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 736                 if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then
 737                         AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"])
 738                 fi
 739         fi
 740 fi
 741
 742 # enable building man pages (user's intention)
 743 AC_ARG_ENABLE(
 744         man-pages,
 745         AS_HELP_STRING(
 746                 [--disable-man-pages],
 747                 [Do not build and install man pages (already built in a distributed tarball)]
 748         ),
 749         [man_pages_opt=$enableval],
 750         [man_pages_opt=yes]
 751 )
 752
 753 # check for asciidoc and xmlto if we enabled building the man pages
 754 have_asciidoc_xmlto=no
 755 warn_prebuilt_man_pages=no
 756
 757 AS_IF([test "x$man_pages_opt" = "xyes"], [
 758         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 759         AC_PATH_PROG([XMLTO], [xmlto], [no])
 760
 761         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 762                 AS_IF([test "x$in_git_repo" = "xyes"], [
 763                         # this is an error because we're in the Git repo, which
 764                         # means the man pages are not already generated for us,
 765                         # thus asciidoc/xmlto are required because we were asked
 766                         # to build the man pages
 767                         AC_MSG_ERROR([
 768 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 769 --disable-man-pages to disable building the man pages, in which case
 770 they will not be installed.
 771                         ])
 772                 ], [
 773                         # only warn here: since we're in the tarball, the man
 774                         # pages should already be generated at this point, thus
 775                         # asciidoc/xmlto are not strictly required
 776                         warn_prebuilt_man_pages=yes
 777                 ])
 778         ], [
 779                 have_asciidoc_xmlto=yes
 780         ])
 781 ])
 782
 783 # export man page build condition: build the man pages if the user
 784 # asked for it, and if the tools are available
 785 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 786 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 787
 788 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 789
 790 # embedded --help message
 791 AC_ARG_ENABLE(
 792         [embedded-help],
 793         AS_HELP_STRING(
 794                 [--enable-embedded-help],
 795                 [Embed the --help messages in the executable files]
 796         ),
 797         [embedded_help=$enableval],
 798         [embedded_help=no]
 799 )
 800 AS_IF([test "x$embedded_help" = "xyes"], [
 801         AS_IF([test "x$man_pages_opt" = "xno"], [
 802                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 803         ])
 804         AC_PATH_PROG([man_prog_path], [man], [no])
 805         AS_IF([test "x$man_prog_path" = "xno"], [
 806                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 807         ])
 808         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 809         AC_SUBST([MANPROG], [$man_prog_path])
 810 ])
 811 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 812
 813 # Python agent test
 814 UST_PYTHON_AGENT="lttngust"
 815
 816 AC_ARG_ENABLE(test-python2-agent,
 817         AS_HELP_STRING([--enable-test-python2-agent],
 818                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 819         ),[:],[test_python2_agent_autodetect=yes]
 820 )
 821
 822 AC_ARG_ENABLE(test-python3-agent,
 823         AS_HELP_STRING([--enable-test-python3-agent],
 824                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 825         ),[:],[test_python3_agent_autodetect=yes]
 826 )
 827
 828 AC_ARG_ENABLE(test-python-agent-all,
 829         AS_HELP_STRING([--enable-test-python-agent-all],
 830                 [enable test for all python{2/3} agent.]
 831         ),
 832 )
 833
 834 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 835        unset test_python2_agent_autodetect
 836        unset test_python3_agent_autodetect
 837 ])
 838
 839 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 840        enable_test_python2_agent=yes
 841        enable_test_python3_agent=yes
 842 ])
 843
 844 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 845        enable_test_python2_agent=no
 846        enable_test_python3_agent=no
 847 ])
 848
 849
 850 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 851         AS_IF([test -z "$PYTHON2"], [
 852                         PYTHON2=python2
 853                 ], [
 854                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 855         ])
 856
 857         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 858         AS_IF([test -z "$PYTHON2_BIN"], [
 859                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 860                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 861                 ])
 862         ], [
 863                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 864                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 865                         PYTHON2_AGENT=$PYTHON2_BIN
 866                         AC_MSG_RESULT([yes])
 867                         RUN_PYTHON_AGENT_TEST=yes
 868                 ], [
 869                         AC_MSG_RESULT([no])
 870                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 871                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 872                         ])
 873                 ])
 874
 875         ])
 876
 877 ])
 878
 879 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 880         AS_IF([test -z "$PYTHON3"], [
 881                 PYTHON3=python3
 882         ], [
 883                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 884         ])
 885
 886         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 887         AS_IF([test -z "$PYTHON3_BIN"], [
 888                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 889                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 890                 ])
 891         ], [
 892                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 893                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 894                         PYTHON3_AGENT=$PYTHON3_BIN
 895                         AC_MSG_RESULT([yes])
 896                         RUN_PYTHON_AGENT_TEST=yes
 897                 ], [
 898                         AC_MSG_RESULT([no])
 899                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 900                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 901                         ])
 902                 ])
 903
 904         ])
 905 ])
 906 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 907 AC_SUBST([PYTHON2_AGENT])
 908 AC_SUBST([PYTHON3_AGENT])
 909
 910 AC_ARG_ENABLE([test-sdt-uprobe],
 911   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 912   [test_sdt_uprobe="$enableval"],
 913   [test_sdt_uprobe=autodetect]
 914 )
 915
 916 AS_IF([test "$test_sdt_uprobe" != "no"], [
 917   LTTNG_CHECK_SDT_WORKS
 918   AC_PATH_PROG([DTRACE], [dtrace])
 919 ])
 920
 921 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 922   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 923     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 924   ])
 925   AS_IF([test "x$DTRACE" = "x"], [
 926     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 927   ])
 928 ])
 929
 930 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 931   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 932     AS_IF([test "x$DTRACE" != "x"], [
 933       test_sdt_uprobe=yes
 934     ])
 935   ])
 936 ])
 937
 938 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 939
 940 # Arguments for binaries build exclusion
 941 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 942 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 943               [Disable the build of lttng-consumerd binaries]))
 944 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 945 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 946               [Disable the build of lttng-relayd binaries]))
 947 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 948               [Disable the build of lttng-sessiond binaries]))
 949 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 950               [Disable the build of the extra components]))
 951
 952
 953 build_lib_consumer=no
 954 build_lib_health=no
 955 build_lib_index=no
 956 build_lib_kernel_consumer=no
 957 build_lib_kernel_ctl=no
 958 build_lib_lttng_ctl=no
 959 build_lib_relayd=no
 960 build_lib_sessiond_comm=no
 961 build_lib_testpoint=no
 962 build_lib_ust_consumer=no
 963
 964 # There is an overlap for enabled dependencies, but this makes everything
 965 # simpler. libcommon and libconfig are always compiled so they are not repeated
 966 # here.
 967
 968 # Enable binary dependencies.
 969 AS_IF([test x$enable_bin_lttng != xno],
 970       [
 971        build_lib_lttng_ctl=yes
 972       ]
 973 )
 974
 975 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 976       [
 977        build_lib_consumer=yes
 978        build_lib_sessiond_comm=yes
 979        build_lib_index=yes
 980        build_lib_health=yes
 981        build_lib_testpoint=yes
 982       ]
 983 )
 984
 985 AS_IF([test x$enable_bin_lttng_crash != xno],
 986       # Do nothing since libconfig and libcommon are built by default.
 987       []
 988 )
 989
 990 AS_IF([test x$enable_bin_lttng_relayd != xno],
 991       [
 992        build_lib_sessiond_comm=yes
 993        build_lib_index=yes
 994        build_lib_health=yes
 995        build_lib_testpoint=yes
 996       ]
 997 )
 998 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 999       [
1000        build_lib_lttng_ctl=yes
1001        build_lib_sessiond_comm=yes
1002        build_lib_kernel_ctl=yes
1003        build_lib_relayd=yes
1004        build_lib_testpoint=yes
1005        build_lib_health=yes
1006       ]
1007 )
1008
1009 # Libraries dependencies enabling
1010 AS_IF([test x$build_lib_lttng_ctl = xyes],
1011       [
1012        build_lib_sessiond_comm=yes
1013       ]
1014 )
1015
1016 AS_IF([test x$build_lib_consumer = xyes],
1017       [
1018        build_lib_sessiond_comm=yes
1019        build_lib_kernel_consumer=yes
1020        build_lib_relayd=yes
1021        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
1022       ]
1023 )
1024
1025 AS_IF([test x$build_lib_kernel_consumer = xyes],
1026       [
1027        build_lib_kernel_ctl=yes
1028        build_lib_relayd=yes
1029       ]
1030 )
1031
1032 AS_IF([test x$build_lib_relayd = xyes],
1033       [
1034        build_lib_sessiond_comm=yes
1035       ]
1036 )
1037
1038 # Find arch type
1039 AS_CASE([$host_cpu],
1040         [k1om], [ARCHTYPE="x86"],
1041         [i386], [ARCHTYPE="x86"],
1042         [i486], [ARCHTYPE="x86"],
1043         [i586], [ARCHTYPE="x86"],
1044         [i686], [ARCHTYPE="x86"],
1045         [amd64], [ARCHTYPE="x86"],
1046         [x86_64], [ARCHTYPE="x86"],
1047         [powerpc], [ARCHTYPE="ppc"],
1048         [ppc64], [ARCHTYPE="ppc"],
1049         [powerpc64], [ARCHTYPE="ppc"],
1050         [powerpc64le], [ARCHTYPE="ppc"],
1051         [ppc], [ARCHTYPE="ppc"],
1052         [s390], [ARCHTYPE="s390"],
1053         [s390x], [ARCHTYPE="s390"],
1054         [sparc], [ARCHTYPE="sparc64"],
1055         [sparc64], [ARCHTYPE="sparc64"],
1056         [alpha*], [ARCHTYPE="alpha"],
1057         [ia64], [ARCHTYPE="ia64"],
1058         [arm*], [ARCHTYPE="arm"],
1059         [aarch64*], [ARCHTYPE="aarch64"],
1060         [mips*], [ARCHTYPE="mips"],
1061         [nios2*], [ARCHTYPE="nios2"],
1062         [tile*], [ARCHTYPE="tile"],
1063         [hppa*], [ARCHTYPE="hppa"],
1064         [m68k], [ARCHTYPE="m68k"],
1065         [riscv*], [ARCHTYPE="riscv"],
1066         [ARCHTYPE="unknown"]
1067 )
1068
1069 AC_SUBST(ARCHTYPE)
1070
1071 AS_CASE([$host_os],
1072         [linux*], [OSTYPE="linux"],
1073         [freebsd*], [OSTYPE="freebsd"],
1074         [solaris*], [OSTYPE="solaris"],
1075         [cygwin*], [OSTYPE="cygwin"],
1076         [mingw*], [OSTYPE="mingw"],
1077         [OSTYPE="unknown"]
1078 )
1079 AC_SUBST(OSTYPE)
1080 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1081
1082
1083
1084 # Userspace callstack capture is only supported by the Linux kernel on x86.
1085 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1086 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1087         have_modules_userspace_callstack_context=yes
1088         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1089 ])
1090 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1091
1092 # Export binaries build conditions.
1093 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1094 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1095 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1096 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1097 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1098
1099 # Export the tests and extras build conditions.
1100 AS_IF([\
1101 test "x$enable_bin_lttng" != "xno" && \
1102 test "x$enable_bin_lttng_consumerd" != "xno" && \
1103 test "x$enable_bin_lttng_crash" != "xno" && \
1104 test "x$enable_bin_lttng_relayd" != "xno" && \
1105 test "x$enable_bin_lttng_sessiond" != "xno"],
1106 [build_tests=yes],
1107 [build_tests=no]
1108 )
1109
1110 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1111 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1112
1113 # Export libraries build conditions.
1114 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1115 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1116 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1117 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1118 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1119 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1120 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1121 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1122 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1123 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1124
1125 AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1126 AC_SUBST(AM_CFLAGS)
1127
1128 AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1129 AC_SUBST(AM_CXXFLAGS)
1130
1131 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1132 AM_LDFLAGS=""
1133 AC_SUBST(AM_LDFLAGS)
1134
1135 # The order in which the include folders are searched is important.
1136 # The top_builddir should always be searched first in the event that a build
1137 # time generated file is included. An example of this is the "version.i" file.
1138 # In a scenario where lttng-tools is built from a distribution tarball and in a
1139 # out-of-tree manner, the generated "version.i" has priority on the one from
1140 # the source (distribution tarball) and must be found first.
1141 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1142 AC_SUBST(AM_CPPFLAGS)
1143
1144 lttngincludedir="${includedir}/lttng"
1145 AC_SUBST(lttngincludedir)
1146
1147 lttngactionincludedir="${includedir}/lttng/action"
1148 AC_SUBST(lttngactionincludedir)
1149
1150 lttngconditionincludedir="${includedir}/lttng/condition"
1151 AC_SUBST(lttngconditionincludedir)
1152
1153 lttngnotificationincludedir="${includedir}/lttng/notification"
1154 AC_SUBST(lttngnotificationincludedir)
1155
1156 lttngtriggerincludedir="${includedir}/lttng/trigger"
1157 AC_SUBST(lttngtriggerincludedir)
1158
1159 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1160 AC_SUBST(lttngeventruleincludedir)
1161
1162 lttnglibexecdir="${libdir}/lttng/libexec"
1163 AC_SUBST(lttnglibexecdir)
1164
1165 AC_CONFIG_FILES([
1166         Makefile
1167         doc/Makefile
1168         doc/examples/Makefile
1169         doc/examples/rotation/Makefile
1170         doc/examples/trigger-condition-event-matches/Makefile
1171         doc/man/Makefile
1172         doc/man/asciidoc-attrs.conf
1173         include/Makefile
1174         extras/Makefile
1175         extras/bindings/Makefile
1176         extras/bindings/swig/Makefile
1177         extras/bindings/swig/python/Makefile
1178         extras/core-handler/Makefile
1179         src/Makefile
1180         src/common/Makefile
1181         src/lib/Makefile
1182         src/lib/lttng-ctl/Makefile
1183         src/lib/lttng-ctl/lttng-ctl.pc
1184         src/bin/Makefile
1185         src/bin/lttng-consumerd/Makefile
1186         src/bin/lttng-sessiond/Makefile
1187         src/bin/lttng-relayd/Makefile
1188         src/bin/lttng/Makefile
1189         src/bin/lttng-crash/Makefile
1190         src/vendor/Makefile
1191         src/vendor/msgpack/Makefile
1192         tests/Makefile
1193         tests/destructive/Makefile
1194         tests/regression/Makefile
1195         tests/regression/kernel/Makefile
1196         tests/regression/tools/Makefile
1197         tests/regression/tools/streaming/Makefile
1198         tests/regression/tools/filtering/Makefile
1199         tests/regression/tools/health/Makefile
1200         tests/regression/tools/tracefile-limits/Makefile
1201         tests/regression/tools/snapshots/Makefile
1202         tests/regression/tools/live/Makefile
1203         tests/regression/tools/exclusion/Makefile
1204         tests/regression/tools/save-load/Makefile
1205         tests/regression/tools/save-load/configuration/Makefile
1206         tests/regression/tools/mi/Makefile
1207         tests/regression/tools/wildcard/Makefile
1208         tests/regression/tools/channel/Makefile
1209         tests/regression/tools/crash/Makefile
1210         tests/regression/tools/regen-metadata/Makefile
1211         tests/regression/tools/regen-statedump/Makefile
1212         tests/regression/tools/notification/Makefile
1213         tests/regression/tools/rotation/Makefile
1214         tests/regression/tools/base-path/Makefile
1215         tests/regression/tools/metadata/Makefile
1216         tests/regression/tools/tracker/Makefile
1217         tests/regression/tools/working-directory/Makefile
1218         tests/regression/tools/relayd-grouping/Makefile
1219         tests/regression/tools/clear/Makefile
1220         tests/regression/tools/trigger/Makefile
1221         tests/regression/tools/trigger/rate-policy/Makefile
1222         tests/regression/tools/trigger/start-stop/Makefile
1223         tests/regression/tools/trigger/utils/Makefile
1224         tests/regression/tools/trigger/name/Makefile
1225         tests/regression/tools/trigger/hidden/Makefile
1226         tests/regression/ust/Makefile
1227         tests/regression/ust/nprocesses/Makefile
1228         tests/regression/ust/high-throughput/Makefile
1229         tests/regression/ust/low-throughput/Makefile
1230         tests/regression/ust/before-after/Makefile
1231         tests/regression/ust/buffers-pid/Makefile
1232         tests/regression/ust/periodical-metadata-flush/Makefile
1233         tests/regression/ust/multi-session/Makefile
1234         tests/regression/ust/multi-lib/Makefile
1235         tests/regression/ust/overlap/Makefile
1236         tests/regression/ust/overlap/demo/Makefile
1237         tests/regression/ust/linking/Makefile
1238         tests/regression/ust/daemon/Makefile
1239         tests/regression/ust/exit-fast/Makefile
1240         tests/regression/ust/fork/Makefile
1241         tests/regression/ust/libc-wrapper/Makefile
1242         tests/regression/ust/baddr-statedump/Makefile
1243         tests/regression/ust/ust-dl/Makefile
1244         tests/regression/ust/java-jul/Makefile
1245         tests/regression/ust/java-log4j/Makefile
1246         tests/regression/ust/java-log4j2/Makefile
1247         tests/regression/ust/getcpu-override/Makefile
1248         tests/regression/ust/clock-override/Makefile
1249         tests/regression/ust/type-declarations/Makefile
1250         tests/regression/ust/rotation-destroy-flush/Makefile
1251         tests/regression/ust/blocking/Makefile
1252         tests/regression/ust/namespaces/Makefile
1253         tests/stress/Makefile
1254         tests/unit/Makefile
1255         tests/unit/ini_config/Makefile
1256         tests/perf/Makefile
1257         tests/utils/Makefile
1258         tests/utils/tap/Makefile
1259         tests/utils/testapp/Makefile
1260         tests/utils/testapp/gen-ns-events/Makefile
1261         tests/utils/testapp/gen-kernel-test-events/Makefile
1262         tests/utils/testapp/gen-py-events/Makefile
1263         tests/utils/testapp/gen-ust-events/Makefile
1264         tests/utils/testapp/gen-ust-events-ns/Makefile
1265         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1266         tests/utils/testapp/gen-ust-nevents/Makefile
1267         tests/utils/testapp/gen-ust-nevents-str/Makefile
1268         tests/utils/testapp/gen-syscall-events/Makefile
1269         tests/utils/testapp/gen-ust-tracef/Makefile
1270         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1271         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1272         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1273         tests/utils/xml-utils/Makefile
1274 ])
1275
1276 # Inject variable into python test script.
1277 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1278 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1279 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1280 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1281
1282 AC_OUTPUT
1283
1284 #
1285 # Mini-report on what will be built.
1286 #
1287
1288 PPRINT_INIT
1289 PPRINT_SET_INDENT(1)
1290 PPRINT_SET_TS(38)
1291
1292 AS_ECHO
1293 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1294 AS_ECHO
1295
1296 AS_IF([test -n "$report_fold"], [
1297         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1298 ], [
1299         AS_ECHO("$version_description")
1300 ])
1301
1302 AS_ECHO
1303 PPRINT_SUBTITLE([Features])
1304
1305 # Target architecture we're building for.
1306 target_arch=$host_cpu
1307 [
1308 for f in $CFLAGS; do
1309         if test $f = "-m32"; then
1310                         target_arch="32-bit"
1311         elif test $f = "-m64"; then
1312                         target_arch="64-bit"
1313         fi
1314 done
1315 ]
1316 PPRINT_PROP_STRING([Target architecture], $target_arch)
1317
1318 # kmod enabled/disabled
1319 test "x$with_kmod" != "xno" && value=1 || value=0
1320 PPRINT_PROP_BOOL([libkmod support], $value)
1321
1322 # LTTng-UST enabled/disabled
1323 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1324 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1325
1326 AS_ECHO
1327 PPRINT_SUBTITLE([Binaries])
1328
1329 # List binaries to be built
1330 test x$enable_bin_lttng != xno && value=1 || value=0
1331 PPRINT_PROP_BOOL([lttng], $value)
1332
1333 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1334 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1335
1336 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1337 PPRINT_PROP_BOOL([lttng-crash], $value)
1338
1339 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1340 PPRINT_PROP_BOOL([lttng-relayd], $value)
1341
1342 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1343 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1344
1345 # Extras
1346 test x$enable_extras != xno && value=1 || value=0
1347 AS_ECHO
1348 PPRINT_SET_INDENT(0)
1349 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1350 PPRINT_SET_INDENT(1)
1351
1352 AS_ECHO
1353 PPRINT_SUBTITLE([Tests])
1354
1355 # Print clear message that tests won't be built
1356 AS_IF([test "x$build_tests" = "xno"],[
1357         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1358 ])
1359
1360 # LTTng UST Java agent JUL tests enabled/disabled
1361 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1362 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1363
1364 # LTTng UST Java agent Log4j 1.x tests enabled/disabled
1365 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1366 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value)
1367
1368 # LTTng UST Java agent Log4j 2.x tests enabled/disabled
1369 test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0
1370 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value)
1371
1372 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1373 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1374
1375 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1376 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1377
1378 # userspace-probe SDT instrumentation tests enabled/disabled
1379 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1380 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1381
1382 #Python binding enabled/disabled
1383 test "x$enable_python_binding" = xyes && value=1 || value=0
1384 AS_ECHO
1385 PPRINT_SET_INDENT(0)
1386 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1387
1388 # man pages build enabled/disabled
1389 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1390
1391 AS_IF([test "x$man_pages_opt" != "xno"], [
1392         AS_IF([test "x$in_git_repo" = "xyes"], [
1393                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1394         ], [
1395                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1396                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1397                 ], [
1398                         PPRINT_PROP_STRING([build_man_pages_msg],
1399                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1400                                 $PPRINT_COLOR_SUBTITLE)
1401                 ])
1402         ])
1403 ], [
1404         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1405 ])
1406
1407 m4_popdef([build_man_pages_msg])
1408
1409 test "x$embedded_help" = xyes && value=1 || value=0
1410 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1411
1412 PPRINT_SET_INDENT(1)
1413
1414 report_bindir="`eval eval echo $bindir`"
1415 report_libdir="`eval eval echo $libdir`"
1416
1417 # Print the bindir and libdir this `make install' will install into.
1418 AS_ECHO
1419 PPRINT_SUBTITLE([Install directories])
1420 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1421 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1422
1423 AS_ECHO
1424 PPRINT_SUBTITLE([Search directories])
1425
1426 # If we build the sessiond, print the paths it will use
1427 AS_IF([test "$SESSIOND_BIN" = ""],[
1428         path="$report_bindir/lttng-sessiond"
1429 ],[
1430         path="$SESSIOND_BIN"
1431 ])
1432 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1433
1434 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1435         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1436 ],[
1437         path="$CONSUMERD32_BIN"
1438 ])
1439 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1440
1441 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1442         path="`eval eval echo $libdir`"
1443 ],[
1444         path="$CONSUMERD32_LIBDIR"
1445 ])
1446 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1447
1448 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1449         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1450 ],[
1451         path="$CONSUMERD64_BIN"
1452 ])
1453 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1454
1455 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1456         path="`eval eval echo $libdir`"
1457 ],[
1458         path="$CONSUMERD64_LIBDIR"
1459 ])
1460 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1461 PPRINT_SET_INDENT(0)
1462
1463 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1464         AS_ECHO
1465         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1466
1467 Note that the man pages are already built in this distribution tarball,
1468 therefore asciidoc and xmlto are only needed if you intend to modify
1469 their sources.
1470
1471 Also note that the installed man pages will contain the project's
1472 default command-line option and environment variable values.
1473
1474 Use --disable-man-pages to completely disable building and installing
1475 the man pages.])
1476 ])