configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.6.2],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3 AC_CONFIG_AUX_DIR([config])
   4 AC_CANONICAL_TARGET
   5 AC_CANONICAL_HOST
   6 AC_CONFIG_MACRO_DIR([config])
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AM_MAINTAINER_MODE([enable])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 # Compute minor/major/patchlevel version numbers
  12 AC_PROG_SED
  13 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  14 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  15 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  16 AC_SUBST([MAJOR_VERSION], [$major_version])
  17 AC_SUBST([MINOR_VERSION], [$minor_version])
  18 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  21 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  22
  23 version_name="Gaia"
  24 version_description="From Benelux brewery in Montreal, the Gaia is a witbier with a cloudy light amber ale color. Aroma of coriander with floral hay notes is enchanting. Taste is also dominated by the very floral coriander note and some medium sweet malt notes."
  25
  26 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  27 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  28
  29 AC_CONFIG_HEADERS([include/config.h])
  30
  31 AC_PROG_GREP
  32 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  33 AC_ARG_ENABLE(libtool-linkdep-fixup,
  34         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  35                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  36         libtool_fixup=$enableval,
  37         libtool_fixup=yes)
  38
  39 AS_IF([test "x$libtool_fixup" = "xyes"],
  40             [
  41             libtool_m4="$srcdir/config/libtool.m4"
  42             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  43             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  44             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  45             AS_IF([test $libtool_flag_pattern_count -ne 0],
  46             [
  47                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  48                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  49                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  50                   ],
  51                   [
  52                   AC_MSG_RESULT([none])
  53                   ])
  54             ])
  55
  56 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  57
  58 AC_CHECK_HEADERS([ \
  59         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  60         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  61         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  62 ])
  63
  64 # Babeltrace viewer check
  65 AC_ARG_WITH([babeltrace-bin],
  66         AS_HELP_STRING([--with-babeltrace-bin],
  67         [Location of the babeltrace viewer executable (including the filename)]),
  68         [BABELTRACE_BIN="$withval"],
  69         [BABELTRACE_BIN=''])
  70 AC_SUBST([BABELTRACE_BIN])
  71
  72 # lttv-gui
  73 AC_ARG_WITH([lttv-gui-bin],
  74         AS_HELP_STRING([--with-lttv-gui-bin],
  75    [Location of the lttv GUI viewer executable (including the filename)]),
  76    [LTTV_GUI_BIN="$withval"],
  77    [LTTV_GUI_BIN=''])
  78 AC_SUBST([LTTV_GUI_BIN])
  79
  80 AC_ARG_WITH([consumerd32-bin],
  81         AS_HELP_STRING([--with-consumerd32-bin],
  82         [Location of the 32-bit consumerd executable (including the filename)]),
  83         [CONSUMERD32_BIN="$withval"],
  84         [CONSUMERD32_BIN=''])
  85 AC_SUBST([CONSUMERD32_BIN])
  86
  87 AC_ARG_WITH([consumerd64-bin],
  88         AS_HELP_STRING([--with-consumerd64-bin],
  89         [Location of the 64-bit consumerd executable (including the filename)]),
  90         [CONSUMERD64_BIN="$withval"],
  91         [CONSUMERD64_BIN=''])
  92 AC_SUBST([CONSUMERD64_BIN])
  93
  94 AC_ARG_WITH([consumerd32-libdir],
  95         AS_HELP_STRING([--with-consumerd32-libdir],
  96         [Directory containing the 32-bit consumerd libraries]),
  97         [CONSUMERD32_LIBDIR="$withval"],
  98         [CONSUMERD32_LIBDIR=''])
  99 AC_SUBST([CONSUMERD32_LIBDIR])
 100
 101 AC_ARG_WITH([consumerd64-libdir],
 102         AS_HELP_STRING([--with-consumerd64-libdir],
 103         [Directory containing the 64-bit consumerd libraries]),
 104         [CONSUMERD64_LIBDIR="$withval"],
 105         [CONSUMERD64_LIBDIR=''])
 106 AC_SUBST([CONSUMERD64_LIBDIR])
 107
 108 AC_ARG_WITH([sessiond-bin],
 109         AS_HELP_STRING([--with-sessiond-bin],
 110         [Location of the sessiond executable (including the filename)]),
 111         [SESSIOND_BIN="$withval"],
 112         [SESSIOND_BIN=''])
 113 AC_SUBST([SESSIOND_BIN])
 114
 115 AC_ARG_WITH([lttng-system-rundir],
 116         AS_HELP_STRING([--with-lttng-system-rundir],
 117         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 118         [LTTNG_SYSTEM_RUNDIR="$withval"],
 119         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 120 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 121
 122 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 123 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 124 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 125 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 126 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 127 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 128 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 129 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 130
 131 if test "x$prefix" = "xNONE"; then
 132         prefix=$ac_default_prefix
 133 fi
 134 CONFDIR=`eval echo $sysconfdir`
 135 AC_SUBST(CONFDIR)
 136 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 137
 138 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 139
 140 #
 141 # Check for pthread
 142 AC_CHECK_LIB([pthread], [pthread_create], [],
 143         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 144 )
 145
 146 # Check libpopt
 147 PKG_CHECK_MODULES([POPT], [popt],
 148         [LIBS="$LIBS $POPT_LIBS"],
 149         [
 150                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 151                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 152                 AC_CHECK_LIB([popt],
 153                         [poptGetContext],
 154                         [],
 155                         [
 156                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 157                         ]
 158                 )
 159         ]
 160 )
 161
 162 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 163
 164 # Check for libuuid
 165 PKG_CHECK_MODULES([UUID], [uuid],
 166 [
 167         LIBS="$LIBS $UUID_LIBS"
 168         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 169         have_libuuid=yes
 170 ],
 171 [
 172         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 173         AC_MSG_WARN([Finding libuuid without pkg-config.])
 174         AC_CHECK_LIB([uuid],
 175                 [uuid_generate],
 176                 [
 177                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 178                         have_libuuid=yes
 179                 ],
 180                 [
 181                         # libuuid not found, check for uuid_create in libc.
 182                         AC_CHECK_LIB([c],
 183                                 [uuid_create],
 184                                 [
 185                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 186                                         have_libc_uuid=yes
 187                                 ],
 188                                 [
 189                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 190                                 ]
 191                         )
 192                 ]
 193         )
 194 ])
 195 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 196 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 197
 198 # URCU library version needed or newer
 199 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 200
 201 # Check liburcu needed function calls
 202 AC_CHECK_DECL([cds_list_add], [],
 203         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 204 AC_CHECK_DECL([cds_wfcq_init], [],
 205         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 206 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 207         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 208 AC_CHECK_DECL([futex_async], [],
 209         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 210 AC_CHECK_DECL([rcu_thread_offline], [],
 211         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 212 AC_CHECK_DECL([rcu_thread_online], [],
 213         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 214 AC_CHECK_DECL([caa_likely], [],
 215         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 216
 217 #Function added in urcu 0.7.0
 218 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 219         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 220 )
 221
 222 # Check kmod library
 223 AC_ARG_WITH(kmod-prefix,
 224   AS_HELP_STRING([--with-kmod-prefix=PATH],
 225                 [Specify the installation prefix of the kmod library.
 226                 Headers must be in PATH/include; libraries in PATH/lib.]),
 227                 [
 228                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 229                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 230                 ])
 231
 232 AC_ARG_ENABLE(kmod,
 233         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 234         kmod_support=zz$enableval, kmod_support=yes)
 235
 236 AS_IF([test "x$kmod_support" = "xyes"], [
 237         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 238                 [
 239                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 240                         LIBS="$LIBS -lkmod"
 241                         kmod_found=yes
 242                 ],
 243                 kmod_found=no
 244         )
 245 ])
 246 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 247
 248 AC_ARG_WITH(lttng-ust-prefix,
 249   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 250                  [Specify the installation prefix of the lttng-ust library.
 251                   Headers must be in PATH/include; libraries in PATH/lib.]),
 252                   [
 253                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 254                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 255                   ])
 256
 257 # Check liblttng-ust-ctl library
 258 AC_ARG_ENABLE(lttng-ust,
 259         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 260         lttng_ust_support=$enableval, lttng_ust_support=yes)
 261
 262 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 263         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 264                 [
 265                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 266                         lttng_ust_ctl_found=yes
 267                 ],
 268                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 269                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
 270         )
 271 ])
 272 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 273 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 274
 275 # check for dlopen
 276 AC_CHECK_LIB([dl], [dlopen],
 277 [
 278         have_libdl=yes
 279 ],
 280 [
 281         #libdl not found, check for dlopen in libc.
 282         AC_CHECK_LIB([c], [dlopen],
 283         [
 284                 have_libc_dl=yes
 285         ],
 286         [
 287                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 288         ])
 289 ])
 290 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 291 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 292
 293 # Check for fmemopen
 294 AC_CHECK_LIB([c], [fmemopen],
 295 [
 296         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 297 ]
 298 )
 299
 300 # Check for open_memstream
 301 AC_CHECK_LIB([c], [open_memstream],
 302 [
 303         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 304 ]
 305 )
 306
 307 AC_ARG_ENABLE([git-version],
 308               [AC_HELP_STRING([--disable-git-version],
 309                               [Do not use the git version for the build])],
 310               [have_git_version=$enableval], [have_git_version=yes]
 311 )
 312
 313 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 314         [test "x${have_git_version}" = "xyes"])
 315
 316 # For Python
 317 # SWIG version needed or newer:
 318 swig_version=2.0.0
 319
 320 AC_ARG_ENABLE([python-bindings],
 321               [AC_HELP_STRING([--enable-python-bindings],
 322                               [compile Python bindings])],
 323               [enable_python=yes], [enable_python=no])
 324
 325 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 326
 327 if test "x${enable_python:-yes}" = xyes; then
 328   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 329   AM_PATH_PYTHON
 330
 331   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 332   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 333   AS_IF([test -z "$PYTHON_INCLUDE"], [
 334     AS_IF([test -z "$PYTHON_CONFIG"], [
 335       AC_PATH_PROGS([PYTHON_CONFIG],
 336                     [python$PYTHON_VERSION-config python-config],
 337                     [no],
 338                     [`dirname $PYTHON`])
 339       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 340     ])
 341     AC_MSG_CHECKING([python include flags])
 342     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 343     AC_MSG_RESULT([$PYTHON_INCLUDE])
 344   ])
 345
 346 else
 347     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 348 [if you want Python bindings.])
 349
 350 fi
 351
 352 # Epoll check. If not present, the build will fallback on poll() API
 353 AX_HAVE_EPOLL(
 354         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 355         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 356 )
 357 AX_CONFIG_FEATURE(
 358         [epoll], [This platform supports epoll(7)],
 359         [HAVE_EPOLL], [This platform supports epoll(7).],
 360         [enable_epoll="yes"], [enable_epoll="no"]
 361 )
 362 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 363
 364 # Set compile flags to java include files if given. This is only used to
 365 # compile java agent tests.
 366 AC_ARG_WITH([java-jdk],
 367         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 368         [JAVA_JDK=$withval],
 369         [JAVA_JDK=""]
 370 )
 371 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 372 AC_SUBST([JAVA_JDK])
 373
 374 AS_IF([test $JAVA_JDK],[
 375         AS_IF([test -d $JAVA_JDK],
 376                 [
 377                         AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 378                         SUBDIRS=`find $JAVA_JDK/include -type d`
 379                         CPPFLAGS+=" "
 380                         CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 381                         CPPFLAGS+=" "
 382         ],[AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)]
 383         )
 384 ])
 385
 386 # Check for the UST agent jar file in the system. Hardcoded path is added here
 387 # since we have *no* idea where this could be installed. Note that this is only
 388 # used for agent testing.
 389 AC_MSG_CHECKING(Java UST agent jar file)
 390 java_agent_jar_path="${prefix}/share/java/liblttng-ust-agent.jar"
 391 if test -f $java_agent_jar_path; then
 392         build_java_agent=yes
 393         AC_MSG_RESULT(found)
 394 else
 395         build_java_agent=no
 396         AC_MSG_RESULT(not found)
 397 fi
 398 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$build_java_agent" = "xyes"])
 399 AC_SUBST([java_agent_jar_path])
 400
 401 # Check for log4j support on the system to know if we can build or not the
 402 # log4j tests.
 403 if test "x$build_java_agent" = "xyes"; then
 404         AC_MSG_CHECKING(Java agent support for log4j)
 405         AX_JAVA_OPTIONS
 406         AX_PROG_JAR
 407         AX_PROG_JAVA
 408         AX_PROG_JAVAC
 409
 410         # By default, use a commonly used classpath on the system to ease things up
 411         # for the Java testing in this directory.
 412         LOG4J_CLASSPATH="$java_agent_jar_path:$CLASSPATH:.:/usr/share/java/*"
 413         JAVAFLAGS="-cp $LOG4J_CLASSPATH"
 414         JAVACFLAGS="$JAVAFLAGS"
 415         AX_CHECK_CLASS(org.apache.log4j.Logger)
 416
 417         if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 418                 build_java_log4j_agent=no
 419         else
 420                 build_java_log4j_agent=yes
 421         fi
 422 fi
 423 AM_CONDITIONAL([BUILD_JAVA_LOG4J_AGENT], [test "x$build_java_log4j_agent" = "xyes"])
 424
 425 AC_SYS_LARGEFILE
 426 AC_PROG_CC
 427 LT_INIT
 428 AC_PROG_YACC
 429 AC_PROG_LEX
 430
 431 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 432         if test x"$YACC" != "xbison -y"; then
 433                 AC_MSG_ERROR([[bison not found and is required when building from git.
 434                 Please install bison]])
 435         fi
 436         AC_PATH_PROG([BISON],[bison])
 437         AX_PROG_BISON_VERSION([2.4], [],[
 438                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 439         ])
 440 fi
 441
 442 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 443         if test x"$LEX" != "xflex"; then
 444                 AC_MSG_ERROR([[flex not found and is required when building from git.
 445                 Please install flex]])
 446         fi
 447         AC_PATH_PROG([FLEX],[flex])
 448         AX_PROG_FLEX_VERSION([2.5.35], [],[
 449                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 450         ])
 451 fi
 452
 453 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 454
 455 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 456
 457 lttngincludedir="${includedir}/lttng"
 458
 459 AC_SUBST(lttngincludedir)
 460 AC_SUBST(DEFAULT_INCLUDES)
 461
 462 lttnglibexecdir="${libdir}/lttng/libexec"
 463 AC_SUBST(lttnglibexecdir)
 464
 465 AC_CONFIG_FILES([
 466         Makefile
 467         doc/Makefile
 468         doc/man/Makefile
 469         include/Makefile
 470         extras/Makefile
 471         extras/bindings/Makefile
 472         extras/bindings/swig/Makefile
 473         extras/bindings/swig/python/Makefile
 474         extras/core-handler/Makefile
 475         src/Makefile
 476         src/common/Makefile
 477         src/common/kernel-ctl/Makefile
 478         src/common/kernel-consumer/Makefile
 479         src/common/ust-consumer/Makefile
 480         src/common/hashtable/Makefile
 481         src/common/sessiond-comm/Makefile
 482         src/common/compat/Makefile
 483         src/common/relayd/Makefile
 484         src/common/testpoint/Makefile
 485         src/common/index/Makefile
 486         src/common/health/Makefile
 487         src/common/config/Makefile
 488         src/lib/Makefile
 489         src/lib/lttng-ctl/Makefile
 490         src/lib/lttng-ctl/filter/Makefile
 491         src/lib/lttng-ctl/lttng-ctl.pc
 492         src/bin/Makefile
 493         src/bin/lttng-consumerd/Makefile
 494         src/bin/lttng-sessiond/Makefile
 495         src/bin/lttng-relayd/Makefile
 496         src/bin/lttng/Makefile
 497         tests/Makefile
 498         tests/regression/Makefile
 499         tests/regression/kernel/Makefile
 500         tests/regression/tools/Makefile
 501         tests/regression/tools/streaming/Makefile
 502         tests/regression/tools/filtering/Makefile
 503         tests/regression/tools/health/Makefile
 504         tests/regression/tools/tracefile-limits/Makefile
 505         tests/regression/tools/snapshots/Makefile
 506         tests/regression/tools/live/Makefile
 507         tests/regression/tools/exclusion/Makefile
 508         tests/regression/tools/save-load/Makefile
 509         tests/regression/tools/mi/Makefile
 510         tests/regression/ust/Makefile
 511         tests/regression/ust/nprocesses/Makefile
 512         tests/regression/ust/high-throughput/Makefile
 513         tests/regression/ust/low-throughput/Makefile
 514         tests/regression/ust/before-after/Makefile
 515         tests/regression/ust/buffers-pid/Makefile
 516         tests/regression/ust/periodical-metadata-flush/Makefile
 517         tests/regression/ust/multi-session/Makefile
 518         tests/regression/ust/overlap/Makefile
 519         tests/regression/ust/overlap/demo/Makefile
 520         tests/regression/ust/linking/Makefile
 521         tests/regression/ust/daemon/Makefile
 522         tests/regression/ust/exit-fast/Makefile
 523         tests/regression/ust/fork/Makefile
 524         tests/regression/ust/libc-wrapper/Makefile
 525         tests/regression/ust/java-jul/Makefile
 526         tests/regression/ust/java-log4j/Makefile
 527         tests/stress/Makefile
 528         tests/unit/Makefile
 529         tests/unit/ini_config/Makefile
 530         tests/utils/Makefile
 531         tests/utils/tap/Makefile
 532         tests/utils/testapp/Makefile
 533         tests/utils/testapp/gen-ust-events/Makefile
 534         tests/utils/testapp/gen-ust-nevents/Makefile
 535         tests/utils/testapp/gen-ust-tracef/Makefile
 536 ])
 537
 538 AC_OUTPUT
 539
 540 #
 541 # Mini-report on what will be built
 542 #
 543 AS_ECHO()
 544
 545 AS_ECHO("Version name: $version_name")
 546 AS_ECHO("$version_description")
 547
 548 AS_ECHO()
 549
 550 # Target architecture we're building for
 551 target_arch=$host_cpu
 552 [
 553 for f in $CFLAGS; do
 554         if test $f = "-m32"; then
 555                         target_arch="32-bit"
 556         elif test $f = "-m64"; then
 557                         target_arch="64-bit"
 558         fi
 559 done
 560 ]
 561 AS_ECHO_N("Target architecture: ")
 562 AS_ECHO($target_arch)
 563
 564 # kmod enabled/disabled
 565 AS_ECHO_N("libkmod support: ")
 566 AS_IF([test "x$kmod_found" = "xyes"],[
 567         AS_ECHO("Enabled")
 568 ],[
 569         AS_ECHO("Disabled")
 570 ])
 571
 572 # LTTng-UST enabled/disabled
 573 AS_ECHO_N("Lttng-UST support: ")
 574 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 575         AS_ECHO("Enabled")
 576 ],[
 577         AS_ECHO("Disabled")
 578 ])
 579
 580 #Python binding enabled/disabled
 581 AS_ECHO_N("Python binding: ")
 582 AS_IF([test "x${enable_python:-yes}" = xyes], [
 583         AS_ECHO("Enabled")
 584 ],[
 585         AS_ECHO("Disabled")
 586 ])
 587
 588 # Do we build only the consumerd, or everything
 589 AS_IF([test "x$consumerd_only" = "xyes"],[
 590         AS_ECHO("Only the consumerd daemon will be built.")
 591 ],[
 592         AS_ECHO("All binaries will be built.")
 593 ])
 594
 595 # Print the bindir and libdir this `make install' will install into.
 596 AS_ECHO()
 597 AS_ECHO_N("Binaries will be installed in:  ")
 598 AS_ECHO("`eval eval echo $bindir`")
 599 AS_ECHO_N("Libraries will be installed in: ")
 600 AS_ECHO("`eval eval echo $libdir`")
 601
 602 # If we build the sessiond, print the paths it will use
 603 AS_IF([test "x$consumerd_only" = "xno"],[
 604         AS_ECHO()
 605         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 606         AS_IF([test "$SESSIOND_BIN" = ""],[
 607                 AS_ECHO_N("`eval eval echo $bindir`")
 608                 AS_ECHO("/lttng-sessiond")
 609         ],[
 610                 AS_ECHO("$SESSIOND_BIN")
 611         ])
 612
 613         AS_ECHO()
 614         AS_ECHO("The sessiond daemon will look in the following directories: ")
 615         AS_ECHO_N("32-bit consumerd executable at: ")
 616         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 617                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 618                 AS_ECHO("/lttng-consumerd")
 619         ],[
 620                 AS_ECHO("$CONSUMERD32_BIN")
 621         ])
 622
 623         AS_ECHO_N("32-bit consumer libraries in:   ")
 624         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 625                 AS_ECHO("`eval eval echo $libdir`")
 626         ],[
 627                 AS_ECHO("$CONSUMERD32_LIBDIR")
 628         ])
 629
 630         AS_ECHO_N("64-bit consumerd executable at: ")
 631         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 632                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 633                 AS_ECHO("/lttng-consumerd")
 634         ],[
 635                 AS_ECHO("$CONSUMERD64_BIN")
 636         ])
 637
 638         AS_ECHO_N("64-bit consumer libraries in:   ")
 639         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 640                 AS_ECHO("`eval eval echo $libdir`")
 641         ],[
 642                 AS_ECHO("$CONSUMERD64_LIBDIR")
 643         ])
 644 ])
 645
 646 AS_ECHO()
 647