[lttng-ust.git] / configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_INIT([lttng-ust],[2.4.0],[mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
# This is the library version of liblttng-ust.
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

# This is the library version of liblttng-ust-ctl, used internally by
# liblttng-ust, lttng-sessiond, and lttng-consumerd.
AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
AM_MAINTAINER_MODE([enable])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])

# Compute minor/major/patchlevel version numbers
AC_PROG_SED
major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
AC_SUBST([MAJOR_VERSION], [$major_version])
AC_SUBST([MINOR_VERSION], [$minor_version])
AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])

version_name="Époque Opaque"
version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."

AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])

AC_PROG_GREP
# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
AC_ARG_ENABLE(libtool-linkdep-fixup,
	AS_HELP_STRING([--disable-libtool-linkdep-fixup],
			[disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
	libtool_fixup=$enableval,
	libtool_fixup=yes)

AS_IF([test "x$libtool_fixup" = "xyes"],
	    [
	    libtool_m4="$srcdir/config/libtool.m4"
	    libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
	    AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	    libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
	    AS_IF([test $libtool_flag_pattern_count -ne 0],
	    [
		  AC_MSG_RESULT([$libtool_flag_pattern_count])
		  AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
		  sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
		  ],
		  [
		  AC_MSG_RESULT([none])
		  ])
	    ])

AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_MAKE_SET
LT_INIT

# rw_PROG_CXX_WORKS
# Check whether the C++ compiler works.
AC_CACHE_CHECK([whether the C++ compiler works],
		[rw_cv_prog_cxx_works],
		[AC_LANG_PUSH([C++])
		AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
				[check_cxx_designated_initializers=yes],
				[rw_cv_prog_cxx_works=no])
		if test "$check_cxx_designated_initializers" = "yes"; then
			AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				struct foo { int a; int b; };
				void fct(void)
				{
					struct foo f = { .a = 0, .b = 1 };
				}
			]])],[
				rw_cv_prog_cxx_works=yes
			],[
				rw_cv_prog_cxx_works=no
			])
		fi
		AC_LANG_POP([C++])])

AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])

## Checks for libraries.
AC_CHECK_LIB([dl], [dlopen],
[
	have_libdl=yes
],
[
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen],
	[
		have_libc_dl=yes
	],
	[
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])

# Check for dlfcn.h
AC_CHECK_HEADER([dlfcn.h])
AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
	[AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
		[#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
		#include <dlfcn.h>])
	],
	[ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])

# Checks for header files.
#AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
#AC_TYPE_INT16_T
#AC_TYPE_INT32_T
#AC_TYPE_INT64_T
#AC_TYPE_INT8_T
#AC_TYPE_PID_T
#AC_TYPE_SIZE_T
#AC_TYPE_SSIZE_T
#AC_TYPE_UINT16_T
#AC_TYPE_UINT32_T
#AC_TYPE_UINT64_T
#AC_TYPE_UINT8_T
#AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

CFLAGS="-Wall $CFLAGS"

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
#include <urcu/compiler.h>
void fct(void)
{
	if (caa_likely(1)) {
	}
}
]])],[
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])

])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])

# optional linux/perf_event.h
AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])

if test "x$have_perf_event" = "xyes"; then
AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
fi

AC_MSG_CHECKING([host system alignment requirements])
case $host_cpu in
changequote(,)dnl
	i[3456]86)
changequote([,])dnl
	  ;;
	x86_64) ;;
	amd64) ;;
	powerpc) ;;
	ppc64) ;;
	powerpc64) ;;
	s390) NO_UNALIGNED_ACCESS=1 ;;
	s390x) NO_UNALIGNED_ACCESS=1 ;;
        arm*) NO_UNALIGNED_ACCESS=1 ;;
	mips*) NO_UNALIGNED_ACCESS=1 ;;
	tile*) NO_UNALIGNED_ACCESS=1 ;;
	*) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
esac
AC_MSG_RESULT([$host_cpu])

if test x$NO_UNALIGNED_ACCESS = x ; then
AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
fi

