configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [10])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [rc1])
   6 m4_define([V_NAME], [[KeKriek]])
   7 m4_define([V_DESC], [[From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  24 # note: remember to update tracepoint.h dlopen() to match this version
  25 # number. TODO: eventually automate by exporting the major number.
  26
  27 # This is the library version of liblttng-ust-ctl, used internally by
  28 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  29 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  30
  31 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  32 AC_CONFIG_AUX_DIR([config])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38
  39 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  40 AM_MAINTAINER_MODE([enable])
  41
  42 # Enable silent rules if available (Introduced in AM 1.11)
  43 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  44
  45 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  46
  47 # Checks for C compiler
  48 AC_USE_SYSTEM_EXTENSIONS
  49 AC_SYS_LARGEFILE
  50 AC_PROG_CC
  51 AC_PROG_CC_STDC
  52 AC_PROG_CXX
  53 rw_PROG_CXX_WORKS
  54 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  55
  56 # Check if the compiler support weak symbols
  57 AX_SYS_WEAK_ALIAS
  58
  59 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  60         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  61 ])
  62
  63 # Checks for programs.
  64 AC_PROG_SED
  65 AC_PROG_GREP
  66 AC_PROG_LN_S
  67 AC_PROG_MKDIR_P
  68 AC_PROG_MAKE_SET
  69 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  70 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  71
  72 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  73 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  74 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  75 ], [
  76         libtool_fixup=$enableval
  77 ], [
  78         libtool_fixup=yes
  79 ])
  80
  81 AS_IF([test "x$libtool_fixup" = "xyes"], [
  82         libtool_m4="$srcdir/m4/libtool.m4"
  83         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  84         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  85         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  86
  87         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  88         AC_MSG_RESULT([$libtool_flag_pattern_count])
  89         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  90                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  91         ], [
  92                 AC_MSG_RESULT([none])
  93         ])
  94 ])
  95 LT_INIT([disable-static])
  96
  97 AC_MSG_CHECKING([whether shared libraries are enabled])
  98 AS_IF([test "x$enable_shared" = "xyes"], [
  99         AC_MSG_RESULT([yes])
 100 ], [
 101         AC_MSG_RESULT([no])
 102         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 103 ])
 104
 105 # Checks for typedefs, structures, and compiler characteristics.
 106 AC_C_INLINE
 107 AC_TYPE_INT8_T
 108 AC_TYPE_INT16_T
 109 AC_TYPE_INT32_T
 110 AC_TYPE_INT64_T
 111 AC_TYPE_MODE_T
 112 AC_TYPE_OFF_T
 113 AC_TYPE_PID_T
 114 AC_TYPE_SIZE_T
 115 AC_TYPE_SSIZE_T
 116 AC_TYPE_UID_T
 117 AC_TYPE_UINT8_T
 118 AC_TYPE_UINT16_T
 119 AC_TYPE_UINT32_T
 120 AC_TYPE_UINT64_T
 121 AC_CHECK_TYPES([ptrdiff_t])
 122
 123 AX_C___ATTRIBUTE__
 124 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 125         [:],
 126         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 127
 128 # Checks for library functions.
 129 AC_FUNC_CHOWN
 130 AC_FUNC_FORK
 131 AC_FUNC_MMAP
 132 AC_FUNC_REALLOC
 133 AC_FUNC_STRERROR_R
 134 AC_FUNC_STRNLEN
 135 AC_CHECK_FUNCS([ \
 136         atexit \
 137         clock_gettime \
 138         ftruncate \
 139         getpagesize \
 140         gettimeofday \
 141         localeconv \
 142         memchr \
 143         memmove \
 144         memset \
 145         mkdir \
 146         munmap \
 147         realpath \
 148         sched_getcpu \
 149         socket \
 150         strchr \
 151         strdup \
 152         strerror \
 153         strtol \
 154         sysconf \
 155 ])
 156
 157 # AC_FUNC_MALLOC causes problems when cross-compiling.
 158 #AC_FUNC_MALLOC
 159
 160 # Checks for header files.
 161 AC_HEADER_STDBOOL
 162 AC_CHECK_HEADERS([ \
 163         arpa/inet.h \
 164         fcntl.h \
 165         float.h \
 166         limits.h \
 167         locale.h \
 168         stddef.h \
 169         sys/socket.h \
 170         sys/time.h \
 171         wchar.h \
 172 ])
 173
 174 # Set architecture specific options
 175 AS_CASE([$host_cpu],
 176         [i[[3456]]86], [],
 177         [x86_64], [],
 178         [amd64], [],
 179         [powerpc], [],
 180         [ppc64], [],
 181         [ppc64le], [],
 182         [powerpc64], [],
 183         [powerpc64le], [],
 184         [s390], [NO_UNALIGNED_ACCESS=1],
 185         [s390x], [NO_UNALIGNED_ACCESS=1],
 186         [arm*], [
 187                 NO_UNALIGNED_ACCESS=1
 188                 NO_NUMA=1
 189                 ],
 190         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 191         [mips*], [NO_UNALIGNED_ACCESS=1],
 192         [tile*], [NO_UNALIGNED_ACCESS=1],
 193         [
 194                 UNSUPPORTED_ARCH=1
 195                 NO_UNALIGNED_ACCESS=1
 196         ])
 197
 198 # Configuration options, which will be installed in the config.h
 199 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 200 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 201 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 202
 203 # Checks for libraries.
 204 AC_CHECK_LIB([dl], [dlopen], [
 205         have_libdl=yes
 206         libdl_name=dl
 207 ], [
 208         #libdl not found, check for dlopen in libc.
 209         AC_CHECK_LIB([c], [dlopen], [
 210                 have_libc_dl=yes
 211                 libdl_name=c
 212         ], [
 213                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 214         ])
 215 ])
 216
 217 # Check if libdl has dlmopen support.
 218 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 219 AC_CHECK_LIB([$libdl_name], [dlmopen],
 220         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 221 )
 222
 223 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 224 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 225
 226 AC_CHECK_LIB([pthread], [pthread_create])
 227 AC_CHECK_LIB([pthread], [pthread_setname_np],
 228         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 229         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 230                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 231                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 232
 233 # Check for dlfcn.h
 234 AC_CHECK_HEADER([dlfcn.h])
 235 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 236         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 237                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 238                 #include <dlfcn.h>
 239         ])
 240 ], [
 241         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 242 ])
 243
 244 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 245
 246 # URCU
 247
 248 # urcu - check if we just find the headers it out of the box.
 249 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 250 This error can also occur when the liburcu package's configure script has not been run.])])
 251
 252 # URCU library version needed or newer
 253 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.11.0 is needed])
 254
 255 #Macro added in urcu 0.6.6
 256 AC_CHECK_DECL([caa_likely], [],
 257         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 258 #Macro added in urcu 0.11.0
 259 AC_CHECK_DECL([DEFINE_URCU_TLS_IE], [],
 260         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/tls-compat.h>]]
 261 )
 262
 263 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 264 # Part of Userspace RCU library 0.7.2 or better.
 265 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 266 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 267
 268 # urcu - check that URCU lib is available to compilation
 269 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 270
 271 # urcu - check that URCU lib is at least version 0.6
 272 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 273
 274 # numa.h integration
 275 AS_IF([test "x$NO_NUMA" = "x1"],[
 276       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 277 ])
 278
 279 AC_ARG_ENABLE([numa], [
 280 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 281 ], [
 282         enable_numa=$enableval
 283 ], [
 284         enable_numa=yes
 285 ])
 286
 287 AS_IF([test "x$enable_numa" = "xyes"], [
 288         # numa - check that numa lib is available
 289         AC_CHECK_LIB([numa], [numa_available], [],
 290 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 291         have_libnuma=yes
 292 ])
 293 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 294
 295 # optional linux/perf_event.h
 296 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 297
 298 # Perf event counters are supported on all architectures supported by
 299 # perf, using the read system call as fallback.
 300 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 301
 302 AS_IF([test "x$have_perf_event" = "xyes"], [
 303         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 304 ])
 305
 306 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 307         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 308 ])
 309
 310 # Check for JNI header files if requested
 311 AC_ARG_ENABLE([jni-interface], [
 312 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 313 ], [
 314         jni_interface=$enableval
 315 ], [
 316         jni_interface=no
 317 ])
 318
 319 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 320
 321
 322 AC_ARG_ENABLE([java-agent-jul], [
 323 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 324 ], [
 325         java_agent_jul=$enableval
 326 ], [
 327         java_agent_jul=no
 328 ])
 329
 330 AC_ARG_ENABLE([java-agent-log4j], [
 331 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 332 ], [
 333         java_agent_log4j=$enableval
 334 ], [
 335         java_agent_log4j=no
 336 ])
 337
 338 AC_ARG_ENABLE([java-agent-all], [
 339 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 340 ], [
 341         java_agent_jul=$enableval
 342         java_agent_log4j=$enableval
 343 ], [:])
 344
 345 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 346 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 347 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 348
 349 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 350         AX_JAVA_OPTIONS
 351         AX_PROG_JAVAC
 352         AX_PROG_JAVA
 353         AX_PROG_JAR
 354
 355         AX_JNI_INCLUDE_DIR
 356         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 357         do
 358                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 359         done
 360
 361         saved_CPPFLAGS="$CPPFLAGS"
 362         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 363         AX_PROG_JAVAH
 364         CPPFLAGS="$saved_CPPFLAGS"
 365 ])
 366
 367 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 368         AX_CHECK_CLASSPATH
 369         AX_CHECK_CLASS([org.apache.log4j.Logger])
 370         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 371                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 372         ])
 373 ])
 374
 375 # Option to build the python agent
 376 AC_ARG_ENABLE([python-agent], [
 377 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 378 ], [
 379         python_agent=$enableval
 380 ], [:])
 381 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 382 AS_IF([test "x$python_agent" = "xyes"], [
 383         AM_PATH_PYTHON([2.7])
 384 ])
 385
 386 # sdt.h integration
 387 AC_ARG_WITH([sdt], [
 388 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 389 ], [
 390         with_sdt=$withval
 391 ], [
 392         with_sdt="no"
 393 ])
 394
 395 AS_IF([test "x$with_sdt" = "xyes"], [
 396         AC_MSG_CHECKING([STAP_PROBEV()])
 397         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 398                 #define SDT_USE_VARIADIC
 399                 #include <sys/sdt.h>
 400                 void fct(void)
 401                 {
 402                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 403                 }
 404         ]])], [
 405                 AC_MSG_RESULT([yes])
 406                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 407         ], [
 408                 AC_MSG_RESULT([no])
 409                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 410         ])
 411 ])
 412
 413 AC_ARG_WITH([lttng-system-rundir], [
 414 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 415 ], [
 416         lttng_system_rundir="$withval"
 417 ], [
 418         lttng_system_rundir="/var/run/lttng"
 419 ])
 420 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 421                 [LTTng system runtime directory])
 422
 423 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 424 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 425
 426 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 427 # is not distributed in tarballs.
 428 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 429 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 430
 431 # Enable building man pages (user's intention).
 432 AC_ARG_ENABLE(
 433         man-pages,
 434         AS_HELP_STRING(
 435                 [--disable-man-pages],
 436                 [Do not build and install man pages (already built in a distributed tarball)]
 437         ),
 438         [man_pages_opt=$enableval],
 439         [man_pages_opt=yes]
 440 )
 441
 442 # Check for asciidoc and xmlto if we enabled building the man pages.
 443 have_asciidoc_xmlto=no
 444 warn_prebuilt_man_pages=no
 445
 446 AS_IF([test "x$man_pages_opt" = "xyes"], [
 447         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 448         AC_PATH_PROG([XMLTO], [xmlto], [no])
 449
 450         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 451                 AS_IF([test "x$in_git_repo" = "xyes"], [
 452                         # This is an error because we're in the Git repo, which
 453                         # means the man pages are not already generated for us,
 454                         # thus asciidoc/xmlto are required because we were asked
 455                         # to build the man pages.
 456                         AC_MSG_ERROR([
 457 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 458 --disable-man-pages to disable building the man pages, in which case
 459 they will not be installed.
 460                         ])
 461                 ], [
 462                         # Only warn here: since we're in the tarball, the man
 463                         # pages should already be generated at this point, thus
 464                         # asciidoc/xmlto are not strictly required.
 465                         warn_prebuilt_man_pages=yes
 466                 ])
 467         ], [
 468                 have_asciidoc_xmlto=yes
 469         ])
 470 ])
 471
 472 # Export man page build condition: build the man pages if the user
 473 # asked for it, and if the tools are available.
 474 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 475 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 476
 477 # Default values
 478 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 479         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 480         $1="$2"
 481         AC_SUBST([$1])
 482 ])
 483
 484 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 485
 486 AM_CFLAGS="-Wall"
 487 AC_SUBST(AM_CFLAGS)
 488 AC_SUBST(JNI_CPPFLAGS)
 489
 490 AC_CONFIG_FILES([
 491         Makefile
 492         doc/Makefile
 493         doc/examples/Makefile
 494         doc/man/Makefile
 495         include/Makefile
 496         include/lttng/ust-version.h
 497         snprintf/Makefile
 498         libringbuffer/Makefile
 499         liblttng-ust-comm/Makefile
 500         liblttng-ust/Makefile
 501         liblttng-ust-ctl/Makefile
 502         liblttng-ust-fork/Makefile
 503         liblttng-ust-dl/Makefile
 504         liblttng-ust-fd/Makefile
 505         liblttng-ust-java/Makefile
 506         liblttng-ust-java-agent/Makefile
 507         liblttng-ust-java-agent/java/Makefile
 508         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 509         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 510         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 511         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 512         liblttng-ust-java-agent/jni/Makefile
 513         liblttng-ust-java-agent/jni/common/Makefile
 514         liblttng-ust-java-agent/jni/jul/Makefile
 515         liblttng-ust-java-agent/jni/log4j/Makefile
 516         liblttng-ust-libc-wrapper/Makefile
 517         liblttng-ust-cyg-profile/Makefile
 518         liblttng-ust-python-agent/Makefile
 519         python-lttngust/Makefile
 520         python-lttngust/setup.py
 521         python-lttngust/lttngust/__init__.py
 522         tools/Makefile
 523         tests/Makefile
 524         tests/ctf-types/Makefile
 525         tests/hello/Makefile
 526         tests/hello.cxx/Makefile
 527         tests/same_line_tracepoint/Makefile
 528         tests/snprintf/Makefile
 529         tests/ust-elf/Makefile
 530         tests/benchmark/Makefile
 531         tests/utils/Makefile
 532         tests/test-app-ctx/Makefile
 533         tests/gcc-weak-hidden/Makefile
 534         lttng-ust.pc
 535 ])
 536
 537 # Create link for python agent for the VPATH guru.
 538 AC_CONFIG_LINKS([
 539         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 540         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 541         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 542         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 543 ])
 544
 545 AC_OUTPUT
 546
 547
 548 #
 549 # Mini-report on what will be built.
 550 #
 551
 552 PPRINT_INIT
 553 PPRINT_SET_INDENT(1)
 554 PPRINT_SET_TS(38)
 555
 556 AS_ECHO
 557 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 558 AS_ECHO
 559
 560 AS_ECHO("V_DESC")
 561
 562 AS_ECHO
 563 PPRINT_SUBTITLE([System])
 564
 565 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 566
 567 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 568 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 569
 570 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 571        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 572 ])
 573
 574 AS_ECHO
 575 PPRINT_SUBTITLE([Features])
 576 PPRINT_SET_INDENT(1)
 577
 578 test "x$with_sdt" = "xyes" && value=1 || value=0
 579 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 580
 581 test "x$java_agent_jul" = xyes && value=1 || value=0
 582 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 583
 584 test "x$java_agent_log4j" = xyes && value=1 || value=0
 585 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 586
 587 test "x$jni_interface" = xyes && value=1 || value=0
 588 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 589
 590 test "x$python_agent" = xyes && value=1 || value=0
 591 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 592
 593 test "x$enable_numa" = xyes && value=1 || value=0
 594 PPRINT_PROP_BOOL([NUMA], $value)
 595
 596 AS_ECHO
 597 PPRINT_SET_INDENT(0)
 598
 599 # man pages build enabled/disabled
 600 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 601
 602 AS_IF([test "x$man_pages_opt" != "xno"], [
 603         AS_IF([test "x$in_git_repo" = "xyes"], [
 604                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 605         ], [
 606                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 607                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 608                 ], [
 609                         PPRINT_PROP_STRING([build_man_pages_msg],
 610                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 611                                 $PPRINT_COLOR_SUBTITLE)
 612                 ])
 613         ])
 614 ], [
 615         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 616 ])
 617
 618 m4_popdef([build_man_pages_msg])
 619
 620 PPRINT_SET_INDENT(1)
 621
 622 report_bindir="`eval eval echo $bindir`"
 623 report_libdir="`eval eval echo $libdir`"
 624
 625 # Print the bindir and libdir this `make install' will install into.
 626 AS_ECHO
 627 PPRINT_SUBTITLE([Install directories])
 628 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 629 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 630
 631 AS_ECHO
 632 PPRINT_SUBTITLE([System directories])
 633
 634 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 635
 636 PPRINT_SET_INDENT(0)
 637
 638 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 639         AS_ECHO
 640         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 641
 642 Note that the man pages are already built in this distribution tarball,
 643 therefore asciidoc and xmlto are only needed if you intend to modify
 644 their sources.
 645
 646 Use --disable-man-pages to completely disable building and installing
 647 the man pages.])
 648 ])