src/lib/lttng-ctl/filter/filter-parser.y

   1 %{
   2 /*
   3  * filter-parser.y
   4  *
   5  * LTTng filter expression parser
   6  *
   7  * Copyright 2012 - Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
   8  *
   9  * This library is free software; you can redistribute it and/or modify it
  10  * under the terms of the GNU Lesser General Public License, version 2.1 only,
  11  * as published by the Free Software Foundation.
  12  *
  13  * This library is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16  * Lesser General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU Lesser General Public License
  19  * along with this library; if not, write to the Free Software Foundation,
  20  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  21  *
  22  * Grammar inspired from http://www.quut.com/c/ANSI-C-grammar-y.html
  23  */
  24
  25 #include <stdio.h>
  26 #include <unistd.h>
  27 #include <string.h>
  28 #include <stdlib.h>
  29 #include <assert.h>
  30 #include <errno.h>
  31 #include <inttypes.h>
  32 #include "filter-ast.h"
  33 #include "filter-parser.h"
  34
  35 #include <common/macros.h>
  36
  37 #define WIDTH_u64_SCANF_IS_A_BROKEN_API "20"
  38 #define WIDTH_o64_SCANF_IS_A_BROKEN_API "22"
  39 #define WIDTH_x64_SCANF_IS_A_BROKEN_API "17"
  40 #define WIDTH_lg_SCANF_IS_A_BROKEN_API  "4096"  /* Hugely optimistic approximation */
  41
  42 LTTNG_HIDDEN
  43 int yydebug;
  44 LTTNG_HIDDEN
  45 int filter_parser_debug = 0;
  46
  47 LTTNG_HIDDEN
  48 int yyparse(struct filter_parser_ctx *parser_ctx, yyscan_t scanner);
  49 LTTNG_HIDDEN
  50 int yylex(union YYSTYPE *yyval, yyscan_t scanner);
  51 LTTNG_HIDDEN
  52 int yylex_init_extra(struct filter_parser_ctx *parser_ctx, yyscan_t * ptr_yy_globals);
  53 LTTNG_HIDDEN
  54 int yylex_destroy(yyscan_t yyparser_ctx);
  55 LTTNG_HIDDEN
  56 void yyrestart(FILE * in_str, yyscan_t parser_ctx);
  57
  58 struct gc_string {
  59         struct cds_list_head gc;
  60         size_t alloclen;
  61         char s[];
  62 };
  63
  64 static const char *node_type_to_str[] = {
  65         [ NODE_UNKNOWN ] = "NODE_UNKNOWN",
  66         [ NODE_ROOT ] = "NODE_ROOT",
  67         [ NODE_EXPRESSION ] = "NODE_EXPRESSION",
  68         [ NODE_OP ] = "NODE_OP",
  69         [ NODE_UNARY_OP ] = "NODE_UNARY_OP",
  70 };
  71
  72 LTTNG_HIDDEN
  73 const char *node_type(struct filter_node *node)
  74 {
  75         if (node->type < NR_NODE_TYPES)
  76                 return node_type_to_str[node->type];
  77         else
  78                 return NULL;
  79 }
  80
  81 static struct gc_string *gc_string_alloc(struct filter_parser_ctx *parser_ctx,
  82                                          size_t len)
  83 {
  84         struct gc_string *gstr;
  85         size_t alloclen;
  86
  87         /* TODO: could be faster with find first bit or glib Gstring */
  88         /* sizeof long to account for malloc header (int or long ?) */
  89         for (alloclen = 8; alloclen < sizeof(long) + sizeof(*gstr) + len;
  90              alloclen *= 2);
  91
  92         gstr = zmalloc(alloclen);
  93         if (!gstr) {
  94                 goto end;
  95         }
  96         cds_list_add(&gstr->gc, &parser_ctx->allocated_strings);
  97         gstr->alloclen = alloclen;
  98 end:
  99         return gstr;
 100 }
 101
 102 /*
 103  * note: never use gc_string_append on a string that has external references.
 104  * gsrc will be garbage collected immediately, and gstr might be.
 105  * Should only be used to append characters to a string literal or constant.
 106  */
 107 LTTNG_HIDDEN
 108 struct gc_string *gc_string_append(struct filter_parser_ctx *parser_ctx,
 109                                    struct gc_string *gstr,
 110                                    struct gc_string *gsrc)
 111 {
 112         size_t newlen = strlen(gsrc->s) + strlen(gstr->s) + 1;
 113         size_t alloclen;
 114
 115         /* TODO: could be faster with find first bit or glib Gstring */
 116         /* sizeof long to account for malloc header (int or long ?) */
 117         for (alloclen = 8; alloclen < sizeof(long) + sizeof(*gstr) + newlen;
 118              alloclen *= 2);
 119
 120         if (alloclen > gstr->alloclen) {
 121                 struct gc_string *newgstr;
 122
 123                 newgstr = gc_string_alloc(parser_ctx, newlen);
 124                 strcpy(newgstr->s, gstr->s);
 125                 strcat(newgstr->s, gsrc->s);
 126                 cds_list_del(&gstr->gc);
 127                 free(gstr);
 128                 gstr = newgstr;
 129         } else {
 130                 strcat(gstr->s, gsrc->s);
 131         }
 132         cds_list_del(&gsrc->gc);
 133         free(gsrc);
 134         return gstr;
 135 }
 136
 137 LTTNG_HIDDEN
 138 void setstring(struct filter_parser_ctx *parser_ctx, YYSTYPE *lvalp, const char *src)
 139 {
 140         lvalp->gs = gc_string_alloc(parser_ctx, strlen(src) + 1);
 141         strcpy(lvalp->gs->s, src);
 142 }
 143
 144 static struct filter_node *make_node(struct filter_parser_ctx *scanner,
 145                                   enum node_type type)
 146 {
 147         struct filter_ast *ast = filter_parser_get_ast(scanner);
 148         struct filter_node *node;
 149
 150         node = zmalloc(sizeof(*node));
 151         if (!node)
 152                 return NULL;
 153         memset(node, 0, sizeof(*node));
 154         node->type = type;
 155         cds_list_add(&node->gc, &ast->allocated_nodes);
 156
 157         switch (type) {
 158         case NODE_ROOT:
 159                 fprintf(stderr, "[error] %s: trying to create root node\n", __func__);
 160                 break;
 161
 162         case NODE_EXPRESSION:
 163                 break;
 164         case NODE_OP:
 165                 break;
 166         case NODE_UNARY_OP:
 167                 break;
 168
 169         case NODE_UNKNOWN:
 170         default:
 171                 fprintf(stderr, "[error] %s: unknown node type %d\n", __func__,
 172                         (int) type);
 173                 break;
 174         }
 175
 176         return node;
 177 }
 178
 179 static struct filter_node *make_op_node(struct filter_parser_ctx *scanner,
 180                         enum op_type type,
 181                         struct filter_node *lchild,
 182                         struct filter_node *rchild)
 183 {
 184         struct filter_ast *ast = filter_parser_get_ast(scanner);
 185         struct filter_node *node;
 186
 187         node = zmalloc(sizeof(*node));
 188         if (!node)
 189                 return NULL;
 190         memset(node, 0, sizeof(*node));
 191         node->type = NODE_OP;
 192         cds_list_add(&node->gc, &ast->allocated_nodes);
 193         node->u.op.type = type;
 194         node->u.op.lchild = lchild;
 195         node->u.op.rchild = rchild;
 196         return node;
 197 }
 198
 199 LTTNG_HIDDEN
 200 void yyerror(struct filter_parser_ctx *parser_ctx, yyscan_t scanner, const char *str)
 201 {
 202         fprintf(stderr, "error %s\n", str);
 203 }
 204
 205 LTTNG_HIDDEN
 206 int yywrap(void)
 207 {
 208         return 1;
 209 }
 210
 211 #define parse_error(parser_ctx, str)                            \
 212 do {                                                            \
 213         yyerror(parser_ctx, parser_ctx->scanner, YY_("parse error: " str "\n"));        \
 214         YYERROR;                                                \
 215 } while (0)
 216
 217 static void free_strings(struct cds_list_head *list)
 218 {
 219         struct gc_string *gstr, *tmp;
 220
 221         cds_list_for_each_entry_safe(gstr, tmp, list, gc)
 222                 free(gstr);
 223 }
 224
 225 static struct filter_ast *filter_ast_alloc(void)
 226 {
 227         struct filter_ast *ast;
 228
 229         ast = zmalloc(sizeof(*ast));
 230         if (!ast)
 231                 return NULL;
 232         memset(ast, 0, sizeof(*ast));
 233         CDS_INIT_LIST_HEAD(&ast->allocated_nodes);
 234         ast->root.type = NODE_ROOT;
 235         return ast;
 236 }
 237
 238 static void filter_ast_free(struct filter_ast *ast)
 239 {
 240         struct filter_node *node, *tmp;
 241
 242         cds_list_for_each_entry_safe(node, tmp, &ast->allocated_nodes, gc)
 243                 free(node);
 244         free(ast);
 245 }
 246
 247 LTTNG_HIDDEN
 248 int filter_parser_ctx_append_ast(struct filter_parser_ctx *parser_ctx)
 249 {
 250         return yyparse(parser_ctx, parser_ctx->scanner);
 251 }
 252
 253 LTTNG_HIDDEN
 254 struct filter_parser_ctx *filter_parser_ctx_alloc(FILE *input)
 255 {
 256         struct filter_parser_ctx *parser_ctx;
 257         int ret;
 258
 259         yydebug = filter_parser_debug;
 260
 261         parser_ctx = zmalloc(sizeof(*parser_ctx));
 262         if (!parser_ctx)
 263                 return NULL;
 264         memset(parser_ctx, 0, sizeof(*parser_ctx));
 265
 266         ret = yylex_init_extra(parser_ctx, &parser_ctx->scanner);
 267         if (ret) {
 268                 fprintf(stderr, "yylex_init error\n");
 269                 goto cleanup_parser_ctx;
 270         }
 271         /* Start processing new stream */
 272         yyrestart(input, parser_ctx->scanner);
 273
 274         parser_ctx->ast = filter_ast_alloc();
 275         if (!parser_ctx->ast)
 276                 goto cleanup_lexer;
 277         CDS_INIT_LIST_HEAD(&parser_ctx->allocated_strings);
 278
 279         if (yydebug)
 280                 fprintf(stdout, "parser_ctx input is a%s.\n",
 281                         isatty(fileno(input)) ? "n interactive tty" :
 282                                                 " noninteractive file");
 283
 284         return parser_ctx;
 285
 286 cleanup_lexer:
 287         ret = yylex_destroy(parser_ctx->scanner);
 288         if (!ret)
 289                 fprintf(stderr, "yylex_destroy error\n");
 290 cleanup_parser_ctx:
 291         free(parser_ctx);
 292         return NULL;
 293 }
 294
 295 LTTNG_HIDDEN
 296 void filter_parser_ctx_free(struct filter_parser_ctx *parser_ctx)
 297 {
 298         int ret;
 299
 300         ret = yylex_destroy(parser_ctx->scanner);
 301         if (ret)
 302                 fprintf(stderr, "yylex_destroy error\n");
 303
 304         filter_ast_free(parser_ctx->ast);
 305         free_strings(&parser_ctx->allocated_strings);
 306         filter_ir_free(parser_ctx);
 307         free(parser_ctx->bytecode);
 308         free(parser_ctx->bytecode_reloc);
 309
 310         free(parser_ctx);
 311 }
 312
 313 %}
 314
 315 %define api.pure
 316         /* %locations */
 317 %parse-param {struct filter_parser_ctx *parser_ctx}
 318 %parse-param {yyscan_t scanner}
 319 %lex-param {yyscan_t scanner}
 320 %start translation_unit
 321 %token CHARACTER_CONSTANT_START SQUOTE STRING_LITERAL_START DQUOTE
 322 %token ESCSEQ CHAR_STRING_TOKEN
 323 %token DECIMAL_CONSTANT OCTAL_CONSTANT HEXADECIMAL_CONSTANT FLOAT_CONSTANT
 324 %token LSBRAC RSBRAC LPAREN RPAREN LBRAC RBRAC RARROW
 325 %token STAR PLUS MINUS
 326 %token MOD_OP DIV_OP RIGHT_OP LEFT_OP
 327 %token EQ_OP NE_OP LE_OP GE_OP LT_OP GT_OP AND_OP OR_OP NOT_OP
 328 %token ASSIGN COLON SEMICOLON DOTDOTDOT DOT EQUAL COMMA
 329 %token XOR_BIN AND_BIN OR_BIN NOT_BIN
 330
 331 %token <gs> IDENTIFIER GLOBAL_IDENTIFIER
 332 %token ERROR
 333 %union
 334 {
 335         long long ll;
 336         char c;
 337         struct gc_string *gs;
 338         struct filter_node *n;
 339 }
 340
 341 %type <gs> s_char s_char_sequence c_char c_char_sequence
 342
 343 %type <n> primary_expression
 344 %type <n> prefix_expression
 345 %type <n> prefix_expression_rec
 346 %type <n> postfix_expression
 347 %type <n> unary_expression
 348 %type <n> unary_operator
 349 %type <n> multiplicative_expression
 350 %type <n> additive_expression
 351 %type <n> shift_expression
 352 %type <n> relational_expression
 353 %type <n> equality_expression
 354 %type <n> and_expression
 355 %type <n> exclusive_or_expression
 356 %type <n> inclusive_or_expression
 357 %type <n> logical_and_expression
 358 %type <n> logical_or_expression
 359 %type <n> expression
 360 %type <n> identifiers
 361
 362 %%
 363
 364
 365 /* 1.5 Constants */
 366
 367 c_char_sequence:
 368                 c_char
 369                 {       $$ = $1;                                        }
 370         |       c_char_sequence c_char
 371                 {       $$ = gc_string_append(parser_ctx, $1, $2);              }
 372         ;
 373
 374 c_char:
 375                 CHAR_STRING_TOKEN
 376                 {       $$ = yylval.gs;                                 }
 377         |       ESCSEQ
 378                 {
 379                         parse_error(parser_ctx, "escape sequences not supported yet");
 380                 }
 381         ;
 382
 383 /* 1.6 String literals */
 384
 385 s_char_sequence:
 386                 s_char
 387                 {       $$ = $1;                                        }
 388         |       s_char_sequence s_char
 389                 {       $$ = gc_string_append(parser_ctx, $1, $2);              }
 390         ;
 391
 392 s_char:
 393                 CHAR_STRING_TOKEN
 394                 {       $$ = yylval.gs;                                 }
 395         |       ESCSEQ
 396                 {
 397                         parse_error(parser_ctx, "escape sequences not supported yet");
 398                 }
 399         ;
 400
 401 primary_expression:
 402                 DECIMAL_CONSTANT
 403                 {
 404                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 405                         $$->u.expression.type = AST_EXP_CONSTANT;
 406                         if (sscanf(yylval.gs->s, "%" WIDTH_u64_SCANF_IS_A_BROKEN_API SCNu64,
 407                                         &$$->u.expression.u.constant) != 1) {
 408                                 parse_error(parser_ctx, "cannot scanf decimal constant");
 409                         }
 410                 }
 411         |       OCTAL_CONSTANT
 412                 {
 413                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 414                         $$->u.expression.type = AST_EXP_CONSTANT;
 415                         if (!strcmp(yylval.gs->s, "0")) {
 416                                 $$->u.expression.u.constant = 0;
 417                         } else if (sscanf(yylval.gs->s, "0%" WIDTH_o64_SCANF_IS_A_BROKEN_API SCNo64,
 418                                         &$$->u.expression.u.constant) != 1) {
 419                                 parse_error(parser_ctx, "cannot scanf octal constant");
 420                         }
 421                 }
 422         |       HEXADECIMAL_CONSTANT
 423                 {
 424                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 425                         $$->u.expression.type = AST_EXP_CONSTANT;
 426                         if (sscanf(yylval.gs->s, "0x%" WIDTH_x64_SCANF_IS_A_BROKEN_API SCNx64,
 427                                         &$$->u.expression.u.constant) != 1) {
 428                                 parse_error(parser_ctx, "cannot scanf hexadecimal constant");
 429                         }
 430                 }
 431         |       FLOAT_CONSTANT
 432                 {
 433                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 434                         $$->u.expression.type = AST_EXP_FLOAT_CONSTANT;
 435                         if (sscanf(yylval.gs->s, "%" WIDTH_lg_SCANF_IS_A_BROKEN_API "lg",
 436                                         &$$->u.expression.u.float_constant) != 1) {
 437                                 parse_error(parser_ctx, "cannot scanf float constant");
 438                         }
 439                 }
 440         |       STRING_LITERAL_START DQUOTE
 441                 {
 442                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 443                         $$->u.expression.type = AST_EXP_STRING;
 444                         $$->u.expression.u.string = "";
 445                 }
 446         |       STRING_LITERAL_START s_char_sequence DQUOTE
 447                 {
 448                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 449                         $$->u.expression.type = AST_EXP_STRING;
 450                         $$->u.expression.u.string = $2->s;
 451                 }
 452         |       CHARACTER_CONSTANT_START c_char_sequence SQUOTE
 453                 {
 454                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 455                         $$->u.expression.type = AST_EXP_STRING;
 456                         $$->u.expression.u.string = $2->s;
 457                 }
 458         |       LPAREN expression RPAREN
 459                 {
 460                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 461                         $$->u.expression.type = AST_EXP_NESTED;
 462                         $$->u.expression.u.child = $2;
 463                 }
 464         ;
 465
 466 identifiers
 467         :       IDENTIFIER
 468                 {
 469                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 470                         $$->u.expression.type = AST_EXP_IDENTIFIER;
 471                         $$->u.expression.u.identifier = yylval.gs->s;
 472                 }
 473         |       GLOBAL_IDENTIFIER
 474                 {
 475                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 476                         $$->u.expression.type = AST_EXP_GLOBAL_IDENTIFIER;
 477                         $$->u.expression.u.identifier = yylval.gs->s;
 478                 }
 479         ;
 480
 481 prefix_expression_rec
 482         : LSBRAC unary_expression RSBRAC
 483                 {
 484                         $$ = $2;
 485                 }
 486         | LSBRAC unary_expression RSBRAC prefix_expression_rec
 487                 {
 488                         $$ = $2;
 489                         $$->u.expression.pre_op = AST_LINK_BRACKET;
 490                         $$->u.expression.prev = $4;
 491                 }
 492         ;
 493
 494 prefix_expression
 495         : identifiers
 496                 {
 497                         $$ = $1;
 498                 }
 499         | identifiers prefix_expression_rec
 500                 {
 501                         $$ = $1;
 502                         $$->u.expression.pre_op = AST_LINK_BRACKET;
 503                         $$->u.expression.next_bracket = $2;
 504                 }
 505         ;
 506
 507 postfix_expression
 508         : prefix_expression
 509                 {
 510                         $$ = $1;
 511                 }
 512         | postfix_expression DOT prefix_expression
 513                 {
 514                         $$ = $3;
 515                         $$->u.expression.post_op = AST_LINK_DOT;
 516                         $$->u.expression.prev = $1;
 517                 }
 518         | postfix_expression RARROW prefix_expression
 519                 {
 520                         $$ = $3;
 521                         $$->u.expression.post_op = AST_LINK_RARROW;
 522                         $$->u.expression.prev = $1;
 523                 }
 524         ;
 525
 526 unary_expression
 527         : postfix_expression
 528                 {       $$ = $1;                                        }
 529         | primary_expression
 530                 {       $$ = $1;                                        }
 531         | unary_operator unary_expression
 532                 {
 533                         $$ = $1;
 534                         $$->u.unary_op.child = $2;
 535                 }
 536         ;
 537
 538 unary_operator
 539         : PLUS
 540                 {
 541                         $$ = make_node(parser_ctx, NODE_UNARY_OP);
 542                         $$->u.unary_op.type = AST_UNARY_PLUS;
 543                 }
 544         | MINUS
 545                 {
 546                         $$ = make_node(parser_ctx, NODE_UNARY_OP);
 547                         $$->u.unary_op.type = AST_UNARY_MINUS;
 548                 }
 549         | NOT_OP
 550                 {
 551                         $$ = make_node(parser_ctx, NODE_UNARY_OP);
 552                         $$->u.unary_op.type = AST_UNARY_NOT;
 553                 }
 554         | NOT_BIN
 555                 {
 556                         $$ = make_node(parser_ctx, NODE_UNARY_OP);
 557                         $$->u.unary_op.type = AST_UNARY_BIT_NOT;
 558                 }
 559         ;
 560
 561 multiplicative_expression
 562         : unary_expression
 563                 {       $$ = $1;                                        }
 564         | multiplicative_expression STAR unary_expression
 565                 {
 566                         $$ = make_op_node(parser_ctx, AST_OP_MUL, $1, $3);
 567                 }
 568         | multiplicative_expression DIV_OP unary_expression
 569                 {
 570                         $$ = make_op_node(parser_ctx, AST_OP_DIV, $1, $3);
 571                 }
 572         | multiplicative_expression MOD_OP unary_expression
 573                 {
 574                         $$ = make_op_node(parser_ctx, AST_OP_MOD, $1, $3);
 575                 }
 576         ;
 577
 578 additive_expression
 579         : multiplicative_expression
 580                 {       $$ = $1;                                        }
 581         | additive_expression PLUS multiplicative_expression
 582                 {
 583                         $$ = make_op_node(parser_ctx, AST_OP_PLUS, $1, $3);
 584                 }
 585         | additive_expression MINUS multiplicative_expression
 586                 {
 587                         $$ = make_op_node(parser_ctx, AST_OP_MINUS, $1, $3);
 588                 }
 589         ;
 590
 591 shift_expression
 592         : additive_expression
 593                 {       $$ = $1;                                        }
 594         | shift_expression LEFT_OP additive_expression
 595                 {
 596                         $$ = make_op_node(parser_ctx, AST_OP_BIT_LSHIFT, $1, $3);
 597                 }
 598         | shift_expression RIGHT_OP additive_expression
 599                 {
 600                         $$ = make_op_node(parser_ctx, AST_OP_BIT_RSHIFT, $1, $3);
 601                 }
 602         ;
 603
 604 and_expression
 605         : shift_expression
 606                 {       $$ = $1;                                        }
 607         | and_expression AND_BIN shift_expression
 608                 {
 609                         $$ = make_op_node(parser_ctx, AST_OP_BIT_AND, $1, $3);
 610                 }
 611         ;
 612
 613 exclusive_or_expression
 614         : and_expression
 615                 {       $$ = $1;                                        }
 616         | exclusive_or_expression XOR_BIN and_expression
 617                 {
 618                         $$ = make_op_node(parser_ctx, AST_OP_BIT_XOR, $1, $3);
 619                 }
 620         ;
 621
 622 inclusive_or_expression
 623         : exclusive_or_expression
 624                 {       $$ = $1;                                        }
 625         | inclusive_or_expression OR_BIN exclusive_or_expression
 626                 {
 627                         $$ = make_op_node(parser_ctx, AST_OP_BIT_OR, $1, $3);
 628                 }
 629         ;
 630
 631 relational_expression
 632         : inclusive_or_expression
 633                 {       $$ = $1;                                        }
 634         | relational_expression LT_OP inclusive_or_expression
 635                 {
 636                         $$ = make_op_node(parser_ctx, AST_OP_LT, $1, $3);
 637                 }
 638         | relational_expression GT_OP inclusive_or_expression
 639                 {
 640                         $$ = make_op_node(parser_ctx, AST_OP_GT, $1, $3);
 641                 }
 642         | relational_expression LE_OP inclusive_or_expression
 643                 {
 644                         $$ = make_op_node(parser_ctx, AST_OP_LE, $1, $3);
 645                 }
 646         | relational_expression GE_OP inclusive_or_expression
 647                 {
 648                         $$ = make_op_node(parser_ctx, AST_OP_GE, $1, $3);
 649                 }
 650         ;
 651
 652 equality_expression
 653         : relational_expression
 654                 {       $$ = $1;                                        }
 655         | equality_expression EQ_OP relational_expression
 656                 {
 657                         $$ = make_op_node(parser_ctx, AST_OP_EQ, $1, $3);
 658                 }
 659         | equality_expression NE_OP relational_expression
 660                 {
 661                         $$ = make_op_node(parser_ctx, AST_OP_NE, $1, $3);
 662                 }
 663         ;
 664
 665 logical_and_expression
 666         : equality_expression
 667                 {       $$ = $1;                                        }
 668         | logical_and_expression AND_OP equality_expression
 669                 {
 670                         $$ = make_op_node(parser_ctx, AST_OP_AND, $1, $3);
 671                 }
 672         ;
 673
 674 logical_or_expression
 675         : logical_and_expression
 676                 {       $$ = $1;                                        }
 677         | logical_or_expression OR_OP logical_and_expression
 678                 {
 679                         $$ = make_op_node(parser_ctx, AST_OP_OR, $1, $3);
 680                 }
 681         ;
 682
 683 expression
 684         : logical_or_expression
 685                 {       $$ = $1;                                        }
 686         ;
 687
 688 translation_unit
 689         : expression
 690                 {
 691                         parser_ctx->ast->root.u.root.child = $1;
 692                 }
 693         ;