# Set compile flags to java include files if given
AC_ARG_WITH([java-jdk],
	[AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
	[JAVA_JDK=$withval],
	[JAVA_JDK=""]
)
AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
AC_SUBST([JAVA_JDK])

AS_IF([test $JAVA_JDK],[
	AS_IF([test -d $JAVA_JDK],[
                AC_MSG_RESULT([using Java includes in $JAVA_SDK])
                SUBDIRS=`find $JAVA_JDK/include -type d`
		CPPFLAGS+=" "
                CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
		CPPFLAGS+=" "
        ],[
                AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
        ])
])

# Check for JNI header files if requested
AC_ARG_WITH([jni-interface],
	[AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	[jni_interface=$withval],
	[jni_interface=no]
)

AS_IF([test "x$jni_interface" = "xyes"],[
        AC_CHECK_HEADERS([jni.h],[],[
        AC_MSG_ERROR([missing jni.h
Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
	])
])
AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])

# sdt.h integration
AC_ARG_WITH([sdt],
	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
	[with_sdt=$withval],
	[with_sdt="no"]
)

AS_IF([test "x$with_sdt" = "xyes"],[
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#define SDT_USE_VARIADIC
	#include <sys/sdt.h>
	void fct(void)
	{
		STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	}
	]])],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	],[
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

AC_MSG_CHECKING([whether shared libraries are enabled])
AS_IF([test "x$enable_shared" = "xyes"],
	[
		AC_MSG_RESULT([yes])
	],
	[
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	])

AC_ARG_WITH([lttng-system-rundir],
	AS_HELP_STRING([--with-lttng-system-rundir],
	[Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	[lttng_system_rundir="$withval"],
	[lttng_system_rundir="/var/run/lttng"])
AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	[LTTng system runtime directory])

lttnglibjavadir="${libdir}/lttng/java"
AC_SUBST(lttnglibjavadir)

AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-dl/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-jul/Makefile
	liblttng-ust-libc-wrapper/Makefile
	liblttng-ust-cyg-profile/Makefile
	tools/Makefile
	tests/Makefile
	tests/hello/Makefile
	tests/hello.cxx/Makefile
	tests/same_line_tracepoint/Makefile
	tests/snprintf/Makefile
	tests/benchmark/Makefile
	tests/utils/Makefile
	tests/java-jul/Makefile
	lttng-ust.pc
])

AC_OUTPUT

AS_ECHO()
AS_ECHO("Version name: $version_name")
AS_ECHO("$version_description")

# Report on the configuration options
AS_ECHO()
AS_ECHO("LTTng-UST will be built with the following options:")

AS_ECHO()
AS_ECHO_N("Java support (JNI): ")
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])

AS_ECHO_N("sdt.h integration:  ")
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])

AS_ECHO()
AS_ECHO("Type 'make' to compile.")
Commit	Line	Data
1304f3df PMF	1	# -- Autoconf --
	2	# Process this file with autoconf to produce a configure script.
	3
5ba5bf7f	4	AC_INIT([lttng-ust],[2.4.0],[mathieu dot desnoyers at efficios dot com])
a334646a MD	5
	6	# Following the numbering scheme proposed by libtool for the library version
	7	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
41a2a9aa	8	# This is the library version of liblttng-ust.
a334646a MD	9	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	10	# note: remember to update tracepoint.h dlopen() to match this version
	11	# number. TODO: eventually automate by exporting the major number.
	12
41a2a9aa MD	13	# This is the library version of liblttng-ust-ctl, used internally by
41a2a9aa MD	14	# liblttng-ust, lttng-sessiond, and lttng-consumerd.
76bacff6	15	AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
41a2a9aa	16
55355fa5	17	AC_CONFIG_AUX_DIR([config])
9441df61 PMF	18	AC_CANONICAL_TARGET
9441df61 PMF	19	AC_CANONICAL_HOST
50f3dba0	20	AC_CONFIG_MACRO_DIR([config])
76ceb8db	21	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
846154aa	22	AM_MAINTAINER_MODE([enable])
50f3dba0	23	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
4318ae1b	24	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
4846fadc AM	25
4846fadc AM	26	# Configuration options, which will be installed in the config.h
562c813a MD	27	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
562c813a MD	28	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
02120ddf	29	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
d58d1454	30	AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
23c8854a	31
b728d87e	32	# Compute minor/major/patchlevel version numbers
23c8854a	33	AC_PROG_SED
2694975d MD	34	major_version=$(echo AC_PACKAGE_VERSION \| sed 's/^\([[0-9]]\)\.[[0-9]]\.[[0-9]].$/\1/')
	35	minor_version=$(echo AC_PACKAGE_VERSION \| sed 's/^[[0-9]]\.\([[0-9]]\)\.[[0-9]].$/\1/')
	36	patchlevel_version=$(echo AC_PACKAGE_VERSION \| sed 's/^[[0-9]]\.[[0-9]]\.\([[0-9]]\).$/\1/')
