formal-model/ooomem-two-writes/mem.spin

   1 /*
   2  * mem.spin: Promela code to validate memory barriers with OOO memory.
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program; if not, write to the Free Software
  16  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  17  *
  18  * Copyright (c) 2009 Mathieu Desnoyers
  19  */
  20
  21 /* Promela validation variables. */
  22
  23 /*
  24  * Produced process data flow. Updated after each instruction to show which
  25  * variables are ready. Assigned using SSA (static single assignment) (defuse
  26  * analysis must be done on the program to map "real" variables to single define
  27  * followed by use). Using one-hot bit encoding per variable to save state
  28  * space.  Used as triggers to execute the instructions having those variables
  29  * as input.
  30  */
  31
  32 #define PRODUCE_TOKENS(state, bits)     \
  33         state = (state) | (bits)
  34
  35 /* All bits must be active to consume. All notbits must be inactive. */
  36 /* Consuming a token does not clear it, it just waits for it. */
  37 #define CONSUME_TOKENS(state, bits, notbits)                            \
  38         ((!((state) & (notbits))) && ((state) & (bits)) == (bits))
  39
  40 #define CLEAR_TOKENS(state, bits)       \
  41         state = (state) & ~(bits)
  42
  43 /*
  44  * Bit encoding, proc_one_produced :
  45  */
  46
  47 #define P1_PROD_NONE    (1 << 0)
  48
  49 #define P1_WRITE        (1 << 1)
  50 #define P1_WMB          (1 << 2)
  51 #define P1_SYNC_CORE    (1 << 3)
  52 #define P1_RMB          (1 << 4)
  53 #define P1_READ         (1 << 5)
  54
  55 int proc_one_produced;
  56
  57 #define P2_PROD_NONE    (1 << 0)
  58
  59 #define P2_WRITE        (1 << 1)
  60 #define P2_WMB          (1 << 2)
  61 #define P2_SYNC_CORE    (1 << 3)
  62 #define P2_RMB          (1 << 4)
  63 #define P2_READ         (1 << 5)
  64
  65 int proc_two_produced;
  66
  67 #define NR_PROCS 2
  68
  69 #define get_pid()       (_pid)
  70
  71 /*
  72  * Each process have its own data in cache. Caches are randomly updated.
  73  * smp_wmb and smp_rmb forces cache updates (write and read), wmb_mb forces
  74  * both.
  75  */
  76
  77 #define DECLARE_CACHED_VAR(type, x, v)          \
  78         type mem_##x = v;                       \
  79         type cached_##x[NR_PROCS] = v;          \
  80         bit cache_dirty_##x[NR_PROCS] = 0;
  81
  82 #define IS_CACHE_DIRTY(x, id)   (cache_dirty_##x[id])
  83
  84 #define READ_CACHED_VAR(x)                      \
  85         (cached_##x[get_pid()])
  86
  87 #define WRITE_CACHED_VAR(x, v)                  \
  88         atomic {                                \
  89                 cached_##x[get_pid()] = v;      \
  90                 cache_dirty_##x[get_pid()] = 1; \
  91         }
  92
  93 #define CACHE_WRITE_TO_MEM(x, id)               \
  94         if                                      \
  95         :: IS_CACHE_DIRTY(x, id) ->             \
  96                 mem_##x = cached_##x[id];       \
  97                 cache_dirty_##x[id] = 0;        \
  98         :: else ->                              \
  99                 skip                            \
 100         fi;
 101
 102 #define CACHE_READ_FROM_MEM(x, id)              \
 103         if                                      \
 104         :: !IS_CACHE_DIRTY(x, id) ->            \
 105                 cached_##x[id] = mem_##x;       \
 106         :: else ->                              \
 107                 skip                            \
 108         fi;
 109
 110 /*
 111  * May update other caches if cache is dirty, or not.
 112  */
 113 #define RANDOM_CACHE_WRITE_TO_MEM(x, id)        \
 114         if                                      \
 115         :: 1 -> CACHE_WRITE_TO_MEM(x, id);      \
 116         :: 1 -> skip                            \
 117         fi;
 118
 119 #define RANDOM_CACHE_READ_FROM_MEM(x, id)\
 120         if                                      \
 121         :: 1 -> CACHE_READ_FROM_MEM(x, id);     \
 122         :: 1 -> skip                            \
 123         fi;
 124
 125 inline ooo_mem()
 126 {
 127         atomic {
 128                 RANDOM_CACHE_WRITE_TO_MEM(alpha, get_pid());
 129                 RANDOM_CACHE_WRITE_TO_MEM(beta, get_pid());
 130                 RANDOM_CACHE_READ_FROM_MEM(alpha, get_pid());
 131                 RANDOM_CACHE_READ_FROM_MEM(beta, get_pid());
 132         }
 133 }
 134
 135 /* must consume all prior read tokens */
 136 inline smp_rmb()
 137 {
 138         atomic {
 139                 /* todo : consume all read tokens .. ? */
 140                 CACHE_READ_FROM_MEM(alpha, get_pid());
 141                 CACHE_READ_FROM_MEM(beta, get_pid());
 142         }
 143 }
 144
 145 /* must consume all prior write tokens */
 146 inline smp_wmb()
 147 {
 148         atomic {
 149                 CACHE_WRITE_TO_MEM(alpha, get_pid());
 150                 CACHE_WRITE_TO_MEM(beta, get_pid());
 151         }
 152 }
 153
 154 /* sync_core() must consume all prior read and write tokens, including rmb/wmb
 155  * tokens */
 156
 157 /* must consume all prior read and write tokens */
 158 inline smp_mb()
 159 {
 160         atomic {
 161                 smp_wmb();
 162                 /* sync_core() */
 163                 smp_rmb();
 164         }
 165 }
 166
 167 /* Keep in sync manually with smp_rmb, wmp_wmb and ooo_mem */
 168 DECLARE_CACHED_VAR(byte, alpha, 0);
 169 DECLARE_CACHED_VAR(byte, beta, 0);
 170
 171 /* value 2 is uninitialized */
 172 byte read_one = 2;
 173 byte read_two = 2;
 174
 175 active proctype test_proc_one()
 176 {
 177         assert(get_pid() < NR_PROCS);
 178
 179         PRODUCE_TOKENS(proc_one_produced, P1_PROD_NONE);
 180
 181 #ifdef NO_WMB
 182         PRODUCE_TOKENS(proc_one_produced, P1_WMB);
 183 #endif
 184 #ifdef NO_RMB
 185         PRODUCE_TOKENS(proc_one_produced, P1_RMB);
 186 #endif
 187 #ifdef NO_SYNC
 188         PRODUCE_TOKENS(proc_one_produced, P1_SYNC_CORE);
 189 #endif
 190
 191         do
 192         :: CONSUME_TOKENS(proc_one_produced, P1_PROD_NONE, P1_WRITE) ->
 193                 ooo_mem();
 194                 WRITE_CACHED_VAR(alpha, 1);
 195                 ooo_mem();
 196                 PRODUCE_TOKENS(proc_one_produced, P1_WRITE);
 197         :: CONSUME_TOKENS(proc_one_produced, P1_WRITE, P1_WMB) ->
 198                 smp_wmb();
 199                 PRODUCE_TOKENS(proc_one_produced, P1_WMB);
 200         :: CONSUME_TOKENS(proc_one_produced, P1_WRITE | P1_WMB, P1_SYNC_CORE) ->
 201                 /* sync_core(); */
 202                 PRODUCE_TOKENS(proc_one_produced, P1_SYNC_CORE);
 203         :: CONSUME_TOKENS(proc_one_produced, P1_SYNC_CORE, P1_RMB) ->
 204                 smp_rmb();
 205                 PRODUCE_TOKENS(proc_one_produced, P1_RMB);
 206         :: CONSUME_TOKENS(proc_one_produced, P1_RMB | P1_SYNC_CORE, P1_READ) ->
 207                 ooo_mem();
 208                 read_one = READ_CACHED_VAR(beta);
 209                 ooo_mem();
 210                 PRODUCE_TOKENS(proc_one_produced, P1_READ);
 211         :: CONSUME_TOKENS(proc_one_produced, P1_PROD_NONE | P1_WRITE
 212                 | P1_WMB | P1_SYNC_CORE | P1_RMB | P1_READ, 0) ->
 213                 break;
 214         od;
 215
 216         //CLEAR_TOKENS(proc_one_produced,
 217         //      P1_PROD_NONE | P1_WRITE | P1_WMB | P1_SYNC_CORE | P1_RMB |
 218         //      P2_READ);
 219
 220         // test : [] (read_one == 0 -> read_two != 0)
 221         // test : [] (read_two == 0 -> read_one != 0)
 222         assert(!(read_one == 0 && read_two == 0));
 223 }
 224
 225 active proctype test_proc_two()
 226 {
 227         assert(get_pid() < NR_PROCS);
 228
 229         PRODUCE_TOKENS(proc_two_produced, P2_PROD_NONE);
 230
 231 #ifdef NO_WMB
 232         PRODUCE_TOKENS(proc_two_produced, P2_WMB);
 233 #endif
 234 #ifdef NO_RMB
 235         PRODUCE_TOKENS(proc_two_produced, P2_RMB);
 236 #endif
 237 #ifdef NO_SYNC
 238         PRODUCE_TOKENS(proc_two_produced, P2_SYNC_CORE);
 239 #endif
 240
 241         do
 242         :: CONSUME_TOKENS(proc_two_produced, P2_PROD_NONE, P2_WRITE) ->
 243                 ooo_mem();
 244                 WRITE_CACHED_VAR(beta, 1);
 245                 ooo_mem();
 246                 PRODUCE_TOKENS(proc_two_produced, P2_WRITE);
 247         :: CONSUME_TOKENS(proc_two_produced, P2_WRITE, P2_WMB) ->
 248                 smp_wmb();
 249                 PRODUCE_TOKENS(proc_two_produced, P2_WMB);
 250         :: CONSUME_TOKENS(proc_two_produced, P2_WRITE | P2_WMB, P2_SYNC_CORE) ->
 251                 /* sync_core(); */
 252                 PRODUCE_TOKENS(proc_two_produced, P2_SYNC_CORE);
 253         :: CONSUME_TOKENS(proc_two_produced, P2_SYNC_CORE, P2_RMB) ->
 254                 smp_rmb();
 255                 PRODUCE_TOKENS(proc_two_produced, P2_RMB);
 256         :: CONSUME_TOKENS(proc_two_produced, P2_SYNC_CORE | P2_RMB, P2_READ) ->
 257                 ooo_mem();
 258                 read_two = READ_CACHED_VAR(alpha);
 259                 ooo_mem();
 260                 PRODUCE_TOKENS(proc_two_produced, P2_READ);
 261         :: CONSUME_TOKENS(proc_two_produced, P2_PROD_NONE | P2_WRITE
 262                 | P2_WMB | P2_SYNC_CORE | P2_RMB | P2_READ, 0) ->
 263                 break;
 264         od;
 265
 266         //CLEAR_TOKENS(proc_two_produced,
 267         //      P2_PROD_NONE | P2_WRITE | P2_WMB | P2_SYNC_CORE | P2_RMB |
 268         //      P2_READ);
 269
 270         // test : [] (read_one == 0 -> read_two != 0)
 271         // test : [] (read_two == 0 -> read_one != 0)
 272         assert(!(read_one == 0 && read_two == 0));
 273 }