configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.2.3],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  24
  25 # Configuration options, which will be installed in the config.h
  26 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  27 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  29
  30 # Compute minor/major/patchlevel version numbers
  31 AC_PROG_SED
  32 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  33 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  34 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  35 AC_SUBST([MAJOR_VERSION], [$major_version])
  36 AC_SUBST([MINOR_VERSION], [$minor_version])
  37 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  38 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  39 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  40 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  41
  42 version_name="Cuda"
  43 version_description="Brewed at the Benelux microbrewery, this IPA has huge floral, citric and resinous hop aroma, simply an amazing nose. The flavor is very fresh with a light caramel malting touch completing a strong body. Huge amounts of hops, lots of grapefruit, lemon and oranges. This is an outstanding IPA!"
  44 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  45 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  46
  47 AC_PROG_GREP
  48 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  49 AC_ARG_ENABLE(libtool-linkdep-fixup,
  50         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  51                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  52         libtool_fixup=$enableval,
  53         libtool_fixup=yes)
  54
  55 AS_IF([test "x$libtool_fixup" = "xyes"],
  56             [
  57             libtool_m4="$srcdir/config/libtool.m4"
  58             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  59             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  60             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  61             AS_IF([test $libtool_flag_pattern_count -ne 0],
  62             [
  63                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  64                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  65                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  66                   ],
  67                   [
  68                   AC_MSG_RESULT([none])
  69                   ])
  70             ])
  71
  72 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  73
  74 # Checks for programs.
  75 AC_PROG_CC
  76 AC_PROG_CXX
  77 AC_PROG_MAKE_SET
  78 LT_INIT
  79
  80 # rw_PROG_CXX_WORKS
  81 # Check whether the C++ compiler works.
  82 AC_CACHE_CHECK([whether the C++ compiler works],
  83                 [rw_cv_prog_cxx_works],
  84                 [AC_LANG_PUSH([C++])
  85                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  86                                 [rw_cv_prog_cxx_works=yes],
  87                                 [rw_cv_prog_cxx_works=no])
  88                 AC_LANG_POP([C++])])
  89
  90 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  91
  92 ## Checks for libraries.
  93 AC_CHECK_LIB([dl], [dlopen],
  94 [
  95         have_libdl=yes
  96 ],
  97 [
  98         #libdl not found, check for dlopen in libc.
  99         AC_CHECK_LIB([c], [dlopen],
 100         [
 101                 have_libc_dl=yes
 102         ],
 103         [
 104                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 105         ])
 106 ])
 107 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 108 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 109
 110 AC_CHECK_LIB([pthread], [pthread_create])
 111
 112 # Checks for header files.
 113 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 114
 115 # Checks for typedefs, structures, and compiler characteristics.
 116 AC_C_INLINE
 117 #AC_TYPE_INT16_T
 118 #AC_TYPE_INT32_T
 119 #AC_TYPE_INT64_T
 120 #AC_TYPE_INT8_T
 121 #AC_TYPE_PID_T
 122 #AC_TYPE_SIZE_T
 123 #AC_TYPE_SSIZE_T
 124 #AC_TYPE_UINT16_T
 125 #AC_TYPE_UINT32_T
 126 #AC_TYPE_UINT64_T
 127 #AC_TYPE_UINT8_T
 128 #AC_CHECK_TYPES([ptrdiff_t])
 129
 130 # Checks for library functions.
 131 AC_FUNC_MALLOC
 132 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 133
 134 CFLAGS="-Wall $CFLAGS"
 135
 136 # URCU
 137
 138 # urcu - check if we just find the headers it out of the box.
 139 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 140 This error can also occur when the liburcu package's configure script has not been run.])])
 141
 142 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 143 # Part of Userspace RCU library 0.7.2 or better.
 144 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 145 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 146
 147 AC_MSG_CHECKING([caa_likely()])
 148 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 149 #include <urcu/compiler.h>
 150 void fct(void)
 151 {
 152         if (caa_likely(1)) {
 153         }
 154 }
 155 ]])],[
 156         AC_MSG_RESULT([yes])
 157 ],[
 158         AC_MSG_RESULT([no])
 159         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 160
 161 ])
 162
 163 # urcu - check that URCU lib is available to compilation
 164 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 165
 166 # urcu - check that URCU lib is at least version 0.6
 167 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 168
 169 AC_MSG_CHECKING([host system alignment requirements])
 170 case $host_cpu in
 171 changequote(,)dnl
 172         i[3456]86)
 173 changequote([,])dnl
 174           ;;
 175         x86_64) ;;
 176         amd64) ;;
 177         powerpc) ;;
 178         ppc64) ;;
 179         powerpc64) ;;
 180         s390) NO_UNALIGNED_ACCESS=1 ;;
 181         s390x) NO_UNALIGNED_ACCESS=1 ;;
 182         arm*) NO_UNALIGNED_ACCESS=1 ;;
 183         mips*) NO_UNALIGNED_ACCESS=1 ;;
 184         tile*) NO_UNALIGNED_ACCESS=1 ;;
 185         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 186 esac
 187
 188 if test x$NO_UNALIGNED_ACCESS = x ; then
 189 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 190 fi
 191
 192 # Set compile flags to java include files if given
 193 AC_ARG_WITH([java-jdk],
 194         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 195         [JAVA_JDK=$withval],
 196         [JAVA_JDK=""]
 197 )
 198 AS_IF([test $JAVA_JDK],[
 199         AS_IF([test -d $JAVA_JDK],[
 200                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 201                 SUBDIRS=`find $JAVA_JDK/include -type d`
 202                 CPPFLAGS+=" "
 203                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 204                 CPPFLAGS+=" "
 205         ],[
 206                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 207         ])
 208 ])
 209
 210 # Check for JNI header files if requested
 211 AC_ARG_WITH([jni-interface],
 212         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 213         [jni_interface=$withval],
 214         [jni_interface=no]
 215 )
 216
 217 AS_IF([test "x$jni_interface" = "xyes"],[
 218         AC_CHECK_HEADERS([jni.h],[],[
 219         AC_MSG_ERROR([missing jni.h
 220 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 221 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 222         ])
 223 ])
 224 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 225
 226 # sdt.h integration
 227 AC_ARG_WITH([sdt],
 228         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 229         [with_sdt=$withval],
 230         [with_sdt="no"]
 231 )
 232
 233 AS_IF([test "x$with_sdt" = "xyes"],[
 234         AC_MSG_CHECKING([STAP_PROBEV()])
 235         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 236         #define SDT_USE_VARIADIC
 237         #include <sys/sdt.h>
 238         void fct(void)
 239         {
 240                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 241         }
 242         ]])],[
 243                 AC_MSG_RESULT([yes])
 244                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 245         ],[
 246                 AC_MSG_RESULT([no])
 247                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 248         ])
 249 ])
 250
 251 AC_CONFIG_FILES([
 252         Makefile
 253         doc/Makefile
 254         doc/examples/Makefile
 255         include/Makefile
 256         include/lttng/ust-version.h
 257         snprintf/Makefile
 258         libringbuffer/Makefile
 259         liblttng-ust-comm/Makefile
 260         liblttng-ust/Makefile
 261         liblttng-ust-ctl/Makefile
 262         liblttng-ust-fork/Makefile
 263         liblttng-ust-java/Makefile
 264         liblttng-ust-libc-wrapper/Makefile
 265         liblttng-ust-cyg-profile/Makefile
 266         tools/Makefile
 267         tests/Makefile
 268         tests/hello/Makefile
 269         tests/hello.cxx/Makefile
 270         tests/same_line_tracepoint/Makefile
 271         tests/snprintf/Makefile
 272         lttng-ust.pc
 273 ])
 274
 275 AC_OUTPUT
 276
 277 AS_ECHO()
 278 AS_ECHO("Version name: $version_name")
 279 AS_ECHO("$version_description")
 280
 281 # Report on the configuration options
 282 AS_ECHO()
 283 AS_ECHO("LTTng-UST will be built with the following options:")
 284
 285 AS_ECHO()
 286 AS_ECHO_N("Java support (JNI): ")
 287 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 288
 289 AS_ECHO_N("sdt.h integration:  ")
 290 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 291
 292 AS_ECHO()
 293 AS_ECHO("Type 'make' to compile.")
 294