configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.4.0],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 AM_MAINTAINER_MODE([enable])
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  25
  26 # Configuration options, which will be installed in the config.h
  27 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  29 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  30
  31 # Compute minor/major/patchlevel version numbers
  32 AC_PROG_SED
  33 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  34 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  35 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  36 AC_SUBST([MAJOR_VERSION], [$major_version])
  37 AC_SUBST([MINOR_VERSION], [$minor_version])
  38 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  39 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  40 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  41 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  42
  43 version_name="Époque Opaque"
  44 version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
  45
  46 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  47 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  48
  49 AC_PROG_GREP
  50 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  51 AC_ARG_ENABLE(libtool-linkdep-fixup,
  52         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  53                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  54         libtool_fixup=$enableval,
  55         libtool_fixup=yes)
  56
  57 AS_IF([test "x$libtool_fixup" = "xyes"],
  58             [
  59             libtool_m4="$srcdir/config/libtool.m4"
  60             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  61             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  62             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  63             AS_IF([test $libtool_flag_pattern_count -ne 0],
  64             [
  65                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  66                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  67                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  68                   ],
  69                   [
  70                   AC_MSG_RESULT([none])
  71                   ])
  72             ])
  73
  74 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  75
  76 # Checks for programs.
  77 AC_PROG_CC
  78 AC_PROG_CXX
  79 AC_PROG_MAKE_SET
  80 LT_INIT
  81
  82 # rw_PROG_CXX_WORKS
  83 # Check whether the C++ compiler works.
  84 AC_CACHE_CHECK([whether the C++ compiler works],
  85                 [rw_cv_prog_cxx_works],
  86                 [AC_LANG_PUSH([C++])
  87                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  88                                 [check_cxx_designated_initializers=yes],
  89                                 [rw_cv_prog_cxx_works=no])
  90                 if test "$check_cxx_designated_initializers" = "yes"; then
  91                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  92                                 struct foo { int a; int b; };
  93                                 void fct(void)
  94                                 {
  95                                         struct foo f = { .a = 0, .b = 1 };
  96                                 }
  97                         ]])],[
  98                                 rw_cv_prog_cxx_works=yes
  99                         ],[
 100                                 rw_cv_prog_cxx_works=no
 101                         ])
 102                 fi
 103                 AC_LANG_POP([C++])])
 104
 105 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 106
 107 ## Checks for libraries.
 108 AC_CHECK_LIB([dl], [dlopen],
 109 [
 110         have_libdl=yes
 111 ],
 112 [
 113         #libdl not found, check for dlopen in libc.
 114         AC_CHECK_LIB([c], [dlopen],
 115         [
 116                 have_libc_dl=yes
 117         ],
 118         [
 119                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 120         ])
 121 ])
 122 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 123 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 124
 125 AC_CHECK_LIB([pthread], [pthread_create])
 126
 127 # Checks for header files.
 128 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 129
 130 # Checks for typedefs, structures, and compiler characteristics.
 131 AC_C_INLINE
 132 #AC_TYPE_INT16_T
 133 #AC_TYPE_INT32_T
 134 #AC_TYPE_INT64_T
 135 #AC_TYPE_INT8_T
 136 #AC_TYPE_PID_T
 137 #AC_TYPE_SIZE_T
 138 #AC_TYPE_SSIZE_T
 139 #AC_TYPE_UINT16_T
 140 #AC_TYPE_UINT32_T
 141 #AC_TYPE_UINT64_T
 142 #AC_TYPE_UINT8_T
 143 #AC_CHECK_TYPES([ptrdiff_t])
 144
 145 # Checks for library functions.
 146 AC_FUNC_MALLOC
 147 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 148
 149 CFLAGS="-Wall $CFLAGS"
 150
 151 # URCU
 152
 153 # urcu - check if we just find the headers it out of the box.
 154 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 155 This error can also occur when the liburcu package's configure script has not been run.])])
 156
 157 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 158 # Part of Userspace RCU library 0.7.2 or better.
 159 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 160 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 161
 162 AC_MSG_CHECKING([caa_likely()])
 163 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 164 #include <urcu/compiler.h>
 165 void fct(void)
 166 {
 167         if (caa_likely(1)) {
 168         }
 169 }
 170 ]])],[
 171         AC_MSG_RESULT([yes])
 172 ],[
 173         AC_MSG_RESULT([no])
 174         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 175
 176 ])
 177
 178 # urcu - check that URCU lib is available to compilation
 179 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 180
 181 # urcu - check that URCU lib is at least version 0.6
 182 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 183
 184 AC_MSG_CHECKING([host system alignment requirements])
 185 case $host_cpu in
 186 changequote(,)dnl
 187         i[3456]86)
 188 changequote([,])dnl
 189           ;;
 190         x86_64) ;;
 191         amd64) ;;
 192         powerpc) ;;
 193         ppc64) ;;
 194         powerpc64) ;;
 195         s390) NO_UNALIGNED_ACCESS=1 ;;
 196         s390x) NO_UNALIGNED_ACCESS=1 ;;
 197         arm*) NO_UNALIGNED_ACCESS=1 ;;
 198         mips*) NO_UNALIGNED_ACCESS=1 ;;
 199         tile*) NO_UNALIGNED_ACCESS=1 ;;
 200         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 201 esac
 202 AC_MSG_RESULT([$host_cpu])
 203
 204 if test x$NO_UNALIGNED_ACCESS = x ; then
 205 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 206 fi
 207
 208 # Set compile flags to java include files if given
 209 AC_ARG_WITH([java-jdk],
 210         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 211         [JAVA_JDK=$withval],
 212         [JAVA_JDK=""]
 213 )
 214 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 215 AC_SUBST([JAVA_JDK])
 216
 217 AS_IF([test $JAVA_JDK],[
 218         AS_IF([test -d $JAVA_JDK],[
 219                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 220                 SUBDIRS=`find $JAVA_JDK/include -type d`
 221                 CPPFLAGS+=" "
 222                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 223                 CPPFLAGS+=" "
 224         ],[
 225                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 226         ])
 227 ])
 228
 229 # Check for JNI header files if requested
 230 AC_ARG_WITH([jni-interface],
 231         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 232         [jni_interface=$withval],
 233         [jni_interface=no]
 234 )
 235
 236 AS_IF([test "x$jni_interface" = "xyes"],[
 237         AC_CHECK_HEADERS([jni.h],[],[
 238         AC_MSG_ERROR([missing jni.h
 239 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 240 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 241         ])
 242 ])
 243 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 244
 245 # sdt.h integration
 246 AC_ARG_WITH([sdt],
 247         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 248         [with_sdt=$withval],
 249         [with_sdt="no"]
 250 )
 251
 252 AS_IF([test "x$with_sdt" = "xyes"],[
 253         AC_MSG_CHECKING([STAP_PROBEV()])
 254         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 255         #define SDT_USE_VARIADIC
 256         #include <sys/sdt.h>
 257         void fct(void)
 258         {
 259                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 260         }
 261         ]])],[
 262                 AC_MSG_RESULT([yes])
 263                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 264         ],[
 265                 AC_MSG_RESULT([no])
 266                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 267         ])
 268 ])
 269
 270 AC_MSG_CHECKING([whether shared libraries are enabled])
 271 AS_IF([test "x$enable_shared" = "xyes"],
 272         [
 273                 AC_MSG_RESULT([yes])
 274         ],
 275         [
 276                 AC_MSG_RESULT([no])
 277                 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 278         ])
 279
 280 AC_ARG_WITH([lttng-system-rundir],
 281         AS_HELP_STRING([--with-lttng-system-rundir],
 282         [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 283         [lttng_system_rundir="$withval"],
 284         [lttng_system_rundir="/var/run/lttng"])
 285 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 286         [LTTng system runtime directory])
 287
 288 lttnglibjavadir="${libdir}/lttng/java"
 289 AC_SUBST(lttnglibjavadir)
 290
 291 AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
 292 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
 293
 294 AC_CONFIG_FILES([
 295         Makefile
 296         doc/Makefile
 297         doc/examples/Makefile
 298         include/Makefile
 299         include/lttng/ust-version.h
 300         snprintf/Makefile
 301         libringbuffer/Makefile
 302         liblttng-ust-comm/Makefile
 303         liblttng-ust/Makefile
 304         liblttng-ust-ctl/Makefile
 305         liblttng-ust-fork/Makefile
 306         liblttng-ust-dl/Makefile
 307         liblttng-ust-java/Makefile
 308         liblttng-ust-jul/Makefile
 309         liblttng-ust-libc-wrapper/Makefile
 310         liblttng-ust-cyg-profile/Makefile
 311         tools/Makefile
 312         tests/Makefile
 313         tests/hello/Makefile
 314         tests/hello.cxx/Makefile
 315         tests/same_line_tracepoint/Makefile
 316         tests/snprintf/Makefile
 317         tests/benchmark/Makefile
 318         tests/utils/Makefile
 319         tests/java-jul/Makefile
 320         lttng-ust.pc
 321 ])
 322
 323 AC_OUTPUT
 324
 325 AS_ECHO()
 326 AS_ECHO("Version name: $version_name")
 327 AS_ECHO("$version_description")
 328
 329 # Report on the configuration options
 330 AS_ECHO()
 331 AS_ECHO("LTTng-UST will be built with the following options:")
 332
 333 AS_ECHO()
 334 AS_ECHO_N("Java support (JNI): ")
 335 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 336
 337 AS_ECHO_N("sdt.h integration:  ")
 338 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 339
 340 AS_ECHO()
 341 AS_ECHO("Type 'make' to compile.")
 342