Add support for hppa/PA-RISC architecture
[urcu.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4
5 AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])
6
7 # Following the numbering scheme proposed by libtool for the library version
8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9 AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
10
11 AC_CONFIG_AUX_DIR([config])
12 AC_CONFIG_MACRO_DIR([config])
13 AC_CANONICAL_TARGET
14 AC_CANONICAL_HOST
15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
16 AM_MAINTAINER_MODE([enable])
17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
18
19 m4_include([config/ax_tls.m4])
20
21 AC_CONFIG_SRCDIR([urcu.h])
22
23 AC_CONFIG_HEADERS([config.h urcu/config.h])
24
25 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
26 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
27 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
28 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
29 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
30 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
31
32 # Allow overriding storage used for TLS variables.
33 AC_ARG_ENABLE([compiler-tls],
34 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
35 [def_compiler_tls=$enableval],
36 [def_compiler_tls="yes"])
37
38 # If not overridden, use ax_tls.m4 to check if TLS is available.
39 AS_IF([test "x$def_compiler_tls" = "xyes"],
40 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
41 [:])
42
43 AS_IF([test "x$def_tls_detect" = "x"],
44 [:],
45 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
46
47 # Checks for programs.
48 AC_PROG_CC
49 AC_PROG_MAKE_SET
50 LT_INIT
51
52 # Checks for typedefs, structures, and compiler characteristics.
53 AC_C_INLINE
54 AC_TYPE_PID_T
55 AC_TYPE_SIZE_T
56
57 # Checks for library functions.
58 AC_FUNC_MALLOC
59 AC_FUNC_MMAP
60 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf gettid])
61
62 # Find arch type
63 AS_CASE([$host_cpu],
64 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
65 [i486], [ARCHTYPE="x86"],
66 [i586], [ARCHTYPE="x86"],
67 [i686], [ARCHTYPE="x86"],
68 [amd64], [ARCHTYPE="x86"],
69 [x86_64], [ARCHTYPE="x86"],
70 [powerpc], [ARCHTYPE="ppc"],
71 [ppc64], [ARCHTYPE="ppc"],
72 [powerpc64], [ARCHTYPE="ppc"],
73 [powerpc64le], [ARCHTYPE="gcc"],
74 [ppc], [ARCHTYPE="ppc"],
75 [s390], [ARCHTYPE="s390"],
76 [s390x], [ARCHTYPE="s390"],
77 [sparc], [ARCHTYPE="sparc64"],
78 [sparc64], [ARCHTYPE="sparc64"],
79 [alpha*], [ARCHTYPE="alpha"],
80 [ia64], [ARCHTYPE="gcc"],
81 [arm*], [ARCHTYPE="arm"],
82 [aarch64], [ARCHTYPE="gcc"],
83 [mips*], [ARCHTYPE="mips"],
84 [tile*], [ARCHTYPE="gcc"],
85 [hppa*], [ARCHTYPE="hppa"],
86 [ARCHTYPE="unknown"]
87 )
88
89 AS_CASE([$host],[*-*-linux-androideabi],
90 [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
91 [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
92 )
93
94 AC_SUBST(ARCHTYPE)
95 AC_SUBST(SUBARCHTYPE)
96
97 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
98 ARCHSRC=urcu/arch/$ARCHTYPE.h
99
100 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
101 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
102 ])
103
104 AS_IF([test "$host_cpu" = "armv7l"],[
105 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
106 ])
107
108 # ARM-specific checks
109 AS_IF([test "x$ARCHTYPE" = "xarm"],[
110 AC_MSG_CHECKING([for dmb instruction])
111 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
112 int main()
113 {
114 asm volatile("dmb":::"memory");
115 return 0;
116 }
117 ]])
118 ],[
119 AC_MSG_RESULT([yes])
120 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
121 ],[
122 AC_MSG_RESULT([no])
123 ])
124 ])
125
126 # Tile-specific checks
127 AS_IF([echo "$host_cpu" | grep "^tile"],[
128 AC_MSG_CHECKING([for Tile architecture type])
129 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
130 #ifndef __tilegx__
131 #error
132 #endif
133 ]])
134 ],[
135 AC_MSG_RESULT([ok])
136 ],[
137 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
138 ])
139 ])
140
141 # x86-specific checks
142 AS_IF([test "x$ARCHTYPE" = "xx86"],[
143 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
144 #For now, using lock; addl compatibility mode even for i686, because the
145 #Pentium III is seen as a i686, but lacks mfence instruction.
146 #Only using fence for x86_64.
147 #
148 #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
149 #variant but lacks fence instructions.
150 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
151 AC_MSG_RESULT([yes])
152 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
153 ],[
154 AC_MSG_RESULT([no])
155 ])
156 ])
157
158 # Check if sys_futex() is available
159 AC_MSG_CHECKING([for sys_futex()])
160 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
161 #include <sys/syscall.h>
162 #ifndef __NR_futex
163 #error "futexes not available"
164 #endif
165 ]])
166 ],[
167 AC_MSG_RESULT([yes])
168 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
169 compat_futex_test=0
170 ],[
171 AC_MSG_RESULT([no])
172 compat_futex_test=1
173 ])
174
175 # Check for pthread
176 AC_CHECK_LIB([pthread], [pthread_create],
177 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
178 [AC_CHECK_LIB([c], [pthread_create],
179 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
180 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
181 )]
182 )
183
184 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
185 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
186 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
187
188 # smp-support configure option
189 AC_ARG_ENABLE([smp-support],
190 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
191 [def_smp_support=$enableval],
192 [def_smp_support="yes"])
193 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
194
195
196 # From the sched_setaffinity(2)'s man page:
197 # ~~~~
198 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
199 # The library interfaces were introduced in glibc 2.3. Initially, the
200 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
201 # the cpuset size argument was removed, but this argument was
202 # restored in glibc 2.3.4.
203 # ~~~~
204
205 # In addition to that, some vendors ported the system call to 2.4
206 # kernels.
207
208 # Furthermore, when the function first appeared, the MASK argument was
209 # an unsigned long pointer, while later it was made into a cpu_set_t
210 # pointer. Systems that have the cpu_set_t version also should have
211 # the CPU_ZERO, CPU_SET, etc. macros.
212
213 # All this mess means we have to cater for at least 3 different
214 # sched_setaffinity prototypes:
215
216 # ~~~~
217 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
218 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
219 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
220 # ~~~~
221
222 # Since we define _GNU_SOURCE in the sources, must do so too in the
223 # autoconf tests, as defining _GNU_SOURCE or not exposes
224 # sched_setaffinity bits differently.
225 saved_CFLAGS=$CFLAGS
226 CFLAGS="$CFLAGS -D_GNU_SOURCE"
227
228 AC_CHECK_TYPES([cpu_set_t],
229 [have_cpu_set_t="yes"],
230 [have_cpu_set_t="no"],
231 [#include <sched.h>])
232
233 # Confirm that we have CPU_ZERO, and it actually works.
234 AC_MSG_CHECKING([whether CPU_ZERO works])
235 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
236 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
237 #define _GNU_SOURCE
238 #include <sched.h>
239 int main()
240 {
241 cpu_set_t foo; CPU_ZERO(&foo);
242 return 0;
243 }
244 ]])
245 ],[
246 AC_DEFINE(HAVE_CPU_ZERO, 1)
247 AC_MSG_RESULT([yes])
248 ],[
249 AC_MSG_RESULT([no])
250 ])
251
252 # Confirm that we have CPU_SET, and it actually works.
253 AC_MSG_CHECKING([whether CPU_SET works])
254 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
255 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
256 #define _GNU_SOURCE
257 #include <sched.h>
258 int main()
259 {
260 cpu_set_t foo, mask; CPU_SET(0, &foo);
261 return 0;
262 }
263 ]])
264 ],[
265 AC_DEFINE(HAVE_CPU_SET, 1)
266 AC_MSG_RESULT([yes])
267 ],[
268 AC_MSG_RESULT([no])
269 ])
270
271 # First check if the function is available at all.
272 AC_CHECK_FUNCS([sched_setaffinity],[
273 # Okay, we have it. Check if also have cpu_set_t. If we don't,
274 # then we have the first version using unsigned long, and no
275 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
276 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
277 # should also be present, but we confirm nonetheless.
278
279 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
280 # We do have it.
281 # Check how many arguments does sched_setaffinity take.
282 # Should be 3 or 2.
283 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
284 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
285 #include <sched.h>
286 int main()
287 {
288 cpu_set_t foo;
289 sched_setaffinity(0, sizeof (foo), &foo);
290 return 0;
291 }
292 ]])
293 ],
294 [sched_set_affinity_args=3],
295 [sched_set_affinity_args=2])
296 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
297 $sched_set_affinity_args,
298 [Defined to sched_setaffinity's number of arguments.])
299 AC_MSG_RESULT([$sched_set_affinity_args])
300 ],[
301 # No cpu_set_t, always 3 args.
302 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
303 ])
304 ])
305
306 CFLAGS=$saved_CFLAGS
307
308 AC_CONFIG_LINKS([
309 urcu/arch.h:$ARCHSRC
310 urcu/uatomic.h:$UATOMICSRC
311 ])
312 AC_CONFIG_FILES([
313 Makefile
314 doc/Makefile
315 doc/examples/Makefile
316 tests/Makefile
317 tests/common/Makefile
318 tests/unit/Makefile
319 tests/benchmark/Makefile
320 tests/regression/Makefile
321 liburcu.pc
322 liburcu-bp.pc
323 liburcu-cds.pc
324 liburcu-qsbr.pc
325 liburcu-mb.pc
326 liburcu-signal.pc
327 ])
328 AC_OUTPUT
329
330 # Report on selected configure options
331 AS_IF([test "x$def_smp_support" = "xyes"],[
332 AS_ECHO("SMP support enabled.")
333 ],[
334 AS_ECHO("SMP support disabled.")
335 ])
336
337 AS_IF([test "x$def_tls_detect" = "x"],[
338 AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
339 ],[
340 AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
341 ])
This page took 0.063723 seconds and 4 git commands to generate.