configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.6.0-rc1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 AM_MAINTAINER_MODE([enable])
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  25
  26 # Configuration options, which will be installed in the config.h
  27 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  29 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  30 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
  31
  32 # Compute minor/major/patchlevel version numbers
  33 AC_PROG_SED
  34 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  35 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  36 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  37 AC_SUBST([MAJOR_VERSION], [$major_version])
  38 AC_SUBST([MINOR_VERSION], [$minor_version])
  39 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  40 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  41 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  42 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  43
  44 version_name="Gaia"
  45 version_description="From Benelux brewery in Montreal, the Gaia is a witbier with a cloudy light amber ale color. Aroma of coriander with floral hay notes is enchanting. Taste is also dominated by the very floral coriander note and some medium sweet malt notes."
  46
  47 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  48 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  49
  50 AC_PROG_GREP
  51 AC_PROG_LN_S
  52 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  53 AC_ARG_ENABLE(libtool-linkdep-fixup,
  54         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  55                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  56         libtool_fixup=$enableval,
  57         libtool_fixup=yes)
  58
  59 AS_IF([test "x$libtool_fixup" = "xyes"],
  60             [
  61             libtool_m4="$srcdir/config/libtool.m4"
  62             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  63             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  64             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  65             AS_IF([test $libtool_flag_pattern_count -ne 0],
  66             [
  67                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  68                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  69                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  70                   ],
  71                   [
  72                   AC_MSG_RESULT([none])
  73                   ])
  74             ])
  75
  76 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  77
  78 # Checks for programs.
  79 AC_PROG_CC
  80 AC_PROG_CXX
  81 AC_PROG_MAKE_SET
  82 LT_INIT
  83
  84 # rw_PROG_CXX_WORKS
  85 # Check whether the C++ compiler works.
  86 AC_CACHE_CHECK([whether the C++ compiler works],
  87                 [rw_cv_prog_cxx_works],
  88                 [AC_LANG_PUSH([C++])
  89                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  90                                 [check_cxx_designated_initializers=yes],
  91                                 [rw_cv_prog_cxx_works=no])
  92                 if test "$check_cxx_designated_initializers" = "yes"; then
  93                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  94                                 struct foo { int a; int b; };
  95                                 void fct(void)
  96                                 {
  97                                         struct foo f = { .a = 0, .b = 1 };
  98                                 }
  99                         ]])],[
 100                                 rw_cv_prog_cxx_works=yes
 101                         ],[
 102                                 rw_cv_prog_cxx_works=no
 103                         ])
 104                 fi
 105                 AC_LANG_POP([C++])])
 106
 107 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 108
 109 ## Checks for libraries.
 110 AC_CHECK_LIB([dl], [dlopen],
 111 [
 112         have_libdl=yes
 113 ],
 114 [
 115         #libdl not found, check for dlopen in libc.
 116         AC_CHECK_LIB([c], [dlopen],
 117         [
 118                 have_libc_dl=yes
 119         ],
 120         [
 121                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 122         ])
 123 ])
 124 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 125 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 126
 127 AC_CHECK_LIB([pthread], [pthread_create])
 128
 129 # Check for dlfcn.h
 130 AC_CHECK_HEADER([dlfcn.h])
 131 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
 132         [AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
 133                 [#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 134                 #include <dlfcn.h>])
 135         ],
 136         [ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
 137 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 138
 139 # Checks for header files.
 140 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 141
 142 # Checks for typedefs, structures, and compiler characteristics.
 143 AC_C_INLINE
 144 #AC_TYPE_INT16_T
 145 #AC_TYPE_INT32_T
 146 #AC_TYPE_INT64_T
 147 #AC_TYPE_INT8_T
 148 #AC_TYPE_PID_T
 149 #AC_TYPE_SIZE_T
 150 #AC_TYPE_SSIZE_T
 151 #AC_TYPE_UINT16_T
 152 #AC_TYPE_UINT32_T
 153 #AC_TYPE_UINT64_T
 154 #AC_TYPE_UINT8_T
 155 #AC_CHECK_TYPES([ptrdiff_t])
 156
 157 # Checks for library functions.
 158 AC_FUNC_MALLOC
 159 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 160
 161 CFLAGS="-Wall $CFLAGS"
 162
 163 # URCU
 164
 165 # urcu - check if we just find the headers it out of the box.
 166 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 167 This error can also occur when the liburcu package's configure script has not been run.])])
 168
 169 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 170 # Part of Userspace RCU library 0.7.2 or better.
 171 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 172 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 173
 174 AC_MSG_CHECKING([caa_likely()])
 175 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 176 #include <urcu/compiler.h>
 177 void fct(void)
 178 {
 179         if (caa_likely(1)) {
 180         }
 181 }
 182 ]])],[
 183         AC_MSG_RESULT([yes])
 184 ],[
 185         AC_MSG_RESULT([no])
 186         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 187
 188 ])
 189
 190 # urcu - check that URCU lib is available to compilation
 191 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 192
 193 # urcu - check that URCU lib is at least version 0.6
 194 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 195
 196 # optional linux/perf_event.h
 197 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 198
 199 # Perf event counters are only supported on x86 so far.
 200 AC_MSG_CHECKING([UST support for architecture perf event counters])
 201 case $host_cpu in
 202 changequote(,)dnl
 203         i[3456]86)
 204 changequote([,])dnl
 205         UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 206         x86_64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 207         amd64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 208         *) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no;;
 209 esac
 210 AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
 211
 212 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
 213
 214 if test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"; then
 215 AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 216 fi
 217
 218 AC_MSG_CHECKING([host system alignment requirements])
 219 case $host_cpu in
 220 changequote(,)dnl
 221         i[3456]86)
 222 changequote([,])dnl
 223           ;;
 224         x86_64) ;;
 225         amd64) ;;
 226         powerpc) ;;
 227         ppc64) ;;
 228         ppc64le) ;;
 229         powerpc64) ;;
 230         powerpc64le) ;;
 231         s390) NO_UNALIGNED_ACCESS=1 ;;
 232         s390x) NO_UNALIGNED_ACCESS=1 ;;
 233         arm*) NO_UNALIGNED_ACCESS=1 ;;
 234         mips*) NO_UNALIGNED_ACCESS=1 ;;
 235         tile*) NO_UNALIGNED_ACCESS=1 ;;
 236         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 237 esac
 238 AC_MSG_RESULT([$host_cpu])
 239
 240 if test x$NO_UNALIGNED_ACCESS = x ; then
 241 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 242 fi
 243
 244 # Check for JNI header files if requested
 245 AC_ARG_ENABLE([jni-interface],
 246         [AS_HELP_STRING([--enable-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 247         [jni_interface=$withval],
 248         [jni_interface=no]
 249 )
 250
 251 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 252
 253
 254 AC_ARG_ENABLE([java-agent-jul],
 255         [AS_HELP_STRING([--enable-java-agent-jul],[build the LTTng UST Java agent with JUL support [default=no]])],
 256         [java_agent_jul=$enableval],
 257         [java_agent_jul=no]
 258 )
 259
 260 AC_ARG_ENABLE([java-agent-log4j],
 261         [AS_HELP_STRING([--enable-java-agent-log4j],[build the LTTng UST Java agent with Log4j support [default=no]])],
 262         [java_agent_log4j=$enableval],
 263         [java_agent_log4j=no]
 264 )
 265
 266 AC_ARG_ENABLE([java-agent-all],
 267         [AS_HELP_STRING([--enable-java-agent-all],[build the LTTng UST Java agent with all supported backends [default=no]])],
 268         [java_agent_jul=$enableval
 269          java_agent_log4j=$enableval],
 270         [:]
 271 )
 272
 273
 274 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 275 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 276 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 277
 278 if test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"; then
 279   AX_JAVA_OPTIONS
 280   AX_PROG_JAVAC
 281   AX_PROG_JAVA
 282   AX_PROG_JAR
 283
 284   AX_JNI_INCLUDE_DIR
 285   for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 286   do
 287         CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
 288   done
 289
 290   AX_PROG_JAVAH
 291 fi
 292
 293 if test "x$java_agent_log4j" = "xyes"; then
 294   AX_CHECK_CLASSPATH
 295
 296   AX_CHECK_CLASS(org.apache.log4j.Logger)
 297
 298   if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 299      AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 300   fi
 301 fi
 302
 303 # Option to build the python agent
 304 AC_ARG_ENABLE([python-agent],
 305         [AS_HELP_STRING([--enable-python-agent],[build the LTTng UST Python agent [default=no]])],
 306     [python_agent=$enableval],
 307         [:]
 308 )
 309 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 310
 311 # sdt.h integration
 312 AC_ARG_WITH([sdt],
 313         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 314         [with_sdt=$withval],
 315         [with_sdt="no"]
 316 )
 317
 318 AS_IF([test "x$with_sdt" = "xyes"],[
 319         AC_MSG_CHECKING([STAP_PROBEV()])
 320         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 321         #define SDT_USE_VARIADIC
 322         #include <sys/sdt.h>
 323         void fct(void)
 324         {
 325                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 326         }
 327         ]])],[
 328                 AC_MSG_RESULT([yes])
 329                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 330         ],[
 331                 AC_MSG_RESULT([no])
 332                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 333         ])
 334 ])
 335
 336 AC_MSG_CHECKING([whether shared libraries are enabled])
 337 AS_IF([test "x$enable_shared" = "xyes"],
 338         [
 339                 AC_MSG_RESULT([yes])
 340         ],
 341         [
 342                 AC_MSG_RESULT([no])
 343                 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 344         ])
 345
 346 AC_ARG_WITH([lttng-system-rundir],
 347         AS_HELP_STRING([--with-lttng-system-rundir],
 348         [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 349         [lttng_system_rundir="$withval"],
 350         [lttng_system_rundir="/var/run/lttng"])
 351 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 352         [LTTng system runtime directory])
 353
 354 AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
 355 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
 356
 357 AC_CONFIG_FILES([
 358         Makefile
 359         doc/Makefile
 360         doc/examples/Makefile
 361         include/Makefile
 362         include/lttng/ust-version.h
 363         snprintf/Makefile
 364         libringbuffer/Makefile
 365         liblttng-ust-comm/Makefile
 366         liblttng-ust/Makefile
 367         liblttng-ust-ctl/Makefile
 368         liblttng-ust-fork/Makefile
 369         liblttng-ust-dl/Makefile
 370         liblttng-ust-java/Makefile
 371         liblttng-ust-java-agent/Makefile
 372         liblttng-ust-java-agent/java/Makefile
 373         liblttng-ust-java-agent/jni/Makefile
 374         liblttng-ust-java-agent/jni/jul/Makefile
 375         liblttng-ust-java-agent/jni/log4j/Makefile
 376         liblttng-ust-libc-wrapper/Makefile
 377         liblttng-ust-cyg-profile/Makefile
 378         liblttng-ust-python-agent/Makefile
 379         tools/Makefile
 380         tests/Makefile
 381         tests/hello/Makefile
 382         tests/hello.cxx/Makefile
 383         tests/same_line_tracepoint/Makefile
 384         tests/snprintf/Makefile
 385         tests/benchmark/Makefile
 386         tests/utils/Makefile
 387         lttng-ust.pc
 388 ])
 389
 390 AC_OUTPUT
 391
 392 AS_ECHO()
 393 AS_ECHO("Version name: $version_name")
 394 AS_ECHO("$version_description")
 395
 396 # Report on the configuration options
 397 AS_ECHO()
 398 AS_ECHO("LTTng-UST will be built with the following options:")
 399
 400 AS_ECHO()
 401
 402 AS_ECHO_N("Java agent (JUL support): ")
 403 AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 404
 405 AS_ECHO_N("Java agent (Log4j support): ")
 406 AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 407
 408 AS_ECHO_N("JNI interface (JNI): ")
 409 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 410
 411 AS_ECHO_N("Python agent: ")
 412 AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 413
 414 AS_ECHO_N("sdt.h integration:  ")
 415 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 416
 417 AS_ECHO()
 418 AS_ECHO("Type 'make' to compile.")
 419