configure.ac

   1 # This file is part of the Linux Trace Toolkit viewer
   2 # Copyright (C) 2003-2004 Mathieu Desnoyers
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License Version 2 as
   6 # published by the Free Software Foundation;
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  16 # MA 02111-1307, USA.
  17
  18
  19
  20 #                                               -*- Autoconf -*-
  21 # Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([lttv], [0.12.38-21032011], [yannick.brosseau@gmail.com])
  25 AC_CONFIG_AUX_DIR([config])
  26 AC_CONFIG_MACRO_DIR([config])
  27 AM_INIT_AUTOMAKE([dist-bzip2 no-dist-gzip])
  28 AM_SILENT_RULES([yes])
  29 AC_CONFIG_HEADERS([config.h])
  30 LT_INIT
  31
  32 # If requested, only build the ltt trace reading library
  33 AC_ARG_WITH(lttv,
  34         AS_HELP_STRING([--with-lttv],
  35         [build whole LTTV system, as opposd to only the trace reading library [[default=yes]]]),
  36         [with_lttv="$withval"],
  37         [with_lttv="yes"])
  38
  39 # If we've requested the lib only, turn off the lttv-gui building as well
  40 AS_IF([test "x$with_lttv" = "xno"], [with_lttv_gui="no"])
  41
  42 AM_CONDITIONAL([BUILD_LIB_ONLY], [ test "x$with_lttv" = "xno" ])
  43
  44
  45 # If requested, avoid building LTTV part
  46 AC_ARG_WITH(lttv-gui,
  47         AS_HELP_STRING([--with-lttv-gui],
  48         [build LTTV gui, as opposed to only build textmode LTTV [[default=yes]]]),
  49         [with_lttv_gui="$withval"],
  50         [with_lttv_gui="yes"])
  51
  52 AM_CONDITIONAL([BUILD_LTTV_GUI], [ test "x$with_lttv_gui" = "xyes" ])
  53
  54 AM_PATH_GLIB_2_0(2.4.0, , AC_MSG_ERROR([glib is required in order to compile LTTV]) , gmodule)
  55
  56 # GTK is only needed by the GUI
  57 AS_IF([test "x$with_lttv_gui" = "xyes"],[
  58         AM_PATH_GTK_2_0(2.4.0, , AC_MSG_ERROR([GTK 2 is required in order to compile the LTTV GUI]) , gmodule)
  59 ])
  60
  61 AC_PATH_PROGS(BASH, bash)
  62
  63 AC_SYS_LARGEFILE
  64
  65 # Checks for programs.
  66 AC_PROG_CC
  67
  68 # Checks for libraries.
  69 AC_CHECK_LIB([popt], [poptGetNextOpt], [],
  70         AC_MSG_ERROR([libpopt is required in order to compile LTTV])
  71 )
  72 AC_CHECK_LIB([m], [round], [],
  73         AC_MSG_ERROR([Mathematical libraries are missing.])
  74 )
  75 AC_CHECK_LIB([util], [forkpty], [],
  76         AC_MSG_ERROR([libutil is required in order to compile LTTV])
  77 )
  78
  79 # Trace synchronization feature, which requires libglpk
  80 AC_ARG_WITH([trace-sync],
  81         AS_HELP_STRING([--with-trace-sync],
  82         [support trace synchronization accuracy calculation (needs libglpk) [default=no]]),
  83         [with_trace_sync="$withval"],
  84         [with_trace_sync="no"])
  85
  86 AS_IF([test "x$with_trace_sync" = "xyes"],[
  87         AC_CHECK_LIB([glpk], [glp_create_prob], [], [
  88                 AC_MSG_ERROR([The trace synchronization feature requires libglpk, please install it first.])
  89         ])
  90         AC_DEFINE([HAVE_LIBGLPK], [1], [Define if you have libglpk]),
  91 ])
  92
  93
  94 # Checks for header files.
  95 AC_HEADER_STDC
  96 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h sys/time.h unistd.h pthread.h])
  97
  98 # Check for JNI header files if requested
  99 AC_ARG_WITH(jni-interface,
 100         AS_HELP_STRING([--with-jni-interface],
 101         [build JNI interface between C and Java. Needs JNI header file. [[default=no]]]),
 102         [with_jni_interface="$withval"],
 103         [with_jni_interface="no"])
 104
 105 AS_IF([test "x$with_jni_interface" = "xyes"],[
 106         AC_CHECK_HEADERS([jni.h], [], AC_MSG_ERROR([missing jni.h
 107 Make sure Sun Java or OpenJDK or GCJ is installed and that this header file exists in the system path.
 108 Use CFLAGS=-I/path/ to specify a non-standard path or disable the JNI interface.]))
 109 ])
 110 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [ test "$with_jni_interface" = "yes" ] )
 111
 112
 113 # If we want the gui, we need additionnal flags for GTK
 114 AS_IF([test "x$with_lttv_gui" = "xyes"],[
 115         pkg_modules="gtk+-2.0 >= 2.0.0"
 116         PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
 117 ])
 118
 119 pkg_modules="gmodule-2.0 >= 2.0.0"
 120 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 121
 122 pkg_modules="gobject-2.0 >= 2.0.0"
 123 PKG_CHECK_MODULES(GOBJECT, [$pkg_modules])
 124
 125 LIBS="$LIBS $GTK_LIBS $GOBJECT_LIBS $GMODULE_LIBS"
 126 PACKAGE_CFLAGS="$GTK_CFLAGS $GOBJECT_CFLAGS $GMODULE_CFLAGS -Wall -Wformat-security"
 127 MODULE_CFLAGS="$PACKAGE_CFLAGS -fvisibility=hidden"
 128 MODULE_LDFLAGS="-module -avoid-version"
 129 AC_SUBST([PACKAGE_CFLAGS])
 130 AC_SUBST(PACKAGE_LIBS)
 131 AC_SUBST([MODULE_CFLAGS])
 132 AC_SUBST([MODULE_LDFLAGS])
 133
 134 # Checks for typedefs, structures, and compiler characteristics.
 135 AC_HEADER_STDBOOL
 136 AC_C_CONST
 137 AC_C_INLINE
 138 AC_TYPE_OFF_T
 139 AC_TYPE_SIZE_T
 140 AC_HEADER_TIME
 141
 142 # Checks for library functions.
 143 AC_FUNC_ERROR_AT_LINE
 144 AC_FUNC_SELECT_ARGTYPES
 145 AC_CHECK_FUNCS([select])
 146
 147 AC_ARG_ENABLE(lttvstatic,
 148         AS_HELP_STRING([--enable-lttvstatic],
 149         [build a statically linked executable [[default=no]]]),
 150         [lttvstatic="$enableval"],
 151         [lttvstatic="no"])
 152 AM_CONDITIONAL([LTTVSTATIC], [ test "x$lttvstatic" = "xyes" ] )
 153
 154 lttvlibdir="${libdir}/lttv"
 155 lttvplugindir="${lttvlibdir}/plugins"
 156 #lttlibdir="${libdir}/ltt"
 157 top_lttvdir="\$(top_srcdir)/lttv"
 158 top_lttvwindowdir="\$(top_srcdir)/lttv/modules/gui/lttvwindow"
 159
 160 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_lttvdir) -I\$(top_lttvwindowdir)"
 161
 162 lttincludedir="${includedir}/ltt"
 163 lttvincludedir="${includedir}/lttv"
 164 lttvwindowincludedir="${includedir}/lttvwindow"
 165 lttctlincludedir="${includedir}/liblttctl"
 166
 167 AC_SUBST(lttvlibdir)
 168 AC_SUBST(lttvplugindir)
 169 #AC_SUBST(lttlibdir)
 170 AC_SUBST(top_lttvdir)
 171 AC_SUBST(top_lttvwindowdir)
 172 AC_SUBST(DEFAULT_INCLUDES)
 173 AC_SUBST(lttincludedir)
 174 AC_SUBST(lttvincludedir)
 175 AC_SUBST(lttvwindowincludedir)
 176 AC_SUBST(lttctlincludedir)
 177
 178 AC_CONFIG_FILES([Makefile
 179         lttv/Makefile
 180         lttv/lttv/Makefile
 181         lttv/lttv/sync/Makefile
 182         lttv/modules/Makefile
 183         lttv/modules/text/Makefile
 184         lttv/modules/gui/Makefile
 185         lttv/modules/gui/lttvwindow/Makefile
 186         lttv/modules/gui/interrupts/Makefile
 187         lttv/modules/gui/lttvwindow/lttvwindow/Makefile
 188         lttv/modules/gui/lttvwindow/pixmaps/Makefile
 189         lttv/modules/gui/controlflow/Makefile
 190         lttv/modules/gui/detailedevents/Makefile
 191         lttv/modules/gui/statistics/Makefile
 192         lttv/modules/gui/histogram/Makefile
 193         lttv/modules/gui/filter/Makefile
 194         lttv/modules/gui/tracecontrol/Makefile
 195         lttv/modules/gui/resourceview/Makefile
 196         ltt/Makefile
 197         doc/Makefile
 198         doc/developer/Makefile
 199         doc/developer/developer_guide/Makefile
 200         doc/developer/developer_guide/docbook/Makefile
 201         doc/developer/developer_guide/html/Makefile
 202         doc/user/Makefile
 203         doc/user/user_guide/Makefile
 204         doc/user/user_guide/docbook/Makefile
 205         doc/user/user_guide/html/Makefile])
 206
 207 AC_OUTPUT
 208
 209 # Report on what will be built
 210 AS_ECHO()
 211 AS_ECHO("The following components will be built:")
 212 AS_ECHO("LTT trace reading library: Enabled") # It's always enabled!
 213
 214 AS_ECHO_N("LTTV command line tool:    ")
 215 AS_IF([test "x$with_lttv" = "xyes"],[AS_ECHO("Enabled")],[AS_ECHO("Disabled")])
 216
 217 AS_ECHO_N("LTTV graphical interface:  ")
 218 AS_IF([test "x$with_lttv_gui" = "xyes"],[AS_ECHO("Enabled")],[AS_ECHO("Disabled")])
 219
 220 AS_ECHO_N("Trace synchronization:     ")
 221 AS_IF([test "x$with_trace_sync" = "xyes"],[AS_ECHO("Enabled")],[AS_ECHO("Disabled")])
 222
 223 AS_ECHO_N("Java (JNI) interface:      ")
 224 AS_IF([test "x$with_jni_interface" = "xyes"],[AS_ECHO("Enabled")],[AS_ECHO("Disabled")])
 225
 226 AS_ECHO()
 227 AS_ECHO_N("Statically linked executable: ")
 228 AS_IF([test "x$lttvstatic" = "xyes"],[AS_ECHO("Yes")],[AS_ECHO("No")])
 229
 230 AS_ECHO()
 231 AS_ECHO("Type 'make' to build LTTV.")
 232