configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7
   8 # Project version information
   9 m4_define([ust_version_major], [2])
  10 m4_define([ust_version_minor], [14])
  11 m4_define([ust_version_patch], [0])
  12 m4_define([ust_version_dev_stage], [-pre])
  13 m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
  14 m4_define([ust_version_name], [[O-Beer]])
  15 m4_define([ust_version_description], [[An alcoholic drink made from yeast-fermented malt flavored with hops.]])
  16
  17 # Library version information of "liblttng-ust"
  18 # Following the numbering scheme proposed by libtool for the library version
  19 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  20 m4_define([ust_lib_version_current], [1])
  21 m4_define([ust_lib_version_revision], [0])
  22 m4_define([ust_lib_version_age], [0])
  23 m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
  24
  25 # Library version information of "liblttng-ust-ctl"
  26 # Following the numbering scheme proposed by libtool for the library version
  27 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  28 m4_define([ust_ctl_lib_version_current], [5])
  29 m4_define([ust_ctl_lib_version_revision], [0])
  30 m4_define([ust_ctl_lib_version_age], [0])
  31 m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
  32
  33
  34 ##                     ##
  35 ## Autoconf base setup ##
  36 ##                     ##
  37
  38 AC_PREREQ([2.69])
  39 AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
  40
  41 AC_CONFIG_HEADERS([src/common/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
  42 AC_CONFIG_AUX_DIR([config])
  43 AC_CONFIG_MACRO_DIR([m4])
  44
  45 AC_CANONICAL_TARGET
  46 AC_CANONICAL_HOST
  47
  48
  49 ##                     ##
  50 ## Automake base setup ##
  51 ##                     ##
  52
  53 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  54 AM_MAINTAINER_MODE([enable])
  55
  56 # Enable silent rules by default
  57 AM_SILENT_RULES([yes])
  58
  59
  60 ##                               ##
  61 ## OS and Arch specific defaults ##
  62 ##                               ##
  63
  64 # Set os specific options
  65 AS_CASE([$host_os],
  66   [freebsd*], [AE_FEATURE_DISABLE([numa])]
  67 )
  68
  69 # Set architecture specific options
  70 AS_CASE([$host_cpu],
  71   [i[[3456]]86], [],
  72   [x86_64], [],
  73   [amd64], [],
  74   [powerpc], [],
  75   [ppc64], [],
  76   [ppc64le], [],
  77   [powerpc64], [],
  78   [powerpc64le], [],
  79   [s390], [],
  80   [s390x], [],
  81   [arm*], [AE_FEATURE_DISABLE([numa])],
  82   [aarch64*], [],
  83   [mips*], [],
  84   [tile*], [],
  85   [
  86     unsupported_arch="yes"
  87   ])
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 # Choose the C compiler
  95 AC_PROG_CC
  96 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  97 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  98
  99 # Make sure the C compiler supports C99
 100 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
 101
 102 # Enable available system extensions and LFS support
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Make sure the C compiler supports __attribute__
 107 AX_C___ATTRIBUTE__
 108 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 109   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 110
 111 # Make sure we have pthread support
 112 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 113
 114 # Make sure the C compiler supports weak symbols
 115 AX_SYS_WEAK_ALIAS
 116 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
 117   [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_C_TYPEOF
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_INT8_T
 126 AC_TYPE_MODE_T
 127 AC_TYPE_OFF_T
 128 AC_TYPE_PID_T
 129 AC_TYPE_SIZE_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UID_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136 AC_CHECK_TYPES([ptrdiff_t])
 137
 138 # Detect warning flags supported by the C compiler and append them to
 139 # WARN_CFLAGS.
 140 m4_define([WARN_FLAGS_LIST], [ dnl
 141   -Wall dnl
 142   -Wextra dnl
 143   -Wmissing-prototypes dnl
 144   -Wmissing-declarations dnl
 145   -Wnull-dereference dnl
 146   -Wundef dnl
 147   -Wshadow dnl
 148   -Wjump-misses-init dnl
 149   -Wsuggest-attribute=format dnl
 150   -Wtautological-constant-out-of-range-compare dnl
 151   -Wnested-externs dnl
 152   -Wwrite-strings dnl
 153   -Wformat=2 dnl
 154   -Wstrict-aliasing dnl
 155   -Wmissing-noreturn dnl
 156   -Winit-self dnl
 157   -Wduplicated-cond dnl
 158   -Wduplicated-branches dnl
 159   -Wlogical-op dnl
 160   dnl These would require reworking the tracepoint macros
 161   dnl-Wredundant-decls dnl
 162   -Wno-sign-compare dnl
 163   -Wno-missing-field-initializers dnl
 164   -Wno-null-dereference dnl
 165 ])
 166
 167 # Pass -Werror as an extra flag during the test: this is needed to make the
 168 # -Wunknown-warning-option diagnostic fatal with clang.
 169 AC_LANG_PUSH([C])
 170 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
 171 AC_LANG_POP([C])
 172
 173 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 174 # written in such a way that it triggers warnings with the following warning
 175 # flags.  So they would always end up disabled if we put them there, because
 176 # the test program would not build.
 177 #
 178 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 179 # Clang >= 3.3 (required by the project) and are only valid for C code.
 180 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 181
 182 # Disable 'strict aliasing' if the compiler supports it.
 183 AC_LANG_PUSH([C])
 184 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 185 AC_LANG_POP([C])
 186
 187
 188 ##                     ##
 189 ## C++ compiler checks ##
 190 ##                     ##
 191
 192 # Find an optional C++11 compiler without GNU extensions (-std=c++11)
 193 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 194
 195 AS_IF([test "$HAVE_CXX11" = "1"], [
 196   # Pass -Werror as an extra flag during the test: this is needed to make the
 197   # -Wunknown-warning-option diagnostic fatal with clang.
 198   AC_LANG_PUSH([C++])
 199   AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST -Wno-undef -Wno-duplicated-branches], [WARN_CXXFLAGS], [-Werror])
 200   AC_LANG_POP([C++])
 201 ])
 202
 203
 204 ##               ##
 205 ## Header checks ##
 206 ##               ##
 207
 208 AC_HEADER_STDBOOL
 209 AC_CHECK_HEADERS([ \
 210   arpa/inet.h \
 211   dlfcn.h \
 212   fcntl.h \
 213   float.h \
 214   limits.h \
 215   linux/perf_event.h \
 216   locale.h \
 217   stddef.h \
 218   sys/socket.h \
 219   sys/time.h \
 220   wchar.h \
 221 ])
 222
 223 # Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
 224 AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
 225   AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
 226 ])
 227
 228
 229 ##                 ##
 230 ## Programs checks ##
 231 ##                 ##
 232
 233 AM_PROG_AR
 234 AC_PROG_SED
 235 AC_PROG_GREP
 236 AC_PROG_LN_S
 237 AC_PROG_MKDIR_P
 238 AC_PROG_MAKE_SET
 239 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 240 AC_CHECK_PROGS([CMAKE], [cmake])
 241 AC_CHECK_PROGS([FOLD], [fold])
 242 AC_CHECK_PROGS([XMLTO], [xmlto])
 243
 244 AM_PATH_PYTHON([2.7], [], [PYTHON=""])
 245
 246 # Initialize and configure libtool
 247 LT_INIT([disable-static])
 248
 249
 250 ##                ##
 251 ## Library checks ##
 252 ##                ##
 253
 254 AC_FUNC_CHOWN
 255 AC_FUNC_FORK
 256 AC_FUNC_MMAP
 257 AC_FUNC_STRERROR_R
 258 AC_FUNC_STRNLEN
 259 AC_CHECK_FUNCS([ \
 260   atexit \
 261   clock_gettime \
 262   ftruncate \
 263   getpagesize \
 264   gettid \
 265   gettimeofday \
 266   localeconv \
 267   memchr \
 268   memmove \
 269   memset \
 270   mkdir \
 271   munmap \
 272   realpath \
 273   sched_getcpu \
 274   socket \
 275   strchr \
 276   strdup \
 277   strerror \
 278   strtol \
 279   strtoul \
 280   sysconf \
 281 ])
 282
 283 # AC_FUNC_MALLOC causes problems when cross-compiling.
 284 #AC_FUNC_MALLOC
 285 #AC_FUNC_REALLOC
 286
 287 # Check for pthread_setname_np and its signature
 288 LTTNG_PTHREAD_SETNAME_NP
 289 LTTNG_PTHREAD_GETNAME_NP
 290
 291 # Check dor dlopen() in -ldl or -lc
 292 AC_CHECK_LIB([dl], [dlopen], [
 293   libdl_name=dl
 294   DL_LIBS="-ldl"
 295 ], [
 296   # dlopen not found in libdl, check in libc
 297   AC_CHECK_LIB([c], [dlopen], [
 298     libdl_name=c
 299     DL_LIBS="-lc"
 300   ], [
 301     AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 302   ])
 303 ])
 304 AC_SUBST(DL_LIBS)
 305
 306 # Check if libdl has dlmopen()
 307 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 308   AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
 309 ])
 310
 311 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 312 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 313
 314
 315 ##                 ##
 316 ## User variables  ##
 317 ##                 ##
 318
 319 # Additional variables captured during ./configure
 320
 321 AC_ARG_VAR([CLASSPATH], [Java class path])
 322 AC_ARG_VAR([JAVACFLAGS], [Java compiler flags])
 323 AC_ARG_VAR([JAVAC], [Java compiler])
 324 AC_ARG_VAR([JAVAFLAGS], [Java VM flags])
 325 AC_ARG_VAR([JAVA], [Java VM])
 326 AC_ARG_VAR([JAVAPREFIX], [prefix where Java runtime is installed])
 327
 328
 329 ##                              ##
 330 ## Optional features selection ##
 331 ##                              ##
 332
 333 # numa integration
 334 # Enabled by default, except on some platforms
 335 AE_FEATURE_DEFAULT_ENABLE
 336 AE_FEATURE([numa],[disable NUMA support])
 337
 338 # Java JNI interface library
 339 # Disabled by default
 340 AE_FEATURE_DEFAULT_DISABLE
 341 AE_FEATURE([jni-interface], [build JNI interface between C and Java])
 342
 343 # Build the Java Logging API agent
 344 # Disabled by default
 345 AE_FEATURE_DEFAULT_DISABLE
 346 AE_FEATURE([java-agent-jul],[build the LTTng UST Java agent with JUL support])
 347
 348 # Build the Java Log4j 1.x agent
 349 # Disabled by default
 350 AE_FEATURE_DEFAULT_DISABLE
 351 AE_FEATURE([java-agent-log4j],[build the LTTng UST Java agent with Log4j 1.x support (deprecated)])
 352
 353 # Build the Java Log4j 2.x agent
 354 # Disabled by default
 355 AE_FEATURE_DEFAULT_DISABLE
 356 AE_FEATURE([java-agent-log4j2],[build the LTTng UST Java agent with Log4j 2.x support])
 357
 358 # Build both Java agents
 359 # Disabled by default
 360 AE_FEATURE_DEFAULT_DISABLE
 361 AE_FEATURE([java-agent-all],[build the LTTng UST Java agent with all supported backends])
 362
 363 # Build the Python agent
 364 # Disabled by default
 365 AE_FEATURE_DEFAULT_DISABLE
 366 AE_FEATURE([python-agent],[build the LTTng UST Python agent])
 367
 368 # Build the examples
 369 # Disabled by default
 370 AE_FEATURE_DEFAULT_ENABLE
 371 AE_FEATURE([examples],[Do not build and install examples])
 372
 373 # Man pages
 374 # Enabled by default
 375 AE_FEATURE_DEFAULT_ENABLE
 376 AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball)])
 377
 378 # Systemtap sdt.h integration
 379 # Disabled by default
 380 AC_ARG_WITH([sdt],
 381   [AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])]
 382 )
 383
 384 # Override the default runtime directory
 385 AC_ARG_WITH([lttng-system-rundir], [
 386 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 387 ], [
 388   lttng_system_rundir="$withval"
 389 ], [
 390   lttng_system_rundir="/var/run/lttng"
 391 ])
 392
 393
 394 ##                                          ##
 395 ## Check for conflicting features selection ##
 396 ##                                          ##
 397
 398 AE_IF_FEATURE_DISABLED([shared], [
 399   AC_MSG_ERROR(LTTng-UST requires shared libraries to be enabled)
 400 ])
 401
 402 AE_IF_FEATURE_ENABLED([java-agent-all], [
 403   AE_FEATURE_ENABLE([java-agent-jul])
 404   AE_FEATURE_ENABLE([java-agent-log4j])
 405   AE_FEATURE_ENABLE([java-agent-log4j2])
 406 ])
 407
 408
 409 ##                                          ##
 410 ## Check for optional features dependencies ##
 411 ##                                          ##
 412
 413 # The numa integration requires libnuma
 414 AE_IF_FEATURE_ENABLED([numa], [
 415   AC_CHECK_LIB([numa], [numa_available], [
 416     AC_DEFINE([HAVE_LIBNUMA], [1], [Define to 1 if libnuma is available.])
 417   ], [
 418     AC_MSG_ERROR([dnl
 419 libnuma is not available. Please either install it (e.g. libnuma-dev) or use
 420 [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure
 421 argument to disable NUMA support.
 422     ])
 423   ])
 424 ])
 425
 426 # The JNI interface and Java Agents require a working Java JDK
 427 AS_IF([AE_IS_FEATURE_ENABLED([jni-interface]) || AE_IS_FEATURE_ENABLED([java-agent-jul]) || \
 428     AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2])], [
 429   AX_PROG_JAVAC
 430   AX_PROG_JAVA
 431   AX_PROG_JAR
 432
 433   # Get the CPPFLAGS required to build jni libraries
 434   AX_JNI_INCLUDE_DIR
 435   for jni_include_dir in $JNI_INCLUDE_DIRS; do
 436     JNI_CPPFLAGS="$JNI_CPPFLAGS -I$jni_include_dir"
 437   done
 438
 439   # Check for javah and jni.h
 440   saved_CPPFLAGS="$CPPFLAGS"
 441   CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 442   AX_PROG_JAVAH
 443   CPPFLAGS="$saved_CPPFLAGS"
 444 ])
 445
 446 # The log4j 1.x agent requires the log4j jar in the classpath
 447 AE_IF_FEATURE_ENABLED([java-agent-log4j], [
 448   AX_CHECK_CLASS([org.apache.log4j.Logger])
 449   AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 450     AC_MSG_ERROR([dnl
 451 The UST Java agent support for log4j was requested but the Log4j classes were
 452 not found. Please specify the location of the Log4j jar via the Java CLASSPATH
 453 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j.jar"
 454
 455 Current CLASSPATH: "$CLASSPATH"
 456     ])
 457   ])
 458 ])
 459
 460 # The log4j 2.x agent requires the log4j core and api jars in the classpath
 461 AE_IF_FEATURE_ENABLED([java-agent-log4j2], [
 462   AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 463   AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 464   AS_IF([test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"], [
 465     AC_MSG_ERROR([dnl
 466 The UST Java agent support for log4j was requested but the Log4j classes were
 467 not found. Please specify the location of the Log4j API and core 2.x jars via the Java CLASSPATH
 468 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"
 469
 470 Current CLASSPATH: "$CLASSPATH"
 471     ])
 472   ])
 473 ])
 474
 475 # The python agent requires a python interpreter
 476 AE_IF_FEATURE_ENABLED([python-agent], [
 477   AS_IF([test "x$PYTHON" = "x"], [
 478     AC_MSG_ERROR([dnl
 479 Cannot find a suitable python interpreter. You can override it with the PYTHON
 480 environment variable.
 481     ])
 482   ])
 483 ])
 484
 485 # Check for asciidoc and xmlto if we enabled building the man pages.
 486 AE_IF_FEATURE_ENABLED([man-pages], [
 487   AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 488     AE_IF_IN_GIT_REPO([
 489       # This is an error because we're in the Git repo, which
 490       # means the man pages are not already generated for us,
 491       # thus asciidoc/xmlto are required because we were asked
 492       # to build the man pages.
 493       AC_MSG_ERROR([dnl
 494 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 495 --disable-man-pages to disable building the man pages, in which case
 496 they will not be installed.
 497       ])
 498     ], [
 499       # Only warn here: since we're in the tarball, the man
 500       # pages should already be generated at this point, thus
 501       # asciidoc/xmlto are not strictly required.
 502       warn_prebuilt_man_pages=yes
 503     ])
 504   ], [
 505     have_asciidoc_xmlto=yes
 506   ])
 507 ])
 508
 509 AS_IF([test "x$with_sdt" = "xyes"], [
 510   AC_MSG_CHECKING([STAP_PROBEV()])
 511   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 512     #define SDT_USE_VARIADIC
 513     #include <sys/sdt.h>
 514     void fct(void)
 515     {
 516       STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 517     }
 518   ]])], [
 519     AC_MSG_RESULT([yes])
 520     AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1], [SystemTap integration via sdt.h])
 521   ], [
 522     AC_MSG_RESULT([no])
 523     AC_MSG_ERROR([dnl
 524 The sdt.h integration was requested but the STAP_PROBEV define cannot be used.
 525 Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify
 526 a non-standard path to sys/sdt.h
 527     ])
 528   ])
 529 ])
 530
 531
 532 ##                                                                    ##
 533 ## Set defines for optional features conditionnals in the source code ##
 534 ##                                                                    ##
 535
 536 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], [LTTng system runtime directory])
 537
 538 # Defined in include/lttng/ust-version.h
 539 AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
 540 AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
 541 AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
 542 AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
 543 AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
 544 AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
 545
 546
 547 ##                                                                          ##
 548 ## Set automake variables for optional feature conditionnals in Makefile.am ##
 549 ##                                                                          ##
 550
 551 AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([examples]))
 552 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
 553 AM_CONDITIONAL([ENABLE_JAVA_AGENT], AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 554 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], AE_IS_FEATURE_ENABLED([java-agent-jul]))
 555 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], AE_IS_FEATURE_ENABLED([java-agent-log4j]))
 556 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J2], AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 557 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J_COMMON], AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 558 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], AE_IS_FEATURE_ENABLED([jni-interface]))
 559 AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
 560 AM_CONDITIONAL([ENABLE_NUMA], AE_IS_FEATURE_ENABLED([numa]))
 561 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], AE_IS_FEATURE_ENABLED([python-agent]))
 562 AM_CONDITIONAL([ENABLE_UST_DL], [test "x$ac_cv_have_decl_RTLD_DI_LINKMAP" = "xyes"])
 563 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 564 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
 565 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
 566 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 567 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
 568
 569
 570 ##                                             ##
 571 ## Substitute variables for use in Makefile.am ##
 572 ##                                             ##
 573
 574 # Library versions for libtool
 575 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], ust_lib_version)
 576 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], ust_ctl_lib_version)
 577
 578 # Major soname for python-lttngust
 579 AC_SUBST([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current])
 580
 581 AM_CFLAGS="$OPT_CFLAGS $WARN_CFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 582 AC_SUBST(AM_CFLAGS)
 583
 584 AM_CXXFLAGS="$WARN_CXXFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 585 AC_SUBST(AM_CXXFLAGS)
 586
 587 # The order in which the include folders are searched is important.
 588 # The top_builddir should always be searched first in the event that a build
 589 # time generated file is included.
 590 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 591 AC_SUBST(AM_CPPFLAGS)
 592
 593 AC_SUBST(JNI_CPPFLAGS)
 594
 595
 596 ##                                     ##
 597 ## Output files generated by configure ##
 598 ##                                     ##
 599
 600 # List of files to be generated from '.in' templates by AC_OUTPUT
 601 AC_CONFIG_FILES([
 602   Makefile
 603   doc/examples/Makefile
 604   doc/Makefile
 605   doc/man/Makefile
 606   extras/Makefile
 607   include/Makefile
 608   src/common/Makefile
 609   src/lib/lttng-ust-common/Makefile
 610   src/lib/lttng-ust-ctl/Makefile
 611   src/lib/lttng-ust-cyg-profile/Makefile
 612   src/lib/lttng-ust-dl/Makefile
 613   src/lib/lttng-ust-fd/Makefile
 614   src/lib/lttng-ust-fork/Makefile
 615   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 616   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 617   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 618   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 619   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j2/Makefile
 620   src/lib/lttng-ust-java-agent/java/Makefile
 621   src/lib/lttng-ust-java-agent/jni/common/Makefile
 622   src/lib/lttng-ust-java-agent/jni/jul/Makefile
 623   src/lib/lttng-ust-java-agent/jni/log4j/Makefile
 624   src/lib/lttng-ust-java-agent/jni/Makefile
 625   src/lib/lttng-ust-java-agent/Makefile
 626   src/lib/lttng-ust-java/Makefile
 627   src/lib/lttng-ust-libc-wrapper/Makefile
 628   src/lib/lttng-ust-pthread-wrapper/Makefile
 629   src/lib/lttng-ust-tracepoint/Makefile
 630   src/lib/lttng-ust/Makefile
 631   src/lib/lttng-ust-python-agent/Makefile
 632   src/lib/Makefile
 633   src/lib/lttng-ust-ctl.pc
 634   src/lib/lttng-ust.pc
 635   src/Makefile
 636   src/python-lttngust/lttngust/version.py
 637   src/python-lttngust/Makefile
 638   src/python-lttngust/setup.py
 639   tests/benchmark/Makefile
 640   tests/compile/api0/ctf-types/Makefile
 641   tests/compile/api0/hello.cxx/Makefile
 642   tests/compile/api0/hello/Makefile
 643   tests/compile/api0/hello-many/Makefile
 644   tests/compile/api0/Makefile
 645   tests/compile/api0/same_line_tracepoint/Makefile
 646   tests/compile/api1/ust-fields/Makefile
 647   tests/compile/api1/hello.cxx/Makefile
 648   tests/compile/api1/hello/Makefile
 649   tests/compile/api1/hello-many/Makefile
 650   tests/compile/api1/Makefile
 651   tests/compile/api1/same_line_tracepoint/Makefile
 652   tests/compile/api1/test-app-ctx/Makefile
 653   tests/compile/Makefile
 654   tests/Makefile
 655   tests/regression/abi0-conflict/Makefile
 656   tests/regression/Makefile
 657   tests/unit/gcc-weak-hidden/Makefile
 658   tests/unit/libmsgpack/Makefile
 659   tests/unit/libringbuffer/Makefile
 660   tests/unit/Makefile
 661   tests/unit/pthread_name/Makefile
 662   tests/unit/snprintf/Makefile
 663   tests/unit/ust-elf/Makefile
 664   tests/unit/ust-error/Makefile
 665   tests/unit/ust-utils/Makefile
 666   tests/utils/Makefile
 667   tools/Makefile
 668 ])
 669
 670 AC_OUTPUT
 671
 672
 673 ##                                    ##
 674 ## Mini-report on what will be built. ##
 675 ##                                    ##
 676
 677 PPRINT_INIT
 678 PPRINT_SET_INDENT(1)
 679 PPRINT_SET_TS(38)
 680
 681 AS_ECHO
 682 AS_IF([test -n "ust_version_name"], [
 683   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
 684 ], [
 685   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
 686 ])
 687
 688 AS_ECHO
 689
 690 AS_IF([test -n "ust_version_description"], [
 691   AS_IF([test -n "$FOLD"], [
 692     AS_ECHO(["ust_version_description"]) | $FOLD -s
 693   ], [
 694     AS_ECHO(["ust_version_description"])
 695   ])
 696   AS_ECHO
 697 ])
 698
 699 PPRINT_SUBTITLE([System])
 700
 701 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 702
 703 AS_IF([test "x$unsupported_arch" = "xyes"],[
 704        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 705 ])
 706
 707 AS_ECHO
 708 PPRINT_SUBTITLE([Features])
 709 PPRINT_SET_INDENT(1)
 710
 711 test "x$with_sdt" = "xyes" && value=1 || value=0
 712 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 713
 714 AE_IS_FEATURE_ENABLED([java-agent-jul]) && value=1 || value=0
 715 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 716
 717 AE_IS_FEATURE_ENABLED([java-agent-log4j]) && value=1 || value=0
 718 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 1.x support (deprecated))], $value, [use --enable-java-agent-log4j])
 719
 720 AE_IS_FEATURE_ENABLED([java-agent-log4j2]) && value=1 || value=0
 721 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 2.x support)], $value, [use --enable-java-agent-log4j2])
 722
 723 AE_IS_FEATURE_ENABLED([jni-interface]) && value=1 || value=0
 724 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 725
 726 AE_IS_FEATURE_ENABLED([python-agent]) && value=1 || value=0
 727 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 728
 729 test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
 730 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 731
 732 AE_IS_FEATURE_ENABLED([numa]) && value=1 || value=0
 733 PPRINT_PROP_BOOL([NUMA], $value)
 734
 735 AS_ECHO
 736 PPRINT_SET_INDENT(0)
 737
 738 AE_IS_FEATURE_ENABLED([examples]) && value=1 || value=0
 739 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 740
 741 # man pages build enabled/disabled
 742 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 743
 744 AE_IF_FEATURE_ENABLED([man-pages], [
 745   AE_IF_IN_GIT_REPO([
 746     PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 747   ], [
 748     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 749       PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 750     ], [
 751       PPRINT_PROP_STRING([build_man_pages_msg],
 752         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 753         $PPRINT_COLOR_SUBTITLE)
 754     ])
 755   ])
 756 ], [
 757   PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 758 ])
 759
 760 m4_popdef([build_man_pages_msg])
 761
 762 PPRINT_SET_INDENT(1)
 763
 764 report_bindir="`eval eval echo $bindir`"
 765 report_libdir="`eval eval echo $libdir`"
 766
 767 # Print the bindir and libdir this `make install' will install into.
 768 AS_ECHO
 769 PPRINT_SUBTITLE([Install directories])
 770 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 771 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 772
 773 AS_ECHO
 774 PPRINT_SUBTITLE([System directories])
 775
 776 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 777
 778 PPRINT_SET_INDENT(0)
 779
 780 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 781   AS_ECHO
 782   PPRINT_WARN([dnl
 783 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 784
 785 Note that the man pages are already built in this distribution tarball,
 786 therefore asciidoc and xmlto are only needed if you intend to modify
 787 their sources.
 788
 789 Use --disable-man-pages to completely disable building and installing
 790 the man pages.])
 791 ])
 792
 793 # vim: shiftwidth=2 softtabstop=2 expandtab