161239e0 YB	37	AC_SUBST([MAJOR_VERSION], [$major_version])
161239e0 YB	38	AC_SUBST([MINOR_VERSION], [$minor_version])
b728d87e	39	AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
161239e0 YB	40	AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
161239e0 YB	41	AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
b728d87e	42	AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
161239e0	43
48de55ad MD	44	version_name="Époque Opaque"
48de55ad MD	45	version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
0ff43c44	46
1c59f149 MD	47	AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
1c59f149 MD	48	AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
1304f3df	49
faebb418 CB	50	AC_PROG_GREP
	51	# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
	52	AC_ARG_ENABLE(libtool-linkdep-fixup,
	53	AS_HELP_STRING([--disable-libtool-linkdep-fixup],
	54	[disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
	55	libtool_fixup=$enableval,
	56	libtool_fixup=yes)
	57
	58	AS_IF([test "x$libtool_fixup" = "xyes"],
	59	[
	60	libtool_m4="$srcdir/config/libtool.m4"
	61	libtool_flag_pattern=".link_all_deplibs\s,\s\$1\s)"
	62	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	63	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s=\sno" $libtool_m4)
	64	AS_IF([test $libtool_flag_pattern_count -ne 0],
	65	[
	66	AC_MSG_RESULT([$libtool_flag_pattern_count])
	67	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
	68	sed -i "s/\($libtool_flag_pattern\)\s=\sno/\1=unknown/g" $libtool_m4
	69	],
	70	[
	71	AC_MSG_RESULT([none])
	72	])
	73	])
	74
824a00a7 MD	75	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
824a00a7 MD	76
1304f3df PMF	77	# Checks for programs.
1304f3df PMF	78	AC_PROG_CC
6b79f035	79	AC_PROG_CXX
1304f3df	80	AC_PROG_MAKE_SET
fa1c6efe	81	LT_INIT
1304f3df	82
340f7763 SM	83	# rw_PROG_CXX_WORKS
	84	# Check whether the C++ compiler works.
	85	AC_CACHE_CHECK([whether the C++ compiler works],
	86	[rw_cv_prog_cxx_works],
	87	[AC_LANG_PUSH([C++])
	88	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
8481f7a0	89	[check_cxx_designated_initializers=yes],
340f7763	90	[rw_cv_prog_cxx_works=no])
8481f7a0 ZT	91	if test "$check_cxx_designated_initializers" = "yes"; then
	92	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	93	struct foo { int a; int b; };
	94	void fct(void)
	95	{
	96	struct foo f = { .a = 0, .b = 1 };
	97	}
	98	]])],[
	99	rw_cv_prog_cxx_works=yes
	100	],[
	101	rw_cv_prog_cxx_works=no
	102	])
	103	fi
340f7763 SM	104	AC_LANG_POP([C++])])
	105
	106	AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
	107
1304f3df	108	## Checks for libraries.
c6c454ab MD	109	AC_CHECK_LIB([dl], [dlopen],
	110	[
	111	have_libdl=yes
	112	],
	113	[
	114	#libdl not found, check for dlopen in libc.
	115	AC_CHECK_LIB([c], [dlopen],
	116	[
	117	have_libc_dl=yes
	118	],
	119	[
	120	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	121	])
	122	])
	123	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	124	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	125
