configure.ac: check for an existing liburcu-cds symbol
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.9.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_LEX
28 AC_PROG_MAKE_SET
29 AC_PROG_SED
30 AC_PROG_YACC
31 AC_PATH_PROG(report_fold, fold)
32 LT_INIT
33
34 # Check for objcopy, required by the base address statedump and dynamic linker tests
35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
36 AS_IF([test "x$OBJCOPY" = xno],
37 [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
38 )
39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
40
41 # Checks for typedefs, structures, and compiler characteristics.
42 AC_C_INLINE
43 AC_TYPE_INT32_T
44 AC_TYPE_INT64_T
45 AC_TYPE_MODE_T
46 AC_TYPE_OFF_T
47 AC_TYPE_PID_T
48 AC_TYPE_SIZE_T
49 AC_TYPE_SSIZE_T
50 AC_TYPE_UID_T
51 AC_TYPE_UINT16_T
52 AC_TYPE_UINT32_T
53 AC_TYPE_UINT64_T
54 AC_TYPE_UINT8_T
55
56 AX_C___ATTRIBUTE__
57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
58 [:],
59 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
60
61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
62 LIBS="$PTHREAD_LIBS $LIBS"
63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
64 CC="$PTHREAD_CC"
65
66 AX_LIB_SOCKET_NSL
67
68 # Compute minor/major/patchlevel version numbers
69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
72
73 AC_SUBST([MAJOR_VERSION], [$major_version])
74 AC_SUBST([MINOR_VERSION], [$minor_version])
75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
79
80 version_name="Codename TBD"
81 version_description='Description TBD'
82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
83
84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
86
87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
88 AC_ARG_ENABLE(libtool-linkdep-fixup,
89 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
90 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
91 libtool_fixup=$enableval,
92 libtool_fixup=yes)
93
94 AS_IF([test "x$libtool_fixup" = "xyes"],
95 [
96 libtool_m4="$srcdir/m4/libtool.m4"
97 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
98 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
99 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
100 AS_IF([test $libtool_flag_pattern_count -ne 0],
101 [
102 AC_MSG_RESULT([$libtool_flag_pattern_count])
103 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
104 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
105 ],
106 [
107 AC_MSG_RESULT([none])
108 ])
109 ])
110
111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
112
113 AC_CHECK_HEADERS([ \
114 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
115 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
116 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
117 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
118 sys/mount.h sys/param.h sys/time.h
119 ])
120
121 # Basic functions check
122 AC_CHECK_FUNCS([ \
123 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
124 gethostbyname gethostname getpagesize localtime_r memchr memset \
125 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
126 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
127 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
128 ])
129
130 # Babeltrace viewer check
131 AC_ARG_WITH([babeltrace-bin],
132 AS_HELP_STRING([--with-babeltrace-bin],
133 [Location of the babeltrace viewer executable (including the filename)]),
134 [BABELTRACE_BIN="$withval"],
135 [BABELTRACE_BIN=''])
136 AC_SUBST([BABELTRACE_BIN])
137
138 # lttv-gui
139 AC_ARG_WITH([lttv-gui-bin],
140 AS_HELP_STRING([--with-lttv-gui-bin],
141 [Location of the lttv GUI viewer executable (including the filename)]),
142 [LTTV_GUI_BIN="$withval"],
143 [LTTV_GUI_BIN=''])
144 AC_SUBST([LTTV_GUI_BIN])
145
146 AC_ARG_WITH([consumerd32-bin],
147 AS_HELP_STRING([--with-consumerd32-bin],
148 [Location of the 32-bit consumerd executable (including the filename)]),
149 [CONSUMERD32_BIN="$withval"],
150 [CONSUMERD32_BIN=''])
151 AC_SUBST([CONSUMERD32_BIN])
152
153 AC_ARG_WITH([consumerd64-bin],
154 AS_HELP_STRING([--with-consumerd64-bin],
155 [Location of the 64-bit consumerd executable (including the filename)]),
156 [CONSUMERD64_BIN="$withval"],
157 [CONSUMERD64_BIN=''])
158 AC_SUBST([CONSUMERD64_BIN])
159
160 AC_ARG_WITH([consumerd32-libdir],
161 AS_HELP_STRING([--with-consumerd32-libdir],
162 [Directory containing the 32-bit consumerd libraries]),
163 [CONSUMERD32_LIBDIR="$withval"],
164 [CONSUMERD32_LIBDIR=''])
165 AC_SUBST([CONSUMERD32_LIBDIR])
166
167 AC_ARG_WITH([consumerd64-libdir],
168 AS_HELP_STRING([--with-consumerd64-libdir],
169 [Directory containing the 64-bit consumerd libraries]),
170 [CONSUMERD64_LIBDIR="$withval"],
171 [CONSUMERD64_LIBDIR=''])
172 AC_SUBST([CONSUMERD64_LIBDIR])
173
174 AC_ARG_WITH([sessiond-bin],
175 AS_HELP_STRING([--with-sessiond-bin],
176 [Location of the sessiond executable (including the filename)]),
177 [SESSIOND_BIN="$withval"],
178 [SESSIOND_BIN=''])
179 AC_SUBST([SESSIOND_BIN])
180
181 AC_ARG_WITH([lttng-system-rundir],
182 AS_HELP_STRING([--with-lttng-system-rundir],
183 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
184 [LTTNG_SYSTEM_RUNDIR="$withval"],
185 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
186 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
187
188 AC_ARG_ENABLE([test-java-agent-jul],
189 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
190 [test_java_agent_jul=$enableval],
191 [test_java_agent_jul=no]
192 )
193
194 AC_ARG_ENABLE([test-java-agent-log4j],
195 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
196 [test_java_agent_log4j=$enableval],
197 [test_java_agent_log4j=no]
198 )
199
200 AC_ARG_ENABLE([test-java-agent-all],
201 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
202 [test_java_agent_jul=$enableval
203 test_java_agent_log4j=$enableval],
204 [:]
205 )
206
207 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
208 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
209 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
210 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
211 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
212 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
213 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
214 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
215
216 if test "x$prefix" = "xNONE"; then
217 prefix=$ac_default_prefix
218 fi
219 CONFDIR=`eval echo $sysconfdir`
220 AC_SUBST(CONFDIR)
221 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
222
223 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
224
225 #
226 # Check for pthread
227 AC_CHECK_LIB([pthread], [pthread_create], [],
228 [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
229 )
230
231 # Check libpopt
232 PKG_CHECK_MODULES([POPT], [popt],
233 [LIBS="$LIBS $POPT_LIBS"],
234 [
235 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
236 AC_MSG_WARN([Finding libpopt without pkg-config.])
237 AC_CHECK_LIB([popt],
238 [poptGetContext],
239 [],
240 [
241 AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
242 ]
243 )
244 ]
245 )
246
247 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
248
249 # Check for libuuid
250 PKG_CHECK_MODULES([UUID], [uuid],
251 [
252 LIBS="$LIBS $UUID_LIBS"
253 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
254 have_libuuid=yes
255 ],
256 [
257 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
258 AC_MSG_WARN([Finding libuuid without pkg-config.])
259 AC_CHECK_LIB([uuid],
260 [uuid_generate],
261 [
262 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
263 have_libuuid=yes
264 ],
265 [
266 # libuuid not found, check for uuid_create in libc.
267 AC_CHECK_LIB([c],
268 [uuid_create],
269 [
270 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
271 have_libc_uuid=yes
272 ],
273 [
274 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
275 ]
276 )
277 ]
278 )
279 ])
280 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
281 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
282
283 # URCU library version needed or newer
284 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
285
286 # Check liburcu needed function calls
287 AC_CHECK_DECL([cds_list_add], [],
288 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
289 AC_CHECK_DECL([cds_wfcq_init], [],
290 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
291 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
292 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
293 AC_CHECK_DECL([futex_async], [],
294 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
295 AC_CHECK_DECL([rcu_thread_offline], [],
296 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
297 AC_CHECK_DECL([rcu_thread_online], [],
298 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
299 AC_CHECK_DECL([caa_likely], [],
300 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
301 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
302 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
303
304 #Function added in urcu 0.7.0
305 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
306 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
307 )
308
309 # Check kmod library
310 AC_ARG_WITH(kmod-prefix,
311 AS_HELP_STRING([--with-kmod-prefix=PATH],
312 [Specify the installation prefix of the kmod library.
313 Headers must be in PATH/include; libraries in PATH/lib.]),
314 [
315 CPPFLAGS="$CPPFLAGS -I${withval}/include"
316 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
317 ])
318
319 AC_ARG_ENABLE(kmod,
320 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
321 kmod_support=zz$enableval, kmod_support=yes)
322
323 AS_IF([test "x$kmod_support" = "xyes"], [
324 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
325 [
326 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
327 LIBS="$LIBS -lkmod"
328 kmod_found=yes
329 ],
330 kmod_found=no
331 )
332 ])
333 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
334
335 AC_ARG_WITH(lttng-ust-prefix,
336 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
337 [Specify the installation prefix of the lttng-ust library.
338 Headers must be in PATH/include; libraries in PATH/lib.]),
339 [
340 CPPFLAGS="$CPPFLAGS -I${withval}/include"
341 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
342 ])
343
344 # Check liblttng-ust-ctl library
345 AC_ARG_WITH(lttng-ust,
346 AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
347 lttng_ust_support=$withval, lttng_ust_support=yes)
348
349 AS_IF([test "x$lttng_ust_support" = "xyes"], [
350 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
351 [
352 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
353 lttng_ust_ctl_found=yes
354 ],
355 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
356 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
357 )
358 ])
359 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
360 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
361
362 # check for dlopen
363 AC_CHECK_LIB([dl], [dlopen],
364 [
365 have_libdl=yes
366 ],
367 [
368 #libdl not found, check for dlopen in libc.
369 AC_CHECK_LIB([c], [dlopen],
370 [
371 have_libc_dl=yes
372 ],
373 [
374 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
375 ])
376 ])
377 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
378 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
379
380 # Check for fmemopen
381 AC_CHECK_LIB([c], [fmemopen],
382 [
383 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
384 ]
385 )
386
387 # Check for open_memstream
388 AC_CHECK_LIB([c], [open_memstream],
389 [
390 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
391 ]
392 )
393
394 AC_ARG_ENABLE([git-version],
395 [AC_HELP_STRING([--disable-git-version],
396 [Do not use the git version for the build])],
397 [have_git_version=$enableval], [have_git_version=yes]
398 )
399
400 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
401 [test "x${have_git_version}" = "xyes"])
402
403 # For Python
404 # SWIG version needed or newer:
405 swig_version=2.0.0
406
407 AC_ARG_ENABLE([python-bindings],
408 [AC_HELP_STRING([--enable-python-bindings],
409 [compile Python bindings])],
410 [enable_python_binding=yes], [enable_python_binding=no])
411
412 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
413
414 if test "x${enable_python_binding:-yes}" = xyes; then
415 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
416 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
417 AM_PATH_PYTHON([3.0])
418
419 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
420 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
421 AS_IF([test -z "$PYTHON_INCLUDE"], [
422 AS_IF([test -z "$PYTHON_CONFIG"], [
423 AC_PATH_PROGS([PYTHON_CONFIG],
424 [python$PYTHON_VERSION-config python-config],
425 [no],
426 [`dirname $PYTHON`])
427 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
428 ])
429 AC_MSG_CHECKING([python include flags])
430 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
431 AC_MSG_RESULT([$PYTHON_INCLUDE])
432 ])
433
434 else
435 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
436 [if you want Python bindings.])
437
438 fi
439
440 # Epoll check. If not present, the build will fallback on poll() API
441 AX_HAVE_EPOLL(
442 [AX_CONFIG_FEATURE_ENABLE(epoll)],
443 [AX_CONFIG_FEATURE_DISABLE(epoll)]
444 )
445 AX_CONFIG_FEATURE(
446 [epoll], [This platform supports epoll(7)],
447 [HAVE_EPOLL], [This platform supports epoll(7).],
448 [enable_epoll="yes"], [enable_epoll="no"]
449 )
450 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
451
452 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
453 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
454
455 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
456 AX_JAVA_OPTIONS
457 AX_PROG_JAVAC
458 AX_PROG_JAVA
459 AX_PROG_JAR
460
461 AX_CHECK_CLASSPATH
462
463 # Check for Java UST agent common class first
464 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
465 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
466 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
467 fi
468
469 if test "x$test_java_agent_jul" = "xyes"; then
470 # Check for JUL agent class
471 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
472 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
473 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
474 fi
475 fi
476
477 if test "x$test_java_agent_log4j" = "xyes"; then
478 # Check for Log4j agent class
479 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
480 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
481 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
482 fi
483
484 # Check for Log4j class
485 AX_CHECK_CLASS(org.apache.log4j.Logger)
486 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
487 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
488 fi
489 fi
490 fi
491
492 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
493 # is not distributed in tarballs
494 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
495 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
496
497 # enable building man pages
498 AC_ARG_ENABLE(
499 build-man-pages,
500 AS_HELP_STRING(
501 [--disable-build-man-pages],
502 [Build man pages (already built in a distributed tarball)]
503 ),
504 [build_man_pages=$enableval],
505 [build_man_pages=yes]
506 )
507
508 # export man page build condition
509 AM_CONDITIONAL([BUILD_MAN_PAGES], [test "x$build_man_pages" != "xno"])
510
511 # check for asciidoc and xmlto if we enabled building the man pages
512 AS_IF([test "x$build_man_pages" = "xyes"], [
513 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
514 AC_PATH_PROG([XMLTO], [xmlto], [no])
515
516 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
517 AC_MSG_ERROR([Both asciidoc and xmlto are needed to build the LTTng man pages.])
518 ])
519 ])
520
521 # Python agent test
522 UST_PYTHON_AGENT="lttngust"
523
524 AC_ARG_ENABLE(test-python2-agent,
525 AS_HELP_STRING([--enable-test-python2-agent],
526 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
527 ),[:],[test_python2_agent_autodetect=yes]
528 )
529
530 AC_ARG_ENABLE(test-python3-agent,
531 AS_HELP_STRING([--enable-test-python3-agent],
532 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
533 ),[:],[test_python3_agent_autodetect=yes]
534 )
535
536 AC_ARG_ENABLE(test-python-agent-all,
537 AS_HELP_STRING([--enable-test-python-agent-all],
538 [enable test for all python{2/3} agent.]
539 ),
540 )
541
542 AS_IF([test ! -z "$enable_test_python_agent_all"], [
543 unset test_python2_agent_autodetect
544 unset test_python3_agent_autodetect
545 ])
546
547 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
548 enable_test_python2_agent=yes
549 enable_test_python3_agent=yes
550 ])
551
552 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
553 enable_test_python2_agent=no
554 enable_test_python3_agent=no
555 ])
556
557
558 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
559 AS_IF([test -z "$PYTHON2"], [
560 PYTHON2=python2
561 ], [
562 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
563 ])
564
565 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
566 AS_IF([test -z "$PYTHON2_BIN"], [
567 AS_IF([test -z "$test_python2_agent_autodetect"],[
568 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
569 ])
570 ], [
571 AC_MSG_CHECKING([for python2 lttng-ust agent])
572 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
573 PYTHON2_AGENT=$PYTHON2_BIN
574 AC_MSG_RESULT([yes])
575 RUN_PYTHON_AGENT_TEST=yes
576 ], [
577 AC_MSG_RESULT([no])
578 AS_IF([test -z "$test_python2_agent_autodetect"],[
579 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
580 ])
581 ])
582
583 ])
584
585 ])
586
587 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
588 AS_IF([test -z "$PYTHON3"], [
589 PYTHON3=python3
590 ], [
591 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
592 ])
593
594 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
595 AS_IF([test -z "$PYTHON3_BIN"], [
596 AS_IF([test -z "$test_python3_agent_autodetect"],[
597 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
598 ])
599 ], [
600 AC_MSG_CHECKING([for python3 lttng-ust agent])
601 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
602 PYTHON3_AGENT=$PYTHON3_BIN
603 AC_MSG_RESULT([yes])
604 RUN_PYTHON_AGENT_TEST=yes
605 ], [
606 AC_MSG_RESULT([no])
607 AS_IF([test -z "$test_python3_agent_autodetect"],[
608 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
609 ])
610 ])
611
612 ])
613 ])
614 AC_SUBST([RUN_PYTHON_AGENT_TEST])
615 AC_SUBST([PYTHON2_AGENT])
616 AC_SUBST([PYTHON3_AGENT])
617
618 # Arguments for binaries build exclusion
619 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
620 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
621 [Disable the build of lttng-consumerd binaries]))
622 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
623 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
624 [Disable the build of lttng-relayd binaries]))
625 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
626 [Disable the build of lttng-sessiond binaries]))
627 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
628 [Disable the build of the extra components]))
629
630
631 # Always build libconfig since it a dependency of libcommon
632 build_lib_config=yes
633
634 build_lib_compat=no
635 build_lib_consumer=no
636 build_lib_hashtable=no
637 build_lib_health=no
638 build_lib_index=no
639 build_lib_kernel_consumer=no
640 build_lib_kernel_ctl=no
641 build_lib_lttng_ctl=no
642 build_lib_relayd=no
643 build_lib_sessiond_comm=no
644 build_lib_testpoint=no
645 build_lib_ust_consumer=no
646
647 # There is an overlap for enabled dependencies, but this makes everything
648 # simpler. libcommon and libconfig are always compiled so they are not repeated
649 # here.
650
651 # Enable binary dependencies.
652 AS_IF([test x$enable_bin_lttng != xno],
653 [
654 build_lib_lttng_ctl=yes
655 ]
656 )
657
658 AS_IF([test x$enable_bin_lttng_consumerd != xno],
659 [
660 build_lib_consumer=yes
661 build_lib_sessiond_comm=yes
662 build_lib_index=yes
663 build_lib_health=yes
664 build_lib_testpoint=yes
665 ]
666 )
667
668 AS_IF([test x$enable_bin_lttng_crash != xno],
669 # Do nothing since libconfig and libcommon are built by default.
670 []
671 )
672
673 AS_IF([test x$enable_bin_lttng_relayd != xno],
674 [
675 build_lib_lttng_ctl=yes
676 build_lib_sessiond_comm=yes
677 build_lib_hashtable=yes
678 build_lib_compat=yes
679 build_lib_index=yes
680 build_lib_health=yes
681 build_lib_testpoint=yes
682 ]
683 )
684 AS_IF([test x$enable_bin_lttng_sessiond != xno],
685 [
686 build_lib_lttng_ctl=yes
687 build_lib_sessiond_comm=yes
688 build_lib_kernel_ctl=yes
689 build_lib_hashtable=yes
690 build_lib_compat=yes
691 build_lib_relayd=yes
692 build_lib_testpoint=yes
693 build_lib_health=yes
694 build_lib_health=yes
695 ]
696 )
697
698 # Libraries dependencies enabling
699 AS_IF([test x$build_lib_lttng_ctl = xyes],
700 [
701 build_lib_sessiond_comm=yes
702 build_lib_hashtable=yes
703 ]
704 )
705
706 AS_IF([test x$build_lib_consumer = xyes],
707 [
708 build_lib_sessiond_comm=yes
709 build_lib_kernel_consumer=yes
710 build_lib_hashtable=yes
711 build_lib_compat=yes
712 build_lib_relayd=yes
713 AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
714 ]
715 )
716
717 AS_IF([test x$build_lib_kernel_consumer = xyes],
718 [
719 build_lib_kernel_ctl=yes
720 build_lib_relayd=yes
721 ]
722 )
723
724 AS_IF([test x$build_lib_relayd = xyes],
725 [
726 build_lib_sessiond_comm=yes
727 ]
728 )
729
730
731 # Export binaries build conditions.
732 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
733 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
734 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
735 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
736 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
737
738 # Export the tests and extras build conditions.
739 AS_IF([\
740 test "x$enable_bin_lttng" != "xno" && \
741 test "x$enable_bin_lttng_consumerd" != "xno" && \
742 test "x$enable_bin_lttng_crash" != "xno" && \
743 test "x$enable_bin_lttng_relayd" != "xno" && \
744 test "x$enable_bin_lttng_sessiond" != "xno"],
745 [build_tests=yes],
746 [build_tests=no]
747 )
748
749 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
750 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
751
752 # Export libraries build conditions.
753 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
754 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
755 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
756 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
757 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
758 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
759 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
760 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
761 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
762 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
763 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
764 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
765 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
766
767 # check for pgrep
768 AC_PATH_PROG([PGREP], [pgrep], [no])
769 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
770
771 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
772 if test x"$(basename "$YACC")" != "xbison -y"; then
773 AC_MSG_ERROR([[bison not found and is required when building from git.
774 Please install bison]])
775 fi
776 AC_PATH_PROG([BISON],[bison])
777 AX_PROG_BISON_VERSION([2.4], [],[
778 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
779 ])
780 fi
781
782 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
783 if test x"$LEX" != "xflex"; then
784 AC_MSG_ERROR([[flex not found and is required when building from git.
785 Please install flex]])
786 fi
787 AC_PATH_PROG([FLEX],[flex])
788 AX_PROG_FLEX_VERSION([2.5.35], [],[
789 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
790 ])
791 fi
792
793 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
794
795 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
796
797 lttngincludedir="${includedir}/lttng"
798
799 AC_SUBST(lttngincludedir)
800 AC_SUBST(DEFAULT_INCLUDES)
801
802 lttnglibexecdir="${libdir}/lttng/libexec"
803 AC_SUBST(lttnglibexecdir)
804
805 AC_CONFIG_FILES([
806 Makefile
807 doc/Makefile
808 doc/man/Makefile
809 include/Makefile
810 extras/Makefile
811 extras/bindings/Makefile
812 extras/bindings/swig/Makefile
813 extras/bindings/swig/python/Makefile
814 extras/core-handler/Makefile
815 src/Makefile
816 src/common/Makefile
817 src/common/kernel-ctl/Makefile
818 src/common/kernel-consumer/Makefile
819 src/common/consumer/Makefile
820 src/common/ust-consumer/Makefile
821 src/common/hashtable/Makefile
822 src/common/sessiond-comm/Makefile
823 src/common/compat/Makefile
824 src/common/relayd/Makefile
825 src/common/testpoint/Makefile
826 src/common/index/Makefile
827 src/common/health/Makefile
828 src/common/config/Makefile
829 src/lib/Makefile
830 src/lib/lttng-ctl/Makefile
831 src/lib/lttng-ctl/filter/Makefile
832 src/lib/lttng-ctl/lttng-ctl.pc
833 src/bin/Makefile
834 src/bin/lttng-consumerd/Makefile
835 src/bin/lttng-sessiond/Makefile
836 src/bin/lttng-relayd/Makefile
837 src/bin/lttng/Makefile
838 src/bin/lttng-crash/Makefile
839 tests/Makefile
840 tests/destructive/Makefile
841 tests/regression/Makefile
842 tests/regression/kernel/Makefile
843 tests/regression/tools/Makefile
844 tests/regression/tools/streaming/Makefile
845 tests/regression/tools/filtering/Makefile
846 tests/regression/tools/health/Makefile
847 tests/regression/tools/tracefile-limits/Makefile
848 tests/regression/tools/snapshots/Makefile
849 tests/regression/tools/live/Makefile
850 tests/regression/tools/exclusion/Makefile
851 tests/regression/tools/save-load/Makefile
852 tests/regression/tools/mi/Makefile
853 tests/regression/tools/wildcard/Makefile
854 tests/regression/tools/crash/Makefile
855 tests/regression/tools/metadata-regen/Makefile
856 tests/regression/ust/Makefile
857 tests/regression/ust/nprocesses/Makefile
858 tests/regression/ust/high-throughput/Makefile
859 tests/regression/ust/low-throughput/Makefile
860 tests/regression/ust/before-after/Makefile
861 tests/regression/ust/buffers-pid/Makefile
862 tests/regression/ust/periodical-metadata-flush/Makefile
863 tests/regression/ust/multi-session/Makefile
864 tests/regression/ust/overlap/Makefile
865 tests/regression/ust/overlap/demo/Makefile
866 tests/regression/ust/linking/Makefile
867 tests/regression/ust/daemon/Makefile
868 tests/regression/ust/exit-fast/Makefile
869 tests/regression/ust/fork/Makefile
870 tests/regression/ust/libc-wrapper/Makefile
871 tests/regression/ust/baddr-statedump/Makefile
872 tests/regression/ust/ust-dl/Makefile
873 tests/regression/ust/java-jul/Makefile
874 tests/regression/ust/java-log4j/Makefile
875 tests/regression/ust/python-logging/Makefile
876 tests/regression/ust/getcpu-override/Makefile
877 tests/regression/ust/clock-override/Makefile
878 tests/regression/ust/type-declarations/Makefile
879 tests/stress/Makefile
880 tests/unit/Makefile
881 tests/unit/ini_config/Makefile
882 tests/utils/Makefile
883 tests/utils/tap/Makefile
884 tests/utils/testapp/Makefile
885 tests/utils/testapp/gen-ust-events/Makefile
886 tests/utils/testapp/gen-ust-nevents/Makefile
887 tests/utils/testapp/gen-ust-tracef/Makefile
888 ])
889
890 # Inject variable into python test script.
891 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
892
893 AC_OUTPUT
894
895 #
896 # Mini-report on what will be built.
897 #
898
899 PPRINT_INIT
900 PPRINT_SET_INDENT(1)
901 PPRINT_SET_TS(38)
902
903 AS_ECHO
904 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
905 AS_ECHO
906
907 AS_IF([test -n "$report_fold"], [
908 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
909 ], [
910 AS_ECHO("$version_description")
911 ])
912
913 AS_ECHO
914 PPRINT_SUBTITLE([Features])
915
916 # Target architecture we're building for.
917 target_arch=$host_cpu
918 [
919 for f in $CFLAGS; do
920 if test $f = "-m32"; then
921 target_arch="32-bit"
922 elif test $f = "-m64"; then
923 target_arch="64-bit"
924 fi
925 done
926 ]
927 PPRINT_PROP_STRING([Target architecture], $target_arch)
928
929 # kmod enabled/disabled
930 test "x$kmod_found" = "xyes" && value=1 || value=0
931 PPRINT_PROP_BOOL([libkmod support], $value)
932
933 # LTTng-UST enabled/disabled
934 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
935 PPRINT_PROP_BOOL([LTTng-UST support], $value)
936
937 AS_ECHO
938 PPRINT_SUBTITLE([Binaries])
939
940 # List binaries to be built
941 test x$enable_bin_lttng != xno && value=1 || value=0
942 PPRINT_PROP_BOOL([lttng], $value)
943
944 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
945 PPRINT_PROP_BOOL([lttng-consumerd], $value)
946
947 test x$enable_bin_lttng_crash != xno && value=1 || value=0
948 PPRINT_PROP_BOOL([lttng-crash], $value)
949
950 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
951 PPRINT_PROP_BOOL([lttng-relayd], $value)
952
953 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
954 PPRINT_PROP_BOOL([lttng-sessiond], $value)
955
956 # Extras
957 test x$enable_extras != xno && value=1 || value=0
958 AS_ECHO
959 PPRINT_SET_INDENT(0)
960 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
961 PPRINT_SET_INDENT(1)
962
963 AS_ECHO
964 PPRINT_SUBTITLE([Tests])
965
966 # Print clear message that tests won't be built
967 AS_IF([test "x$build_tests" = "xno"],[
968 PPRINT_WARN([Tests won't be built since some binaries were disabled])
969 ])
970
971 # LTTng UST Java agent JUL tests enabled/disabled
972 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
973 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
974
975 # LTTng UST Java agent Log4j tests enabled/disabled
976 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
977 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
978
979 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
980 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
981
982 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
983 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
984
985 #Python binding enabled/disabled
986 test "x${enable_python_binding:-yes}" = xyes && value=1 || value=0
987 AS_ECHO
988 PPRINT_SET_INDENT(0)
989 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
990 PPRINT_SET_INDENT(1)
991
992 AS_ECHO
993 PPRINT_SUBTITLE([Man pages])
994
995 # man pages build enabled/disabled
996 AS_IF([test "x$build_man_pages" = "xyes"], [
997 PPRINT_PROP_BOOL([Build man pages], 1)
998 ], [
999 AS_IF([test "x$in_git_repo" = "xyes"], [
1000 PPRINT_PROP_BOOL([Build man pages], 0)
1001 ], [
1002 PPRINT_PROP_STRING([Build man pages], [${PPRINT_COLOR_BLDGRN}Already built])
1003 ])
1004 ])
1005
1006 # man pages install enabled/disabled (always true in tarball)
1007 test "x$build_man_pages" != "xyes" && test "x$in_git_repo" = "xyes" && value=0 || value=1
1008 PPRINT_PROP_BOOL([Install man pages], $value)
1009
1010 report_bindir="`eval eval echo $bindir`"
1011 report_libdir="`eval eval echo $libdir`"
1012
1013 # Print the bindir and libdir this `make install' will install into.
1014 AS_ECHO
1015 PPRINT_SUBTITLE([Install directories])
1016 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1017 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1018
1019 AS_ECHO
1020 PPRINT_SUBTITLE([Search directories])
1021
1022 # If we build the sessiond, print the paths it will use
1023 AS_IF([test "$SESSIOND_BIN" = ""],[
1024 path="$report_bindir/lttng-sessiond"
1025 ],[
1026 path="$SESSIOND_BIN"
1027 ])
1028 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1029
1030 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1031 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1032 ],[
1033 path="$CONSUMERD32_BIN"
1034 ])
1035 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1036
1037 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1038 path="`eval eval echo $libdir`"
1039 ],[
1040 path="$CONSUMERD32_LIBDIR"
1041 ])
1042 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1043
1044 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1045 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1046 ],[
1047 path="$CONSUMERD64_BIN"
1048 ])
1049 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1050
1051 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1052 path="`eval eval echo $libdir`"
1053 ],[
1054 path="$CONSUMERD64_LIBDIR"
1055 ])
1056 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
This page took 0.084648 seconds and 4 git commands to generate.