configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7
   8 # Project version information
   9 m4_define([ust_version_major], [2])
  10 m4_define([ust_version_minor], [13])
  11 m4_define([ust_version_patch], [8])
  12 m4_define([ust_version_dev_stage], [])
  13 m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
  14 m4_define([ust_version_name], [[Nordicité]])
  15 m4_define([ust_version_description], [[The product of a collaboration between Champ Libre and Boréale, this farmhouse IPA is brewed with Kveik yeast and Québec-grown barley, oats and juniper branches. The result is a remarkable fruity hazy golden IPA that offers a balanced touch of resinous and woodsy bitterness.]])
  16
  17 # Library version information of "liblttng-ust"
  18 # Following the numbering scheme proposed by libtool for the library version
  19 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  20 m4_define([ust_lib_version_current], [1])
  21 m4_define([ust_lib_version_revision], [0])
  22 m4_define([ust_lib_version_age], [0])
  23 m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
  24
  25 # Library version information of "liblttng-ust-ctl"
  26 # Following the numbering scheme proposed by libtool for the library version
  27 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  28 m4_define([ust_ctl_lib_version_current], [5])
  29 m4_define([ust_ctl_lib_version_revision], [0])
  30 m4_define([ust_ctl_lib_version_age], [0])
  31 m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
  32
  33
  34 ##                     ##
  35 ## Autoconf base setup ##
  36 ##                     ##
  37
  38 AC_PREREQ([2.69])
  39 AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
  40
  41 AC_CONFIG_HEADERS([src/common/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
  42 AC_CONFIG_AUX_DIR([config])
  43 AC_CONFIG_MACRO_DIR([m4])
  44
  45 AC_CANONICAL_TARGET
  46 AC_CANONICAL_HOST
  47
  48
  49 ##                     ##
  50 ## Automake base setup ##
  51 ##                     ##
  52
  53 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  54 AM_MAINTAINER_MODE([enable])
  55
  56 # Enable silent rules by default
  57 AM_SILENT_RULES([yes])
  58
  59
  60 ##                               ##
  61 ## OS and Arch specific defaults ##
  62 ##                               ##
  63
  64 # Set os specific options
  65 AS_CASE([$host_os],
  66   [freebsd*], [AE_FEATURE_DISABLE([numa])]
  67 )
  68
  69 # Set architecture specific options
  70 AS_CASE([$host_cpu],
  71   [i[[3456]]86], [],
  72   [x86_64], [],
  73   [amd64], [],
  74   [powerpc], [],
  75   [ppc64], [],
  76   [ppc64le], [],
  77   [powerpc64], [],
  78   [powerpc64le], [],
  79   [s390], [],
  80   [s390x], [],
  81   [arm*], [AE_FEATURE_DISABLE([numa])],
  82   [aarch64*], [],
  83   [mips*], [],
  84   [tile*], [],
  85   [
  86     unsupported_arch="yes"
  87   ])
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 # Choose the C compiler
  95 AC_PROG_CC
  96 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  97 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  98
  99 # Make sure the C compiler supports C99
 100 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
 101
 102 # Enable available system extensions and LFS support
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Make sure the C compiler supports __attribute__
 107 AX_C___ATTRIBUTE__
 108 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 109   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 110
 111 # Make sure we have pthread support
 112 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 113
 114 # Make sure the C compiler supports weak symbols
 115 AX_SYS_WEAK_ALIAS
 116 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
 117   [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_C_TYPEOF
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_INT8_T
 126 AC_TYPE_MODE_T
 127 AC_TYPE_OFF_T
 128 AC_TYPE_PID_T
 129 AC_TYPE_SIZE_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UID_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136 AC_CHECK_TYPES([ptrdiff_t])
 137
 138 # Detect warning flags supported by the C compiler and append them to
 139 # WARN_CFLAGS.
 140 m4_define([WARN_FLAGS_LIST], [ dnl
 141   -Wall dnl
 142   -Wextra dnl
 143   -Wmissing-prototypes dnl
 144   -Wmissing-declarations dnl
 145   -Wnull-dereference dnl
 146   -Wundef dnl
 147   -Wshadow dnl
 148   -Wjump-misses-init dnl
 149   -Wsuggest-attribute=format dnl
 150   -Wtautological-constant-out-of-range-compare dnl
 151   -Wnested-externs dnl
 152   -Wwrite-strings dnl
 153   -Wformat=2 dnl
 154   -Wstrict-aliasing dnl
 155   -Wmissing-noreturn dnl
 156   -Winit-self dnl
 157   -Wduplicated-cond dnl
 158   -Wduplicated-branches dnl
 159   -Wlogical-op dnl
 160   dnl These would require reworking the tracepoint macros
 161   dnl-Wredundant-decls dnl
 162   -Wno-sign-compare dnl
 163   -Wno-missing-field-initializers dnl
 164   -Wno-null-dereference dnl
 165   -Wno-gnu dnl Disable warnings for GNU extensions on Clang
 166 ])
 167
 168 # Pass -Werror as an extra flag during the test: this is needed to make the
 169 # -Wunknown-warning-option diagnostic fatal with clang.
 170 AC_LANG_PUSH([C])
 171 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
 172 AC_LANG_POP([C])
 173
 174 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 175 # written in such a way that it triggers warnings with the following warning
 176 # flags.  So they would always end up disabled if we put them there, because
 177 # the test program would not build.
 178 #
 179 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 180 # Clang >= 3.3 (required by the project) and are only valid for C code.
 181 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 182
 183 # Disable 'strict aliasing' if the compiler supports it.
 184 AC_LANG_PUSH([C])
 185 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 186 AC_LANG_POP([C])
 187
 188
 189 ##                     ##
 190 ## C++ compiler checks ##
 191 ##                     ##
 192
 193 # Find an optional C++11 compiler without GNU extensions (-std=c++11)
 194 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 195
 196 AS_IF([test "$HAVE_CXX11" = "1"], [
 197   # Pass -Werror as an extra flag during the test: this is needed to make the
 198   # -Wunknown-warning-option diagnostic fatal with clang.
 199   AC_LANG_PUSH([C++])
 200   AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST -Wno-undef -Wno-duplicated-branches], [WARN_CXXFLAGS], [-Werror])
 201   AC_LANG_POP([C++])
 202 ])
 203
 204
 205 ##               ##
 206 ## Header checks ##
 207 ##               ##
 208
 209 AC_HEADER_STDBOOL
 210 AC_CHECK_HEADERS([ \
 211   arpa/inet.h \
 212   dlfcn.h \
 213   fcntl.h \
 214   float.h \
 215   limits.h \
 216   linux/perf_event.h \
 217   locale.h \
 218   stddef.h \
 219   sys/socket.h \
 220   sys/time.h \
 221   wchar.h \
 222 ])
 223
 224 # Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
 225 AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
 226   AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
 227 ])
 228
 229
 230 ##                 ##
 231 ## Programs checks ##
 232 ##                 ##
 233
 234 AM_PROG_AR
 235 AC_PROG_SED
 236 AC_PROG_GREP
 237 AC_PROG_LN_S
 238 AC_PROG_MKDIR_P
 239 AC_PROG_MAKE_SET
 240 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 241 AC_CHECK_PROGS([CMAKE], [cmake])
 242 AC_CHECK_PROGS([FOLD], [fold])
 243 AC_CHECK_PROGS([XMLTO], [xmlto])
 244
 245 AM_PATH_PYTHON([2.7], [], [PYTHON=""])
 246
 247 # Initialize and configure libtool
 248 LT_INIT([disable-static])
 249
 250
 251 ##                ##
 252 ## Library checks ##
 253 ##                ##
 254
 255 AC_FUNC_CHOWN
 256 AC_FUNC_FORK
 257 AC_FUNC_MMAP
 258 AC_FUNC_STRERROR_R
 259 AC_FUNC_STRNLEN
 260 AC_CHECK_FUNCS([ \
 261   atexit \
 262   clock_gettime \
 263   ftruncate \
 264   getpagesize \
 265   gettid \
 266   gettimeofday \
 267   localeconv \
 268   memchr \
 269   memmove \
 270   memset \
 271   mkdir \
 272   munmap \
 273   realpath \
 274   sched_getcpu \
 275   socket \
 276   strchr \
 277   strdup \
 278   strerror \
 279   strtol \
 280   strtoul \
 281   sysconf \
 282 ])
 283
 284 # AC_FUNC_MALLOC causes problems when cross-compiling.
 285 #AC_FUNC_MALLOC
 286 #AC_FUNC_REALLOC
 287
 288 # Check for pthread_setname_np and its signature
 289 LTTNG_PTHREAD_SETNAME_NP
 290 LTTNG_PTHREAD_GETNAME_NP
 291
 292 # Check dor dlopen() in -ldl or -lc
 293 AC_CHECK_LIB([dl], [dlopen], [
 294   libdl_name=dl
 295   DL_LIBS="-ldl"
 296 ], [
 297   # dlopen not found in libdl, check in libc
 298   AC_CHECK_LIB([c], [dlopen], [
 299     libdl_name=c
 300     DL_LIBS="-lc"
 301   ], [
 302     AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 303   ])
 304 ])
 305 AC_SUBST(DL_LIBS)
 306
 307 # Check if libdl has dlmopen()
 308 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 309   AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
 310 ])
 311
 312 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 313 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 314
 315
 316 ##                 ##
 317 ## User variables  ##
 318 ##                 ##
 319
 320 # Additional variables captured during ./configure
 321
 322 AC_ARG_VAR([CLASSPATH], [Java class path])
 323
 324
 325 ##                              ##
 326 ## Optionnal features selection ##
 327 ##                              ##
 328
 329 # numa integration
 330 # Enabled by default, except on some platforms
 331 AE_FEATURE_DEFAULT_ENABLE
 332 AE_FEATURE([numa],[disable NUMA support])
 333
 334 # Java JNI interface library
 335 # Disabled by default
 336 AE_FEATURE_DEFAULT_DISABLE
 337 AE_FEATURE([jni-interface], [build JNI interface between C and Java])
 338
 339 # Build the Java Logging API agent
 340 # Disabled by default
 341 AE_FEATURE_DEFAULT_DISABLE
 342 AE_FEATURE([java-agent-jul],[build the LTTng UST Java agent with JUL support])
 343
 344 # Build the Java Log4j 1.x agent
 345 # Disabled by default
 346 AE_FEATURE_DEFAULT_DISABLE
 347 AE_FEATURE([java-agent-log4j],[build the LTTng UST Java agent with Log4j 1.x support])
 348
 349 # Build the Java Log4j 2.x agent
 350 # Disabled by default
 351 AE_FEATURE_DEFAULT_DISABLE
 352 AE_FEATURE([java-agent-log4j2],[build the LTTng UST Java agent with Log4j 2.x support])
 353
 354 # Build both Java agents
 355 # Disabled by default
 356 AE_FEATURE_DEFAULT_DISABLE
 357 AE_FEATURE([java-agent-all],[build the LTTng UST Java agent with all supported backends])
 358
 359 # Build the Python agent
 360 # Disabled by default
 361 AE_FEATURE_DEFAULT_DISABLE
 362 AE_FEATURE([python-agent],[build the LTTng UST Python agent])
 363
 364 # Build the examples
 365 # Disabled by default
 366 AE_FEATURE_DEFAULT_ENABLE
 367 AE_FEATURE([examples],[Do not build and install examples])
 368
 369 # Man pages
 370 # Enabled by default
 371 AE_FEATURE_DEFAULT_ENABLE
 372 AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball)])
 373
 374 # Systemtap sdt.h integration
 375 # Disabled by default
 376 AC_ARG_WITH([sdt],
 377   [AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])]
 378 )
 379
 380 # Override the default runtime directory
 381 AC_ARG_WITH([lttng-system-rundir], [
 382 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 383 ], [
 384   lttng_system_rundir="$withval"
 385 ], [
 386   lttng_system_rundir="/var/run/lttng"
 387 ])
 388
 389 # Add the java command line arguments like '--wit-java-prefix'
 390 AX_JAVA_OPTIONS
 391
 392
 393 ##                                          ##
 394 ## Check for conflicting features selection ##
 395 ##                                          ##
 396
 397 AE_IF_FEATURE_DISABLED([shared], [
 398   AC_MSG_ERROR(LTTng-UST requires shared libraries to be enabled)
 399 ])
 400
 401 AE_IF_FEATURE_ENABLED([java-agent-all], [
 402   AE_FEATURE_ENABLE([java-agent-jul])
 403   AE_FEATURE_ENABLE([java-agent-log4j])
 404   # This backport to a stable branch requires the explicit use of
 405   # '--enable-java-agent-log4j2' to avoid introducing a new dependency in
 406   # an existing configuration.
 407   dnl AE_FEATURE_ENABLE([java-agent-lkog4j2])
 408 ])
 409
 410
 411 ##                                          ##
 412 ## Check for optional features dependencies ##
 413 ##                                          ##
 414
 415 # The numa integration requires libnuma
 416 AE_IF_FEATURE_ENABLED([numa], [
 417   AC_CHECK_LIB([numa], [numa_available], [
 418     AC_DEFINE([HAVE_LIBNUMA], [1], [Define to 1 if libnuma is available.])
 419   ], [
 420     AC_MSG_ERROR([dnl
 421 libnuma is not available. Please either install it (e.g. libnuma-dev) or use
 422 [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure
 423 argument to disable NUMA support.
 424     ])
 425   ])
 426 ])
 427
 428 # The JNI interface and Java Agents require a working Java JDK
 429 AS_IF([AE_IS_FEATURE_ENABLED([jni-interface]) || AE_IS_FEATURE_ENABLED([java-agent-jul]) || \
 430     AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2])], [
 431   AX_PROG_JAVAC
 432   AX_PROG_JAVA
 433   AX_PROG_JAR
 434
 435   # Get the CPPFLAGS required to build jni libaries
 436   AX_JNI_INCLUDE_DIR
 437   for jni_include_dir in $JNI_INCLUDE_DIRS; do
 438     JNI_CPPFLAGS="$JNI_CPPFLAGS -I$jni_include_dir"
 439   done
 440
 441   # Check for javah and jni.h
 442   saved_CPPFLAGS="$CPPFLAGS"
 443   CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 444   AX_PROG_JAVAH
 445   CPPFLAGS="$saved_CPPFLAGS"
 446 ])
 447
 448 # The log4j 1.x agent requires the log4j jar in the classpath
 449 AE_IF_FEATURE_ENABLED([java-agent-log4j], [
 450   AX_CHECK_CLASS([org.apache.log4j.Logger])
 451   AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 452     AC_MSG_ERROR([dnl
 453 The UST Java agent support for log4j was requested but the Log4j classes were
 454 not found. Please specify the location of the Log4j jar via the Java CLASSPATH
 455 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j.jar"
 456
 457 Current CLASSPATH: "$CLASSPATH"
 458     ])
 459   ])
 460 ])
 461
 462 # The log4j 2.x agent requires the log4j core and api jars in the classpath
 463 AE_IF_FEATURE_ENABLED([java-agent-log4j2], [
 464   AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 465   AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 466   AS_IF([test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"], [
 467     AC_MSG_ERROR([dnl
 468 The UST Java agent support for log4j was requested but the Log4j classes were
 469 not found. Please specify the location of the Log4j API and core 2.x jars via the Java CLASSPATH
 470 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"
 471
 472 Current CLASSPATH: "$CLASSPATH"
 473     ])
 474   ])
 475 ])
 476
 477 # The python agent requires a python interpreter
 478 AE_IF_FEATURE_ENABLED([python-agent], [
 479   AS_IF([test "x$PYTHON" = "x"], [
 480     AC_MSG_ERROR([dnl
 481 Cannot find a suitable python interpreter. You can override it with the PYTHON
 482 environment variable.
 483     ])
 484   ])
 485
 486   AX_COMPARE_VERSION(["$PYTHON_VERSION"], [ge], ["3.12"], [
 487     have_python_312_or_greater=yes
 488     AC_MSG_CHECKING([for python setuptools])
 489     AS_IF(["$PYTHON" -c "import setuptools" 2>/dev/null], [
 490       AC_MSG_RESULT([yes])
 491     ], [
 492       AC_MSG_RESULT([no])
 493       AC_MSG_ERROR([Python >= 3.12 removed 'distutils', the 'setuptools' module needs to be installed for the selected interpreter.])
 494     ])
 495   ])
 496 ])
 497
 498 # Check for asciidoc and xmlto if we enabled building the man pages.
 499 AE_IF_FEATURE_ENABLED([man-pages], [
 500   AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 501     AE_IF_IN_GIT_REPO([
 502       # This is an error because we're in the Git repo, which
 503       # means the man pages are not already generated for us,
 504       # thus asciidoc/xmlto are required because we were asked
 505       # to build the man pages.
 506       AC_MSG_ERROR([dnl
 507 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 508 --disable-man-pages to disable building the man pages, in which case
 509 they will not be installed.
 510       ])
 511     ], [
 512       # Only warn here: since we're in the tarball, the man
 513       # pages should already be generated at this point, thus
 514       # asciidoc/xmlto are not strictly required.
 515       warn_prebuilt_man_pages=yes
 516     ])
 517   ], [
 518     have_asciidoc_xmlto=yes
 519   ])
 520 ])
 521
 522 AS_IF([test "x$with_sdt" = "xyes"], [
 523   AC_MSG_CHECKING([STAP_PROBEV()])
 524   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 525     #define SDT_USE_VARIADIC
 526     #include <sys/sdt.h>
 527     void fct(void)
 528     {
 529       STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 530     }
 531   ]])], [
 532     AC_MSG_RESULT([yes])
 533     AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1], [SystemTap integration via sdt.h])
 534   ], [
 535     AC_MSG_RESULT([no])
 536     AC_MSG_ERROR([dnl
 537 The sdt.h integration was requested but the STAP_PROBEV define cannot be used.
 538 Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify
 539 a non-standard path to sys/sdt.h
 540     ])
 541   ])
 542 ])
 543
 544
 545 ##                                                                    ##
 546 ## Set defines for optional features conditionnals in the source code ##
 547 ##                                                                    ##
 548
 549 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], [LTTng system runtime directory])
 550
 551 # Defined in include/lttng/ust-version.h
 552 AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
 553 AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
 554 AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
 555 AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
 556 AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
 557 AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
 558
 559
 560 ##                                                                          ##
 561 ## Set automake variables for optional feature conditionnals in Makefile.am ##
 562 ##                                                                          ##
 563
 564 AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([examples]))
 565 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
 566 AM_CONDITIONAL([ENABLE_JAVA_AGENT], AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 567 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], AE_IS_FEATURE_ENABLED([java-agent-jul]))
 568 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], AE_IS_FEATURE_ENABLED([java-agent-log4j]))
 569 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J2], AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 570 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J_COMMON], AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 571 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], AE_IS_FEATURE_ENABLED([jni-interface]))
 572 AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
 573 AM_CONDITIONAL([ENABLE_NUMA], AE_IS_FEATURE_ENABLED([numa]))
 574 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], AE_IS_FEATURE_ENABLED([python-agent]))
 575 AM_CONDITIONAL([ENABLE_UST_DL], [test "x$ac_cv_have_decl_RTLD_DI_LINKMAP" = "xyes"])
 576 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 577 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
 578 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
 579 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 580 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
 581 AM_CONDITIONAL([HAVE_PYTHON_312_OR_GREATER], [test "x$have_python_312_or_greater" = "xyes"])
 582
 583
 584 ##                                             ##
 585 ## Substitute variables for use in Makefile.am ##
 586 ##                                             ##
 587
 588 # Library versions for libtool
 589 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], ust_lib_version)
 590 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], ust_ctl_lib_version)
 591
 592 # Major soname for python-lttngust
 593 AC_SUBST([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current])
 594
 595 AM_CFLAGS="$OPT_CFLAGS $WARN_CFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 596 AC_SUBST(AM_CFLAGS)
 597
 598 AM_CXXFLAGS="$WARN_CXXFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 599 AC_SUBST(AM_CXXFLAGS)
 600
 601 # The order in which the include folders are searched is important.
 602 # The top_builddir should always be searched first in the event that a build
 603 # time generated file is included.
 604 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 605 AC_SUBST(AM_CPPFLAGS)
 606
 607 AC_SUBST(JNI_CPPFLAGS)
 608
 609
 610 ##                                     ##
 611 ## Output files generated by configure ##
 612 ##                                     ##
 613
 614 # List of files to be generated from '.in' templates by AC_OUTPUT
 615 AC_CONFIG_FILES([
 616   Makefile
 617   doc/examples/Makefile
 618   doc/Makefile
 619   doc/man/Makefile
 620   extras/Makefile
 621   include/Makefile
 622   src/common/Makefile
 623   src/lib/lttng-ust-common/Makefile
 624   src/lib/lttng-ust-ctl/Makefile
 625   src/lib/lttng-ust-cyg-profile/Makefile
 626   src/lib/lttng-ust-dl/Makefile
 627   src/lib/lttng-ust-fd/Makefile
 628   src/lib/lttng-ust-fork/Makefile
 629   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 630   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 631   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 632   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 633   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j2/Makefile
 634   src/lib/lttng-ust-java-agent/java/Makefile
 635   src/lib/lttng-ust-java-agent/jni/common/Makefile
 636   src/lib/lttng-ust-java-agent/jni/jul/Makefile
 637   src/lib/lttng-ust-java-agent/jni/log4j/Makefile
 638   src/lib/lttng-ust-java-agent/jni/Makefile
 639   src/lib/lttng-ust-java-agent/Makefile
 640   src/lib/lttng-ust-java/Makefile
 641   src/lib/lttng-ust-libc-wrapper/Makefile
 642   src/lib/lttng-ust-pthread-wrapper/Makefile
 643   src/lib/lttng-ust-tracepoint/Makefile
 644   src/lib/lttng-ust/Makefile
 645   src/lib/lttng-ust-python-agent/Makefile
 646   src/lib/Makefile
 647   src/lib/lttng-ust-ctl.pc
 648   src/lib/lttng-ust.pc
 649   src/Makefile
 650   src/python-lttngust/lttngust/version.py
 651   src/python-lttngust/Makefile
 652   src/python-lttngust/setup.py
 653   tests/benchmark/Makefile
 654   tests/compile/api0/ctf-types/Makefile
 655   tests/compile/api0/hello.cxx/Makefile
 656   tests/compile/api0/hello/Makefile
 657   tests/compile/api0/hello-many/Makefile
 658   tests/compile/api0/Makefile
 659   tests/compile/api0/same_line_tracepoint/Makefile
 660   tests/compile/api1/ust-fields/Makefile
 661   tests/compile/api1/hello.cxx/Makefile
 662   tests/compile/api1/hello/Makefile
 663   tests/compile/api1/hello-many/Makefile
 664   tests/compile/api1/Makefile
 665   tests/compile/api1/same_line_tracepoint/Makefile
 666   tests/compile/api1/test-app-ctx/Makefile
 667   tests/compile/Makefile
 668   tests/Makefile
 669   tests/regression/abi0-conflict/Makefile
 670   tests/regression/Makefile
 671   tests/unit/gcc-weak-hidden/Makefile
 672   tests/unit/libcommon/Makefile
 673   tests/unit/libmsgpack/Makefile
 674   tests/unit/libringbuffer/Makefile
 675   tests/unit/Makefile
 676   tests/unit/pthread_name/Makefile
 677   tests/unit/snprintf/Makefile
 678   tests/unit/ust-elf/Makefile
 679   tests/unit/ust-error/Makefile
 680   tests/unit/ust-utils/Makefile
 681   tests/utils/Makefile
 682   tools/Makefile
 683 ])
 684
 685 AC_OUTPUT
 686
 687
 688 ##                                    ##
 689 ## Mini-report on what will be built. ##
 690 ##                                    ##
 691
 692 PPRINT_INIT
 693 PPRINT_SET_INDENT(1)
 694 PPRINT_SET_TS(38)
 695
 696 AS_ECHO
 697 AS_IF([test -n "ust_version_name"], [
 698   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
 699 ], [
 700   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
 701 ])
 702
 703 AS_ECHO
 704
 705 AS_IF([test -n "ust_version_description"], [
 706   AS_IF([test -n "$FOLD"], [
 707     AS_ECHO(["ust_version_description"]) | $FOLD -s
 708   ], [
 709     AS_ECHO(["ust_version_description"])
 710   ])
 711   AS_ECHO
 712 ])
 713
 714 PPRINT_SUBTITLE([System])
 715
 716 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 717
 718 AS_IF([test "x$unsupported_arch" = "xyes"],[
 719        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 720 ])
 721
 722 AS_ECHO
 723 PPRINT_SUBTITLE([Features])
 724 PPRINT_SET_INDENT(1)
 725
 726 test "x$with_sdt" = "xyes" && value=1 || value=0
 727 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 728
 729 AE_IS_FEATURE_ENABLED([java-agent-jul]) && value=1 || value=0
 730 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 731
 732 AE_IS_FEATURE_ENABLED([java-agent-log4j]) && value=1 || value=0
 733 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 1.x support)], $value, [use --enable-java-agent-log4j])
 734
 735 AE_IS_FEATURE_ENABLED([java-agent-log4j2]) && value=1 || value=0
 736 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 2.x support)], $value, [use --enable-java-agent-log4j2])
 737
 738 AE_IS_FEATURE_ENABLED([jni-interface]) && value=1 || value=0
 739 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 740
 741 AE_IS_FEATURE_ENABLED([python-agent]) && value=1 || value=0
 742 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 743
 744 test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
 745 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 746
 747 AE_IS_FEATURE_ENABLED([numa]) && value=1 || value=0
 748 PPRINT_PROP_BOOL([NUMA], $value)
 749
 750 AS_ECHO
 751 PPRINT_SET_INDENT(0)
 752
 753 AE_IS_FEATURE_ENABLED([examples]) && value=1 || value=0
 754 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 755
 756 # man pages build enabled/disabled
 757 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 758
 759 AE_IF_FEATURE_ENABLED([man-pages], [
 760   AE_IF_IN_GIT_REPO([
 761     PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 762   ], [
 763     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 764       PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 765     ], [
 766       PPRINT_PROP_STRING([build_man_pages_msg],
 767         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 768         $PPRINT_COLOR_SUBTITLE)
 769     ])
 770   ])
 771 ], [
 772   PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 773 ])
 774
 775 m4_popdef([build_man_pages_msg])
 776
 777 PPRINT_SET_INDENT(1)
 778
 779 report_bindir="`eval eval echo $bindir`"
 780 report_libdir="`eval eval echo $libdir`"
 781
 782 # Print the bindir and libdir this `make install' will install into.
 783 AS_ECHO
 784 PPRINT_SUBTITLE([Install directories])
 785 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 786 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 787
 788 AS_ECHO
 789 PPRINT_SUBTITLE([System directories])
 790
 791 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 792
 793 PPRINT_SET_INDENT(0)
 794
 795 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 796   AS_ECHO
 797   PPRINT_WARN([dnl
 798 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 799
 800 Note that the man pages are already built in this distribution tarball,
 801 therefore asciidoc and xmlto are only needed if you intend to modify
 802 their sources.
 803
 804 Use --disable-man-pages to completely disable building and installing
 805 the man pages.])
 806 ])
 807
 808 # vim: shiftwidth=2 softtabstop=2 expandtab