configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [10])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [rc1])
   6 m4_define([V_NAME], [[KeKriek]])
   7 m4_define([V_DESC], [[From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  24 # note: remember to update tracepoint.h dlopen() to match this version
  25 # number. TODO: eventually automate by exporting the major number.
  26
  27 # This is the library version of liblttng-ust-ctl, used internally by
  28 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  29 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  30
  31 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  32 AC_CONFIG_AUX_DIR([config])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38
  39 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  40 AM_MAINTAINER_MODE([enable])
  41
  42 # Enable silent rules if available (Introduced in AM 1.11)
  43 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  44
  45 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  46
  47 # Checks for C compiler
  48 AC_USE_SYSTEM_EXTENSIONS
  49 AC_SYS_LARGEFILE
  50 AC_PROG_CC
  51 AC_PROG_CC_STDC
  52 AC_PROG_CXX
  53 rw_PROG_CXX_WORKS
  54 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  55
  56 # Check if the compiler support weak symbols
  57 AX_SYS_WEAK_ALIAS
  58
  59 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  60         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  61 ])
  62
  63 # Checks for programs.
  64 AC_PROG_SED
  65 AC_PROG_GREP
  66 AC_PROG_LN_S
  67 AC_PROG_MKDIR_P
  68 AC_PROG_MAKE_SET
  69 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  70 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  71
  72 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  73 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  74 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  75 ], [
  76         libtool_fixup=$enableval
  77 ], [
  78         libtool_fixup=yes
  79 ])
  80
  81 AS_IF([test "x$libtool_fixup" = "xyes"], [
  82         libtool_m4="$srcdir/m4/libtool.m4"
  83         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  84         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  85         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  86
  87         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  88         AC_MSG_RESULT([$libtool_flag_pattern_count])
  89         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  90                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  91         ], [
  92                 AC_MSG_RESULT([none])
  93         ])
  94 ])
  95 LT_INIT([disable-static])
  96
  97 AC_MSG_CHECKING([whether shared libraries are enabled])
  98 AS_IF([test "x$enable_shared" = "xyes"], [
  99         AC_MSG_RESULT([yes])
 100 ], [
 101         AC_MSG_RESULT([no])
 102         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 103 ])
 104
 105 # Checks for typedefs, structures, and compiler characteristics.
 106 AC_C_INLINE
 107 AC_TYPE_INT8_T
 108 AC_TYPE_INT16_T
 109 AC_TYPE_INT32_T
 110 AC_TYPE_INT64_T
 111 AC_TYPE_MODE_T
 112 AC_TYPE_OFF_T
 113 AC_TYPE_PID_T
 114 AC_TYPE_SIZE_T
 115 AC_TYPE_SSIZE_T
 116 AC_TYPE_UID_T
 117 AC_TYPE_UINT8_T
 118 AC_TYPE_UINT16_T
 119 AC_TYPE_UINT32_T
 120 AC_TYPE_UINT64_T
 121 AC_CHECK_TYPES([ptrdiff_t])
 122
 123 AX_C___ATTRIBUTE__
 124 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 125         [:],
 126         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 127
 128 # Checks for library functions.
 129 AC_FUNC_CHOWN
 130 AC_FUNC_FORK
 131 AC_FUNC_MMAP
 132 AC_FUNC_REALLOC
 133 AC_FUNC_STRERROR_R
 134 AC_FUNC_STRNLEN
 135 AC_CHECK_FUNCS([ \
 136         atexit \
 137         clock_gettime \
 138         ftruncate \
 139         getpagesize \
 140         gettimeofday \
 141         localeconv \
 142         memchr \
 143         memmove \
 144         memset \
 145         mkdir \
 146         munmap \
 147         realpath \
 148         sched_getcpu \
 149         socket \
 150         strchr \
 151         strdup \
 152         strerror \
 153         strtol \
 154         sysconf \
 155 ])
 156
 157 # AC_FUNC_MALLOC causes problems when cross-compiling.
 158 #AC_FUNC_MALLOC
 159
 160 # Checks for header files.
 161 AC_HEADER_STDBOOL
 162 AC_CHECK_HEADERS([ \
 163         arpa/inet.h \
 164         fcntl.h \
 165         float.h \
 166         limits.h \
 167         locale.h \
 168         stddef.h \
 169         sys/socket.h \
 170         sys/time.h \
 171         wchar.h \
 172 ])
 173
 174 # Configuration options, which will be installed in the config.h
 175 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 176 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 177 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 178
 179 # Checks for libraries.
 180 AC_CHECK_LIB([dl], [dlopen], [
 181         have_libdl=yes
 182         libdl_name=dl
 183 ], [
 184         #libdl not found, check for dlopen in libc.
 185         AC_CHECK_LIB([c], [dlopen], [
 186                 have_libc_dl=yes
 187                 libdl_name=c
 188         ], [
 189                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 190         ])
 191 ])
 192
 193 # Check if libdl has dlmopen support.
 194 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 195 AC_CHECK_LIB([$libdl_name], [dlmopen],
 196         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 197 )
 198
 199 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 200 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 201
 202 AC_CHECK_LIB([pthread], [pthread_create])
 203 AC_CHECK_LIB([pthread], [pthread_setname_np],
 204         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 205         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 206                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 207                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 208
 209 # Check for dlfcn.h
 210 AC_CHECK_HEADER([dlfcn.h])
 211 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 212         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 213                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 214                 #include <dlfcn.h>
 215         ])
 216 ], [
 217         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 218 ])
 219
 220 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 221
 222 # URCU
 223
 224 # urcu - check if we just find the headers it out of the box.
 225 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 226 This error can also occur when the liburcu package's configure script has not been run.])])
 227
 228 # URCU library version needed or newer
 229 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.11.0 is needed])
 230
 231 #Macro added in urcu 0.6.6
 232 AC_CHECK_DECL([caa_likely], [],
 233         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 234 #Macro added in urcu 0.11.0
 235 AC_CHECK_DECL([DEFINE_URCU_TLS_IE], [],
 236         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/tls-compat.h>]]
 237 )
 238
 239 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 240 # Part of Userspace RCU library 0.7.2 or better.
 241 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 242 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 243
 244 # urcu - check that URCU lib is available to compilation
 245 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 246
 247 # urcu - check that URCU lib is at least version 0.6
 248 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 249
 250 # optional linux/perf_event.h
 251 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 252
 253 # Perf event counters are supported on all architectures supported by
 254 # perf, using the read system call as fallback.
 255 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 256
 257 AS_IF([test "x$have_perf_event" = "xyes"], [
 258         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 259 ])
 260
 261 AC_MSG_CHECKING([host system alignment requirements])
 262 AS_CASE([$host_cpu],
 263         [i[[3456]]86], [],
 264         [x86_64], [],
 265         [amd64], [],
 266         [powerpc], [],
 267         [ppc64], [],
 268         [ppc64le], [],
 269         [powerpc64], [],
 270         [powerpc64le], [],
 271         [s390], [NO_UNALIGNED_ACCESS=1],
 272         [s390x], [NO_UNALIGNED_ACCESS=1],
 273         [arm*], [NO_UNALIGNED_ACCESS=1],
 274         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 275         [mips*], [NO_UNALIGNED_ACCESS=1],
 276         [tile*], [NO_UNALIGNED_ACCESS=1],
 277         [
 278                 UNSUPPORTED_ARCH=1
 279                 NO_UNALIGNED_ACCESS=1
 280         ])
 281 AC_MSG_RESULT([$host_cpu])
 282
 283 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 284         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 285 ])
 286
 287 # Check for JNI header files if requested
 288 AC_ARG_ENABLE([jni-interface], [
 289 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 290 ], [
 291         jni_interface=$enableval
 292 ], [
 293         jni_interface=no
 294 ])
 295
 296 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 297
 298
 299 AC_ARG_ENABLE([java-agent-jul], [
 300 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 301 ], [
 302         java_agent_jul=$enableval
 303 ], [
 304         java_agent_jul=no
 305 ])
 306
 307 AC_ARG_ENABLE([java-agent-log4j], [
 308 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 309 ], [
 310         java_agent_log4j=$enableval
 311 ], [
 312         java_agent_log4j=no
 313 ])
 314
 315 AC_ARG_ENABLE([java-agent-all], [
 316 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 317 ], [
 318         java_agent_jul=$enableval
 319         java_agent_log4j=$enableval
 320 ], [:])
 321
 322 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 323 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 324 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 325
 326 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 327         AX_JAVA_OPTIONS
 328         AX_PROG_JAVAC
 329         AX_PROG_JAVA
 330         AX_PROG_JAR
 331
 332         AX_JNI_INCLUDE_DIR
 333         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 334         do
 335                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 336         done
 337
 338         saved_CPPFLAGS="$CPPFLAGS"
 339         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 340         AX_PROG_JAVAH
 341         CPPFLAGS="$saved_CPPFLAGS"
 342 ])
 343
 344 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 345         AX_CHECK_CLASSPATH
 346         AX_CHECK_CLASS([org.apache.log4j.Logger])
 347         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 348                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 349         ])
 350 ])
 351
 352 # Option to build the python agent
 353 AC_ARG_ENABLE([python-agent], [
 354 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 355 ], [
 356         python_agent=$enableval
 357 ], [:])
 358 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 359 AS_IF([test "x$python_agent" = "xyes"], [
 360         AM_PATH_PYTHON([2.7])
 361 ])
 362
 363 # sdt.h integration
 364 AC_ARG_WITH([sdt], [
 365 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 366 ], [
 367         with_sdt=$withval
 368 ], [
 369         with_sdt="no"
 370 ])
 371
 372 AS_IF([test "x$with_sdt" = "xyes"], [
 373         AC_MSG_CHECKING([STAP_PROBEV()])
 374         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 375                 #define SDT_USE_VARIADIC
 376                 #include <sys/sdt.h>
 377                 void fct(void)
 378                 {
 379                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 380                 }
 381         ]])], [
 382                 AC_MSG_RESULT([yes])
 383                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 384         ], [
 385                 AC_MSG_RESULT([no])
 386                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 387         ])
 388 ])
 389
 390 AC_ARG_WITH([lttng-system-rundir], [
 391 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 392 ], [
 393         lttng_system_rundir="$withval"
 394 ], [
 395         lttng_system_rundir="/var/run/lttng"
 396 ])
 397 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 398                 [LTTng system runtime directory])
 399
 400 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 401 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 402
 403 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 404 # is not distributed in tarballs.
 405 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 406 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 407
 408 # Enable building man pages (user's intention).
 409 AC_ARG_ENABLE(
 410         man-pages,
 411         AS_HELP_STRING(
 412                 [--disable-man-pages],
 413                 [Do not build and install man pages (already built in a distributed tarball)]
 414         ),
 415         [man_pages_opt=$enableval],
 416         [man_pages_opt=yes]
 417 )
 418
 419 # Check for asciidoc and xmlto if we enabled building the man pages.
 420 have_asciidoc_xmlto=no
 421 warn_prebuilt_man_pages=no
 422
 423 AS_IF([test "x$man_pages_opt" = "xyes"], [
 424         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 425         AC_PATH_PROG([XMLTO], [xmlto], [no])
 426
 427         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 428                 AS_IF([test "x$in_git_repo" = "xyes"], [
 429                         # This is an error because we're in the Git repo, which
 430                         # means the man pages are not already generated for us,
 431                         # thus asciidoc/xmlto are required because we were asked
 432                         # to build the man pages.
 433                         AC_MSG_ERROR([
 434 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 435 --disable-man-pages to disable building the man pages, in which case
 436 they will not be installed.
 437                         ])
 438                 ], [
 439                         # Only warn here: since we're in the tarball, the man
 440                         # pages should already be generated at this point, thus
 441                         # asciidoc/xmlto are not strictly required.
 442                         warn_prebuilt_man_pages=yes
 443                 ])
 444         ], [
 445                 have_asciidoc_xmlto=yes
 446         ])
 447 ])
 448
 449 # Export man page build condition: build the man pages if the user
 450 # asked for it, and if the tools are available.
 451 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 452 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 453
 454 # Default values
 455 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 456         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 457         $1="$2"
 458         AC_SUBST([$1])
 459 ])
 460
 461 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 462
 463 AM_CFLAGS="-Wall"
 464 AC_SUBST(AM_CFLAGS)
 465 AC_SUBST(JNI_CPPFLAGS)
 466
 467 AC_CONFIG_FILES([
 468         Makefile
 469         doc/Makefile
 470         doc/examples/Makefile
 471         doc/man/Makefile
 472         include/Makefile
 473         include/lttng/ust-version.h
 474         snprintf/Makefile
 475         libringbuffer/Makefile
 476         liblttng-ust-comm/Makefile
 477         liblttng-ust/Makefile
 478         liblttng-ust-ctl/Makefile
 479         liblttng-ust-fork/Makefile
 480         liblttng-ust-dl/Makefile
 481         liblttng-ust-fd/Makefile
 482         liblttng-ust-java/Makefile
 483         liblttng-ust-java-agent/Makefile
 484         liblttng-ust-java-agent/java/Makefile
 485         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 486         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 487         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 488         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 489         liblttng-ust-java-agent/jni/Makefile
 490         liblttng-ust-java-agent/jni/common/Makefile
 491         liblttng-ust-java-agent/jni/jul/Makefile
 492         liblttng-ust-java-agent/jni/log4j/Makefile
 493         liblttng-ust-libc-wrapper/Makefile
 494         liblttng-ust-cyg-profile/Makefile
 495         liblttng-ust-python-agent/Makefile
 496         python-lttngust/Makefile
 497         python-lttngust/setup.py
 498         python-lttngust/lttngust/__init__.py
 499         tools/Makefile
 500         tests/Makefile
 501         tests/ctf-types/Makefile
 502         tests/hello/Makefile
 503         tests/hello.cxx/Makefile
 504         tests/same_line_tracepoint/Makefile
 505         tests/snprintf/Makefile
 506         tests/ust-elf/Makefile
 507         tests/benchmark/Makefile
 508         tests/utils/Makefile
 509         tests/test-app-ctx/Makefile
 510         tests/gcc-weak-hidden/Makefile
 511         lttng-ust.pc
 512 ])
 513
 514 # Create link for python agent for the VPATH guru.
 515 AC_CONFIG_LINKS([
 516         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 517         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 518         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 519         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 520 ])
 521
 522 AC_OUTPUT
 523
 524
 525 #
 526 # Mini-report on what will be built.
 527 #
 528
 529 PPRINT_INIT
 530 PPRINT_SET_INDENT(1)
 531 PPRINT_SET_TS(38)
 532
 533 AS_ECHO
 534 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 535 AS_ECHO
 536
 537 AS_ECHO("V_DESC")
 538
 539 AS_ECHO
 540 PPRINT_SUBTITLE([System])
 541
 542 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 543
 544 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 545 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 546
 547 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 548        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 549 ])
 550
 551 AS_ECHO
 552 PPRINT_SUBTITLE([Features])
 553 PPRINT_SET_INDENT(1)
 554
 555 test "x$with_sdt" = "xyes" && value=1 || value=0
 556 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 557
 558 test "x$java_agent_jul" = xyes && value=1 || value=0
 559 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 560
 561 test "x$java_agent_log4j" = xyes && value=1 || value=0
 562 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 563
 564 test "x$jni_interface" = xyes && value=1 || value=0
 565 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 566
 567 test "x$python_agent" = xyes && value=1 || value=0
 568 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 569
 570 AS_ECHO
 571 PPRINT_SET_INDENT(0)
 572
 573 # man pages build enabled/disabled
 574 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 575
 576 AS_IF([test "x$man_pages_opt" != "xno"], [
 577         AS_IF([test "x$in_git_repo" = "xyes"], [
 578                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 579         ], [
 580                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 581                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 582                 ], [
 583                         PPRINT_PROP_STRING([build_man_pages_msg],
 584                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 585                                 $PPRINT_COLOR_SUBTITLE)
 586                 ])
 587         ])
 588 ], [
 589         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 590 ])
 591
 592 m4_popdef([build_man_pages_msg])
 593
 594 PPRINT_SET_INDENT(1)
 595
 596 report_bindir="`eval eval echo $bindir`"
 597 report_libdir="`eval eval echo $libdir`"
 598
 599 # Print the bindir and libdir this `make install' will install into.
 600 AS_ECHO
 601 PPRINT_SUBTITLE([Install directories])
 602 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 603 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 604
 605 AS_ECHO
 606 PPRINT_SUBTITLE([System directories])
 607
 608 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 609
 610 PPRINT_SET_INDENT(0)
 611
 612 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 613         AS_ECHO
 614         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 615
 616 Note that the man pages are already built in this distribution tarball,
 617 therefore asciidoc and xmlto are only needed if you intend to modify
 618 their sources.
 619
 620 Use --disable-man-pages to completely disable building and installing
 621 the man pages.])
 622 ])