configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.8.11],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [3:0:1])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 # Allow overriding storage used for TLS variables.
  32 AC_ARG_ENABLE([compiler-tls],
  33         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  34         [def_compiler_tls=$enableval],
  35         [def_compiler_tls="yes"])
  36
  37 # If not overridden, use ax_tls.m4 to check if TLS is available.
  38 AS_IF([test "x$def_compiler_tls" = "xyes"],
  39         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  40         [:])
  41
  42 AS_IF([test "x$def_tls_detect" = "x"],
  43         [:],
  44         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 LT_INIT
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_INLINE
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55
  56 # Checks for library functions.
  57 AC_FUNC_MMAP
  58 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  59
  60 # AC_FUNC_MALLOC causes problems when cross-compiling.
  61 #AC_FUNC_MALLOC
  62
  63 # Find arch type
  64 AS_CASE([$host_cpu],
  65         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  66         [i486], [ARCHTYPE="x86"],
  67         [i586], [ARCHTYPE="x86"],
  68         [i686], [ARCHTYPE="x86"],
  69         [amd64], [ARCHTYPE="x86"],
  70         [x86_64], [ARCHTYPE="x86"],
  71         [powerpc], [ARCHTYPE="ppc"],
  72         [ppc64], [ARCHTYPE="ppc"],
  73         [powerpc64], [ARCHTYPE="ppc"],
  74         [powerpc64le], [ARCHTYPE="gcc"],
  75         [ppc], [ARCHTYPE="ppc"],
  76         [s390], [ARCHTYPE="s390"],
  77         [s390x], [ARCHTYPE="s390"],
  78         [sparc], [ARCHTYPE="sparc64"],
  79         [sparc64], [ARCHTYPE="sparc64"],
  80         [alpha*], [ARCHTYPE="alpha"],
  81         [ia64], [ARCHTYPE="gcc"],
  82         [arm*], [ARCHTYPE="arm"],
  83         [aarch64], [ARCHTYPE="gcc"],
  84         [mips*], [ARCHTYPE="mips"],
  85         [tile*], [ARCHTYPE="gcc"],
  86         [ARCHTYPE="unknown"]
  87 )
  88
  89 AC_SUBST(ARCHTYPE)
  90 AC_SUBST(SUBARCHTYPE)
  91
  92 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  93 ARCHSRC=urcu/arch/$ARCHTYPE.h
  94
  95 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  96         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  97 ])
  98
  99 AS_IF([test "$host_cpu" = "armv7l"],[
 100         AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 101 ])
 102
 103 # ARM-specific checks
 104 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 105         AC_MSG_CHECKING([for dmb instruction])
 106         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 107                                 int main()
 108                                 {
 109                                         asm volatile("dmb":::"memory");
 110                                         return 0;
 111                                 }
 112                 ]])
 113         ],[
 114                 AC_MSG_RESULT([yes])
 115                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 116         ],[
 117                 AC_MSG_RESULT([no])
 118         ])
 119 ])
 120
 121 # Tile-specific checks
 122 AS_IF([echo "$host_cpu" | grep "^tile"],[
 123         AC_MSG_CHECKING([for Tile architecture type])
 124         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 125                                 #ifndef __tilegx__
 126                                 #error
 127                                 #endif
 128                 ]])
 129         ],[
 130                 AC_MSG_RESULT([ok])
 131         ],[
 132                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 133         ])
 134 ])
 135
 136 # x86-specific checks
 137 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 138         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 139         #For now, using lock; addl compatibility mode even for i686, because the
 140         #Pentium III is seen as a i686, but lacks mfence instruction.
 141         #Only using fence for x86_64.
 142         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 143                 AC_MSG_RESULT([yes])
 144                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 145         ],[
 146                 AC_MSG_RESULT([no])
 147         ])
 148 ])
 149
 150 # Check if sys_futex() is available
 151 AC_MSG_CHECKING([for sys_futex()])
 152 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 153                 #include <sys/syscall.h>
 154                 #ifndef __NR_futex
 155                 #error "futexes not available"
 156                 #endif
 157         ]])
 158 ],[
 159         AC_MSG_RESULT([yes])
 160         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 161         compat_futex_test=0
 162 ],[
 163         AC_MSG_RESULT([no])
 164         compat_futex_test=1
 165 ])
 166
 167 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 168 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 169 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 170
 171 # smp-support configure option
 172 AC_ARG_ENABLE([smp-support],
 173         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 174         [def_smp_support=$enableval],
 175         [def_smp_support="yes"])
 176 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 177
 178
 179 # From the sched_setaffinity(2)'s man page:
 180 # ~~~~
 181 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 182 # The library interfaces were introduced in glibc 2.3.  Initially, the
 183 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 184 # the cpuset size argument was removed, but this argument was
 185 # restored in glibc 2.3.4.
 186 # ~~~~
 187
 188 # In addition to that, some vendors ported the system call to 2.4
 189 # kernels.
 190
 191 # Furthermore, when the function first appeared, the MASK argument was
 192 # an unsigned long pointer, while later it was made into a cpu_set_t
 193 # pointer.  Systems that have the cpu_set_t version also should have
 194 # the CPU_ZERO, CPU_SET, etc. macros.
 195
 196 # All this mess means we have to cater for at least 3 different
 197 # sched_setaffinity prototypes:
 198
 199 # ~~~~
 200 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 201 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 202 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 203 # ~~~~
 204
 205 # Since we define _GNU_SOURCE in the sources, must do so too in the
 206 # autoconf tests, as defining _GNU_SOURCE or not exposes
 207 # sched_setaffinity bits differently.
 208 saved_CFLAGS="$CFLAGS"
 209 CFLAGS="$CFLAGS $AM_CFLAGS -D_GNU_SOURCE"
 210
 211 AC_CHECK_TYPES([cpu_set_t],
 212         [have_cpu_set_t="yes"],
 213         [have_cpu_set_t="no"],
 214         [#include <sched.h>])
 215
 216 # Confirm that we have CPU_ZERO, and it actually works.
 217 AC_MSG_CHECKING([whether CPU_ZERO works])
 218 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 219 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 220                 #define _GNU_SOURCE
 221                 #include <sched.h>
 222                 int main()
 223                 {
 224                         cpu_set_t foo; CPU_ZERO(&foo);
 225                         return 0;
 226                 }
 227         ]])
 228 ],[
 229         AC_DEFINE(HAVE_CPU_ZERO, 1)
 230         AC_MSG_RESULT([yes])
 231 ],[
 232         AC_MSG_RESULT([no])
 233 ])
 234
 235 # Confirm that we have CPU_SET, and it actually works.
 236 AC_MSG_CHECKING([whether CPU_SET works])
 237 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 238 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 239                 #define _GNU_SOURCE
 240                 #include <sched.h>
 241                 int main()
 242                 {
 243                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 244                         return 0;
 245                 }
 246         ]])
 247 ],[
 248         AC_DEFINE(HAVE_CPU_SET, 1)
 249         AC_MSG_RESULT([yes])
 250 ],[
 251         AC_MSG_RESULT([no])
 252 ])
 253
 254 # First check if the function is available at all.
 255 AC_CHECK_FUNCS([sched_setaffinity],[
 256         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 257         # then we have the first version using unsigned long, and no
 258         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 259         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 260         # should also be present, but we confirm nonetheless.
 261
 262         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 263                 # We do have it.
 264                 # Check how many arguments does sched_setaffinity take.
 265                 # Should be 3 or 2.
 266                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 267                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 268                                 #include <sched.h>
 269                                 int main()
 270                                 {
 271                                         cpu_set_t foo;
 272                                         sched_setaffinity(0, sizeof (foo), &foo);
 273                                         return 0;
 274                                 }
 275                         ]])
 276                 ],
 277                 [sched_set_affinity_args=3],
 278                 [sched_set_affinity_args=2])
 279                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 280                         $sched_set_affinity_args,
 281                         [Defined to sched_setaffinity's number of arguments.])
 282                 AC_MSG_RESULT([$sched_set_affinity_args])
 283         ],[
 284                 # No cpu_set_t, always 3 args.
 285                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 286         ])
 287 ])
 288
 289 CFLAGS=$saved_CFLAGS
 290 AC_SUBST(AM_CFLAGS)
 291
 292 AC_CONFIG_LINKS([
 293         urcu/arch.h:$ARCHSRC
 294         urcu/uatomic.h:$UATOMICSRC
 295 ])
 296 AC_CONFIG_FILES([
 297         Makefile
 298         doc/Makefile
 299         doc/examples/Makefile
 300         tests/Makefile
 301         tests/common/Makefile
 302         tests/unit/Makefile
 303         tests/benchmark/Makefile
 304         tests/regression/Makefile
 305         liburcu.pc
 306         liburcu-bp.pc
 307         liburcu-cds.pc
 308         liburcu-qsbr.pc
 309         liburcu-mb.pc
 310         liburcu-signal.pc
 311 ])
 312 AC_OUTPUT
 313
 314 # Report on selected configure options
 315 AS_IF([test "x$def_smp_support" = "xyes"],[
 316         AS_ECHO("SMP support enabled.")
 317 ],[
 318         AS_ECHO("SMP support disabled.")
 319 ])
 320
 321 AS_IF([test "x$def_tls_detect" = "x"],[
 322         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 323 ],[
 324         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 325 ])