e26c8207	126	AC_CHECK_LIB([pthread], [pthread_create])
1304f3df	127
f9ff7aa4 RN	128	# Check for dlfcn.h
	129	AC_CHECK_HEADER([dlfcn.h])
	130	AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
	131	[AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
	132	[#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
	133	#include <dlfcn.h>])
	134	],
	135	[ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
	136	AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
	137
1304f3df PMF	138	# Checks for header files.
	139	#AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	140
	141	# Checks for typedefs, structures, and compiler characteristics.
	142	AC_C_INLINE
	143	#AC_TYPE_INT16_T
	144	#AC_TYPE_INT32_T
	145	#AC_TYPE_INT64_T
	146	#AC_TYPE_INT8_T
	147	#AC_TYPE_PID_T
	148	#AC_TYPE_SIZE_T
	149	#AC_TYPE_SSIZE_T
	150	#AC_TYPE_UINT16_T
	151	#AC_TYPE_UINT32_T
	152	#AC_TYPE_UINT64_T
	153	#AC_TYPE_UINT8_T
	154	#AC_CHECK_TYPES([ptrdiff_t])
	155
	156	# Checks for library functions.
	157	AC_FUNC_MALLOC
e9d165be	158	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
1304f3df	159
fbae86d6 MD	160	CFLAGS="-Wall $CFLAGS"
fbae86d6 MD	161
8624c549 PMF	162	# URCU
	163
	164	# urcu - check if we just find the headers it out of the box.
135987a5	165	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
cacb7fbe	166	This error can also occur when the liburcu package's configure script has not been run.])])
bf956ec0 MD	167
	168	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	169	# Part of Userspace RCU library 0.7.2 or better.
	170	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	171	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
8624c549	172
b5a3dfa5	173	AC_MSG_CHECKING([caa_likely()])
31b07350	174	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b5a3dfa5	175	#include <urcu/compiler.h>
b5a3dfa5 MD	176	void fct(void)
	177	{
	178	if (caa_likely(1)) {
	179	}
	180	}
727bb6cb	181	]])],[
b5a3dfa5	182	AC_MSG_RESULT([yes])
727bb6cb	183	],[
b5a3dfa5 MD	184	AC_MSG_RESULT([no])
b5a3dfa5 MD	185	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
727bb6cb MD	186
727bb6cb MD	187	])
b5a3dfa5	188
8624c549	189	# urcu - check that URCU lib is available to compilation
cfa0520d	190	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
e3073410	191
a6830b14 MD	192	# urcu - check that URCU lib is at least version 0.6
a6830b14 MD	193	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
e3073410	194
d58d1454 MD	195	# optional linux/perf_event.h
	196	AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
	197	AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
	198
	199	if test "x$have_perf_event" = "xyes"; then
	200	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
	201	fi
	202
dca6e79f	203	AC_MSG_CHECKING([host system alignment requirements])
8fb0c941	204	case $host_cpu in
8c98245f PA	205	changequote(,)dnl
	206	i[3456]86)
	207	changequote([,])dnl
8c98245f	208	;;
dca6e79f MD	209	x86_64) ;;
	210	amd64) ;;
	211	powerpc) ;;
	212	ppc64) ;;
	213	powerpc64) ;;
	214	s390) NO_UNALIGNED_ACCESS=1 ;;
	215	s390x) NO_UNALIGNED_ACCESS=1 ;;
	216	arm*) NO_UNALIGNED_ACCESS=1 ;;
bdac72fd SM	217	mips*) NO_UNALIGNED_ACCESS=1 ;;
bdac72fd SM	218	tile*) NO_UNALIGNED_ACCESS=1 ;;
dca6e79f	219	*) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
9441df61	220	esac
f039c6b0	221	AC_MSG_RESULT([$host_cpu])
ed452f03	222
2699970a	223	if test x$NO_UNALIGNED_ACCESS = x ; then
562c813a	224	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
2699970a JW	225	fi
2699970a JW	226
2b6f8df9	227	# Set compile flags to java include files if given
b2263155 AM	228	AC_ARG_WITH([java-jdk],
	229	[AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
	230	[JAVA_JDK=$withval],
	231	[JAVA_JDK=""]
	232	)
43e5396b DG	233	AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
	234	AC_SUBST([JAVA_JDK])
	235
b2263155 AM	236	AS_IF([test $JAVA_JDK],[
	237	AS_IF([test -d $JAVA_JDK],[
	238	AC_MSG_RESULT([using Java includes in $JAVA_SDK])
	239	SUBDIRS=`find $JAVA_JDK/include -type d`
135987a5 MD	240	CPPFLAGS+=" "
	241	CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
	242	CPPFLAGS+=" "
b2263155 AM	243	],[
	244	AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
	245	])
	246	])
2b6f8df9 MD	247
2b6f8df9 MD	248	# Check for JNI header files if requested
b2263155 AM	249	AC_ARG_WITH([jni-interface],
	250	[AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	251	[jni_interface=$withval],
	252	[jni_interface=no]
	253	)
2b6f8df9	254
b2263155 AM	255	AS_IF([test "x$jni_interface" = "xyes"],[
	256	AC_CHECK_HEADERS([jni.h],[],[
	257	AC_MSG_ERROR([missing jni.h
	258	Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
	259	Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
	260	])
	261	])
	262	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
2b6f8df9	263
4846fadc AM	264	# sdt.h integration
4846fadc AM	265	AC_ARG_WITH([sdt],
02120ddf	266	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
4846fadc AM	267	[with_sdt=$withval],
	268	[with_sdt="no"]
	269	)
	270
	271	AS_IF([test "x$with_sdt" = "xyes"],[
491f30fe MD	272	AC_MSG_CHECKING([STAP_PROBEV()])
	273	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	274	#define SDT_USE_VARIADIC
	275	#include <sys/sdt.h>
	276	void fct(void)
	277	{
	278	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	279	}
	280	]])],[
	281	AC_MSG_RESULT([yes])
562c813a	282	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
4846fadc	283	],[
491f30fe	284	AC_MSG_RESULT([no])
135987a5	285	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
4846fadc AM	286	])
	287	])
	288
