configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.5.7],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 AM_MAINTAINER_MODE([enable])
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  25
  26 # Configuration options, which will be installed in the config.h
  27 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  29 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  30 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
  31
  32 # Compute minor/major/patchlevel version numbers
  33 AC_PROG_SED
  34 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  35 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  36 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  37 AC_SUBST([MAJOR_VERSION], [$major_version])
  38 AC_SUBST([MINOR_VERSION], [$minor_version])
  39 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  40 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  41 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  42 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  43
  44 version_name="Fumisterie"
  45 version_description="The Fumisterie is a beer whose style is at the confluence of English and German ales. On the palate, it is full-bodied, malty and slightly caramelized. The organic hemp seeds incorporated during the brewing gives it a unique and original taste. The hop flavour comes through delicately in the after taste."
  46
  47 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  48 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  49
  50 AC_PROG_GREP
  51 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  52 AC_ARG_ENABLE(libtool-linkdep-fixup,
  53         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  54                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  55         libtool_fixup=$enableval,
  56         libtool_fixup=yes)
  57
  58 AS_IF([test "x$libtool_fixup" = "xyes"],
  59             [
  60             libtool_m4="$srcdir/config/libtool.m4"
  61             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  62             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  63             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  64             AS_IF([test $libtool_flag_pattern_count -ne 0],
  65             [
  66                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  67                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  68                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  69                   ],
  70                   [
  71                   AC_MSG_RESULT([none])
  72                   ])
  73             ])
  74
  75 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  76
  77 # Checks for programs.
  78 AC_PROG_CC
  79 AC_PROG_CXX
  80 AC_PROG_MAKE_SET
  81 LT_INIT
  82
  83 # rw_PROG_CXX_WORKS
  84 # Check whether the C++ compiler works.
  85 AC_CACHE_CHECK([whether the C++ compiler works],
  86                 [rw_cv_prog_cxx_works],
  87                 [AC_LANG_PUSH([C++])
  88                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  89                                 [check_cxx_designated_initializers=yes],
  90                                 [rw_cv_prog_cxx_works=no])
  91                 if test "$check_cxx_designated_initializers" = "yes"; then
  92                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  93                                 struct foo { int a; int b; };
  94                                 void fct(void)
  95                                 {
  96                                         struct foo f = { .a = 0, .b = 1 };
  97                                 }
  98                         ]])],[
  99                                 rw_cv_prog_cxx_works=yes
 100                         ],[
 101                                 rw_cv_prog_cxx_works=no
 102                         ])
 103                 fi
 104                 AC_LANG_POP([C++])])
 105
 106 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 107
 108 # Check if the compiler support weak symbols
 109 AX_SYS_WEAK_ALIAS
 110
 111 if test "x${ax_cv_sys_weak_alias}" = "xno"; then
 112    AC_MSG_ERROR([Your platform doesn't support weak symbols.])
 113 fi
 114
 115 ## Checks for libraries.
 116 AC_CHECK_LIB([dl], [dlopen],
 117 [
 118         have_libdl=yes
 119 ],
 120 [
 121         #libdl not found, check for dlopen in libc.
 122         AC_CHECK_LIB([c], [dlopen],
 123         [
 124                 have_libc_dl=yes
 125         ],
 126         [
 127                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 128         ])
 129 ])
 130 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 131 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 132
 133 AC_CHECK_LIB([pthread], [pthread_create])
 134
 135 # Check for dlfcn.h
 136 AC_CHECK_HEADER([dlfcn.h])
 137 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
 138         [AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
 139                 [#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 140                 #include <dlfcn.h>])
 141         ],
 142         [ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
 143 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 144
 145 # Checks for header files.
 146 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 147
 148 # Checks for typedefs, structures, and compiler characteristics.
 149 AC_C_INLINE
 150 #AC_TYPE_INT16_T
 151 #AC_TYPE_INT32_T
 152 #AC_TYPE_INT64_T
 153 #AC_TYPE_INT8_T
 154 #AC_TYPE_PID_T
 155 #AC_TYPE_SIZE_T
 156 #AC_TYPE_SSIZE_T
 157 #AC_TYPE_UINT16_T
 158 #AC_TYPE_UINT32_T
 159 #AC_TYPE_UINT64_T
 160 #AC_TYPE_UINT8_T
 161 #AC_CHECK_TYPES([ptrdiff_t])
 162
 163 # Checks for library functions.
 164 AC_FUNC_MALLOC
 165 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 166
 167 CFLAGS="-Wall $CFLAGS"
 168
 169 # URCU
 170
 171 # urcu - check if we just find the headers it out of the box.
 172 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 173 This error can also occur when the liburcu package's configure script has not been run.])])
 174
 175 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 176 # Part of Userspace RCU library 0.7.2 or better.
 177 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 178 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 179
 180 AC_MSG_CHECKING([caa_likely()])
 181 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 182 #include <urcu/compiler.h>
 183 void fct(void)
 184 {
 185         if (caa_likely(1)) {
 186         }
 187 }
 188 ]])],[
 189         AC_MSG_RESULT([yes])
 190 ],[
 191         AC_MSG_RESULT([no])
 192         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 193
 194 ])
 195
 196 # urcu - check that URCU lib is available to compilation
 197 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 198
 199 # urcu - check that URCU lib is at least version 0.6
 200 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 201
 202 # optional linux/perf_event.h
 203 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 204
 205 # Perf event counters are only supported on x86 so far.
 206 AC_MSG_CHECKING([UST support for architecture perf event counters])
 207 case $host_cpu in
 208 changequote(,)dnl
 209         i[3456]86)
 210 changequote([,])dnl
 211         UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 212         x86_64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 213         amd64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
 214         *) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no;;
 215 esac
 216 AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
 217
 218 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
 219
 220 if test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"; then
 221 AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 222 fi
 223
 224 AC_MSG_CHECKING([host system alignment requirements])
 225 case $host_cpu in
 226 changequote(,)dnl
 227         i[3456]86)
 228 changequote([,])dnl
 229           ;;
 230         x86_64) ;;
 231         amd64) ;;
 232         powerpc) ;;
 233         ppc64) ;;
 234         ppc64le) ;;
 235         powerpc64) ;;
 236         powerpc64le) ;;
 237         s390) NO_UNALIGNED_ACCESS=1 ;;
 238         s390x) NO_UNALIGNED_ACCESS=1 ;;
 239         arm*) NO_UNALIGNED_ACCESS=1 ;;
 240         mips*) NO_UNALIGNED_ACCESS=1 ;;
 241         tile*) NO_UNALIGNED_ACCESS=1 ;;
 242         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 243 esac
 244 AC_MSG_RESULT([$host_cpu])
 245
 246 if test x$NO_UNALIGNED_ACCESS = x ; then
 247 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 248 fi
 249
 250 # Set compile flags to java include files if given
 251 AC_ARG_WITH([java-jdk],
 252         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 253         [JAVA_JDK=$withval],
 254         [JAVA_JDK=""]
 255 )
 256 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 257 AC_SUBST([JAVA_JDK])
 258
 259 AS_IF([test $JAVA_JDK],[
 260         AS_IF([test -d $JAVA_JDK],[
 261                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 262                 SUBDIRS=`find $JAVA_JDK/include -type d`
 263                 CPPFLAGS+=" "
 264                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 265                 CPPFLAGS+=" "
 266         ],[
 267                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 268         ])
 269 ])
 270
 271 # Check for JNI header files if requested
 272 AC_ARG_WITH([jni-interface],
 273         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 274         [jni_interface=$withval],
 275         [jni_interface=no]
 276 )
 277
 278 AS_IF([test "x$jni_interface" = "xyes"],[
 279         AC_CHECK_HEADERS([jni.h],[],[
 280         AC_MSG_ERROR([missing jni.h
 281 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 282 Use the --with-java-jdk=DIR option to point to your JDK directory, or disable the JNI interface.])
 283         ])
 284 ])
 285 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 286
 287 # sdt.h integration
 288 AC_ARG_WITH([sdt],
 289         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 290         [with_sdt=$withval],
 291         [with_sdt="no"]
 292 )
 293
 294 AS_IF([test "x$with_sdt" = "xyes"],[
 295         AC_MSG_CHECKING([STAP_PROBEV()])
 296         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 297         #define SDT_USE_VARIADIC
 298         #include <sys/sdt.h>
 299         void fct(void)
 300         {
 301                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 302         }
 303         ]])],[
 304                 AC_MSG_RESULT([yes])
 305                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 306         ],[
 307                 AC_MSG_RESULT([no])
 308                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 309         ])
 310 ])
 311
 312 AC_MSG_CHECKING([whether shared libraries are enabled])
 313 AS_IF([test "x$enable_shared" = "xyes"],
 314         [
 315                 AC_MSG_RESULT([yes])
 316         ],
 317         [
 318                 AC_MSG_RESULT([no])
 319                 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 320         ])
 321
 322 AC_ARG_WITH([lttng-system-rundir],
 323         AS_HELP_STRING([--with-lttng-system-rundir],
 324         [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 325         [lttng_system_rundir="$withval"],
 326         [lttng_system_rundir="/var/run/lttng"])
 327 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 328         [LTTng system runtime directory])
 329
 330 lttnglibjavadir="${libdir}/lttng/java"
 331 AC_SUBST(lttnglibjavadir)
 332
 333 AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
 334 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
 335
 336 AC_CONFIG_FILES([
 337         Makefile
 338         doc/Makefile
 339         doc/examples/Makefile
 340         include/Makefile
 341         include/lttng/ust-version.h
 342         snprintf/Makefile
 343         libringbuffer/Makefile
 344         liblttng-ust-comm/Makefile
 345         liblttng-ust/Makefile
 346         liblttng-ust-ctl/Makefile
 347         liblttng-ust-fork/Makefile
 348         liblttng-ust-dl/Makefile
 349         liblttng-ust-java/Makefile
 350         liblttng-ust-jul/Makefile
 351         liblttng-ust-libc-wrapper/Makefile
 352         liblttng-ust-cyg-profile/Makefile
 353         tools/Makefile
 354         tests/Makefile
 355         tests/hello/Makefile
 356         tests/hello.cxx/Makefile
 357         tests/same_line_tracepoint/Makefile
 358         tests/snprintf/Makefile
 359         tests/benchmark/Makefile
 360         tests/utils/Makefile
 361         tests/java-jul/Makefile
 362         lttng-ust.pc
 363 ])
 364
 365 AC_OUTPUT
 366
 367 AS_ECHO()
 368 AS_ECHO("Version name: $version_name")
 369 AS_ECHO("$version_description")
 370
 371 # Report on the configuration options
 372 AS_ECHO()
 373 AS_ECHO("LTTng-UST will be built with the following options:")
 374
 375 AS_ECHO()
 376 AS_ECHO_N("Java support (JNI): ")
 377 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 378
 379 AS_ECHO_N("sdt.h integration:  ")
 380 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 381
 382 AS_ECHO()
 383 AS_ECHO("Type 'make' to compile.")
 384