configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.1.0-rc1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Basse Messe"
  38 version_description="Light coloured German ale whose style was named after the city Cologne (Koln) where it was first brewed. It is a rather simple beer with lightly fruity aromas and a delicate hoppy fragrance. The beer has a pronounced malty taste with a subtle bitter aftertaste"
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  41
  42 AC_PROG_GREP
  43 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  44 AC_ARG_ENABLE(libtool-linkdep-fixup,
  45         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  46                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  47         libtool_fixup=$enableval,
  48         libtool_fixup=yes)
  49
  50 AS_IF([test "x$libtool_fixup" = "xyes"],
  51             [
  52             libtool_m4="$srcdir/config/libtool.m4"
  53             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  54             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  55             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  56             AS_IF([test $libtool_flag_pattern_count -ne 0],
  57             [
  58                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  59                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  60                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  61                   ],
  62                   [
  63                   AC_MSG_RESULT([none])
  64                   ])
  65             ])
  66
  67 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  68
  69 # Checks for programs.
  70 AC_PROG_CC
  71 AC_PROG_CXX
  72 AC_PROG_MAKE_SET
  73 LT_INIT
  74
  75 ## Checks for libraries.
  76 AC_CHECK_LIB([dl], [dlopen],
  77 [
  78         have_libdl=yes
  79 ],
  80 [
  81         #libdl not found, check for dlopen in libc.
  82         AC_CHECK_LIB([c], [dlopen],
  83         [
  84                 have_libc_dl=yes
  85         ],
  86         [
  87                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
  88         ])
  89 ])
  90 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
  91 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
  92
  93 AC_CHECK_LIB([pthread], [pthread_create])
  94
  95 # Check for libuuid
  96 AC_CHECK_LIB([uuid], [uuid_generate],
  97 [
  98         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
  99         have_libuuid=yes
 100 ],
 101 [
 102         # libuuid not found, check for uuid_create in libc.
 103         AC_CHECK_LIB([c], [uuid_create],
 104         [
 105                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 106                 have_libc_uuid=yes
 107         ],
 108         [
 109                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 110         ])
 111 ]
 112 )
 113 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 114 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 115
 116 # Checks for header files.
 117 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 #AC_TYPE_INT16_T
 122 #AC_TYPE_INT32_T
 123 #AC_TYPE_INT64_T
 124 #AC_TYPE_INT8_T
 125 #AC_TYPE_PID_T
 126 #AC_TYPE_SIZE_T
 127 #AC_TYPE_SSIZE_T
 128 #AC_TYPE_UINT16_T
 129 #AC_TYPE_UINT32_T
 130 #AC_TYPE_UINT64_T
 131 #AC_TYPE_UINT8_T
 132 #AC_CHECK_TYPES([ptrdiff_t])
 133
 134 # Checks for library functions.
 135 AC_FUNC_MALLOC
 136 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 137
 138 CFLAGS="-Wall $CFLAGS"
 139
 140 # URCU
 141
 142 # urcu - check if we just find the headers it out of the box.
 143 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 144 This error can also occur when the liburcu package's configure script has not been run.])])
 145
 146 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 147 # Part of Userspace RCU library 0.7.2 or better.
 148 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 149 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 150
 151 AC_MSG_CHECKING([caa_likely()])
 152 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 153 #include <urcu/compiler.h>
 154 void fct(void)
 155 {
 156         if (caa_likely(1)) {
 157         }
 158 }
 159 ]])],[
 160         AC_MSG_RESULT([yes])
 161 ],[
 162         AC_MSG_RESULT([no])
 163         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 164
 165 ])
 166
 167 # urcu - check that URCU lib is available to compilation
 168 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 169
 170 # urcu - check that URCU lib is at least version 0.6
 171 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 172
 173
 174 # Check for various supplementary target information (beyond the
 175 # triplet) which might affect the library format choices.  E.g., we
 176 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 177
 178 case "${target}" in
 179 changequote(,)dnl
 180   i[34567]86-*-linux*)
 181 changequote([,])dnl
 182     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 183                     [save_CPPFLAGS="$CPPFLAGS"
 184                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 185                     AC_EGREP_CPP([got it], [
 186 #if __x86_64__
 187 got it
 188 #endif
 189                  ], [ust_cv_i386_is_x86_64=yes],
 190                     [ust_cv_i386_is_x86_64=no])
 191                     CPPFLAGS="$save_CPPFLAGS"])
 192     ;;
 193 esac
 194
 195 AC_MSG_CHECKING([library format for the target system])
 196 case $target_cpu in
 197 changequote(,)dnl
 198         i[3456]86)
 199 changequote([,])dnl
 200           if test "$ust_cv_i386_is_x86_64" = yes ; then
 201              LIBFORMAT="elf64-x86-64"
 202           else
 203              LIBFORMAT="elf32-i386"
 204           fi
 205           ;;
 206         x86_64) LIBFORMAT="elf64-x86-64" ;;
 207         amd64) LIBFORMAT="elf64-x86-64" ;;
 208         powerpc) LIBFORMAT="elf32-powerpc" ;;
 209         ppc64) LIBFORMAT="elf64-powerpc" ;;
 210         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 211         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 212         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 213         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 214         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 215         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 216         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($target_cpu)?)]) ;;
 217 esac
 218 AC_SUBST(LIBFORMAT)
 219 AC_MSG_RESULT($LIBFORMAT)
 220
 221 if test "x$target_cpu" = "xarm" ; then
 222 AC_MSG_CHECKING([checking for armv5])
 223 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 224 #ifndef __ARM_ARCH_5TEJ__
 225 #error "no arm5 here"
 226 #endif
 227 ]])],[
 228         AC_MSG_RESULT([yes])
 229         NO_UNALIGNED_ACCESS=1
 230
 231 ],[
 232         AC_MSG_RESULT([no])
 233
 234 ])
 235 fi
 236 if test x$NO_UNALIGNED_ACCESS = x ; then
 237 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 238 fi
 239
 240 # Set compile flags to java include files if given
 241 AC_ARG_WITH([java-jdk],
 242         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 243         [JAVA_JDK=$withval],
 244         [JAVA_JDK=""]
 245 )
 246 AS_IF([test $JAVA_JDK],[
 247         AS_IF([test -d $JAVA_JDK],[
 248                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 249                 SUBDIRS=`find $JAVA_JDK/include -type d`
 250                 CPPFLAGS+=" "
 251                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 252                 CPPFLAGS+=" "
 253         ],[
 254                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 255         ])
 256 ])
 257
 258 # Check for JNI header files if requested
 259 AC_ARG_WITH([jni-interface],
 260         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 261         [jni_interface=$withval],
 262         [jni_interface=no]
 263 )
 264
 265 AS_IF([test "x$jni_interface" = "xyes"],[
 266         AC_CHECK_HEADERS([jni.h],[],[
 267         AC_MSG_ERROR([missing jni.h
 268 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 269 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 270         ])
 271 ])
 272 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 273
 274 # sdt.h integration
 275 AC_ARG_WITH([sdt],
 276         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 277         [with_sdt=$withval],
 278         [with_sdt="no"]
 279 )
 280
 281 AS_IF([test "x$with_sdt" = "xyes"],[
 282         AC_MSG_CHECKING([STAP_PROBEV()])
 283         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 284         #define SDT_USE_VARIADIC
 285         #include <sys/sdt.h>
 286         void fct(void)
 287         {
 288                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 289         }
 290         ]])],[
 291                 AC_MSG_RESULT([yes])
 292                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 293         ],[
 294                 AC_MSG_RESULT([no])
 295                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 296         ])
 297 ])
 298
 299 #currently disabled.
 300         #tests/hello2/Makefile
 301         #tests/basic/Makefile
 302         #tests/simple_include/Makefile
 303         #tests/snprintf/Makefile
 304         #tests/test-nevents/Makefile
 305         #tests/test-libustinstr-malloc/Makefile
 306         #tests/dlopen/Makefile
 307         #tests/same_line_marker/Makefile
 308         #tests/trace_event/Makefile
 309         #tests/tracepoint/Makefile
 310         #tests/tracepoint/benchmark/Makefile
 311         #tests/register_test/Makefile
 312         #tests/libustctl_function_#tests/Makefile
 313         #tests/exit-fast/Makefile
 314         #tests/basic_long/Makefile
 315
 316 AC_CONFIG_FILES([
 317         Makefile
 318         doc/Makefile
 319         doc/examples/Makefile
 320         include/Makefile
 321         include/lttng/ust-version.h
 322         snprintf/Makefile
 323         libringbuffer/Makefile
 324         liblttng-ust-comm/Makefile
 325         liblttng-ust/Makefile
 326         liblttng-ust-ctl/Makefile
 327         liblttng-ust-fork/Makefile
 328         liblttng-ust-java/Makefile
 329         liblttng-ust-libc-wrapper/Makefile
 330         tools/Makefile
 331         tests/Makefile
 332         tests/hello/Makefile
 333         tests/hello-static-lib/Makefile
 334         tests/hello.cxx/Makefile
 335         tests/daemon/Makefile
 336         tests/demo/Makefile
 337         tests/fork/Makefile
 338         tests/ust-basic-tracing/Makefile
 339         tests/ust-multi-test/Makefile
 340         lttng-ust.pc
 341 ])
 342
 343 AC_OUTPUT
 344
 345 AS_ECHO()
 346 AS_ECHO("Version name: $version_name")
 347 AS_ECHO("$version_description")
 348
 349 # Report on the configuration options
 350 AS_ECHO()
 351 AS_ECHO("LTTng-UST will be built with the following options:")
 352 AS_ECHO("Library format: $LIBFORMAT")
 353
 354 AS_ECHO()
 355 AS_ECHO_N("Java support (JNI): ")
 356 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 357
 358 AS_ECHO_N("sdt.h integration:  ")
 359 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 360
 361 AS_ECHO()
 362 AS_ECHO("Type 'make' to compile.")
 363