doc/man/manpage.xsl

   1 <?xml version='1.0'?>
   2 <xsl:stylesheet version="1.0"
   3                 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   4     <!-- Callouts -->
   5     <xsl:template match="*[local-name() = 'co']">
   6         <xsl:value-of select="concat('\','fB(',substring-after(@id,'-'),')','\','fR')"/>
   7     </xsl:template>
   8     <xsl:template match="*[local-name() = 'calloutlist']">
   9         <xsl:value-of select="."/>
  10         <xsl:text>sp&#10;</xsl:text>
  11         <xsl:apply-templates/>
  12         <xsl:text>&#10;</xsl:text>
  13     </xsl:template>
  14     <xsl:template match="*[local-name() = 'callout']">
  15         <xsl:value-of select="concat('\','fB',substring-after(@arearefs,'-'),'. ','\','fR')"/>
  16         <xsl:apply-templates/>
  17         <xsl:value-of select="."/>
  18         <xsl:text>br&#10;</xsl:text>
  19     </xsl:template>
  20
  21     <!-- Links -->
  22     <xsl:template match="*[local-name() = 'ulink']">
  23         <xsl:apply-templates/><xsl:text> &lt;</xsl:text><xsl:value-of select="@url"/><xsl:text>&gt;</xsl:text>
  24     </xsl:template>
  25
  26     <!-- Literal -->
  27     <xsl:template match="*[local-name() = 'literal']">
  28         <xsl:text>\fB</xsl:text>
  29         <xsl:value-of select="." />
  30         <xsl:text>\fR</xsl:text>
  31     </xsl:template>
  32
  33     <!--
  34         Make admonitions look like this:
  35
  36             Some paragraph.
  37
  38             Note
  39                 Sit sed culpa elit dolore esse irure dolor amet magna
  40                 veniam elit ut.
  41
  42                 Duis adipisicing magna quis in in in reprehenderit
  43                 proident minim cupidatat dolore sit minim deserunt duis dolore ex ea.
  44
  45             Next paragraph.
  46
  47         instead of:
  48
  49             Some paragraph.
  50
  51                 Note
  52                 Sit sed culpa elit dolore esse irure dolor amet magna
  53                 veniam elit ut.
  54
  55                 Duis adipisicing magna quis in in in reprehenderit
  56                 proident minim cupidatat dolore sit minim deserunt duis
  57                 dolore ex ea.
  58
  59             Next paragraph.
  60
  61         This looks better when, for example, you put a note immediately
  62         after a list:
  63
  64         Ambiguous:
  65             •   Some list item.
  66
  67             •   Some other list item.
  68
  69                 Note
  70                 Does this note apply to the last list item or to the
  71                 previous block?
  72
  73         Clear:
  74             •   Some list item.
  75
  76             •   Some other list item.
  77
  78             Note
  79                 This note applies to the previous block.
  80     -->
  81     <xsl:template match="caution|important|note|tip|warning">
  82         <xsl:call-template name="roff-if-start">
  83             <xsl:with-param name="condition">n</xsl:with-param>
  84         </xsl:call-template>
  85         <xsl:text>.sp&#10;</xsl:text>
  86         <xsl:call-template name="roff-if-end"/>
  87         <xsl:if test="not($man.output.better.ps.enabled = 0)">
  88             <xsl:text>.BM yellow&#10;</xsl:text>
  89         </xsl:if>
  90         <xsl:call-template name="pinch.together"/>
  91         <xsl:text>.ps +1&#10;</xsl:text>
  92         <xsl:call-template name="make.bold.title"/>
  93         <xsl:text>.ps -1&#10;</xsl:text>
  94         <xsl:text>.br&#10;</xsl:text>
  95         <xsl:text>.RS 4&#10;</xsl:text>
  96         <xsl:apply-templates/>
  97         <xsl:text>.sp .5v&#10;</xsl:text>
  98         <xsl:if test="not($man.output.better.ps.enabled = 0)">
  99             <xsl:text>.EM yellow&#10;</xsl:text>
 100         </xsl:if>
 101         <xsl:text>.RE&#10;</xsl:text>
 102     </xsl:template>
 103
 104     <!-- Disable end notes -->
 105     <xsl:param name="man.endnotes.are.numbered">0</xsl:param>
 106
 107     <!-- Disable hyphenation, except for URLs -->
 108     <xsl:param name="man.hyphenate">0</xsl:param>
 109
 110     <!--
 111         Mainly for example blocks: indent the whole example after
 112         the title, like this:
 113
 114             Example 1. Do something
 115
 116                 Amet consectetur adipisicing minim sunt ad dolore culpa
 117                 enim labore incididunt cillum exercitation non non
 118                 deserunt veniam consectetur sint.
 119
 120                     $ lttng something
 121
 122                 Voluptate aliquip.
 123
 124         instead of:
 125
 126             Example 1. Do something
 127
 128             Amet consectetur adipisicing minim sunt ad dolore culpa
 129             enim labore incididunt cillum exercitation non non
 130             deserunt veniam consectetur sint.
 131
 132                 $ lttng something
 133
 134             Voluptate aliquip.
 135     -->
 136     <xsl:template name="formal.object">
 137         <xsl:param name="placement" select="'before'"/>
 138         <xsl:param name="class" select="local-name(.)"/>
 139
 140         <xsl:choose>
 141             <xsl:when test="$placement = 'before'">
 142                 <xsl:call-template name="formal.object.heading"/>
 143                 <xsl:text>.RS 4&#10;</xsl:text>
 144                 <xsl:apply-templates/>
 145                 <xsl:text>.RE&#10;</xsl:text>
 146             </xsl:when>
 147             <xsl:otherwise>
 148                 <xsl:text>.RS 4&#10;</xsl:text>
 149                 <xsl:apply-templates/>
 150                 <xsl:text>.RE&#10;</xsl:text>
 151                 <xsl:call-template name="formal.object.heading"/>
 152             </xsl:otherwise>
 153         </xsl:choose>
 154     </xsl:template>
 155 </xsl:stylesheet>