configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.4.0],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 AM_MAINTAINER_MODE([enable])
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  25
  26 # Configuration options, which will be installed in the config.h
  27 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  29 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  30
  31 # Compute minor/major/patchlevel version numbers
  32 AC_PROG_SED
  33 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  34 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  35 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  36 AC_SUBST([MAJOR_VERSION], [$major_version])
  37 AC_SUBST([MINOR_VERSION], [$minor_version])
  38 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  39 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  40 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  41 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  42
  43 version_name="Époque Opaque"
  44 version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
  45
  46 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  47 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  48
  49 AC_PROG_GREP
  50 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  51 AC_ARG_ENABLE(libtool-linkdep-fixup,
  52         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  53                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  54         libtool_fixup=$enableval,
  55         libtool_fixup=yes)
  56
  57 AS_IF([test "x$libtool_fixup" = "xyes"],
  58             [
  59             libtool_m4="$srcdir/config/libtool.m4"
  60             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  61             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  62             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  63             AS_IF([test $libtool_flag_pattern_count -ne 0],
  64             [
  65                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  66                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  67                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  68                   ],
  69                   [
  70                   AC_MSG_RESULT([none])
  71                   ])
  72             ])
  73
  74 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  75
  76 # Checks for programs.
  77 AC_PROG_CC
  78 AC_PROG_CXX
  79 AC_PROG_MAKE_SET
  80 LT_INIT
  81
  82 # rw_PROG_CXX_WORKS
  83 # Check whether the C++ compiler works.
  84 AC_CACHE_CHECK([whether the C++ compiler works],
  85                 [rw_cv_prog_cxx_works],
  86                 [AC_LANG_PUSH([C++])
  87                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  88                                 [check_cxx_designated_initializers=yes],
  89                                 [rw_cv_prog_cxx_works=no])
  90                 if test "$check_cxx_designated_initializers" = "yes"; then
  91                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  92                                 struct foo { int a; int b; };
  93                                 void fct(void)
  94                                 {
  95                                         struct foo f = { .a = 0, .b = 1 };
  96                                 }
  97                         ]])],[
  98                                 rw_cv_prog_cxx_works=yes
  99                         ],[
 100                                 rw_cv_prog_cxx_works=no
 101                         ])
 102                 fi
 103                 AC_LANG_POP([C++])])
 104
 105 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 106
 107 ## Checks for libraries.
 108 AC_CHECK_LIB([dl], [dlopen],
 109 [
 110         have_libdl=yes
 111 ],
 112 [
 113         #libdl not found, check for dlopen in libc.
 114         AC_CHECK_LIB([c], [dlopen],
 115         [
 116                 have_libc_dl=yes
 117         ],
 118         [
 119                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 120         ])
 121 ])
 122 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 123 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 124
 125 AC_CHECK_LIB([pthread], [pthread_create])
 126
 127 # Check for dlfcn.h
 128 AC_CHECK_HEADER([dlfcn.h])
 129 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
 130         [AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
 131                 [#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 132                 #include <dlfcn.h>])
 133         ],
 134         [ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
 135 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 136
 137 # Checks for header files.
 138 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 139
 140 # Checks for typedefs, structures, and compiler characteristics.
 141 AC_C_INLINE
 142 #AC_TYPE_INT16_T
 143 #AC_TYPE_INT32_T
 144 #AC_TYPE_INT64_T
 145 #AC_TYPE_INT8_T
 146 #AC_TYPE_PID_T
 147 #AC_TYPE_SIZE_T
 148 #AC_TYPE_SSIZE_T
 149 #AC_TYPE_UINT16_T
 150 #AC_TYPE_UINT32_T
 151 #AC_TYPE_UINT64_T
 152 #AC_TYPE_UINT8_T
 153 #AC_CHECK_TYPES([ptrdiff_t])
 154
 155 # Checks for library functions.
 156 AC_FUNC_MALLOC
 157 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 158
 159 CFLAGS="-Wall $CFLAGS"
 160
 161 # URCU
 162
 163 # urcu - check if we just find the headers it out of the box.
 164 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 165 This error can also occur when the liburcu package's configure script has not been run.])])
 166
 167 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 168 # Part of Userspace RCU library 0.7.2 or better.
 169 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 170 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 171
 172 AC_MSG_CHECKING([caa_likely()])
 173 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 174 #include <urcu/compiler.h>
 175 void fct(void)
 176 {
 177         if (caa_likely(1)) {
 178         }
 179 }
 180 ]])],[
 181         AC_MSG_RESULT([yes])
 182 ],[
 183         AC_MSG_RESULT([no])
 184         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 185
 186 ])
 187
 188 # urcu - check that URCU lib is available to compilation
 189 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 190
 191 # urcu - check that URCU lib is at least version 0.6
 192 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 193
 194 AC_MSG_CHECKING([host system alignment requirements])
 195 case $host_cpu in
 196 changequote(,)dnl
 197         i[3456]86)
 198 changequote([,])dnl
 199           ;;
 200         x86_64) ;;
 201         amd64) ;;
 202         powerpc) ;;
 203         ppc64) ;;
 204         powerpc64) ;;
 205         s390) NO_UNALIGNED_ACCESS=1 ;;
 206         s390x) NO_UNALIGNED_ACCESS=1 ;;
 207         arm*) NO_UNALIGNED_ACCESS=1 ;;
 208         mips*) NO_UNALIGNED_ACCESS=1 ;;
 209         tile*) NO_UNALIGNED_ACCESS=1 ;;
 210         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 211 esac
 212 AC_MSG_RESULT([$host_cpu])
 213
 214 if test x$NO_UNALIGNED_ACCESS = x ; then
 215 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 216 fi
 217
 218 # Set compile flags to java include files if given
 219 AC_ARG_WITH([java-jdk],
 220         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 221         [JAVA_JDK=$withval],
 222         [JAVA_JDK=""]
 223 )
 224 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 225 AC_SUBST([JAVA_JDK])
 226
 227 AS_IF([test $JAVA_JDK],[
 228         AS_IF([test -d $JAVA_JDK],[
 229                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 230                 SUBDIRS=`find $JAVA_JDK/include -type d`
 231                 CPPFLAGS+=" "
 232                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 233                 CPPFLAGS+=" "
 234         ],[
 235                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 236         ])
 237 ])
 238
 239 # Check for JNI header files if requested
 240 AC_ARG_WITH([jni-interface],
 241         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 242         [jni_interface=$withval],
 243         [jni_interface=no]
 244 )
 245
 246 AS_IF([test "x$jni_interface" = "xyes"],[
 247         AC_CHECK_HEADERS([jni.h],[],[
 248         AC_MSG_ERROR([missing jni.h
 249 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 250 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 251         ])
 252 ])
 253 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 254
 255 # sdt.h integration
 256 AC_ARG_WITH([sdt],
 257         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 258         [with_sdt=$withval],
 259         [with_sdt="no"]
 260 )
 261
 262 AS_IF([test "x$with_sdt" = "xyes"],[
 263         AC_MSG_CHECKING([STAP_PROBEV()])
 264         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 265         #define SDT_USE_VARIADIC
 266         #include <sys/sdt.h>
 267         void fct(void)
 268         {
 269                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 270         }
 271         ]])],[
 272                 AC_MSG_RESULT([yes])
 273                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 274         ],[
 275                 AC_MSG_RESULT([no])
 276                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 277         ])
 278 ])
 279
 280 AC_MSG_CHECKING([whether shared libraries are enabled])
 281 AS_IF([test "x$enable_shared" = "xyes"],
 282         [
 283                 AC_MSG_RESULT([yes])
 284         ],
 285         [
 286                 AC_MSG_RESULT([no])
 287                 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 288         ])
 289
 290 AC_ARG_WITH([lttng-system-rundir],
 291         AS_HELP_STRING([--with-lttng-system-rundir],
 292         [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 293         [lttng_system_rundir="$withval"],
 294         [lttng_system_rundir="/var/run/lttng"])
 295 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 296         [LTTng system runtime directory])
 297
 298 lttnglibjavadir="${libdir}/lttng/java"
 299 AC_SUBST(lttnglibjavadir)
 300
 301 AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
 302 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
 303
 304 AC_CONFIG_FILES([
 305         Makefile
 306         doc/Makefile
 307         doc/examples/Makefile
 308         include/Makefile
 309         include/lttng/ust-version.h
 310         snprintf/Makefile
 311         libringbuffer/Makefile
 312         liblttng-ust-comm/Makefile
 313         liblttng-ust/Makefile
 314         liblttng-ust-ctl/Makefile
 315         liblttng-ust-fork/Makefile
 316         liblttng-ust-dl/Makefile
 317         liblttng-ust-java/Makefile
 318         liblttng-ust-jul/Makefile
 319         liblttng-ust-libc-wrapper/Makefile
 320         liblttng-ust-cyg-profile/Makefile
 321         tools/Makefile
 322         tests/Makefile
 323         tests/hello/Makefile
 324         tests/hello.cxx/Makefile
 325         tests/same_line_tracepoint/Makefile
 326         tests/snprintf/Makefile
 327         tests/benchmark/Makefile
 328         tests/utils/Makefile
 329         tests/java-jul/Makefile
 330         lttng-ust.pc
 331 ])
 332
 333 AC_OUTPUT
 334
 335 AS_ECHO()
 336 AS_ECHO("Version name: $version_name")
 337 AS_ECHO("$version_description")
 338
 339 # Report on the configuration options
 340 AS_ECHO()
 341 AS_ECHO("LTTng-UST will be built with the following options:")
 342
 343 AS_ECHO()
 344 AS_ECHO_N("Java support (JNI): ")
 345 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 346
 347 AS_ECHO_N("sdt.h integration:  ")
 348 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 349
 350 AS_ECHO()
 351 AS_ECHO("Type 'make' to compile.")
 352