| | 1 | dnl SPDX-License-Identifier: GPL-2.0-only |
| | 2 | AC_PREREQ([2.64]) |
| | 3 | AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 4 | |
| | 5 | AC_CONFIG_HEADERS([include/config.h]) |
| | 6 | AC_CONFIG_AUX_DIR([config]) |
| | 7 | AC_CONFIG_MACRO_DIR([m4]) |
| | 8 | |
| | 9 | AC_CANONICAL_TARGET |
| | 10 | AC_CANONICAL_HOST |
| | 11 | |
| | 12 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 13 | AM_MAINTAINER_MODE([enable]) |
| | 14 | |
| | 15 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 16 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 17 | |
| | 18 | |
| | 19 | ## ## |
| | 20 | ## C compiler checks ## |
| | 21 | ## ## |
| | 22 | |
| | 23 | # Choose the C compiler |
| | 24 | AC_PROG_CC |
| | 25 | # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70 |
| | 26 | m4_version_prereq([2.70], [], [AC_PROG_CC_STDC]) |
| | 27 | |
| | 28 | # Make sure the C compiler supports C99 |
| | 29 | AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])]) |
| | 30 | |
| | 31 | # Enable available system extensions and LFS support |
| | 32 | AC_USE_SYSTEM_EXTENSIONS |
| | 33 | AC_SYS_LARGEFILE |
| | 34 | |
| | 35 | # Make sure the C compiler supports __attribute__ |
| | 36 | AX_C___ATTRIBUTE__ |
| | 37 | AS_IF([test "x$ax_cv___attribute__" != "xyes"], |
| | 38 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 39 | |
| | 40 | # Make sure we have pthread support |
| | 41 | AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])]) |
| | 42 | |
| | 43 | # Checks for typedefs, structures, and compiler characteristics. |
| | 44 | AC_C_INLINE |
| | 45 | AC_TYPE_INT32_T |
| | 46 | AC_TYPE_INT64_T |
| | 47 | AC_TYPE_MODE_T |
| | 48 | AC_TYPE_OFF_T |
| | 49 | AC_TYPE_PID_T |
| | 50 | AC_TYPE_SIZE_T |
| | 51 | AC_TYPE_SSIZE_T |
| | 52 | AC_TYPE_UID_T |
| | 53 | AC_TYPE_UINT16_T |
| | 54 | AC_TYPE_UINT32_T |
| | 55 | AC_TYPE_UINT64_T |
| | 56 | AC_TYPE_UINT8_T |
| | 57 | |
| | 58 | # Detect warning flags supported by the C and C++ compilers and append them to |
| | 59 | # WARN_CFLAGS and WARN_CXXFLAGS. |
| | 60 | m4_define([WARN_FLAGS_LIST], [ dnl |
| | 61 | -Wall dnl |
| | 62 | dnl We currently get this warning when building with Clang: |
| | 63 | dnl |
| | 64 | dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration] |
| | 65 | dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL; |
| | 66 | dnl ^ |
| | 67 | -Wno-incomplete-setjmp-declaration dnl |
| | 68 | -Wdiscarded-qualifiers dnl |
| | 69 | -Wmissing-declarations dnl |
| | 70 | -Wmissing-prototypes dnl |
| | 71 | -Wmissing-parameter-type dnl |
| | 72 | -Wshadow dnl |
| | 73 | -Wno-gnu-folding-constant dnl |
| | 74 | dnl GCC enables this with -Wall in C++, and that generates a |
| | 75 | dnl lot of warnings that have on average a low value to fix. |
| | 76 | -Wno-sign-compare dnl |
| | 77 | ]) |
| | 78 | |
| | 79 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 80 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 81 | AC_LANG_PUSH([C]) |
| | 82 | AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror]) |
| | 83 | AC_LANG_POP([C]) |
| | 84 | |
| | 85 | # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is |
| | 86 | # written in such a way that it triggers warnings with the following warning |
| | 87 | # flags. So they would always end up disabled if we put them there, because |
| | 88 | # the test program would not build. |
| | 89 | # |
| | 90 | # Enable them here unconditionally. They are supported by GCC >= 4.8 and by |
| | 91 | # Clang >= 3.3 (required by the project) and are only valid for C code. |
| | 92 | WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes" |
| | 93 | |
| | 94 | # Disable 'strict aliasing' if the C compiler supports it. |
| | 95 | AC_LANG_PUSH([C]) |
| | 96 | AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror]) |
| | 97 | AC_LANG_POP([C]) |
| | 98 | |
| | 99 | |
| | 100 | ## ## |
| | 101 | ## C++ compiler checks ## |
| | 102 | ## ## |
| | 103 | |
| | 104 | # Find a C++11 compiler with GNU extensions (-std=gnu++11) |
| | 105 | AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory]) |
| | 106 | |
| | 107 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 108 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 109 | AC_LANG_PUSH([C++]) |
| | 110 | AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror]) |
| | 111 | AC_LANG_POP([C++]) |
| | 112 | |
| | 113 | # Disable 'strict aliasing' if the C++ compiler supports it. |
| | 114 | AC_LANG_PUSH([C++]) |
| | 115 | AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror]) |
| | 116 | AC_LANG_POP([C++]) |
| | 117 | |
| | 118 | |
| | 119 | # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS. |
| | 120 | AC_ARG_ENABLE([Werror],[ |
| | 121 | AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.]) |
| | 122 | ]) |
| | 123 | |
| | 124 | AS_IF([test "x$enable_Werror" = "xyes"], [ |
| | 125 | WARN_CFLAGS="${WARN_CFLAGS} -Werror" |
| | 126 | WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror" |
| | 127 | ]) |
| | 128 | |
| | 129 | # Checks for programs. |
| | 130 | AC_PROG_GREP |
| | 131 | AC_PROG_MAKE_SET |
| | 132 | AC_PROG_SED |
| | 133 | AC_PATH_PROG([report_fold], [fold]) |
| | 134 | LT_INIT |
| | 135 | |
| | 136 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 137 | AC_CHECK_TOOL([OBJCOPY], [objcopy], [no]) |
| | 138 | AS_IF([test "x$OBJCOPY" = "xno"], |
| | 139 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 140 | ) |
| | 141 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno]) |
| | 142 | |
| | 143 | # check for pgrep |
| | 144 | AC_PATH_PROG([PGREP], [pgrep], [no]) |
| | 145 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"]) |
| | 146 | |
| | 147 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 148 | # is not distributed in tarballs |
| | 149 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 150 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 151 | |
| | 152 | # check for bison |
| | 153 | AC_PROG_YACC |
| | 154 | BISON=$YACC |
| | 155 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 156 | |
| | 157 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 158 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 159 | AC_MSG_FAILURE([ |
| | 160 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 161 | set the YACC variable to override automatic detection. |
| | 162 | ]) |
| | 163 | ], [ |
| | 164 | AC_MSG_WARN([ |
| | 165 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 166 | this distribution tarball, so Bison is only needed if you intend to |
| | 167 | modify their sources. You can set the YACC variable to override automatic |
| | 168 | detection. |
| | 169 | ]) |
| | 170 | ]) |
| | 171 | ]) |
| | 172 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 173 | |
| | 174 | # check for flex |
| | 175 | # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a |
| | 176 | # problem since the argument is silently ignored by older versions. |
| | 177 | AC_PROG_LEX([noyywrap]) |
| | 178 | FLEX=$LEX |
| | 179 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 180 | |
| | 181 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 182 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 183 | AC_MSG_FAILURE([ |
| | 184 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 185 | set the LEX variable to override automatic detection. |
| | 186 | ]) |
| | 187 | ], [ |
| | 188 | AC_MSG_WARN([ |
| | 189 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 190 | this distribution tarball, so Flex is only needed if you intend to |
| | 191 | modify their sources. You can set the LEX variable to override automatic |
| | 192 | detection. |
| | 193 | ]) |
| | 194 | ]) |
| | 195 | ]) |
| | 196 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 197 | |
| | 198 | |
| | 199 | |
| | 200 | # Check if linker has the -no-pie option. |
| | 201 | AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes]) |
| | 202 | AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"]) |
| | 203 | |
| | 204 | AX_LIB_SOCKET_NSL |
| | 205 | |
| | 206 | LT_NO_UNDEFINED="" |
| | 207 | AS_CASE([$host_os], |
| | 208 | [cygwin*], |
| | 209 | [ |
| | 210 | LT_NO_UNDEFINED="-no-undefined" |
| | 211 | ], |
| | 212 | [cygwin*|darwin*|mingw*|solaris*], |
| | 213 | [ |
| | 214 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 215 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 216 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 217 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 218 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 219 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 220 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 221 | ] |
| | 222 | ) |
| | 223 | |
| | 224 | AC_SUBST(LT_NO_UNDEFINED) |
| | 225 | |
| | 226 | # Compute minor/major/patchlevel version numbers |
| | 227 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 228 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 229 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 230 | |
| | 231 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 232 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 233 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 234 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 235 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 236 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 237 | |
| | 238 | version_name="O-Beer" |
| | 239 | version_description="An alcoholic drink made from yeast-fermented malt flavored with hops." |
| | 240 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 241 | |
| | 242 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 243 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 244 | |
| | 245 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 246 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 247 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 248 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 249 | libtool_fixup=$enableval, |
| | 250 | libtool_fixup=yes) |
| | 251 | |
| | 252 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 253 | [ |
| | 254 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 255 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 256 | AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 257 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 258 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 259 | [ |
| | 260 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 261 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 262 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 263 | ], |
| | 264 | [ |
| | 265 | AC_MSG_RESULT([none]) |
| | 266 | ]) |
| | 267 | ]) |
| | 268 | |
| | 269 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 270 | |
| | 271 | AC_CHECK_HEADERS([ \ |
| | 272 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 273 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 274 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 275 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 276 | sys/mount.h sys/param.h sys/time.h elf.h |
| | 277 | ]) |
| | 278 | |
| | 279 | AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes]) |
| | 280 | |
| | 281 | # Basic functions check |
| | 282 | AC_CHECK_FUNCS([ \ |
| | 283 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 284 | gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \ |
| | 285 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 286 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 287 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 288 | sched_getcpu sysconf sync_file_range |
| | 289 | ]) |
| | 290 | |
| | 291 | # Check for pthread_setname_np and pthread_getname_np |
| | 292 | LTTNG_PTHREAD_SETNAME_NP |
| | 293 | LTTNG_PTHREAD_GETNAME_NP |
| | 294 | |
| | 295 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 296 | # add -lrt to LIBS |
| | 297 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 298 | |
| | 299 | # Checks for dl. |
| | 300 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 301 | have_libdl=yes |
| | 302 | libdl_name=dl |
| | 303 | DL_LIBS="-ldl" |
| | 304 | ], [ |
| | 305 | # libdl not found, check for dlopen in libc. |
| | 306 | AC_CHECK_LIB([c], [dlopen], [ |
| | 307 | have_libc_dl=yes |
| | 308 | libdl_name=c |
| | 309 | DL_LIBS="-lc" |
| | 310 | ], [ |
| | 311 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 312 | ]) |
| | 313 | ]) |
| | 314 | AC_SUBST(DL_LIBS) |
| | 315 | |
| | 316 | # Check if libdl has dlmopen support. |
| | 317 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 318 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 319 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 320 | HAVE_DLMOPEN=1 |
| | 321 | ], [ |
| | 322 | HAVE_DLMOPEN=0 |
| | 323 | ]) |
| | 324 | AC_SUBST(HAVE_DLMOPEN) |
| | 325 | |
| | 326 | # Babeltrace viewer check |
| | 327 | AC_ARG_WITH([babeltrace-bin], |
| | 328 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 329 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 330 | [BABELTRACE_BIN="$withval"], |
| | 331 | [BABELTRACE_BIN='']) |
| | 332 | AC_SUBST([BABELTRACE_BIN]) |
| | 333 | |
| | 334 | AC_ARG_WITH([babeltrace2-bin], |
| | 335 | AS_HELP_STRING([--with-babeltrace2-bin], |
| | 336 | [Location of the babeltrace2 viewer executable (including the filename)]), |
| | 337 | [BABELTRACE2_BIN="$withval"], |
| | 338 | [BABELTRACE2_BIN='']) |
| | 339 | AC_SUBST([BABELTRACE2_BIN]) |
| | 340 | |
| | 341 | AC_ARG_WITH([consumerd32-bin], |
| | 342 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 343 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 344 | [CONSUMERD32_BIN="$withval"], |
| | 345 | [CONSUMERD32_BIN='']) |
| | 346 | AC_SUBST([CONSUMERD32_BIN]) |
| | 347 | |
| | 348 | AC_ARG_WITH([consumerd64-bin], |
| | 349 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 350 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 351 | [CONSUMERD64_BIN="$withval"], |
| | 352 | [CONSUMERD64_BIN='']) |
| | 353 | AC_SUBST([CONSUMERD64_BIN]) |
| | 354 | |
| | 355 | AC_ARG_WITH([consumerd32-libdir], |
| | 356 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 357 | [Directory containing the 32-bit consumerd libraries]), |
| | 358 | [CONSUMERD32_LIBDIR="$withval"], |
| | 359 | [CONSUMERD32_LIBDIR='']) |
| | 360 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 361 | |
| | 362 | AC_ARG_WITH([consumerd64-libdir], |
| | 363 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 364 | [Directory containing the 64-bit consumerd libraries]), |
| | 365 | [CONSUMERD64_LIBDIR="$withval"], |
| | 366 | [CONSUMERD64_LIBDIR='']) |
| | 367 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 368 | |
| | 369 | AC_ARG_WITH([sessiond-bin], |
| | 370 | AS_HELP_STRING([--with-sessiond-bin], |
| | 371 | [Location of the sessiond executable (including the filename)]), |
| | 372 | [SESSIOND_BIN="$withval"], |
| | 373 | [SESSIOND_BIN='']) |
| | 374 | AC_SUBST([SESSIOND_BIN]) |
| | 375 | |
| | 376 | AC_ARG_WITH([lttng-system-rundir], |
| | 377 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 378 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 379 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 380 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 381 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 382 | |
| | 383 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 384 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 385 | [test_java_agent_jul=$enableval], |
| | 386 | [test_java_agent_jul=no] |
| | 387 | ) |
| | 388 | |
| | 389 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 390 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])], |
| | 391 | [test_java_agent_log4j=$enableval], |
| | 392 | [test_java_agent_log4j=no] |
| | 393 | ) |
| | 394 | |
| | 395 | AC_ARG_ENABLE([test-java-agent-all], |
| | 396 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 397 | [test_java_agent_jul=$enableval |
| | 398 | test_java_agent_log4j=$enableval], |
| | 399 | [:] |
| | 400 | ) |
| | 401 | |
| | 402 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 403 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 404 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 405 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 406 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 407 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.]) |
| | 408 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 409 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 410 | |
| | 411 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 412 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 413 | $1="$2" |
| | 414 | AC_SUBST([$1]) |
| | 415 | ]) |
| | 416 | |
| | 417 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 418 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 419 | $1="$2" |
| | 420 | AC_SUBST([$1]) |
| | 421 | ]) |
| | 422 | |
| | 423 | # Default values |
| | 424 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 425 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 426 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 427 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 428 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 429 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 430 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 431 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 432 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 433 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 434 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 435 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 436 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 437 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 438 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 439 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 440 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 441 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 442 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 443 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 444 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 445 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 446 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 447 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 448 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 449 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 450 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 451 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 452 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 453 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 454 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 455 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 456 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 457 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 458 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 459 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 460 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 461 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 462 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 463 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 464 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 465 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 466 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 467 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 468 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 469 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 470 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 471 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 472 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000]) |
| | 473 | _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096]) |
| | 474 | |
| | 475 | # Command short descriptions |
| | 476 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded]) |
| | 477 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger]) |
| | 478 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session]) |
| | 479 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session]) |
| | 480 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions]) |
| | 481 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels]) |
| | 482 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules]) |
| | 483 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule]) |
| | 484 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel]) |
| | 485 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules]) |
| | 486 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule]) |
| | 487 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command]) |
| | 488 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points]) |
| | 489 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers]) |
| | 490 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations]) |
| | 491 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data]) |
| | 492 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger]) |
| | 493 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session]) |
| | 494 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations]) |
| | 495 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session]) |
| | 496 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot]) |
| | 497 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session]) |
| | 498 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session]) |
| | 499 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session]) |
| | 500 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events]) |
| | 501 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events]) |
| | 502 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information]) |
| | 503 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader]) |
| | 504 | |
| | 505 | if test "x$prefix" = "xNONE"; then |
| | 506 | prefix=$ac_default_prefix |
| | 507 | fi |
| | 508 | CONFDIR=`eval echo $sysconfdir` |
| | 509 | AC_SUBST(CONFDIR) |
| | 510 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 511 | |
| | 512 | AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.]) |
| | 513 | |
| | 514 | # Check libpopt |
| | 515 | PKG_CHECK_MODULES([POPT], [popt], |
| | 516 | [ |
| | 517 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 518 | ], |
| | 519 | [ |
| | 520 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 521 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 522 | AC_CHECK_LIB([popt], |
| | 523 | [poptGetContext], |
| | 524 | [POPT_LIBS="-lpopt"], |
| | 525 | [ |
| | 526 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 527 | ] |
| | 528 | ) |
| | 529 | ] |
| | 530 | ) |
| | 531 | AC_SUBST(POPT_LIBS) |
| | 532 | |
| | 533 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 534 | |
| | 535 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 536 | |
| | 537 | # URCU library version needed or newer |
| | 538 | PKG_CHECK_MODULES([URCU], [liburcu >= 0.11]) |
| | 539 | PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11]) |
| | 540 | AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS" |
| | 541 | |
| | 542 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 543 | # it can be explicitly disabled with --without-kmod |
| | 544 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 545 | AC_ARG_WITH([kmod], |
| | 546 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 547 | [], |
| | 548 | [with_kmod=check] |
| | 549 | ) |
| | 550 | |
| | 551 | AS_IF([test "x$with_kmod" != "xno"], |
| | 552 | [ |
| | 553 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 554 | [ |
| | 555 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 556 | KMOD_LIBS="-lkmod" |
| | 557 | ], |
| | 558 | [ |
| | 559 | if test "x$with_kmod" != xcheck; then |
| | 560 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 561 | else |
| | 562 | with_kmod=no |
| | 563 | fi |
| | 564 | ] |
| | 565 | ) |
| | 566 | ] |
| | 567 | ) |
| | 568 | AC_SUBST(KMOD_LIBS) |
| | 569 | |
| | 570 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 571 | # it can be explicitly disabled with --without-lttng-ust |
| | 572 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 573 | AC_ARG_WITH([lttng-ust], |
| | 574 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 575 | [], |
| | 576 | [with_lttng_ust=yes] |
| | 577 | ) |
| | 578 | |
| | 579 | AS_IF([test "x$with_lttng_ust" = "xyes"], [ |
| | 580 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 581 | |
| | 582 | # Check for liblttng-ust |
| | 583 | PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version]) |
| | 584 | |
| | 585 | # Check for liblttng-ust-ctl |
| | 586 | PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version]) |
| | 587 | |
| | 588 | AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS" |
| | 589 | ]) |
| | 590 | |
| | 591 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 592 | |
| | 593 | |
| | 594 | # Check for fmemopen |
| | 595 | AC_CHECK_LIB([c], [fmemopen], |
| | 596 | [ |
| | 597 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 598 | ] |
| | 599 | ) |
| | 600 | |
| | 601 | # check for libpfm |
| | 602 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 603 | [ |
| | 604 | have_libpfm=yes |
| | 605 | ]) |
| | 606 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 607 | |
| | 608 | # For Python |
| | 609 | # SWIG version needed or newer: |
| | 610 | swig_version=2.0.0 |
| | 611 | |
| | 612 | AC_ARG_ENABLE([python-bindings], |
| | 613 | [AS_HELP_STRING([--enable-python-bindings], |
| | 614 | [compile Python bindings])], |
| | 615 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 616 | |
| | 617 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 618 | |
| | 619 | if test "x$enable_python_binding" = xyes; then |
| | 620 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 621 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 622 | AM_PATH_PYTHON([3.0]) |
| | 623 | |
| | 624 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 625 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 626 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 627 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 628 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 629 | [python$PYTHON_VERSION-config python-config], |
| | 630 | [no], |
| | 631 | [`dirname $PYTHON`]) |
| | 632 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 633 | ]) |
| | 634 | AC_MSG_CHECKING([python include flags]) |
| | 635 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 636 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 637 | ]) |
| | 638 | |
| | 639 | else |
| | 640 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 641 | [if you want Python bindings.]) |
| | 642 | |
| | 643 | fi |
| | 644 | |
| | 645 | # Epoll check. If not present, the build will fallback on poll() API |
| | 646 | AX_HAVE_EPOLL( |
| | 647 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 648 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 649 | ) |
| | 650 | AX_CONFIG_FEATURE( |
| | 651 | [epoll], [This platform supports epoll(7)], |
| | 652 | [HAVE_EPOLL], [This platform supports epoll(7).] |
| | 653 | ) |
| | 654 | |
| | 655 | AS_IF([test "x$ac_cv_func_dirfd" = "xyes"], |
| | 656 | [AX_CONFIG_FEATURE_ENABLE(dirfd)], |
| | 657 | [AX_CONFIG_FEATURE_DISABLE(dirfd)] |
| | 658 | ) |
| | 659 | AX_CONFIG_FEATURE( |
| | 660 | [dirfd], [Use directory file descriptors], |
| | 661 | [HAVE_DIRFD], [This platform supports directory file descriptors.] |
| | 662 | ) |
| | 663 | |
| | 664 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 665 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 666 | |
| | 667 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then |
| | 668 | AX_JAVA_OPTIONS |
| | 669 | AX_PROG_JAVAC |
| | 670 | AX_PROG_JAVA |
| | 671 | AX_PROG_JAR |
| | 672 | |
| | 673 | AX_CHECK_CLASSPATH |
| | 674 | |
| | 675 | # Check for Java UST agent common class first |
| | 676 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 677 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 678 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 679 | fi |
| | 680 | |
| | 681 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 682 | # Check for JUL agent class |
| | 683 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 684 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 685 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 686 | fi |
| | 687 | fi |
| | 688 | |
| | 689 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 690 | # Check for Log4j agent class |
| | 691 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 692 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 693 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 694 | fi |
| | 695 | |
| | 696 | # Check for Log4j class |
| | 697 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 698 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 699 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 700 | fi |
| | 701 | fi |
| | 702 | fi |
| | 703 | |
| | 704 | # enable building man pages (user's intention) |
| | 705 | AC_ARG_ENABLE( |
| | 706 | man-pages, |
| | 707 | AS_HELP_STRING( |
| | 708 | [--disable-man-pages], |
| | 709 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 710 | ), |
| | 711 | [man_pages_opt=$enableval], |
| | 712 | [man_pages_opt=yes] |
| | 713 | ) |
| | 714 | |
| | 715 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 716 | have_asciidoc_xmlto=no |
| | 717 | warn_prebuilt_man_pages=no |
| | 718 | |
| | 719 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 720 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) |
| | 721 | AC_PATH_PROG([XMLTO], [xmlto], [no]) |
| | 722 | |
| | 723 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ |
| | 724 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 725 | # this is an error because we're in the Git repo, which |
| | 726 | # means the man pages are not already generated for us, |
| | 727 | # thus asciidoc/xmlto are required because we were asked |
| | 728 | # to build the man pages |
| | 729 | AC_MSG_ERROR([ |
| | 730 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 731 | --disable-man-pages to disable building the man pages, in which case |
| | 732 | they will not be installed. |
| | 733 | ]) |
| | 734 | ], [ |
| | 735 | # only warn here: since we're in the tarball, the man |
| | 736 | # pages should already be generated at this point, thus |
| | 737 | # asciidoc/xmlto are not strictly required |
| | 738 | warn_prebuilt_man_pages=yes |
| | 739 | ]) |
| | 740 | ], [ |
| | 741 | have_asciidoc_xmlto=yes |
| | 742 | ]) |
| | 743 | ]) |
| | 744 | |
| | 745 | # export man page build condition: build the man pages if the user |
| | 746 | # asked for it, and if the tools are available |
| | 747 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 748 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 749 | |
| | 750 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 751 | |
| | 752 | # embedded --help message |
| | 753 | AC_ARG_ENABLE( |
| | 754 | [embedded-help], |
| | 755 | AS_HELP_STRING( |
| | 756 | [--enable-embedded-help], |
| | 757 | [Embed the --help messages in the executable files] |
| | 758 | ), |
| | 759 | [embedded_help=$enableval], |
| | 760 | [embedded_help=no] |
| | 761 | ) |
| | 762 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 763 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 764 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 765 | ]) |
| | 766 | AC_PATH_PROG([man_prog_path], [man], [no]) |
| | 767 | AS_IF([test "x$man_prog_path" = "xno"], [ |
| | 768 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 769 | ]) |
| | 770 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 771 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 772 | ]) |
| | 773 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 774 | |
| | 775 | # Python agent test |
| | 776 | UST_PYTHON_AGENT="lttngust" |
| | 777 | |
| | 778 | AC_ARG_ENABLE(test-python2-agent, |
| | 779 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 780 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 781 | ),[:],[test_python2_agent_autodetect=yes] |
| | 782 | ) |
| | 783 | |
| | 784 | AC_ARG_ENABLE(test-python3-agent, |
| | 785 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 786 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 787 | ),[:],[test_python3_agent_autodetect=yes] |
| | 788 | ) |
| | 789 | |
| | 790 | AC_ARG_ENABLE(test-python-agent-all, |
| | 791 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 792 | [enable test for all python{2/3} agent.] |
| | 793 | ), |
| | 794 | ) |
| | 795 | |
| | 796 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 797 | unset test_python2_agent_autodetect |
| | 798 | unset test_python3_agent_autodetect |
| | 799 | ]) |
| | 800 | |
| | 801 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 802 | enable_test_python2_agent=yes |
| | 803 | enable_test_python3_agent=yes |
| | 804 | ]) |
| | 805 | |
| | 806 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 807 | enable_test_python2_agent=no |
| | 808 | enable_test_python3_agent=no |
| | 809 | ]) |
| | 810 | |
| | 811 | |
| | 812 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 813 | AS_IF([test -z "$PYTHON2"], [ |
| | 814 | PYTHON2=python2 |
| | 815 | ], [ |
| | 816 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 817 | ]) |
| | 818 | |
| | 819 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 820 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 821 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 822 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 823 | ]) |
| | 824 | ], [ |
| | 825 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 826 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 827 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 828 | AC_MSG_RESULT([yes]) |
| | 829 | RUN_PYTHON_AGENT_TEST=yes |
| | 830 | ], [ |
| | 831 | AC_MSG_RESULT([no]) |
| | 832 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 833 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 834 | ]) |
| | 835 | ]) |
| | 836 | |
| | 837 | ]) |
| | 838 | |
| | 839 | ]) |
| | 840 | |
| | 841 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 842 | AS_IF([test -z "$PYTHON3"], [ |
| | 843 | PYTHON3=python3 |
| | 844 | ], [ |
| | 845 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 846 | ]) |
| | 847 | |
| | 848 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 849 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 850 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 851 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 852 | ]) |
| | 853 | ], [ |
| | 854 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 855 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 856 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 857 | AC_MSG_RESULT([yes]) |
| | 858 | RUN_PYTHON_AGENT_TEST=yes |
| | 859 | ], [ |
| | 860 | AC_MSG_RESULT([no]) |
| | 861 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 862 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 863 | ]) |
| | 864 | ]) |
| | 865 | |
| | 866 | ]) |
| | 867 | ]) |
| | 868 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 869 | AC_SUBST([PYTHON2_AGENT]) |
| | 870 | AC_SUBST([PYTHON3_AGENT]) |
| | 871 | |
| | 872 | AC_ARG_ENABLE([test-sdt-uprobe], |
| | 873 | [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])], |
| | 874 | [test_sdt_uprobe="$enableval"], |
| | 875 | [test_sdt_uprobe=autodetect] |
| | 876 | ) |
| | 877 | |
| | 878 | AS_IF([test "$test_sdt_uprobe" != "no"], [ |
| | 879 | LTTNG_CHECK_SDT_WORKS |
| | 880 | AC_PATH_PROG([DTRACE], [dtrace]) |
| | 881 | ]) |
| | 882 | |
| | 883 | AS_IF([test "$test_sdt_uprobe" = "yes"], [ |
| | 884 | AS_IF([test "$lttng_cv_sdt_works" = "no"], [ |
| | 885 | AC_MSG_ERROR([Cannot find 'sys/sdt.h'.]) |
| | 886 | ]) |
| | 887 | AS_IF([test "x$DTRACE" = "x"], [ |
| | 888 | AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.]) |
| | 889 | ]) |
| | 890 | ]) |
| | 891 | |
| | 892 | AS_IF([test "$test_sdt_uprobe" = "autodetect"], [ |
| | 893 | AS_IF([test "$lttng_cv_sdt_works" = "yes"], [ |
| | 894 | AS_IF([test "x$DTRACE" != "x"], [ |
| | 895 | test_sdt_uprobe=yes |
| | 896 | ]) |
| | 897 | ]) |
| | 898 | ]) |
| | 899 | |
| | 900 | AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"]) |
| | 901 | |
| | 902 | # Arguments for binaries build exclusion |
| | 903 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 904 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 905 | [Disable the build of lttng-consumerd binaries])) |
| | 906 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 907 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 908 | [Disable the build of lttng-relayd binaries])) |
| | 909 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 910 | [Disable the build of lttng-sessiond binaries])) |
| | 911 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 912 | [Disable the build of the extra components])) |
| | 913 | |
| | 914 | |
| | 915 | build_lib_consumer=no |
| | 916 | build_lib_health=no |
| | 917 | build_lib_index=no |
| | 918 | build_lib_kernel_consumer=no |
| | 919 | build_lib_kernel_ctl=no |
| | 920 | build_lib_lttng_ctl=no |
| | 921 | build_lib_relayd=no |
| | 922 | build_lib_sessiond_comm=no |
| | 923 | build_lib_testpoint=no |
| | 924 | build_lib_ust_consumer=no |
| | 925 | |
| | 926 | # There is an overlap for enabled dependencies, but this makes everything |
| | 927 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 928 | # here. |
| | 929 | |
| | 930 | # Enable binary dependencies. |
| | 931 | AS_IF([test x$enable_bin_lttng != xno], |
| | 932 | [ |
| | 933 | build_lib_lttng_ctl=yes |
| | 934 | ] |
| | 935 | ) |
| | 936 | |
| | 937 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 938 | [ |
| | 939 | build_lib_consumer=yes |
| | 940 | build_lib_sessiond_comm=yes |
| | 941 | build_lib_index=yes |
| | 942 | build_lib_health=yes |
| | 943 | build_lib_testpoint=yes |
| | 944 | ] |
| | 945 | ) |
| | 946 | |
| | 947 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 948 | # Do nothing since libconfig and libcommon are built by default. |
| | 949 | [] |
| | 950 | ) |
| | 951 | |
| | 952 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 953 | [ |
| | 954 | build_lib_lttng_ctl=yes |
| | 955 | build_lib_sessiond_comm=yes |
| | 956 | build_lib_index=yes |
| | 957 | build_lib_health=yes |
| | 958 | build_lib_testpoint=yes |
| | 959 | ] |
| | 960 | ) |
| | 961 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 962 | [ |
| | 963 | build_lib_lttng_ctl=yes |
| | 964 | build_lib_sessiond_comm=yes |
| | 965 | build_lib_kernel_ctl=yes |
| | 966 | build_lib_relayd=yes |
| | 967 | build_lib_testpoint=yes |
| | 968 | build_lib_health=yes |
| | 969 | ] |
| | 970 | ) |
| | 971 | |
| | 972 | # Libraries dependencies enabling |
| | 973 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 974 | [ |
| | 975 | build_lib_sessiond_comm=yes |
| | 976 | ] |
| | 977 | ) |
| | 978 | |
| | 979 | AS_IF([test x$build_lib_consumer = xyes], |
| | 980 | [ |
| | 981 | build_lib_sessiond_comm=yes |
| | 982 | build_lib_kernel_consumer=yes |
| | 983 | build_lib_relayd=yes |
| | 984 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 985 | ] |
| | 986 | ) |
| | 987 | |
| | 988 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 989 | [ |
| | 990 | build_lib_kernel_ctl=yes |
| | 991 | build_lib_relayd=yes |
| | 992 | ] |
| | 993 | ) |
| | 994 | |
| | 995 | AS_IF([test x$build_lib_relayd = xyes], |
| | 996 | [ |
| | 997 | build_lib_sessiond_comm=yes |
| | 998 | ] |
| | 999 | ) |
| | 1000 | |
| | 1001 | # Find arch type |
| | 1002 | AS_CASE([$host_cpu], |
| | 1003 | [k1om], [ARCHTYPE="x86"], |
| | 1004 | [i386], [ARCHTYPE="x86"], |
| | 1005 | [i486], [ARCHTYPE="x86"], |
| | 1006 | [i586], [ARCHTYPE="x86"], |
| | 1007 | [i686], [ARCHTYPE="x86"], |
| | 1008 | [amd64], [ARCHTYPE="x86"], |
| | 1009 | [x86_64], [ARCHTYPE="x86"], |
| | 1010 | [powerpc], [ARCHTYPE="ppc"], |
| | 1011 | [ppc64], [ARCHTYPE="ppc"], |
| | 1012 | [powerpc64], [ARCHTYPE="ppc"], |
| | 1013 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 1014 | [ppc], [ARCHTYPE="ppc"], |
| | 1015 | [s390], [ARCHTYPE="s390"], |
| | 1016 | [s390x], [ARCHTYPE="s390"], |
| | 1017 | [sparc], [ARCHTYPE="sparc64"], |
| | 1018 | [sparc64], [ARCHTYPE="sparc64"], |
| | 1019 | [alpha*], [ARCHTYPE="alpha"], |
| | 1020 | [ia64], [ARCHTYPE="ia64"], |
| | 1021 | [arm*], [ARCHTYPE="arm"], |
| | 1022 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 1023 | [mips*], [ARCHTYPE="mips"], |
| | 1024 | [nios2*], [ARCHTYPE="nios2"], |
| | 1025 | [tile*], [ARCHTYPE="tile"], |
| | 1026 | [hppa*], [ARCHTYPE="hppa"], |
| | 1027 | [m68k], [ARCHTYPE="m68k"], |
| | 1028 | [riscv*], [ARCHTYPE="riscv"], |
| | 1029 | [ARCHTYPE="unknown"] |
| | 1030 | ) |
| | 1031 | |
| | 1032 | AC_SUBST(ARCHTYPE) |
| | 1033 | |
| | 1034 | AS_CASE([$host_os], |
| | 1035 | [linux*], [OSTYPE="linux"], |
| | 1036 | [freebsd*], [OSTYPE="freebsd"], |
| | 1037 | [solaris*], [OSTYPE="solaris"], |
| | 1038 | [cygwin*], [OSTYPE="cygwin"], |
| | 1039 | [mingw*], [OSTYPE="mingw"], |
| | 1040 | [OSTYPE="unknown"] |
| | 1041 | ) |
| | 1042 | AC_SUBST(OSTYPE) |
| | 1043 | AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"]) |
| | 1044 | |
| | 1045 | |
| | 1046 | |
| | 1047 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 1048 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 1049 | AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[ |
| | 1050 | have_modules_userspace_callstack_context=yes |
| | 1051 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 1052 | ]) |
| | 1053 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes]) |
| | 1054 | |
| | 1055 | # Export binaries build conditions. |
| | 1056 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1057 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1058 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1059 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1060 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1061 | |
| | 1062 | # Export the tests and extras build conditions. |
| | 1063 | AS_IF([\ |
| | 1064 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1065 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1066 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1067 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1068 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1069 | [build_tests=yes], |
| | 1070 | [build_tests=no] |
| | 1071 | ) |
| | 1072 | |
| | 1073 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1074 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1075 | |
| | 1076 | # Export libraries build conditions. |
| | 1077 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1078 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1079 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1080 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1081 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1082 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1083 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1084 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1085 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1086 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1087 | |
| | 1088 | AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS" |
| | 1089 | AC_SUBST(AM_CFLAGS) |
| | 1090 | |
| | 1091 | AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS" |
| | 1092 | AC_SUBST(AM_CXXFLAGS) |
| | 1093 | |
| | 1094 | # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...". |
| | 1095 | AM_LDFLAGS="" |
| | 1096 | AC_SUBST(AM_LDFLAGS) |
| | 1097 | |
| | 1098 | # The order in which the include folders are searched is important. |
| | 1099 | # The top_builddir should always be searched first in the event that a build |
| | 1100 | # time generated file is included. An example of this is the "version.i" file. |
| | 1101 | # In a scenario where lttng-tools is built from a distribution tarball and in a |
| | 1102 | # out-of-tree manner, the generated "version.i" has priority on the one from |
| | 1103 | # the source (distribution tarball) and must be found first. |
| | 1104 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1105 | AC_SUBST(AM_CPPFLAGS) |
| | 1106 | |
| | 1107 | lttngincludedir="${includedir}/lttng" |
| | 1108 | AC_SUBST(lttngincludedir) |
| | 1109 | |
| | 1110 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1111 | AC_SUBST(lttngactionincludedir) |
| | 1112 | |
| | 1113 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1114 | AC_SUBST(lttngconditionincludedir) |
| | 1115 | |
| | 1116 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1117 | AC_SUBST(lttngnotificationincludedir) |
| | 1118 | |
| | 1119 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1120 | AC_SUBST(lttngtriggerincludedir) |
| | 1121 | |
| | 1122 | lttngeventruleincludedir="${includedir}/lttng/event-rule" |
| | 1123 | AC_SUBST(lttngeventruleincludedir) |
| | 1124 | |
| | 1125 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1126 | AC_SUBST(lttnglibexecdir) |
| | 1127 | |
| | 1128 | AC_CONFIG_FILES([ |
| | 1129 | Makefile |
| | 1130 | doc/Makefile |
| | 1131 | doc/examples/Makefile |
| | 1132 | doc/examples/rotation/Makefile |
| | 1133 | doc/examples/trigger-condition-event-matches/Makefile |
| | 1134 | doc/man/Makefile |
| | 1135 | doc/man/asciidoc-attrs.conf |
| | 1136 | include/Makefile |
| | 1137 | extras/Makefile |
| | 1138 | extras/bindings/Makefile |
| | 1139 | extras/bindings/swig/Makefile |
| | 1140 | extras/bindings/swig/python/Makefile |
| | 1141 | extras/core-handler/Makefile |
| | 1142 | src/Makefile |
| | 1143 | src/common/Makefile |
| | 1144 | src/common/argpar/Makefile |
| | 1145 | src/common/bytecode/Makefile |
| | 1146 | src/common/kernel-ctl/Makefile |
| | 1147 | src/common/kernel-consumer/Makefile |
| | 1148 | src/common/consumer/Makefile |
| | 1149 | src/common/ust-consumer/Makefile |
| | 1150 | src/common/hashtable/Makefile |
| | 1151 | src/common/sessiond-comm/Makefile |
| | 1152 | src/common/compat/Makefile |
| | 1153 | src/common/relayd/Makefile |
| | 1154 | src/common/testpoint/Makefile |
| | 1155 | src/common/index/Makefile |
| | 1156 | src/common/health/Makefile |
| | 1157 | src/common/config/Makefile |
| | 1158 | src/common/ini-config/Makefile |
| | 1159 | src/common/string-utils/Makefile |
| | 1160 | src/common/fd-tracker/Makefile |
| | 1161 | src/common/filter/Makefile |
| | 1162 | src/lib/Makefile |
| | 1163 | src/lib/lttng-ctl/Makefile |
| | 1164 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1165 | src/bin/Makefile |
| | 1166 | src/bin/lttng-consumerd/Makefile |
| | 1167 | src/bin/lttng-sessiond/Makefile |
| | 1168 | src/bin/lttng-relayd/Makefile |
| | 1169 | src/bin/lttng/Makefile |
| | 1170 | src/bin/lttng-crash/Makefile |
| | 1171 | src/vendor/Makefile |
| | 1172 | src/vendor/msgpack/Makefile |
| | 1173 | tests/Makefile |
| | 1174 | tests/destructive/Makefile |
| | 1175 | tests/regression/Makefile |
| | 1176 | tests/regression/kernel/Makefile |
| | 1177 | tests/regression/tools/Makefile |
| | 1178 | tests/regression/tools/streaming/Makefile |
| | 1179 | tests/regression/tools/filtering/Makefile |
| | 1180 | tests/regression/tools/health/Makefile |
| | 1181 | tests/regression/tools/tracefile-limits/Makefile |
| | 1182 | tests/regression/tools/snapshots/Makefile |
| | 1183 | tests/regression/tools/live/Makefile |
| | 1184 | tests/regression/tools/exclusion/Makefile |
| | 1185 | tests/regression/tools/save-load/Makefile |
| | 1186 | tests/regression/tools/save-load/configuration/Makefile |
| | 1187 | tests/regression/tools/mi/Makefile |
| | 1188 | tests/regression/tools/wildcard/Makefile |
| | 1189 | tests/regression/tools/channel/Makefile |
| | 1190 | tests/regression/tools/crash/Makefile |
| | 1191 | tests/regression/tools/regen-metadata/Makefile |
| | 1192 | tests/regression/tools/regen-statedump/Makefile |
| | 1193 | tests/regression/tools/notification/Makefile |
| | 1194 | tests/regression/tools/rotation/Makefile |
| | 1195 | tests/regression/tools/base-path/Makefile |
| | 1196 | tests/regression/tools/metadata/Makefile |
| | 1197 | tests/regression/tools/tracker/Makefile |
| | 1198 | tests/regression/tools/working-directory/Makefile |
| | 1199 | tests/regression/tools/relayd-grouping/Makefile |
| | 1200 | tests/regression/tools/clear/Makefile |
| | 1201 | tests/regression/tools/trigger/Makefile |
| | 1202 | tests/regression/tools/trigger/rate-policy/Makefile |
| | 1203 | tests/regression/tools/trigger/start-stop/Makefile |
| | 1204 | tests/regression/tools/trigger/utils/Makefile |
| | 1205 | tests/regression/tools/trigger/name/Makefile |
| | 1206 | tests/regression/tools/trigger/hidden/Makefile |
| | 1207 | tests/regression/ust/Makefile |
| | 1208 | tests/regression/ust/nprocesses/Makefile |
| | 1209 | tests/regression/ust/high-throughput/Makefile |
| | 1210 | tests/regression/ust/low-throughput/Makefile |
| | 1211 | tests/regression/ust/before-after/Makefile |
| | 1212 | tests/regression/ust/buffers-pid/Makefile |
| | 1213 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1214 | tests/regression/ust/multi-session/Makefile |
| | 1215 | tests/regression/ust/multi-lib/Makefile |
| | 1216 | tests/regression/ust/overlap/Makefile |
| | 1217 | tests/regression/ust/overlap/demo/Makefile |
| | 1218 | tests/regression/ust/linking/Makefile |
| | 1219 | tests/regression/ust/daemon/Makefile |
| | 1220 | tests/regression/ust/exit-fast/Makefile |
| | 1221 | tests/regression/ust/fork/Makefile |
| | 1222 | tests/regression/ust/libc-wrapper/Makefile |
| | 1223 | tests/regression/ust/baddr-statedump/Makefile |
| | 1224 | tests/regression/ust/ust-dl/Makefile |
| | 1225 | tests/regression/ust/java-jul/Makefile |
| | 1226 | tests/regression/ust/java-log4j/Makefile |
| | 1227 | tests/regression/ust/getcpu-override/Makefile |
| | 1228 | tests/regression/ust/clock-override/Makefile |
| | 1229 | tests/regression/ust/type-declarations/Makefile |
| | 1230 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1231 | tests/regression/ust/blocking/Makefile |
| | 1232 | tests/regression/ust/namespaces/Makefile |
| | 1233 | tests/stress/Makefile |
| | 1234 | tests/unit/Makefile |
| | 1235 | tests/unit/ini_config/Makefile |
| | 1236 | tests/perf/Makefile |
| | 1237 | tests/utils/Makefile |
| | 1238 | tests/utils/tap/Makefile |
| | 1239 | tests/utils/testapp/Makefile |
| | 1240 | tests/utils/testapp/gen-ns-events/Makefile |
| | 1241 | tests/utils/testapp/gen-kernel-test-events/Makefile |
| | 1242 | tests/utils/testapp/gen-py-events/Makefile |
| | 1243 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1244 | tests/utils/testapp/gen-ust-events-ns/Makefile |
| | 1245 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1246 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1247 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1248 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1249 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1250 | tests/utils/testapp/userspace-probe-elf-binary/Makefile |
| | 1251 | tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile |
| | 1252 | tests/utils/testapp/userspace-probe-sdt-binary/Makefile |
| | 1253 | tests/utils/xml-utils/Makefile |
| | 1254 | ]) |
| | 1255 | |
| | 1256 | # Inject variable into python test script. |
| | 1257 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1258 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1259 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1260 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1261 | |
| | 1262 | AC_OUTPUT |
| | 1263 | |
| | 1264 | # |
| | 1265 | # Mini-report on what will be built. |
| | 1266 | # |
| | 1267 | |
| | 1268 | PPRINT_INIT |
| | 1269 | PPRINT_SET_INDENT(1) |
| | 1270 | PPRINT_SET_TS(38) |
| | 1271 | |
| | 1272 | AS_ECHO |
| | 1273 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1274 | AS_ECHO |
| | 1275 | |
| | 1276 | AS_IF([test -n "$report_fold"], [ |
| | 1277 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1278 | ], [ |
| | 1279 | AS_ECHO("$version_description") |
| | 1280 | ]) |
| | 1281 | |
| | 1282 | AS_ECHO |
| | 1283 | PPRINT_SUBTITLE([Features]) |
| | 1284 | |
| | 1285 | # Target architecture we're building for. |
| | 1286 | target_arch=$host_cpu |
| | 1287 | [ |
| | 1288 | for f in $CFLAGS; do |
| | 1289 | if test $f = "-m32"; then |
| | 1290 | target_arch="32-bit" |
| | 1291 | elif test $f = "-m64"; then |
| | 1292 | target_arch="64-bit" |
| | 1293 | fi |
| | 1294 | done |
| | 1295 | ] |
| | 1296 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1297 | |
| | 1298 | # kmod enabled/disabled |
| | 1299 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1300 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1301 | |
| | 1302 | # LTTng-UST enabled/disabled |
| | 1303 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1304 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1305 | |
| | 1306 | AS_ECHO |
| | 1307 | PPRINT_SUBTITLE([Binaries]) |
| | 1308 | |
| | 1309 | # List binaries to be built |
| | 1310 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1311 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1312 | |
| | 1313 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1314 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1315 | |
| | 1316 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1317 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1318 | |
| | 1319 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1320 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1321 | |
| | 1322 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1323 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1324 | |
| | 1325 | # Extras |
| | 1326 | test x$enable_extras != xno && value=1 || value=0 |
| | 1327 | AS_ECHO |
| | 1328 | PPRINT_SET_INDENT(0) |
| | 1329 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1330 | PPRINT_SET_INDENT(1) |
| | 1331 | |
| | 1332 | AS_ECHO |
| | 1333 | PPRINT_SUBTITLE([Tests]) |
| | 1334 | |
| | 1335 | # Print clear message that tests won't be built |
| | 1336 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1337 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1338 | ]) |
| | 1339 | |
| | 1340 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1341 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1342 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1343 | |
| | 1344 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1345 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1346 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value) |
| | 1347 | |
| | 1348 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1349 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1350 | |
| | 1351 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1352 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1353 | |
| | 1354 | # userspace-probe SDT instrumentation tests enabled/disabled |
| | 1355 | test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0 |
| | 1356 | PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value) |
| | 1357 | |
| | 1358 | #Python binding enabled/disabled |
| | 1359 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1360 | AS_ECHO |
| | 1361 | PPRINT_SET_INDENT(0) |
| | 1362 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1363 | |
| | 1364 | # man pages build enabled/disabled |
| | 1365 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1366 | |
| | 1367 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1368 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1369 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1370 | ], [ |
| | 1371 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1372 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1373 | ], [ |
| | 1374 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1375 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1376 | $PPRINT_COLOR_SUBTITLE) |
| | 1377 | ]) |
| | 1378 | ]) |
| | 1379 | ], [ |
| | 1380 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1381 | ]) |
| | 1382 | |
| | 1383 | m4_popdef([build_man_pages_msg]) |
| | 1384 | |
| | 1385 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1386 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1387 | |
| | 1388 | PPRINT_SET_INDENT(1) |
| | 1389 | |
| | 1390 | report_bindir="`eval eval echo $bindir`" |
| | 1391 | report_libdir="`eval eval echo $libdir`" |
| | 1392 | |
| | 1393 | # Print the bindir and libdir this `make install' will install into. |
| | 1394 | AS_ECHO |
| | 1395 | PPRINT_SUBTITLE([Install directories]) |
| | 1396 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1397 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1398 | |
| | 1399 | AS_ECHO |
| | 1400 | PPRINT_SUBTITLE([Search directories]) |
| | 1401 | |
| | 1402 | # If we build the sessiond, print the paths it will use |
| | 1403 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1404 | path="$report_bindir/lttng-sessiond" |
| | 1405 | ],[ |
| | 1406 | path="$SESSIOND_BIN" |
| | 1407 | ]) |
| | 1408 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1409 | |
| | 1410 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1411 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1412 | ],[ |
| | 1413 | path="$CONSUMERD32_BIN" |
| | 1414 | ]) |
| | 1415 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1416 | |
| | 1417 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1418 | path="`eval eval echo $libdir`" |
| | 1419 | ],[ |
| | 1420 | path="$CONSUMERD32_LIBDIR" |
| | 1421 | ]) |
| | 1422 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1423 | |
| | 1424 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1425 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1426 | ],[ |
| | 1427 | path="$CONSUMERD64_BIN" |
| | 1428 | ]) |
| | 1429 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1430 | |
| | 1431 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1432 | path="`eval eval echo $libdir`" |
| | 1433 | ],[ |
| | 1434 | path="$CONSUMERD64_LIBDIR" |
| | 1435 | ]) |
| | 1436 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1437 | PPRINT_SET_INDENT(0) |
| | 1438 | |
| | 1439 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1440 | AS_ECHO |
| | 1441 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1442 | |
| | 1443 | Note that the man pages are already built in this distribution tarball, |
| | 1444 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1445 | their sources. |
| | 1446 | |
| | 1447 | Also note that the installed man pages will contain the project's |
| | 1448 | default command-line option and environment variable values. |
| | 1449 | |
| | 1450 | Use --disable-man-pages to completely disable building and installing |
| | 1451 | the man pages.]) |
| | 1452 | ]) |
projects / lttng-tools.git / blame_incremental