configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.6.0-rc1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 AM_MAINTAINER_MODE([enable])
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  25
  26 # Configuration options, which will be installed in the config.h
  27 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  29 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  30 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
  31
  32 # Compute minor/major/patchlevel version numbers
  33 AC_PROG_SED
  34 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  35 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  36 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  37 AC_SUBST([MAJOR_VERSION], [$major_version])
  38 AC_SUBST([MINOR_VERSION], [$minor_version])
  39 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  40 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  41 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  42 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  43
  44 version_name="Gaia"
  45 version_description="From Benelux brewery in Montreal, the Gaia is a witbier with a cloudy light amber ale color. Aroma of coriander with floral hay notes is enchanting. Taste is also dominated by the very floral coriander note and some medium sweet malt notes."
  46
  47 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  48 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  49
  50 AC_PROG_GREP
  51 AC_PROG_LN_S
  52 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  53 AC_ARG_ENABLE(libtool-linkdep-fixup,
  54         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  55                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  56         libtool_fixup=$enableval,
  57         libtool_fixup=yes)
  58
  59 AS_IF([test "x$libtool_fixup" = "xyes"],
  60             [
  61             libtool_m4="$srcdir/config/libtool.m4"
  62             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  63             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  64             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  65             AS_IF([test $libtool_flag_pattern_count -ne 0],
  66             [
  67                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  68                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  69                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  70                   ],
  71                   [
  72                   AC_MSG_RESULT([none])
  73                   ])
  74             ])
  75
  76 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  77
  78 # Checks for programs.
  79 AC_PROG_CC
  80 AC_PROG_CXX
  81 AC_PROG_MAKE_SET
  82 LT_INIT
  83
  84 # rw_PROG_CXX_WORKS
  85 # Check whether the C++ compiler works.
  86 AC_CACHE_CHECK([whether the C++ compiler works],
  87                 [rw_cv_prog_cxx_works],
  88                 [AC_LANG_PUSH([C++])
  89                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  90                                 [check_cxx_designated_initializers=yes],
  91                                 [rw_cv_prog_cxx_works=no])
  92                 if test "$check_cxx_designated_initializers" = "yes"; then
  93                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  94                                 struct foo { int a; int b; };
  95                                 void fct(void)
  96                                 {
  97                                         struct foo f = { .a = 0, .b = 1 };
  98                                 }
  99                         ]])],[
 100                                 rw_cv_prog_cxx_works=yes
 101                         ],[
 102                                 rw_cv_prog_cxx_works=no
 103                         ])
 104                 fi
 105                 AC_LANG_POP([C++])])
 106
 107 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 108
 109 # Check if the compiler support weak symbols
 110 AX_SYS_WEAK_ALIAS
 111
 112 if test "x${ax_cv_sys_weak_alias}" = "xno"; then
 113    AC_MSG_ERROR([Your platform doesn't support weak symbols.])
 114 fi
 115
 116 ## Checks for libraries.
 117 AC_CHECK_LIB([dl], [dlopen],
 118 [
 119         have_libdl=yes
 120 ],
 121 [
 122         #libdl not found, check for dlopen in libc.
 123         AC_CHECK_LIB([c], [dlopen],
 124         [
 125                 have_libc_dl=yes
 126         ],
 127         [
 128                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 129         ])
 130 ])
 131 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 132 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 133
 134 AC_CHECK_LIB([pthread], [pthread_create])
 135
 136 # Check for dlfcn.h
 137 AC_CHECK_HEADER([dlfcn.h])
 138 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
 139         [AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
 140                 [#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 141                 #include <dlfcn.h>])
 142         ],
 143         [ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
 144 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 145
 146 # Checks for header files.
 147 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 148
 149 # Checks for typedefs, structures, and compiler characteristics.
 150 AC_C_INLINE
 151 #AC_TYPE_INT16_T
 152 #AC_TYPE_INT32_T
 153 #AC_TYPE_INT64_T
 154 #AC_TYPE_INT8_T
 155 #AC_TYPE_PID_T
 156 #AC_TYPE_SIZE_T
 157 #AC_TYPE_SSIZE_T
 158 #AC_TYPE_UINT16_T
 159 #AC_TYPE_UINT32_T
 160 #AC_TYPE_UINT64_T
 161 #AC_TYPE_UINT8_T
 162 #AC_CHECK_TYPES([ptrdiff_t])
 163
 164 # Checks for library functions.
 165 AC_FUNC_MALLOC
 166 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 167
 168 CFLAGS="-Wall $CFLAGS"
 169
 170 # URCU
 171
 172 # urcu - check if we just find the headers it out of the box.
 173 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 174 This error can also occur when the liburcu package's configure script has not been run.])])
 175
 176 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 177 # Part of Userspace RCU library 0.7.2 or better.
 178 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 179 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 180
 181 AC_MSG_CHECKING([caa_likely()])
 182 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 183 #include <urcu/compiler.h>
 184 void fct(void)
 185 {
 186         if (caa_likely(1)) {
 187         }
 188 }
 189 ]])],[
 190         AC_MSG_RESULT([yes])
 191 ],[
 192         AC_MSG_RESULT([no])
 193         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 194
 195 ])
 196
 197 # urcu - check that URCU lib is available to compilation
 198 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 199
 200 # urcu - check that URCU lib is at least version 0.6
 201 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 202
 203 # optional linux/perf_event.h
 204 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 205
 206 # Perf event counters are only supported on x86 so far.
 207 AC_MSG_CHECKING([UST support for architecture perf event counters])
 208 case $host_cpu in
 209 changequote(,)dnl
 210         i[3456]86)
 211 changequote([,])dnl
 212         UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 213         x86_64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 214         amd64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 215         *) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no;;
 216 esac
 217 AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
 218
 219 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
 220
 221 if test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"; then
 222 AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 223 fi
 224
 225 AC_MSG_CHECKING([host system alignment requirements])
 226 case $host_cpu in
 227 changequote(,)dnl
 228         i[3456]86)
 229 changequote([,])dnl
 230           ;;
 231         x86_64) ;;
 232         amd64) ;;
 233         powerpc) ;;
 234         ppc64) ;;
 235         ppc64le) ;;
 236         powerpc64) ;;
 237         powerpc64le) ;;
 238         s390) NO_UNALIGNED_ACCESS=1 ;;
 239         s390x) NO_UNALIGNED_ACCESS=1 ;;
 240         arm*) NO_UNALIGNED_ACCESS=1 ;;
 241         mips*) NO_UNALIGNED_ACCESS=1 ;;
 242         tile*) NO_UNALIGNED_ACCESS=1 ;;
 243         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 244 esac
 245 AC_MSG_RESULT([$host_cpu])
 246
 247 if test x$NO_UNALIGNED_ACCESS = x ; then
 248 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 249 fi
 250
 251 # Check for JNI header files if requested
 252 AC_ARG_ENABLE([jni-interface],
 253         [AS_HELP_STRING([--enable-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 254         [jni_interface=$withval],
 255         [jni_interface=no]
 256 )
 257
 258 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 259
 260
 261 AC_ARG_ENABLE([java-agent-jul],
 262         [AS_HELP_STRING([--enable-java-agent-jul],[build the LTTng UST Java agent with JUL support [default=no]])],
 263         [java_agent_jul=$enableval],
 264         [java_agent_jul=no]
 265 )
 266
 267 AC_ARG_ENABLE([java-agent-log4j],
 268         [AS_HELP_STRING([--enable-java-agent-log4j],[build the LTTng UST Java agent with Log4j support [default=no]])],
 269         [java_agent_log4j=$enableval],
 270         [java_agent_log4j=no]
 271 )
 272
 273 AC_ARG_ENABLE([java-agent-all],
 274         [AS_HELP_STRING([--enable-java-agent-all],[build the LTTng UST Java agent with all supported backends [default=no]])],
 275         [java_agent_jul=$enableval
 276          java_agent_log4j=$enableval],
 277         [:]
 278 )
 279
 280
 281 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 282 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 283 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 284
 285 if test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"; then
 286   AX_JAVA_OPTIONS
 287   AX_PROG_JAVAC
 288   AX_PROG_JAVA
 289   AX_PROG_JAR
 290
 291   AX_JNI_INCLUDE_DIR
 292   for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 293   do
 294         CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
 295   done
 296
 297   AX_PROG_JAVAH
 298 fi
 299
 300 if test "x$java_agent_log4j" = "xyes"; then
 301   AX_CHECK_CLASSPATH
 302
 303   AX_CHECK_CLASS(org.apache.log4j.Logger)
 304
 305   if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 306      AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 307   fi
 308 fi
 309
 310 # Option to build the python agent
 311 AC_ARG_ENABLE([python-agent],
 312         [AS_HELP_STRING([--enable-python-agent],[build the LTTng UST Python agent [default=no]])],
 313     [python_agent=$enableval],
 314         [:]
 315 )
 316 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 317
 318 # sdt.h integration
 319 AC_ARG_WITH([sdt],
 320         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 321         [with_sdt=$withval],
 322         [with_sdt="no"]
 323 )
 324
 325 AS_IF([test "x$with_sdt" = "xyes"],[
 326         AC_MSG_CHECKING([STAP_PROBEV()])
 327         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 328         #define SDT_USE_VARIADIC
 329         #include <sys/sdt.h>
 330         void fct(void)
 331         {
 332                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 333         }
 334         ]])],[
 335                 AC_MSG_RESULT([yes])
 336                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 337         ],[
 338                 AC_MSG_RESULT([no])
 339                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 340         ])
 341 ])
 342
 343 AC_MSG_CHECKING([whether shared libraries are enabled])
 344 AS_IF([test "x$enable_shared" = "xyes"],
 345         [
 346                 AC_MSG_RESULT([yes])
 347         ],
 348         [
 349                 AC_MSG_RESULT([no])
 350                 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 351         ])
 352
 353 AC_ARG_WITH([lttng-system-rundir],
 354         AS_HELP_STRING([--with-lttng-system-rundir],
 355         [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 356         [lttng_system_rundir="$withval"],
 357         [lttng_system_rundir="/var/run/lttng"])
 358 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 359         [LTTng system runtime directory])
 360
 361 AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
 362 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
 363
 364 AC_CONFIG_FILES([
 365         Makefile
 366         doc/Makefile
 367         doc/examples/Makefile
 368         include/Makefile
 369         include/lttng/ust-version.h
 370         snprintf/Makefile
 371         libringbuffer/Makefile
 372         liblttng-ust-comm/Makefile
 373         liblttng-ust/Makefile
 374         liblttng-ust-ctl/Makefile
 375         liblttng-ust-fork/Makefile
 376         liblttng-ust-dl/Makefile
 377         liblttng-ust-java/Makefile
 378         liblttng-ust-java-agent/Makefile
 379         liblttng-ust-java-agent/java/Makefile
 380         liblttng-ust-java-agent/jni/Makefile
 381         liblttng-ust-java-agent/jni/jul/Makefile
 382         liblttng-ust-java-agent/jni/log4j/Makefile
 383         liblttng-ust-libc-wrapper/Makefile
 384         liblttng-ust-cyg-profile/Makefile
 385         liblttng-ust-python-agent/Makefile
 386         tools/Makefile
 387         tests/Makefile
 388         tests/hello/Makefile
 389         tests/hello.cxx/Makefile
 390         tests/same_line_tracepoint/Makefile
 391         tests/snprintf/Makefile
 392         tests/benchmark/Makefile
 393         tests/utils/Makefile
 394         lttng-ust.pc
 395 ])
 396
 397 AC_OUTPUT
 398
 399 AS_ECHO()
 400 AS_ECHO("Version name: $version_name")
 401 AS_ECHO("$version_description")
 402
 403 # Report on the configuration options
 404 AS_ECHO()
 405 AS_ECHO("LTTng-UST will be built with the following options:")
 406
 407 AS_ECHO()
 408
 409 AS_ECHO_N("Java agent (JUL support): ")
 410 AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 411
 412 AS_ECHO_N("Java agent (Log4j support): ")
 413 AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 414
 415 AS_ECHO_N("JNI interface (JNI): ")
 416 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 417
 418 AS_ECHO_N("Python agent: ")
 419 AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 420
 421 AS_ECHO_N("sdt.h integration:  ")
 422 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 423
 424 AS_ECHO()
 425 AS_ECHO("Type 'make' to compile.")
 426