ccb19569 MD	289	AC_MSG_CHECKING([whether shared libraries are enabled])
	290	AS_IF([test "x$enable_shared" = "xyes"],
	291	[
	292	AC_MSG_RESULT([yes])
	293	],
	294	[
	295	AC_MSG_RESULT([no])
	296	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	297	])
	298
751d4e91 MD	299	AC_ARG_WITH([lttng-system-rundir],
	300	AS_HELP_STRING([--with-lttng-system-rundir],
	301	[Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	302	[lttng_system_rundir="$withval"],
	303	[lttng_system_rundir="/var/run/lttng"])
	304	AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	305	[LTTng system runtime directory])
	306
6490eba0 MD	307	lttnglibjavadir="${libdir}/lttng/java"
	308	AC_SUBST(lttnglibjavadir)
	309
dcb6ba25	310	AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
2b90f1d3 JG	311	AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
2b90f1d3 JG	312
55355fa5 JB	313	AC_CONFIG_FILES([
55355fa5 JB	314	Makefile
7ccf75d3 MD	315	doc/Makefile
7ccf75d3 MD	316	doc/examples/Makefile
69400ac4	317	include/Makefile
b728d87e	318	include/lttng/ust-version.h
69400ac4	319	snprintf/Makefile
4931a13e	320	libringbuffer/Makefile
69400ac4 MD	321	liblttng-ust-comm/Makefile
	322	liblttng-ust/Makefile
	323	liblttng-ust-ctl/Makefile
	324	liblttng-ust-fork/Makefile
b13d93c2	325	liblttng-ust-dl/Makefile
69400ac4	326	liblttng-ust-java/Makefile
43e5396b	327	liblttng-ust-jul/Makefile
476037d9	328	liblttng-ust-libc-wrapper/Makefile
70d654f2	329	liblttng-ust-cyg-profile/Makefile
b25c5b37	330	tools/Makefile
6dd969b5 PMF	331	tests/Makefile
6dd969b5 PMF	332	tests/hello/Makefile
6b79f035	333	tests/hello.cxx/Makefile
90c09854	334	tests/same_line_tracepoint/Makefile
d23b20e9	335	tests/snprintf/Makefile
a44af49d	336	tests/benchmark/Makefile
9a4b88ff	337	tests/utils/Makefile
43e5396b	338	tests/java-jul/Makefile
74a6d87b	339	lttng-ust.pc
55355fa5	340	])
1f9eff07	341
1304f3df	342	AC_OUTPUT
1f9eff07	343
649282a8 MD	344	AS_ECHO()
	345	AS_ECHO("Version name: $version_name")
	346	AS_ECHO("$version_description")
	347
1f9eff07 AM	348	# Report on the configuration options
	349	AS_ECHO()
	350	AS_ECHO("LTTng-UST will be built with the following options:")
1f9eff07 AM	351
	352	AS_ECHO()
	353	AS_ECHO_N("Java support (JNI): ")
	354	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
	355
	356	AS_ECHO_N("sdt.h integration: ")
	357	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
	358
	359	AS_ECHO()
	360	AS_ECHO("Type 'make' to compile.")
	361