configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.4.2],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  24
  25 # Configuration options, which will be installed in the config.h
  26 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  27 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  29
  30 # Compute minor/major/patchlevel version numbers
  31 AC_PROG_SED
  32 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  33 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  34 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  35 AC_SUBST([MAJOR_VERSION], [$major_version])
  36 AC_SUBST([MINOR_VERSION], [$minor_version])
  37 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  38 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  39 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  40 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  41
  42 version_name="Époque Opaque"
  43 version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
  44
  45 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  46 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  47
  48 AC_PROG_GREP
  49 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  50 AC_ARG_ENABLE(libtool-linkdep-fixup,
  51         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  52                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  53         libtool_fixup=$enableval,
  54         libtool_fixup=yes)
  55
  56 AS_IF([test "x$libtool_fixup" = "xyes"],
  57             [
  58             libtool_m4="$srcdir/config/libtool.m4"
  59             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  60             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  61             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  62             AS_IF([test $libtool_flag_pattern_count -ne 0],
  63             [
  64                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  65                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  66                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  67                   ],
  68                   [
  69                   AC_MSG_RESULT([none])
  70                   ])
  71             ])
  72
  73 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  74
  75 # Checks for programs.
  76 AC_PROG_CC
  77 AC_PROG_CXX
  78 AC_PROG_MAKE_SET
  79 LT_INIT
  80
  81 # rw_PROG_CXX_WORKS
  82 # Check whether the C++ compiler works.
  83 AC_CACHE_CHECK([whether the C++ compiler works],
  84                 [rw_cv_prog_cxx_works],
  85                 [AC_LANG_PUSH([C++])
  86                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  87                                 [check_cxx_designated_initializers=yes],
  88                                 [rw_cv_prog_cxx_works=no])
  89                 if test "$check_cxx_designated_initializers" = "yes"; then
  90                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  91                                 struct foo { int a; int b; };
  92                                 void fct(void)
  93                                 {
  94                                         struct foo f = { .a = 0, .b = 1 };
  95                                 }
  96                         ]])],[
  97                                 rw_cv_prog_cxx_works=yes
  98                         ],[
  99                                 rw_cv_prog_cxx_works=no
 100                         ])
 101                 fi
 102                 AC_LANG_POP([C++])])
 103
 104 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 105
 106 ## Checks for libraries.
 107 AC_CHECK_LIB([dl], [dlopen],
 108 [
 109         have_libdl=yes
 110 ],
 111 [
 112         #libdl not found, check for dlopen in libc.
 113         AC_CHECK_LIB([c], [dlopen],
 114         [
 115                 have_libc_dl=yes
 116         ],
 117         [
 118                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 119         ])
 120 ])
 121 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 122 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 123
 124 AC_CHECK_LIB([pthread], [pthread_create])
 125
 126 # Check for dlfcn.h
 127 AC_CHECK_HEADER([dlfcn.h])
 128 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
 129         [AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
 130                 [#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 131                 #include <dlfcn.h>])
 132         ],
 133         [ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
 134 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 135
 136 # Checks for header files.
 137 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 138
 139 # Checks for typedefs, structures, and compiler characteristics.
 140 AC_C_INLINE
 141 #AC_TYPE_INT16_T
 142 #AC_TYPE_INT32_T
 143 #AC_TYPE_INT64_T
 144 #AC_TYPE_INT8_T
 145 #AC_TYPE_PID_T
 146 #AC_TYPE_SIZE_T
 147 #AC_TYPE_SSIZE_T
 148 #AC_TYPE_UINT16_T
 149 #AC_TYPE_UINT32_T
 150 #AC_TYPE_UINT64_T
 151 #AC_TYPE_UINT8_T
 152 #AC_CHECK_TYPES([ptrdiff_t])
 153
 154 # Checks for library functions.
 155 AC_FUNC_MALLOC
 156 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 157
 158 CFLAGS="-Wall $CFLAGS"
 159
 160 # URCU
 161
 162 # urcu - check if we just find the headers it out of the box.
 163 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 164 This error can also occur when the liburcu package's configure script has not been run.])])
 165
 166 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 167 # Part of Userspace RCU library 0.7.2 or better.
 168 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 169 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 170
 171 AC_MSG_CHECKING([caa_likely()])
 172 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 173 #include <urcu/compiler.h>
 174 void fct(void)
 175 {
 176         if (caa_likely(1)) {
 177         }
 178 }
 179 ]])],[
 180         AC_MSG_RESULT([yes])
 181 ],[
 182         AC_MSG_RESULT([no])
 183         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 184
 185 ])
 186
 187 # urcu - check that URCU lib is available to compilation
 188 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 189
 190 # urcu - check that URCU lib is at least version 0.6
 191 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 192
 193 AC_MSG_CHECKING([host system alignment requirements])
 194 case $host_cpu in
 195 changequote(,)dnl
 196         i[3456]86)
 197 changequote([,])dnl
 198           ;;
 199         x86_64) ;;
 200         amd64) ;;
 201         powerpc) ;;
 202         ppc64) ;;
 203         powerpc64) ;;
 204         s390) NO_UNALIGNED_ACCESS=1 ;;
 205         s390x) NO_UNALIGNED_ACCESS=1 ;;
 206         arm*) NO_UNALIGNED_ACCESS=1 ;;
 207         mips*) NO_UNALIGNED_ACCESS=1 ;;
 208         tile*) NO_UNALIGNED_ACCESS=1 ;;
 209         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 210 esac
 211 AC_MSG_RESULT([$host_cpu])
 212
 213 if test x$NO_UNALIGNED_ACCESS = x ; then
 214 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 215 fi
 216
 217 # Set compile flags to java include files if given
 218 AC_ARG_WITH([java-jdk],
 219         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 220         [JAVA_JDK=$withval],
 221         [JAVA_JDK=""]
 222 )
 223 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 224 AC_SUBST([JAVA_JDK])
 225
 226 AS_IF([test $JAVA_JDK],[
 227         AS_IF([test -d $JAVA_JDK],[
 228                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 229                 SUBDIRS=`find $JAVA_JDK/include -type d`
 230                 CPPFLAGS+=" "
 231                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 232                 CPPFLAGS+=" "
 233         ],[
 234                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 235         ])
 236 ])
 237
 238 # Check for JNI header files if requested
 239 AC_ARG_WITH([jni-interface],
 240         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 241         [jni_interface=$withval],
 242         [jni_interface=no]
 243 )
 244
 245 AS_IF([test "x$jni_interface" = "xyes"],[
 246         AC_CHECK_HEADERS([jni.h],[],[
 247         AC_MSG_ERROR([missing jni.h
 248 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 249 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 250         ])
 251 ])
 252 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 253
 254 # sdt.h integration
 255 AC_ARG_WITH([sdt],
 256         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 257         [with_sdt=$withval],
 258         [with_sdt="no"]
 259 )
 260
 261 AS_IF([test "x$with_sdt" = "xyes"],[
 262         AC_MSG_CHECKING([STAP_PROBEV()])
 263         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 264         #define SDT_USE_VARIADIC
 265         #include <sys/sdt.h>
 266         void fct(void)
 267         {
 268                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 269         }
 270         ]])],[
 271                 AC_MSG_RESULT([yes])
 272                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 273         ],[
 274                 AC_MSG_RESULT([no])
 275                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 276         ])
 277 ])
 278
 279 AC_MSG_CHECKING([whether shared libraries are enabled])
 280 AS_IF([test "x$enable_shared" = "xyes"],
 281         [
 282                 AC_MSG_RESULT([yes])
 283         ],
 284         [
 285                 AC_MSG_RESULT([no])
 286                 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 287         ])
 288
 289 AC_ARG_WITH([lttng-system-rundir],
 290         AS_HELP_STRING([--with-lttng-system-rundir],
 291         [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 292         [lttng_system_rundir="$withval"],
 293         [lttng_system_rundir="/var/run/lttng"])
 294 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 295         [LTTng system runtime directory])
 296
 297 lttnglibjavadir="${libdir}/lttng/java"
 298 AC_SUBST(lttnglibjavadir)
 299
 300 AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
 301 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
 302
 303 AC_CONFIG_FILES([
 304         Makefile
 305         doc/Makefile
 306         doc/examples/Makefile
 307         include/Makefile
 308         include/lttng/ust-version.h
 309         snprintf/Makefile
 310         libringbuffer/Makefile
 311         liblttng-ust-comm/Makefile
 312         liblttng-ust/Makefile
 313         liblttng-ust-ctl/Makefile
 314         liblttng-ust-fork/Makefile
 315         liblttng-ust-dl/Makefile
 316         liblttng-ust-java/Makefile
 317         liblttng-ust-jul/Makefile
 318         liblttng-ust-libc-wrapper/Makefile
 319         liblttng-ust-cyg-profile/Makefile
 320         tools/Makefile
 321         tests/Makefile
 322         tests/hello/Makefile
 323         tests/hello.cxx/Makefile
 324         tests/same_line_tracepoint/Makefile
 325         tests/snprintf/Makefile
 326         tests/benchmark/Makefile
 327         tests/utils/Makefile
 328         tests/java-jul/Makefile
 329         lttng-ust.pc
 330 ])
 331
 332 AC_OUTPUT
 333
 334 AS_ECHO()
 335 AS_ECHO("Version name: $version_name")
 336 AS_ECHO("$version_description")
 337
 338 # Report on the configuration options
 339 AS_ECHO()
 340 AS_ECHO("LTTng-UST will be built with the following options:")
 341
 342 AS_ECHO()
 343 AS_ECHO_N("Java support (JNI): ")
 344 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 345
 346 AS_ECHO_N("sdt.h integration:  ")
 347 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 348
 349 AS_ECHO()
 350 AS_ECHO("Type 'make' to compile.")
 351