configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [11])
   4 m4_define([V_PATCH], [3])
   5 dnl m4_define([V_EXTRA], [])
   6 m4_define([V_NAME], [[Lafontaine]])
   7 m4_define([V_DESC], [[A modern Saison beer from Montréal's Oshlag microbrewery, Lafontaine is a refreshing, zesty, rice beer with hints of fruit and spices.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_SUBST([LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules if available (Introduced in AM 1.11)
  48 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  49
  50 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  57 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  58 AC_PROG_CXX
  59 rw_PROG_CXX_WORKS
  60 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  61
  62 # Check if the compiler support weak symbols
  63 AX_SYS_WEAK_ALIAS
  64
  65 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  66         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  67 ])
  68
  69 # Checks for programs.
  70 AC_PROG_SED
  71 AC_PROG_GREP
  72 AC_PROG_LN_S
  73 AC_PROG_MKDIR_P
  74 AC_PROG_MAKE_SET
  75 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  76 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  77
  78 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  79 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  80 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  81 ], [
  82         libtool_fixup=$enableval
  83 ], [
  84         libtool_fixup=yes
  85 ])
  86
  87 AS_IF([test "x$libtool_fixup" = "xyes"], [
  88         libtool_m4="$srcdir/m4/libtool.m4"
  89         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  90         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  91         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  92
  93         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  94         AC_MSG_RESULT([$libtool_flag_pattern_count])
  95         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  96                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  97         ], [
  98                 AC_MSG_RESULT([none])
  99         ])
 100 ])
 101 LT_INIT([disable-static])
 102
 103 AC_MSG_CHECKING([whether shared libraries are enabled])
 104 AS_IF([test "x$enable_shared" = "xyes"], [
 105         AC_MSG_RESULT([yes])
 106 ], [
 107         AC_MSG_RESULT([no])
 108         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 109 ])
 110
 111 # Checks for typedefs, structures, and compiler characteristics.
 112 AC_C_INLINE
 113 AC_TYPE_INT8_T
 114 AC_TYPE_INT16_T
 115 AC_TYPE_INT32_T
 116 AC_TYPE_INT64_T
 117 AC_TYPE_MODE_T
 118 AC_TYPE_OFF_T
 119 AC_TYPE_PID_T
 120 AC_TYPE_SIZE_T
 121 AC_TYPE_SSIZE_T
 122 AC_TYPE_UID_T
 123 AC_TYPE_UINT8_T
 124 AC_TYPE_UINT16_T
 125 AC_TYPE_UINT32_T
 126 AC_TYPE_UINT64_T
 127 AC_CHECK_TYPES([ptrdiff_t])
 128
 129 AX_C___ATTRIBUTE__
 130 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 131         [:],
 132         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 133
 134 # Checks for library functions.
 135 AC_FUNC_CHOWN
 136 AC_FUNC_FORK
 137 AC_FUNC_MMAP
 138 AC_FUNC_REALLOC
 139 AC_FUNC_STRERROR_R
 140 AC_FUNC_STRNLEN
 141 AC_CHECK_FUNCS([ \
 142         atexit \
 143         clock_gettime \
 144         ftruncate \
 145         getpagesize \
 146         gettimeofday \
 147         localeconv \
 148         memchr \
 149         memmove \
 150         memset \
 151         mkdir \
 152         munmap \
 153         realpath \
 154         sched_getcpu \
 155         socket \
 156         strchr \
 157         strdup \
 158         strerror \
 159         strtol \
 160         sysconf \
 161 ])
 162
 163 # AC_FUNC_MALLOC causes problems when cross-compiling.
 164 #AC_FUNC_MALLOC
 165
 166 # Checks for header files.
 167 AC_HEADER_STDBOOL
 168 AC_CHECK_HEADERS([ \
 169         arpa/inet.h \
 170         fcntl.h \
 171         float.h \
 172         limits.h \
 173         locale.h \
 174         stddef.h \
 175         sys/socket.h \
 176         sys/time.h \
 177         wchar.h \
 178 ])
 179
 180 # Set architecture specific options
 181 AS_CASE([$host_cpu],
 182         [i[[3456]]86], [],
 183         [x86_64], [],
 184         [amd64], [],
 185         [powerpc], [],
 186         [ppc64], [],
 187         [ppc64le], [],
 188         [powerpc64], [],
 189         [powerpc64le], [],
 190         [s390], [NO_UNALIGNED_ACCESS=1],
 191         [s390x], [NO_UNALIGNED_ACCESS=1],
 192         [arm*], [
 193                 NO_UNALIGNED_ACCESS=1
 194                 NO_NUMA=1
 195                 ],
 196         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 197         [mips*], [NO_UNALIGNED_ACCESS=1],
 198         [tile*], [NO_UNALIGNED_ACCESS=1],
 199         [
 200                 UNSUPPORTED_ARCH=1
 201                 NO_UNALIGNED_ACCESS=1
 202         ])
 203
 204 # Configuration options, which will be installed in the config.h
 205 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 206 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 207 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 208
 209 # Checks for libraries.
 210 AC_CHECK_LIB([dl], [dlopen], [
 211         have_libdl=yes
 212         libdl_name=dl
 213 ], [
 214         #libdl not found, check for dlopen in libc.
 215         AC_CHECK_LIB([c], [dlopen], [
 216                 have_libc_dl=yes
 217                 libdl_name=c
 218         ], [
 219                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 220         ])
 221 ])
 222
 223 # Check if libdl has dlmopen support.
 224 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 225 AC_CHECK_LIB([$libdl_name], [dlmopen],
 226         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 227 )
 228
 229 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 230 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 231
 232 AC_CHECK_LIB([pthread], [pthread_create])
 233 AC_CHECK_LIB([pthread], [pthread_setname_np],
 234         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 235         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 236                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 237                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 238
 239 # Check for dlfcn.h
 240 AC_CHECK_HEADER([dlfcn.h])
 241 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 242         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 243                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 244                 #include <dlfcn.h>
 245         ])
 246 ], [
 247         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 248 ])
 249
 250 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 251
 252 # URCU
 253
 254 # urcu - check if we just find the headers it out of the box.
 255 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 256 This error can also occur when the liburcu package's configure script has not been run.])])
 257
 258 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 259 # Part of Userspace RCU library 0.7.2 or better.
 260 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 261 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 262
 263 AC_MSG_CHECKING([caa_likely()])
 264 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 265         #include <urcu/compiler.h>
 266         void fct(void)
 267         {
 268                 if (caa_likely(1)) {
 269                 }
 270         }
 271 ]])], [
 272         AC_MSG_RESULT([yes])
 273 ], [
 274         AC_MSG_RESULT([no])
 275         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 276 ])
 277
 278 # urcu - check that URCU lib is available to compilation
 279 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 280
 281 # urcu - check that URCU lib is at least version 0.6
 282 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 283
 284 # numa.h integration
 285 AS_IF([test "x$NO_NUMA" = "x1"],[
 286       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 287 ])
 288
 289 AC_ARG_ENABLE([numa], [
 290 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 291 ], [
 292         enable_numa=$enableval
 293 ], [
 294         enable_numa=yes
 295 ])
 296
 297 AS_IF([test "x$enable_numa" = "xyes"], [
 298         # numa - check that numa lib is available
 299         AC_CHECK_LIB([numa], [numa_available], [],
 300 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 301         have_libnuma=yes
 302 ])
 303 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 304
 305 # optional linux/perf_event.h
 306 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 307
 308 # Perf event counters are supported on all architectures supported by
 309 # perf, using the read system call as fallback.
 310 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 311
 312 AS_IF([test "x$have_perf_event" = "xyes"], [
 313         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 314 ])
 315
 316 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 317         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 318 ])
 319
 320 # Check for JNI header files if requested
 321 AC_ARG_ENABLE([jni-interface], [
 322 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 323 ], [
 324         jni_interface=$enableval
 325 ], [
 326         jni_interface=no
 327 ])
 328
 329 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 330
 331
 332 AC_ARG_ENABLE([java-agent-jul], [
 333 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 334 ], [
 335         java_agent_jul=$enableval
 336 ], [
 337         java_agent_jul=no
 338 ])
 339
 340 AC_ARG_ENABLE([java-agent-log4j], [
 341 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 342 ], [
 343         java_agent_log4j=$enableval
 344 ], [
 345         java_agent_log4j=no
 346 ])
 347
 348 AC_ARG_ENABLE([java-agent-all], [
 349 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 350 ], [
 351         java_agent_jul=$enableval
 352         java_agent_log4j=$enableval
 353 ], [:])
 354
 355 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 356 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 357 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 358
 359 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 360         AX_JAVA_OPTIONS
 361         AX_PROG_JAVAC
 362         AX_PROG_JAVA
 363         AX_PROG_JAR
 364         AC_ARG_VAR([CLASSPATH], [Java class path])
 365
 366         AX_JNI_INCLUDE_DIR
 367         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 368         do
 369                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 370         done
 371
 372         saved_CPPFLAGS="$CPPFLAGS"
 373         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 374         AX_PROG_JAVAH
 375         CPPFLAGS="$saved_CPPFLAGS"
 376 ])
 377
 378 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 379
 380 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 381         AX_CHECK_CLASSPATH
 382         AX_CHECK_CLASS([org.apache.log4j.Logger])
 383         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 384                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 385         ])
 386 ])
 387
 388 # Option to build the python agent
 389 AC_ARG_ENABLE([python-agent], [
 390 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 391 ], [
 392         python_agent=$enableval
 393 ], [:])
 394 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 395 AS_IF([test "x$python_agent" = "xyes"], [
 396         AM_PATH_PYTHON([2.7])
 397 ])
 398
 399 # sdt.h integration
 400 AC_ARG_WITH([sdt], [
 401 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 402 ], [
 403         with_sdt=$withval
 404 ], [
 405         with_sdt="no"
 406 ])
 407
 408 AS_IF([test "x$with_sdt" = "xyes"], [
 409         AC_MSG_CHECKING([STAP_PROBEV()])
 410         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 411                 #define SDT_USE_VARIADIC
 412                 #include <sys/sdt.h>
 413                 void fct(void)
 414                 {
 415                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 416                 }
 417         ]])], [
 418                 AC_MSG_RESULT([yes])
 419                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 420         ], [
 421                 AC_MSG_RESULT([no])
 422                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 423         ])
 424 ])
 425
 426 AC_ARG_WITH([lttng-system-rundir], [
 427 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 428 ], [
 429         lttng_system_rundir="$withval"
 430 ], [
 431         lttng_system_rundir="/var/run/lttng"
 432 ])
 433 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 434                 [LTTng system runtime directory])
 435
 436 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 437 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 438
 439 # Enable building examples
 440 AC_ARG_ENABLE(
 441         examples,
 442         AS_HELP_STRING(
 443                 [--disable-examples],
 444                 [Do not build and install examples]
 445         ),
 446         [enable_examples=$enableval],
 447         [enable_examples=yes]
 448 )
 449
 450 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 451
 452 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 453 # is not distributed in tarballs.
 454 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 455 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 456
 457 # Enable building man pages (user's intention).
 458 AC_ARG_ENABLE(
 459         man-pages,
 460         AS_HELP_STRING(
 461                 [--disable-man-pages],
 462                 [Do not build and install man pages (already built in a distributed tarball)]
 463         ),
 464         [man_pages_opt=$enableval],
 465         [man_pages_opt=yes]
 466 )
 467
 468 # Check for asciidoc and xmlto if we enabled building the man pages.
 469 have_asciidoc_xmlto=no
 470 warn_prebuilt_man_pages=no
 471
 472 AS_IF([test "x$man_pages_opt" = "xyes"], [
 473         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 474         AC_PATH_PROG([XMLTO], [xmlto], [no])
 475
 476         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 477                 AS_IF([test "x$in_git_repo" = "xyes"], [
 478                         # This is an error because we're in the Git repo, which
 479                         # means the man pages are not already generated for us,
 480                         # thus asciidoc/xmlto are required because we were asked
 481                         # to build the man pages.
 482                         AC_MSG_ERROR([
 483 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 484 --disable-man-pages to disable building the man pages, in which case
 485 they will not be installed.
 486                         ])
 487                 ], [
 488                         # Only warn here: since we're in the tarball, the man
 489                         # pages should already be generated at this point, thus
 490                         # asciidoc/xmlto are not strictly required.
 491                         warn_prebuilt_man_pages=yes
 492                 ])
 493         ], [
 494                 have_asciidoc_xmlto=yes
 495         ])
 496 ])
 497
 498 # Export man page build condition: build the man pages if the user
 499 # asked for it, and if the tools are available.
 500 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 501 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 502
 503 # Default values
 504 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 505         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 506         $1="$2"
 507         AC_SUBST([$1])
 508 ])
 509
 510 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 511
 512 AM_CFLAGS="-Wall"
 513 AC_SUBST(AM_CFLAGS)
 514 AC_SUBST(JNI_CPPFLAGS)
 515
 516 AC_CONFIG_FILES([
 517         Makefile
 518         doc/Makefile
 519         doc/examples/Makefile
 520         doc/man/Makefile
 521         include/Makefile
 522         include/lttng/ust-version.h
 523         snprintf/Makefile
 524         libringbuffer/Makefile
 525         liblttng-ust-comm/Makefile
 526         liblttng-ust/Makefile
 527         liblttng-ust-ctl/Makefile
 528         liblttng-ust-fork/Makefile
 529         liblttng-ust-dl/Makefile
 530         liblttng-ust-fd/Makefile
 531         liblttng-ust-java/Makefile
 532         liblttng-ust-java-agent/Makefile
 533         liblttng-ust-java-agent/java/Makefile
 534         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 535         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 536         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 537         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 538         liblttng-ust-java-agent/jni/Makefile
 539         liblttng-ust-java-agent/jni/common/Makefile
 540         liblttng-ust-java-agent/jni/jul/Makefile
 541         liblttng-ust-java-agent/jni/log4j/Makefile
 542         liblttng-ust-libc-wrapper/Makefile
 543         liblttng-ust-cyg-profile/Makefile
 544         liblttng-ust-python-agent/Makefile
 545         python-lttngust/Makefile
 546         python-lttngust/setup.py
 547         python-lttngust/lttngust/__init__.py
 548         tools/Makefile
 549         tests/Makefile
 550         tests/ctf-types/Makefile
 551         tests/hello/Makefile
 552         tests/hello.cxx/Makefile
 553         tests/same_line_tracepoint/Makefile
 554         tests/snprintf/Makefile
 555         tests/ust-elf/Makefile
 556         tests/benchmark/Makefile
 557         tests/utils/Makefile
 558         tests/test-app-ctx/Makefile
 559         tests/gcc-weak-hidden/Makefile
 560         lttng-ust.pc
 561 ])
 562
 563 # Create link for python agent for the VPATH guru.
 564 AC_CONFIG_LINKS([
 565         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 566         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 567         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 568         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 569         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 570 ])
 571
 572 AC_OUTPUT
 573
 574
 575 #
 576 # Mini-report on what will be built.
 577 #
 578
 579 PPRINT_INIT
 580 PPRINT_SET_INDENT(1)
 581 PPRINT_SET_TS(38)
 582
 583 AS_ECHO
 584 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 585 AS_ECHO
 586
 587 AS_ECHO("V_DESC")
 588
 589 AS_ECHO
 590 PPRINT_SUBTITLE([System])
 591
 592 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 593
 594 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 595 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 596
 597 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 598        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 599 ])
 600
 601 AS_ECHO
 602 PPRINT_SUBTITLE([Features])
 603 PPRINT_SET_INDENT(1)
 604
 605 test "x$with_sdt" = "xyes" && value=1 || value=0
 606 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 607
 608 test "x$java_agent_jul" = xyes && value=1 || value=0
 609 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 610
 611 test "x$java_agent_log4j" = xyes && value=1 || value=0
 612 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 613
 614 test "x$jni_interface" = xyes && value=1 || value=0
 615 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 616
 617 test "x$python_agent" = xyes && value=1 || value=0
 618 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 619
 620 test "x$enable_numa" = xyes && value=1 || value=0
 621 PPRINT_PROP_BOOL([NUMA], $value)
 622
 623 AS_ECHO
 624 PPRINT_SET_INDENT(0)
 625
 626 test "x$enable_examples" = xyes && value=1 || value=0
 627 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 628
 629 # man pages build enabled/disabled
 630 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 631
 632 AS_IF([test "x$man_pages_opt" != "xno"], [
 633         AS_IF([test "x$in_git_repo" = "xyes"], [
 634                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 635         ], [
 636                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 637                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 638                 ], [
 639                         PPRINT_PROP_STRING([build_man_pages_msg],
 640                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 641                                 $PPRINT_COLOR_SUBTITLE)
 642                 ])
 643         ])
 644 ], [
 645         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 646 ])
 647
 648 m4_popdef([build_man_pages_msg])
 649
 650 PPRINT_SET_INDENT(1)
 651
 652 report_bindir="`eval eval echo $bindir`"
 653 report_libdir="`eval eval echo $libdir`"
 654
 655 # Print the bindir and libdir this `make install' will install into.
 656 AS_ECHO
 657 PPRINT_SUBTITLE([Install directories])
 658 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 659 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 660
 661 AS_ECHO
 662 PPRINT_SUBTITLE([System directories])
 663
 664 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 665
 666 PPRINT_SET_INDENT(0)
 667
 668 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 669         AS_ECHO
 670         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 671
 672 Note that the man pages are already built in this distribution tarball,
 673 therefore asciidoc and xmlto are only needed if you intend to modify
 674 their sources.
 675
 676 Use --disable-man-pages to completely disable building and installing
 677 the man pages.])
 678 ])