configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_COMMON_LIST], [ dnl
  61   -Wall dnl
  62   -Wextra dnl
  63   -Wmissing-declarations dnl
  64   -Wnull-dereference dnl
  65   -Wundef dnl
  66   -Wredundant-decls dnl
  67   -Wshadow dnl
  68   -Wsuggest-attribute=format dnl
  69   -Wtautological-constant-out-of-range-compare dnl Clang specific
  70   -Wwrite-strings dnl
  71   -Wformat=2 dnl
  72   -Wstrict-aliasing dnl
  73   -Wmissing-noreturn dnl
  74   -Wduplicated-cond dnl
  75   -Wduplicated-branches dnl
  76   -Wlogical-op dnl
  77   -Winit-self dnl
  78   dnl We currently get this warning when building with Clang:
  79   dnl
  80   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  81   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  82   dnl            ^
  83   -Wno-incomplete-setjmp-declaration dnl
  84   -Wno-gnu-folding-constant dnl Clang specific
  85 ])
  86
  87 # Detect warning flags specific to the C compiler and append them to
  88 # WARN_CFLAGS.
  89 m4_define([WARN_FLAGS_C_LIST], [ dnl
  90   -Wdiscarded-qualifiers dnl
  91   -Wmissing-prototypes dnl
  92   -Wmissing-parameter-type dnl
  93   -Wsuggest-final-types dnl
  94   -Wsuggest-final-methods dnl
  95   -Wsuggest-override dnl
  96 ])
  97
  98 # Pass -Werror as an extra flag during the test: this is needed to make the
  99 # -Wunknown-warning-option diagnostic fatal with clang.
 100 AC_LANG_PUSH([C])
 101 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_C_LIST], [WARN_CFLAGS], [-Werror])
 102 AC_LANG_POP([C])
 103
 104 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 105 # written in such a way that it triggers warnings with the following warning
 106 # flags.  So they would always end up disabled if we put them there, because
 107 # the test program would not build.
 108 #
 109 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 110 # Clang >= 3.3 (required by the project) and are only valid for C code.
 111 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 112
 113 # Disable 'strict aliasing' if the C compiler supports it.
 114 AC_LANG_PUSH([C])
 115 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 116 AC_LANG_POP([C])
 117
 118
 119 ##                     ##
 120 ## C++ compiler checks ##
 121 ##                     ##
 122
 123 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 124 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 125
 126 # Detect warning flags specific to the C++ compiler and append them to
 127 # WARN_CXXFLAGS.
 128 m4_define([WARN_FLAGS_CXX_LIST], [ dnl
 129   dnl GCC enables this with -Wall in C++, and that generates a
 130   dnl lot of warnings that have on average a low value to fix.
 131   -Wno-sign-compare dnl
 132 ])
 133
 134 # Pass -Werror as an extra flag during the test: this is needed to make the
 135 # -Wunknown-warning-option diagnostic fatal with clang.
 136 AC_LANG_PUSH([C++])
 137 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_CXX_LIST], [WARN_CXXFLAGS], [-Werror])
 138 AC_LANG_POP([C++])
 139
 140 # Disable 'strict aliasing' if the C++ compiler supports it.
 141 AC_LANG_PUSH([C++])
 142 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 143 AC_LANG_POP([C++])
 144
 145
 146 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 147 AC_ARG_ENABLE([Werror],[
 148   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 149 ])
 150
 151 AS_IF([test "x$enable_Werror" = "xyes"], [
 152   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 153   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 154 ])
 155
 156 # Checks for programs.
 157 AC_PROG_GREP
 158 AC_PROG_MAKE_SET
 159 AC_PROG_SED
 160 AC_PATH_PROG([report_fold], [fold])
 161 LT_INIT
 162
 163 # Check for objcopy, required by the base address statedump and dynamic linker tests
 164 AC_CHECK_TOOL([OBJCOPY], [objcopy])
 165 AS_IF([test "x$OBJCOPY" = "x"],
 166         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 167 )
 168 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != "x"])
 169
 170 # check for pgrep
 171 AC_PATH_PROG([PGREP], [pgrep])
 172 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "x"])
 173
 174 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 175 # is not distributed in tarballs
 176 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 177 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 178
 179 # check for bison
 180 AC_PROG_YACC
 181 BISON=$YACC
 182 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 183
 184 AS_IF([test "x$have_bison" != "xyes"], [
 185   AS_IF([test "x$in_git_repo" = "xyes"], [
 186     AC_MSG_FAILURE([
 187 Bison >= 2.4 is required when building from the Git repository. You can
 188 set the YACC variable to override automatic detection.
 189     ])
 190   ], [
 191     AC_MSG_WARN([
 192 Missing Bison >= 2.4. Note that the parser files are already built in
 193 this distribution tarball, so Bison is only needed if you intend to
 194 modify their sources. You can set the YACC variable to override automatic
 195 detection.
 196     ])
 197   ])
 198 ])
 199 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 200
 201 # check for flex
 202 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 203 # problem since the argument is silently ignored by older versions.
 204 AC_PROG_LEX([noyywrap])
 205 FLEX=$LEX
 206 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 207
 208 AS_IF([test "x$have_flex" != "xyes"], [
 209   AS_IF([test "x$in_git_repo" = "xyes"], [
 210     AC_MSG_FAILURE([
 211 Flex >= 2.5.35 is required when building from the Git repository. You can
 212 set the LEX variable to override automatic detection.
 213     ])
 214   ], [
 215     AC_MSG_WARN([
 216 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 217 this distribution tarball, so Flex is only needed if you intend to
 218 modify their sources. You can set the LEX variable to override automatic
 219 detection.
 220     ])
 221   ])
 222 ])
 223 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 224
 225
 226
 227 # Check if linker has the -no-pie option.
 228 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 229 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 230
 231 AX_LIB_SOCKET_NSL
 232
 233 LT_NO_UNDEFINED=""
 234 AS_CASE([$host_os],
 235   [cygwin*],
 236     [
 237       LT_NO_UNDEFINED="-no-undefined"
 238     ],
 239   [cygwin*|darwin*|mingw*|solaris*],
 240     [
 241       # On platforms where we only support the relayd, disable the other binaries by default
 242       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 243       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 244       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 245       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 246       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 247       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 248     ]
 249 )
 250
 251 AC_SUBST(LT_NO_UNDEFINED)
 252
 253 # Compute minor/major/patchlevel version numbers
 254 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 255 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 256 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 257
 258 AC_SUBST([MAJOR_VERSION], [$major_version])
 259 AC_SUBST([MINOR_VERSION], [$minor_version])
 260 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 261 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 262 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 263 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 264
 265 version_name="O-Beer"
 266 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 267 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 268
 269 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 270 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 271
 272 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 273 AC_ARG_ENABLE(libtool-linkdep-fixup,
 274         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 275                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 276         libtool_fixup=$enableval,
 277         libtool_fixup=yes)
 278
 279 AS_IF([test "x$libtool_fixup" = "xyes"],
 280             [
 281             libtool_m4="$srcdir/m4/libtool.m4"
 282             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 283             AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4])
 284             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 285             AS_IF([test $libtool_flag_pattern_count -ne 0],
 286             [
 287                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 288                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 289                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 290                   ],
 291                   [
 292                   AC_MSG_RESULT([none])
 293                   ])
 294             ])
 295
 296 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 297
 298 AC_CHECK_HEADERS([ \
 299         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 300         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 301         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 302         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 303         sys/mount.h sys/param.h sys/time.h elf.h
 304 ])
 305
 306 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 307
 308 # Basic functions check
 309 AC_CHECK_FUNCS([ \
 310         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 311         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 312         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 313         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 314         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 315         sched_getcpu sysconf sync_file_range
 316 ])
 317
 318 # Check for pthread_setname_np and pthread_getname_np
 319 LTTNG_PTHREAD_SETNAME_NP
 320 LTTNG_PTHREAD_GETNAME_NP
 321
 322 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 323 # add -lrt to LIBS
 324 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 325
 326 # Checks for dl.
 327 AC_CHECK_LIB([dl], [dlopen], [
 328         have_libdl=yes
 329         libdl_name=dl
 330         DL_LIBS="-ldl"
 331 ], [
 332         # libdl not found, check for dlopen in libc.
 333         AC_CHECK_LIB([c], [dlopen], [
 334                 have_libc_dl=yes
 335                 libdl_name=c
 336                 DL_LIBS="-lc"
 337         ], [
 338                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 339         ])
 340 ])
 341 AC_SUBST(DL_LIBS)
 342
 343 # Check if libdl has dlmopen support.
 344 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 345 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 346         AC_DEFINE([HAVE_DLMOPEN], [1])
 347         HAVE_DLMOPEN=1
 348 ], [
 349         HAVE_DLMOPEN=0
 350 ])
 351 AC_SUBST(HAVE_DLMOPEN)
 352
 353 # Babeltrace viewer check
 354 AC_ARG_WITH([babeltrace-bin],
 355         AS_HELP_STRING([--with-babeltrace-bin],
 356         [Location of the babeltrace viewer executable (including the filename)]),
 357         [BABELTRACE_BIN="$withval"],
 358         [BABELTRACE_BIN=''])
 359 AC_SUBST([BABELTRACE_BIN])
 360
 361 AC_ARG_WITH([babeltrace2-bin],
 362         AS_HELP_STRING([--with-babeltrace2-bin],
 363         [Location of the babeltrace2 viewer executable (including the filename)]),
 364         [BABELTRACE2_BIN="$withval"],
 365         [BABELTRACE2_BIN=''])
 366 AC_SUBST([BABELTRACE2_BIN])
 367
 368 AC_ARG_WITH([consumerd32-bin],
 369         AS_HELP_STRING([--with-consumerd32-bin],
 370         [Location of the 32-bit consumerd executable (including the filename)]),
 371         [CONSUMERD32_BIN="$withval"],
 372         [CONSUMERD32_BIN=''])
 373 AC_SUBST([CONSUMERD32_BIN])
 374
 375 AC_ARG_WITH([consumerd64-bin],
 376         AS_HELP_STRING([--with-consumerd64-bin],
 377         [Location of the 64-bit consumerd executable (including the filename)]),
 378         [CONSUMERD64_BIN="$withval"],
 379         [CONSUMERD64_BIN=''])
 380 AC_SUBST([CONSUMERD64_BIN])
 381
 382 AC_ARG_WITH([consumerd32-libdir],
 383         AS_HELP_STRING([--with-consumerd32-libdir],
 384         [Directory containing the 32-bit consumerd libraries]),
 385         [CONSUMERD32_LIBDIR="$withval"],
 386         [CONSUMERD32_LIBDIR=''])
 387 AC_SUBST([CONSUMERD32_LIBDIR])
 388
 389 AC_ARG_WITH([consumerd64-libdir],
 390         AS_HELP_STRING([--with-consumerd64-libdir],
 391         [Directory containing the 64-bit consumerd libraries]),
 392         [CONSUMERD64_LIBDIR="$withval"],
 393         [CONSUMERD64_LIBDIR=''])
 394 AC_SUBST([CONSUMERD64_LIBDIR])
 395
 396 AC_ARG_WITH([sessiond-bin],
 397         AS_HELP_STRING([--with-sessiond-bin],
 398         [Location of the sessiond executable (including the filename)]),
 399         [SESSIOND_BIN="$withval"],
 400         [SESSIOND_BIN=''])
 401 AC_SUBST([SESSIOND_BIN])
 402
 403 AC_ARG_WITH([lttng-system-rundir],
 404         AS_HELP_STRING([--with-lttng-system-rundir],
 405         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 406         [LTTNG_SYSTEM_RUNDIR="$withval"],
 407         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 408 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 409
 410 AC_ARG_ENABLE([test-java-agent-jul],
 411         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 412         [test_java_agent_jul=$enableval],
 413         [test_java_agent_jul=no]
 414 )
 415
 416 AC_ARG_ENABLE([test-java-agent-log4j],
 417         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])],
 418         [test_java_agent_log4j=$enableval],
 419         [test_java_agent_log4j=no]
 420 )
 421
 422 AC_ARG_ENABLE([test-java-agent-log4j2],
 423         [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])],
 424         [test_java_agent_log4j2=$enableval],
 425         [test_java_agent_log4j2=no]
 426 )
 427
 428 AC_ARG_ENABLE([test-java-agent-all],
 429         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 430         [test_java_agent_jul=$enableval
 431          test_java_agent_log4j=$enableval
 432          test_java_agent_log4j2=$enableval],
 433         [:]
 434 )
 435
 436 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 437 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 438 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 439 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 440 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 441 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 442 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 443 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 444
 445 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 446         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 447         $1="$2"
 448         AC_SUBST([$1])
 449 ])
 450
 451 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 452         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 453         $1="$2"
 454         AC_SUBST([$1])
 455 ])
 456
 457 # Default values
 458 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 459 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 460 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 461 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 462 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 463 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 464 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 465 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 466 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 467 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 468 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 469 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 470 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 471 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 472 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 473 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 474 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 475 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 476 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 477 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 478 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 479 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 480 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 481 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 482 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 483 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 484 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 485 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 486 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 487 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 488 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 489 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 490 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 491 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 492 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 493 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 494 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 495 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 496 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 497 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 498 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 499 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 500 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 501 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 502 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 503 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 504 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 505 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 506 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 507 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 508
 509 # Command short descriptions
 510 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 511 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 512 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 513 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 514 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 515 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 516 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 517 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 518 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 519 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 520 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 521 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 522 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 523 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 524 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 525 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 526 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 527 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 528 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 529 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 530 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 531 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 532 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 533 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 534 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 535 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 536 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 537 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 538
 539 if test "x$prefix" = "xNONE"; then
 540         prefix=$ac_default_prefix
 541 fi
 542 CONFDIR=`eval echo $sysconfdir`
 543 AC_SUBST(CONFDIR)
 544 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 545
 546 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 547
 548 # Check libpopt
 549 PKG_CHECK_MODULES([POPT], [popt],
 550   [
 551     dnl PKG_CHECK_MODULES defines POPT_LIBS
 552   ],
 553   [
 554     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 555     AC_MSG_WARN([Finding libpopt without pkg-config.])
 556     AC_CHECK_LIB([popt],
 557       [poptGetContext],
 558       [POPT_LIBS="-lpopt"],
 559       [
 560         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 561       ]
 562     )
 563   ]
 564 )
 565 AC_SUBST(POPT_LIBS)
 566
 567 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 568
 569 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 570
 571 # URCU library version needed or newer
 572 PKG_CHECK_MODULES([URCU], [liburcu >= 0.14])
 573 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.14])
 574 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 575
 576 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 577 # it can be explicitly disabled with --without-kmod
 578 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 579 AC_ARG_WITH([kmod],
 580   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 581   [],
 582   [with_kmod=check]
 583 )
 584
 585 AS_IF([test "x$with_kmod" != "xno"],
 586   [
 587     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 588       [
 589         AC_DEFINE([HAVE_KMOD], [1])
 590         KMOD_LIBS="-lkmod"
 591       ],
 592       [
 593         if test "x$with_kmod" != xcheck; then
 594           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 595         else
 596           with_kmod=no
 597         fi
 598       ]
 599     )
 600   ]
 601 )
 602 AC_SUBST(KMOD_LIBS)
 603
 604 # Check for liblttng-ust-ctl, fail if it's not found,
 605 # it can be explicitly disabled with --without-lttng-ust
 606 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 607 AC_ARG_WITH([lttng-ust],
 608   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 609   [],
 610   [with_lttng_ust=yes]
 611 )
 612
 613 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 614   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 615
 616   # Check for liblttng-ust
 617   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 618
 619   # Check for liblttng-ust-ctl
 620   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 621
 622   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 623 ])
 624
 625 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 626
 627
 628 # Check for fmemopen
 629 AC_CHECK_LIB([c], [fmemopen],
 630 [
 631         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 632 ]
 633 )
 634
 635 # check for libpfm
 636 AC_CHECK_LIB([pfm], [pfm_initialize],
 637              [
 638               have_libpfm=yes
 639               ])
 640 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 641
 642 # For Python
 643 # SWIG version needed or newer:
 644 swig_version=2.0.0
 645
 646 AC_ARG_ENABLE([python-bindings],
 647               [AS_HELP_STRING([--enable-python-bindings],
 648                               [compile Python bindings])],
 649               [enable_python_binding=$enableval], [enable_python_binding=no])
 650
 651 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 652
 653 if test "x$enable_python_binding" = xyes; then
 654   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 655   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 656   AM_PATH_PYTHON([3.0])
 657
 658   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 659   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 660   AS_IF([test -z "$PYTHON_INCLUDE"], [
 661     AS_IF([test -z "$PYTHON_CONFIG"], [
 662       AC_PATH_PROGS([PYTHON_CONFIG],
 663                     [python$PYTHON_VERSION-config python-config],
 664                     [],
 665                     [`dirname $PYTHON`])
 666       AS_IF([test "x$PYTHON_CONFIG" = "x"], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 667     ])
 668     AC_MSG_CHECKING([python include flags])
 669     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 670     AC_MSG_RESULT([$PYTHON_INCLUDE])
 671   ])
 672
 673 else
 674     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 675 [if you want Python bindings.])
 676
 677 fi
 678
 679 # Epoll check. If not present, the build will fallback on poll() API
 680 AX_HAVE_EPOLL(
 681         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 682         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 683 )
 684 AX_CONFIG_FEATURE(
 685         [epoll], [This platform supports epoll(7)],
 686         [HAVE_EPOLL], [This platform supports epoll(7).]
 687 )
 688
 689 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 690         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 691         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 692 )
 693 AX_CONFIG_FEATURE(
 694         [dirfd], [Use directory file descriptors],
 695         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 696 )
 697
 698 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 699 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 700 AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"])
 701
 702 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then
 703         AX_JAVA_OPTIONS
 704         AX_PROG_JAVAC
 705         AX_PROG_JAVA
 706         AX_PROG_JAR
 707
 708         AX_CHECK_CLASSPATH
 709
 710         # Check for Java UST agent common class first
 711         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 712         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 713                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 714         fi
 715
 716         if test "x$test_java_agent_jul" = "xyes"; then
 717                 # Check for JUL agent class
 718                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 719                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 720                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 721                 fi
 722         fi
 723
 724         if test "x$test_java_agent_log4j" = "xyes"; then
 725                 # Check for Log4j agent class
 726                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 727                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 728                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 729                 fi
 730
 731                 # Check for Log4j class
 732                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 733                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 734                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 735                 fi
 736         fi
 737
 738         if test "x$test_java_agent_log4j2" = "xyes"; then
 739                 # Check for Log4j2 agent class
 740                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender)
 741                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then
 742                         AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"])
 743                 fi
 744
 745                 # Check for Log4j 2.x classes
 746                 AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 747                 AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 748                 if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then
 749                         AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"])
 750                 fi
 751         fi
 752 fi
 753
 754 # enable building man pages (user's intention)
 755 AC_ARG_ENABLE(
 756         man-pages,
 757         AS_HELP_STRING(
 758                 [--disable-man-pages],
 759                 [Do not build and install man pages (already built in a distributed tarball)]
 760         ),
 761         [man_pages_opt=$enableval],
 762         [man_pages_opt=yes]
 763 )
 764
 765 # check for asciidoc and xmlto if we enabled building the man pages
 766 have_asciidoc_xmlto=no
 767 warn_prebuilt_man_pages=no
 768
 769 AS_IF([test "x$man_pages_opt" = "xyes"], [
 770         AC_PATH_PROG([ASCIIDOC], [asciidoc])
 771         AC_PATH_PROG([XMLTO], [xmlto])
 772
 773         AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 774                 AS_IF([test "x$in_git_repo" = "xyes"], [
 775                         # this is an error because we're in the Git repo, which
 776                         # means the man pages are not already generated for us,
 777                         # thus asciidoc/xmlto are required because we were asked
 778                         # to build the man pages
 779                         AC_MSG_ERROR([
 780 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 781 --disable-man-pages to disable building the man pages, in which case
 782 they will not be installed.
 783                         ])
 784                 ], [
 785                         # only warn here: since we're in the tarball, the man
 786                         # pages should already be generated at this point, thus
 787                         # asciidoc/xmlto are not strictly required
 788                         warn_prebuilt_man_pages=yes
 789                 ])
 790         ], [
 791                 have_asciidoc_xmlto=yes
 792         ])
 793 ])
 794
 795 # export man page build condition: build the man pages if the user
 796 # asked for it, and if the tools are available
 797 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 798 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 799
 800 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 801
 802 # embedded --help message
 803 AC_ARG_ENABLE(
 804         [embedded-help],
 805         AS_HELP_STRING(
 806                 [--enable-embedded-help],
 807                 [Embed the --help messages in the executable files]
 808         ),
 809         [embedded_help=$enableval],
 810         [embedded_help=no]
 811 )
 812 AS_IF([test "x$embedded_help" = "xyes"], [
 813         AS_IF([test "x$man_pages_opt" = "xno"], [
 814                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 815         ])
 816         AC_PATH_PROG([man_prog_path], [man])
 817         AS_IF([test "x$man_prog_path" = "x"], [
 818                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 819         ])
 820         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 821         AC_SUBST([MANPROG], [$man_prog_path])
 822 ])
 823 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 824
 825 # Python agent test
 826 UST_PYTHON_AGENT="lttngust"
 827
 828 AC_ARG_ENABLE(test-python2-agent,
 829         AS_HELP_STRING([--enable-test-python2-agent],
 830                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 831         ),[:],[test_python2_agent_autodetect=yes]
 832 )
 833
 834 AC_ARG_ENABLE(test-python3-agent,
 835         AS_HELP_STRING([--enable-test-python3-agent],
 836                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 837         ),[:],[test_python3_agent_autodetect=yes]
 838 )
 839
 840 AC_ARG_ENABLE(test-python-agent-all,
 841         AS_HELP_STRING([--enable-test-python-agent-all],
 842                 [enable test for all python{2/3} agent.]
 843         ),
 844 )
 845
 846 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 847        unset test_python2_agent_autodetect
 848        unset test_python3_agent_autodetect
 849 ])
 850
 851 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 852        enable_test_python2_agent=yes
 853        enable_test_python3_agent=yes
 854 ])
 855
 856 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 857        enable_test_python2_agent=no
 858        enable_test_python3_agent=no
 859 ])
 860
 861
 862 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 863         AS_IF([test -z "$PYTHON2"], [
 864                         PYTHON2=python2
 865                 ], [
 866                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 867         ])
 868
 869         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 870         AS_IF([test -z "$PYTHON2_BIN"], [
 871                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 872                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 873                 ])
 874         ], [
 875                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 876                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 877                         PYTHON2_AGENT=$PYTHON2_BIN
 878                         AC_MSG_RESULT([yes])
 879                         RUN_PYTHON_AGENT_TEST=yes
 880                 ], [
 881                         AC_MSG_RESULT([no])
 882                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 883                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 884                         ])
 885                 ])
 886
 887         ])
 888
 889 ])
 890
 891 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 892         AS_IF([test -z "$PYTHON3"], [
 893                 PYTHON3=python3
 894         ], [
 895                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 896         ])
 897
 898         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 899         AS_IF([test -z "$PYTHON3_BIN"], [
 900                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 901                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 902                 ])
 903         ], [
 904                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 905                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 906                         PYTHON3_AGENT=$PYTHON3_BIN
 907                         AC_MSG_RESULT([yes])
 908                         RUN_PYTHON_AGENT_TEST=yes
 909                 ], [
 910                         AC_MSG_RESULT([no])
 911                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 912                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 913                         ])
 914                 ])
 915
 916         ])
 917 ])
 918 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 919 AC_SUBST([PYTHON2_AGENT])
 920 AC_SUBST([PYTHON3_AGENT])
 921
 922 AC_ARG_ENABLE([test-sdt-uprobe],
 923   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 924   [test_sdt_uprobe="$enableval"],
 925   [test_sdt_uprobe=autodetect]
 926 )
 927
 928 AS_IF([test "$test_sdt_uprobe" != "no"], [
 929   LTTNG_CHECK_SDT_WORKS
 930   AC_PATH_PROG([DTRACE], [dtrace])
 931 ])
 932
 933 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 934   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 935     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 936   ])
 937   AS_IF([test "x$DTRACE" = "x"], [
 938     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 939   ])
 940 ])
 941
 942 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 943   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 944     AS_IF([test "x$DTRACE" != "x"], [
 945       test_sdt_uprobe=yes
 946     ])
 947   ])
 948 ])
 949
 950 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 951
 952 # Arguments for binaries build exclusion
 953 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 954 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 955               [Disable the build of lttng-consumerd binaries]))
 956 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 957 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 958               [Disable the build of lttng-relayd binaries]))
 959 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 960               [Disable the build of lttng-sessiond binaries]))
 961 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 962               [Disable the build of the extra components]))
 963
 964
 965 build_lib_consumer=no
 966 build_lib_health=no
 967 build_lib_index=no
 968 build_lib_kernel_consumer=no
 969 build_lib_kernel_ctl=no
 970 build_lib_lttng_ctl=no
 971 build_lib_relayd=no
 972 build_lib_sessiond_comm=no
 973 build_lib_testpoint=no
 974 build_lib_ust_consumer=no
 975
 976 # There is an overlap for enabled dependencies, but this makes everything
 977 # simpler. libcommon and libconfig are always compiled so they are not repeated
 978 # here.
 979
 980 # Enable binary dependencies.
 981 AS_IF([test x$enable_bin_lttng != xno],
 982       [
 983        build_lib_lttng_ctl=yes
 984       ]
 985 )
 986
 987 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 988       [
 989        build_lib_consumer=yes
 990        build_lib_sessiond_comm=yes
 991        build_lib_index=yes
 992        build_lib_health=yes
 993        build_lib_testpoint=yes
 994       ]
 995 )
 996
 997 AS_IF([test x$enable_bin_lttng_crash != xno],
 998       # Do nothing since libconfig and libcommon are built by default.
 999       []
1000 )
1001
1002 AS_IF([test x$enable_bin_lttng_relayd != xno],
1003       [
1004        build_lib_sessiond_comm=yes
1005        build_lib_index=yes
1006        build_lib_health=yes
1007        build_lib_testpoint=yes
1008       ]
1009 )
1010 AS_IF([test x$enable_bin_lttng_sessiond != xno],
1011       [
1012        build_lib_lttng_ctl=yes
1013        build_lib_sessiond_comm=yes
1014        build_lib_kernel_ctl=yes
1015        build_lib_relayd=yes
1016        build_lib_testpoint=yes
1017        build_lib_health=yes
1018       ]
1019 )
1020
1021 # Libraries dependencies enabling
1022 AS_IF([test x$build_lib_lttng_ctl = xyes],
1023       [
1024        build_lib_sessiond_comm=yes
1025       ]
1026 )
1027
1028 AS_IF([test x$build_lib_consumer = xyes],
1029       [
1030        build_lib_sessiond_comm=yes
1031        build_lib_kernel_consumer=yes
1032        build_lib_relayd=yes
1033        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
1034       ]
1035 )
1036
1037 AS_IF([test x$build_lib_kernel_consumer = xyes],
1038       [
1039        build_lib_kernel_ctl=yes
1040        build_lib_relayd=yes
1041       ]
1042 )
1043
1044 AS_IF([test x$build_lib_relayd = xyes],
1045       [
1046        build_lib_sessiond_comm=yes
1047       ]
1048 )
1049
1050 # Find arch type
1051 AS_CASE([$host_cpu],
1052         [k1om], [ARCHTYPE="x86"],
1053         [i386], [ARCHTYPE="x86"],
1054         [i486], [ARCHTYPE="x86"],
1055         [i586], [ARCHTYPE="x86"],
1056         [i686], [ARCHTYPE="x86"],
1057         [amd64], [ARCHTYPE="x86"],
1058         [x86_64], [ARCHTYPE="x86"],
1059         [powerpc], [ARCHTYPE="ppc"],
1060         [ppc64], [ARCHTYPE="ppc"],
1061         [powerpc64], [ARCHTYPE="ppc"],
1062         [powerpc64le], [ARCHTYPE="ppc"],
1063         [ppc], [ARCHTYPE="ppc"],
1064         [s390], [ARCHTYPE="s390"],
1065         [s390x], [ARCHTYPE="s390"],
1066         [sparc], [ARCHTYPE="sparc64"],
1067         [sparc64], [ARCHTYPE="sparc64"],
1068         [alpha*], [ARCHTYPE="alpha"],
1069         [ia64], [ARCHTYPE="ia64"],
1070         [arm*], [ARCHTYPE="arm"],
1071         [aarch64*], [ARCHTYPE="aarch64"],
1072         [mips*], [ARCHTYPE="mips"],
1073         [nios2*], [ARCHTYPE="nios2"],
1074         [tile*], [ARCHTYPE="tile"],
1075         [hppa*], [ARCHTYPE="hppa"],
1076         [m68k], [ARCHTYPE="m68k"],
1077         [riscv*], [ARCHTYPE="riscv"],
1078         [ARCHTYPE="unknown"]
1079 )
1080
1081 AC_SUBST(ARCHTYPE)
1082
1083 AS_CASE([$host_os],
1084         [linux*], [OSTYPE="linux"],
1085         [freebsd*], [OSTYPE="freebsd"],
1086         [solaris*], [OSTYPE="solaris"],
1087         [cygwin*], [OSTYPE="cygwin"],
1088         [mingw*], [OSTYPE="mingw"],
1089         [OSTYPE="unknown"]
1090 )
1091 AC_SUBST(OSTYPE)
1092 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1093
1094
1095
1096 # Userspace callstack capture is only supported by the Linux kernel on x86.
1097 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1098 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1099         have_modules_userspace_callstack_context=yes
1100         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1101 ])
1102 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1103
1104 # Export binaries build conditions.
1105 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1106 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1107 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1108 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1109 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1110
1111 # Export the tests and extras build conditions.
1112 AS_IF([\
1113 test "x$enable_bin_lttng" != "xno" && \
1114 test "x$enable_bin_lttng_consumerd" != "xno" && \
1115 test "x$enable_bin_lttng_crash" != "xno" && \
1116 test "x$enable_bin_lttng_relayd" != "xno" && \
1117 test "x$enable_bin_lttng_sessiond" != "xno"],
1118 [build_tests=yes],
1119 [build_tests=no]
1120 )
1121
1122 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1123 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1124
1125 # Export libraries build conditions.
1126 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1127 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1128 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1129 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1130 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1131 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1132 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1133 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1134 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1135 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1136
1137 AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1138 AC_SUBST(AM_CFLAGS)
1139
1140 AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1141 AC_SUBST(AM_CXXFLAGS)
1142
1143 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1144 AM_LDFLAGS=""
1145 AC_SUBST(AM_LDFLAGS)
1146
1147 # The order in which the include folders are searched is important.
1148 # The top_builddir should always be searched first in the event that a build
1149 # time generated file is included. An example of this is the "version.i" file.
1150 # In a scenario where lttng-tools is built from a distribution tarball and in a
1151 # out-of-tree manner, the generated "version.i" has priority on the one from
1152 # the source (distribution tarball) and must be found first.
1153 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1154 AC_SUBST(AM_CPPFLAGS)
1155
1156 lttngincludedir="${includedir}/lttng"
1157 AC_SUBST(lttngincludedir)
1158
1159 lttngactionincludedir="${includedir}/lttng/action"
1160 AC_SUBST(lttngactionincludedir)
1161
1162 lttngconditionincludedir="${includedir}/lttng/condition"
1163 AC_SUBST(lttngconditionincludedir)
1164
1165 lttngnotificationincludedir="${includedir}/lttng/notification"
1166 AC_SUBST(lttngnotificationincludedir)
1167
1168 lttngtriggerincludedir="${includedir}/lttng/trigger"
1169 AC_SUBST(lttngtriggerincludedir)
1170
1171 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1172 AC_SUBST(lttngeventruleincludedir)
1173
1174 lttnglibexecdir="${libdir}/lttng/libexec"
1175 AC_SUBST(lttnglibexecdir)
1176
1177 AC_CONFIG_FILES([
1178         Makefile
1179         doc/Makefile
1180         doc/examples/Makefile
1181         doc/examples/rotation/Makefile
1182         doc/examples/trigger-condition-event-matches/Makefile
1183         doc/man/Makefile
1184         doc/man/asciidoc-attrs.conf
1185         include/Makefile
1186         extras/Makefile
1187         extras/bindings/Makefile
1188         extras/bindings/swig/Makefile
1189         extras/bindings/swig/python/Makefile
1190         extras/core-handler/Makefile
1191         src/Makefile
1192         src/common/Makefile
1193         src/lib/Makefile
1194         src/lib/lttng-ctl/Makefile
1195         src/lib/lttng-ctl/lttng-ctl.pc
1196         src/bin/Makefile
1197         src/bin/lttng-consumerd/Makefile
1198         src/bin/lttng-sessiond/Makefile
1199         src/bin/lttng-relayd/Makefile
1200         src/bin/lttng/Makefile
1201         src/bin/lttng-crash/Makefile
1202         src/vendor/Makefile
1203         src/vendor/msgpack/Makefile
1204         tests/Makefile
1205         tests/destructive/Makefile
1206         tests/regression/Makefile
1207         tests/regression/kernel/Makefile
1208         tests/regression/tools/Makefile
1209         tests/regression/tools/streaming/Makefile
1210         tests/regression/tools/filtering/Makefile
1211         tests/regression/tools/health/Makefile
1212         tests/regression/tools/tracefile-limits/Makefile
1213         tests/regression/tools/snapshots/Makefile
1214         tests/regression/tools/live/Makefile
1215         tests/regression/tools/exclusion/Makefile
1216         tests/regression/tools/save-load/Makefile
1217         tests/regression/tools/save-load/configuration/Makefile
1218         tests/regression/tools/mi/Makefile
1219         tests/regression/tools/wildcard/Makefile
1220         tests/regression/tools/channel/Makefile
1221         tests/regression/tools/crash/Makefile
1222         tests/regression/tools/regen-metadata/Makefile
1223         tests/regression/tools/regen-statedump/Makefile
1224         tests/regression/tools/notification/Makefile
1225         tests/regression/tools/rotation/Makefile
1226         tests/regression/tools/base-path/Makefile
1227         tests/regression/tools/metadata/Makefile
1228         tests/regression/tools/tracker/Makefile
1229         tests/regression/tools/working-directory/Makefile
1230         tests/regression/tools/relayd-grouping/Makefile
1231         tests/regression/tools/clear/Makefile
1232         tests/regression/tools/trigger/Makefile
1233         tests/regression/tools/trigger/rate-policy/Makefile
1234         tests/regression/tools/trigger/start-stop/Makefile
1235         tests/regression/tools/trigger/utils/Makefile
1236         tests/regression/tools/trigger/name/Makefile
1237         tests/regression/tools/trigger/hidden/Makefile
1238         tests/regression/ust/Makefile
1239         tests/regression/ust/nprocesses/Makefile
1240         tests/regression/ust/high-throughput/Makefile
1241         tests/regression/ust/low-throughput/Makefile
1242         tests/regression/ust/before-after/Makefile
1243         tests/regression/ust/buffers-pid/Makefile
1244         tests/regression/ust/periodical-metadata-flush/Makefile
1245         tests/regression/ust/multi-session/Makefile
1246         tests/regression/ust/multi-lib/Makefile
1247         tests/regression/ust/overlap/Makefile
1248         tests/regression/ust/overlap/demo/Makefile
1249         tests/regression/ust/linking/Makefile
1250         tests/regression/ust/daemon/Makefile
1251         tests/regression/ust/exit-fast/Makefile
1252         tests/regression/ust/fork/Makefile
1253         tests/regression/ust/libc-wrapper/Makefile
1254         tests/regression/ust/baddr-statedump/Makefile
1255         tests/regression/ust/ust-dl/Makefile
1256         tests/regression/ust/java-jul/Makefile
1257         tests/regression/ust/java-log4j/Makefile
1258         tests/regression/ust/java-log4j2/Makefile
1259         tests/regression/ust/getcpu-override/Makefile
1260         tests/regression/ust/clock-override/Makefile
1261         tests/regression/ust/type-declarations/Makefile
1262         tests/regression/ust/rotation-destroy-flush/Makefile
1263         tests/regression/ust/blocking/Makefile
1264         tests/regression/ust/namespaces/Makefile
1265         tests/stress/Makefile
1266         tests/unit/Makefile
1267         tests/unit/ini_config/Makefile
1268         tests/perf/Makefile
1269         tests/utils/Makefile
1270         tests/utils/tap/Makefile
1271         tests/utils/testapp/Makefile
1272         tests/utils/testapp/gen-ns-events/Makefile
1273         tests/utils/testapp/gen-kernel-test-events/Makefile
1274         tests/utils/testapp/gen-py-events/Makefile
1275         tests/utils/testapp/gen-ust-events/Makefile
1276         tests/utils/testapp/gen-ust-events-ns/Makefile
1277         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1278         tests/utils/testapp/gen-ust-nevents/Makefile
1279         tests/utils/testapp/gen-ust-nevents-str/Makefile
1280         tests/utils/testapp/gen-syscall-events/Makefile
1281         tests/utils/testapp/gen-ust-tracef/Makefile
1282         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1283         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1284         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1285         tests/utils/xml-utils/Makefile
1286 ])
1287
1288 # Inject variable into python test script.
1289 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1290 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1291 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1292 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1293
1294 AC_OUTPUT
1295
1296 #
1297 # Mini-report on what will be built.
1298 #
1299
1300 PPRINT_INIT
1301 PPRINT_SET_INDENT(1)
1302 PPRINT_SET_TS(38)
1303
1304 AS_ECHO
1305 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1306 AS_ECHO
1307
1308 AS_IF([test -n "$report_fold"], [
1309         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1310 ], [
1311         AS_ECHO("$version_description")
1312 ])
1313
1314 AS_ECHO
1315 PPRINT_SUBTITLE([Features])
1316
1317 # Target architecture we're building for.
1318 target_arch=$host_cpu
1319 [
1320 for f in $CFLAGS; do
1321         if test $f = "-m32"; then
1322                         target_arch="32-bit"
1323         elif test $f = "-m64"; then
1324                         target_arch="64-bit"
1325         fi
1326 done
1327 ]
1328 PPRINT_PROP_STRING([Target architecture], $target_arch)
1329
1330 # kmod enabled/disabled
1331 test "x$with_kmod" != "xno" && value=1 || value=0
1332 PPRINT_PROP_BOOL([libkmod support], $value)
1333
1334 # LTTng-UST enabled/disabled
1335 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1336 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1337
1338 AS_ECHO
1339 PPRINT_SUBTITLE([Binaries])
1340
1341 # List binaries to be built
1342 test x$enable_bin_lttng != xno && value=1 || value=0
1343 PPRINT_PROP_BOOL([lttng], $value)
1344
1345 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1346 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1347
1348 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1349 PPRINT_PROP_BOOL([lttng-crash], $value)
1350
1351 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1352 PPRINT_PROP_BOOL([lttng-relayd], $value)
1353
1354 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1355 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1356
1357 # Extras
1358 test x$enable_extras != xno && value=1 || value=0
1359 AS_ECHO
1360 PPRINT_SET_INDENT(0)
1361 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1362 PPRINT_SET_INDENT(1)
1363
1364 AS_ECHO
1365 PPRINT_SUBTITLE([Tests])
1366
1367 # Print clear message that tests won't be built
1368 AS_IF([test "x$build_tests" = "xno"],[
1369         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1370 ])
1371
1372 # LTTng UST Java agent JUL tests enabled/disabled
1373 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1374 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1375
1376 # LTTng UST Java agent Log4j 1.x tests enabled/disabled
1377 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1378 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value)
1379
1380 # LTTng UST Java agent Log4j 2.x tests enabled/disabled
1381 test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0
1382 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value)
1383
1384 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1385 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1386
1387 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1388 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1389
1390 # userspace-probe SDT instrumentation tests enabled/disabled
1391 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1392 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1393
1394 #Python binding enabled/disabled
1395 test "x$enable_python_binding" = xyes && value=1 || value=0
1396 AS_ECHO
1397 PPRINT_SET_INDENT(0)
1398 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1399
1400 # man pages build enabled/disabled
1401 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1402
1403 AS_IF([test "x$man_pages_opt" != "xno"], [
1404         AS_IF([test "x$in_git_repo" = "xyes"], [
1405                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1406         ], [
1407                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1408                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1409                 ], [
1410                         PPRINT_PROP_STRING([build_man_pages_msg],
1411                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1412                                 $PPRINT_COLOR_SUBTITLE)
1413                 ])
1414         ])
1415 ], [
1416         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1417 ])
1418
1419 m4_popdef([build_man_pages_msg])
1420
1421 test "x$embedded_help" = xyes && value=1 || value=0
1422 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1423
1424 PPRINT_SET_INDENT(1)
1425
1426 report_bindir="`eval eval echo $bindir`"
1427 report_libdir="`eval eval echo $libdir`"
1428
1429 # Print the bindir and libdir this `make install' will install into.
1430 AS_ECHO
1431 PPRINT_SUBTITLE([Install directories])
1432 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1433 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1434
1435 AS_ECHO
1436 PPRINT_SUBTITLE([Search directories])
1437
1438 # If we build the sessiond, print the paths it will use
1439 AS_IF([test "$SESSIOND_BIN" = ""],[
1440         path="$report_bindir/lttng-sessiond"
1441 ],[
1442         path="$SESSIOND_BIN"
1443 ])
1444 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1445
1446 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1447         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1448 ],[
1449         path="$CONSUMERD32_BIN"
1450 ])
1451 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1452
1453 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1454         path="`eval eval echo $libdir`"
1455 ],[
1456         path="$CONSUMERD32_LIBDIR"
1457 ])
1458 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1459
1460 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1461         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1462 ],[
1463         path="$CONSUMERD64_BIN"
1464 ])
1465 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1466
1467 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1468         path="`eval eval echo $libdir`"
1469 ],[
1470         path="$CONSUMERD64_LIBDIR"
1471 ])
1472 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1473 PPRINT_SET_INDENT(0)
1474
1475 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1476         AS_ECHO
1477         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1478
1479 Note that the man pages are already built in this distribution tarball,
1480 therefore asciidoc and xmlto are only needed if you intend to modify
1481 their sources.
1482
1483 Also note that the installed man pages will contain the project's
1484 default command-line option and environment variable values.
1485
1486 Use --disable-man-pages to completely disable building and installing
1487 the man pages.])
1488 ])