[lttng-ust.git] / configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_INIT([lttng-ust],[2.0.1],[mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])

# Compute minor/major/patchlevel version numbers
AC_PROG_SED
major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
AC_SUBST([MAJOR_VERSION], [$major_version])
AC_SUBST([MINOR_VERSION], [$minor_version])
AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])

version_name="Annedd'ale"
version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_MAKE_SET
LT_INIT

## Checks for libraries.
AC_CHECK_LIB([dl], [dlopen],
[
	have_libdl=yes
],
[
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen],
	[
		have_libc_dl=yes
	],
	[
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])

# Check for libuuid
AC_CHECK_LIB([uuid], [uuid_generate],
[
	AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
	have_libuuid=yes
],
[
	# libuuid not found, check for uuid_create in libc.
	AC_CHECK_LIB([c], [uuid_create],
	[
		AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
		have_libc_uuid=yes
	],
	[
		AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
	])
]
)
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])

# Checks for header files.
#AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
#AC_TYPE_INT16_T
#AC_TYPE_INT32_T
#AC_TYPE_INT64_T
#AC_TYPE_INT8_T
#AC_TYPE_PID_T
#AC_TYPE_SIZE_T
#AC_TYPE_SSIZE_T
#AC_TYPE_UINT16_T
#AC_TYPE_UINT32_T
#AC_TYPE_UINT64_T
#AC_TYPE_UINT8_T
#AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

CFLAGS="-Wall $CFLAGS"

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
#include <urcu/compiler.h>
void fct(void)
{
	if (caa_likely(1)) {
	}
}
]])],[
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])

])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])


# Check for various supplementary host information (beyond the
# triplet) which might affect the library format choices.  E.g., we
# can be building with `i686-unknown-linux-gnu-gcc -m64'

case "${host}" in
changequote(,)dnl
  i[34567]86-*-linux*)
changequote([,])dnl
    AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
                    [save_CPPFLAGS="$CPPFLAGS"
                    CPPFLAGS="$CPPFLAGS $CFLAGS"
                    AC_EGREP_CPP([got it], [
#if __x86_64__
got it
#endif
                 ], [ust_cv_i386_is_x86_64=yes],
                    [ust_cv_i386_is_x86_64=no])
                    CPPFLAGS="$save_CPPFLAGS"])
    ;;
esac

AC_MSG_CHECKING([library format for the host system])
case $host_cpu in
changequote(,)dnl
	i[3456]86)
changequote([,])dnl
	  if test "$ust_cv_i386_is_x86_64" = yes ; then
	     LIBFORMAT="elf64-x86-64"
	  else
	     LIBFORMAT="elf32-i386"
	  fi
	  ;;
	x86_64) LIBFORMAT="elf64-x86-64" ;;
	amd64) LIBFORMAT="elf64-x86-64" ;;
	powerpc) LIBFORMAT="elf32-powerpc" ;;
	ppc64) LIBFORMAT="elf64-powerpc" ;;
	powerpc64) LIBFORMAT="elf64-powerpc" ;;
	s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
	s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
        armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
	arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
	mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
	*) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
esac
AC_SUBST(LIBFORMAT)
AC_MSG_RESULT($LIBFORMAT)

if test "x$host_cpu" = "xarm" ; then
AC_MSG_CHECKING([checking for armv5])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
#ifndef __ARM_ARCH_5TEJ__
#error "no arm5 here"
#endif
]])],[
	AC_MSG_RESULT([yes])
	NO_UNALIGNED_ACCESS=1

],[
	AC_MSG_RESULT([no])

])
fi
if test x$NO_UNALIGNED_ACCESS = x ; then
AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
fi

# Set compile flags to java include files if given
AC_ARG_WITH([java-jdk],
	[AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
	[JAVA_JDK=$withval],
	[JAVA_JDK=""]
)
AS_IF([test $JAVA_JDK],[
	AS_IF([test -d $JAVA_JDK],[
                AC_MSG_RESULT([using Java includes in $JAVA_SDK])
                SUBDIRS=`find $JAVA_JDK/include -type d`
		CPPFLAGS+=" "
                CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
		CPPFLAGS+=" "
        ],[
                AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
        ])
])

# Check for JNI header files if requested
AC_ARG_WITH([jni-interface],
	[AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	[jni_interface=$withval],
	[jni_interface=no]
)

AS_IF([test "x$jni_interface" = "xyes"],[
        AC_CHECK_HEADERS([jni.h],[],[
        AC_MSG_ERROR([missing jni.h
Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
	])
])
AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])

# sdt.h integration
AC_ARG_WITH([sdt],
	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
	[with_sdt=$withval],
	[with_sdt="no"]
)

AS_IF([test "x$with_sdt" = "xyes"],[
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#define SDT_USE_VARIADIC
	#include <sys/sdt.h>
	void fct(void)
	{
		STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	}
	]])],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	],[
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

#currently disabled.
	#tests/hello2/Makefile
	#tests/basic/Makefile
	#tests/simple_include/Makefile
	#tests/snprintf/Makefile
	#tests/test-nevents/Makefile
	#tests/test-libustinstr-malloc/Makefile
	#tests/dlopen/Makefile
	#tests/same_line_marker/Makefile
	#tests/trace_event/Makefile
	#tests/tracepoint/Makefile
	#tests/tracepoint/benchmark/Makefile
	#tests/register_test/Makefile
	#tests/libustctl_function_#tests/Makefile
	#tests/exit-fast/Makefile
	#tests/basic_long/Makefile

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-libc-wrapper/Makefile
	tools/Makefile
	tests/Makefile
	tests/hello/Makefile
	tests/hello-static-lib/Makefile
	tests/hello.cxx/Makefile
	tests/demo/Makefile
	tests/fork/Makefile
	tests/ust-basic-tracing/Makefile
	tests/ust-multi-test/Makefile
	lttng-ust.pc
])

AC_OUTPUT

AS_ECHO()
AS_ECHO("Version name: $version_name")
AS_ECHO("$version_description")

# Report on the configuration options
AS_ECHO()
AS_ECHO("LTTng-UST will be built with the following options:")
AS_ECHO("Library format: $LIBFORMAT")

AS_ECHO()
AS_ECHO_N("Java support (JNI): ")
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])

AS_ECHO_N("sdt.h integration:  ")
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])

AS_ECHO()
AS_ECHO("Type 'make' to compile.")
Commit	Line	Data
1304f3df PMF	1	# -- Autoconf --
	2	# Process this file with autoconf to produce a configure script.
	3
1a94cf83	4	AC_INIT([lttng-ust],[2.0.1],[mathieu dot desnoyers at efficios dot com])
a334646a MD	5
	6	# Following the numbering scheme proposed by libtool for the library version
	7	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	8	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	9	# note: remember to update tracepoint.h dlopen() to match this version
	10	# number. TODO: eventually automate by exporting the major number.
	11
55355fa5	12	AC_CONFIG_AUX_DIR([config])
9441df61 PMF	13	AC_CANONICAL_TARGET
9441df61 PMF	14	AC_CANONICAL_HOST
50f3dba0	15	AC_CONFIG_MACRO_DIR([config])
76ceb8db	16	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
50f3dba0	17	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
4318ae1b	18	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
4846fadc AM	19
4846fadc AM	20	# Configuration options, which will be installed in the config.h
562c813a MD	21	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
562c813a MD	22	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
02120ddf	23	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
23c8854a	24
b728d87e	25	# Compute minor/major/patchlevel version numbers
23c8854a	26	AC_PROG_SED
2694975d MD	27	major_version=$(echo AC_PACKAGE_VERSION \| sed 's/^\([[0-9]]\)\.[[0-9]]\.[[0-9]].$/\1/')
	28	minor_version=$(echo AC_PACKAGE_VERSION \| sed 's/^[[0-9]]\.\([[0-9]]\)\.[[0-9]].$/\1/')
	29	patchlevel_version=$(echo AC_PACKAGE_VERSION \| sed 's/^[[0-9]]\.[[0-9]]\.\([[0-9]]\).$/\1/')
161239e0 YB	30	AC_SUBST([MAJOR_VERSION], [$major_version])
161239e0 YB	31	AC_SUBST([MINOR_VERSION], [$minor_version])
b728d87e	32	AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
161239e0 YB	33	AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
161239e0 YB	34	AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
b728d87e	35	AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
161239e0	36
649282a8 MD	37	version_name="Annedd'ale"
649282a8 MD	38	version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
1c59f149 MD	39	AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
1c59f149 MD	40	AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
1304f3df PMF	41
	42	# Checks for programs.
	43	AC_PROG_CC
6b79f035	44	AC_PROG_CXX
1304f3df	45	AC_PROG_MAKE_SET
fa1c6efe	46	LT_INIT
1304f3df PMF	47
1304f3df PMF	48	## Checks for libraries.
c6c454ab MD	49	AC_CHECK_LIB([dl], [dlopen],
	50	[
	51	have_libdl=yes
	52	],
	53	[
	54	#libdl not found, check for dlopen in libc.
	55	AC_CHECK_LIB([c], [dlopen],
	56	[
	57	have_libc_dl=yes
	58	],
	59	[
	60	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	61	])
	62	])
	63	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	64	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	65
e26c8207	66	AC_CHECK_LIB([pthread], [pthread_create])
1304f3df	67
2cb76594	68	# Check for libuuid
5e8445c4 MD	69	AC_CHECK_LIB([uuid], [uuid_generate],
	70	[
	71	AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
19d8b1b3	72	have_libuuid=yes
5e8445c4 MD	73	],
	74	[
	75	# libuuid not found, check for uuid_create in libc.
	76	AC_CHECK_LIB([c], [uuid_create],
	77	[
	78	AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
19d8b1b3	79	have_libc_uuid=yes
5e8445c4 MD	80	],
5e8445c4 MD	81	[
c6c454ab	82	AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
5e8445c4 MD	83	])
5e8445c4 MD	84	]
2cb76594	85	)
19d8b1b3 MD	86	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
19d8b1b3 MD	87	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
2cb76594	88
1304f3df PMF	89	# Checks for header files.
	90	#AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	91
	92	# Checks for typedefs, structures, and compiler characteristics.
	93	AC_C_INLINE
	94	#AC_TYPE_INT16_T
	95	#AC_TYPE_INT32_T
	96	#AC_TYPE_INT64_T
	97	#AC_TYPE_INT8_T
	98	#AC_TYPE_PID_T
	99	#AC_TYPE_SIZE_T
	100	#AC_TYPE_SSIZE_T
	101	#AC_TYPE_UINT16_T
	102	#AC_TYPE_UINT32_T
	103	#AC_TYPE_UINT64_T
	104	#AC_TYPE_UINT8_T
	105	#AC_CHECK_TYPES([ptrdiff_t])
	106
	107	# Checks for library functions.
	108	AC_FUNC_MALLOC
e9d165be	109	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
1304f3df	110
fbae86d6 MD	111	CFLAGS="-Wall $CFLAGS"
fbae86d6 MD	112
8624c549 PMF	113	# URCU
	114
	115	# urcu - check if we just find the headers it out of the box.
135987a5	116	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
cacb7fbe	117	This error can also occur when the liburcu package's configure script has not been run.])])
bf956ec0 MD	118
	119	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	120	# Part of Userspace RCU library 0.7.2 or better.
	121	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	122	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
8624c549	123
b5a3dfa5	124	AC_MSG_CHECKING([caa_likely()])
31b07350	125	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b5a3dfa5	126	#include <urcu/compiler.h>
b5a3dfa5 MD	127	void fct(void)
	128	{
	129	if (caa_likely(1)) {
	130	}
	131	}
727bb6cb	132	]])],[
b5a3dfa5	133	AC_MSG_RESULT([yes])
727bb6cb	134	],[
b5a3dfa5 MD	135	AC_MSG_RESULT([no])
b5a3dfa5 MD	136	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
727bb6cb MD	137
727bb6cb MD	138	])
b5a3dfa5	139
8624c549	140	# urcu - check that URCU lib is available to compilation
cfa0520d	141	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
e3073410	142
a6830b14 MD	143	# urcu - check that URCU lib is at least version 0.6
a6830b14 MD	144	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
e3073410	145
42d054a0	146
8c98245f PA	147	# Check for various supplementary host information (beyond the
	148	# triplet) which might affect the library format choices. E.g., we
	149	# can be building with `i686-unknown-linux-gnu-gcc -m64'
	150
	151	case "${host}" in
	152	changequote(,)dnl
	153	i[34567]86--linux)
	154	changequote([,])dnl
	155	AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
	156	[save_CPPFLAGS="$CPPFLAGS"
	157	CPPFLAGS="$CPPFLAGS $CFLAGS"
	158	AC_EGREP_CPP([got it], [
	159	#if __x86_64__
	160	got it
	161	#endif
	162	], [ust_cv_i386_is_x86_64=yes],
	163	[ust_cv_i386_is_x86_64=no])
	164	CPPFLAGS="$save_CPPFLAGS"])
	165	;;
	166	esac
	167
2e06f3b5 PMF	168	AC_MSG_CHECKING([library format for the host system])
2e06f3b5 PMF	169	case $host_cpu in
8c98245f PA	170	changequote(,)dnl
	171	i[3456]86)
	172	changequote([,])dnl
	173	if test "$ust_cv_i386_is_x86_64" = yes ; then
	174	LIBFORMAT="elf64-x86-64"
	175	else
	176	LIBFORMAT="elf32-i386"
	177	fi
	178	;;
9441df61	179	x86_64) LIBFORMAT="elf64-x86-64" ;;
272d715a	180	amd64) LIBFORMAT="elf64-x86-64" ;;
6fa0d97f	181	powerpc) LIBFORMAT="elf32-powerpc" ;;
9441df61	182	ppc64) LIBFORMAT="elf64-powerpc" ;;
7af249f6	183	powerpc64) LIBFORMAT="elf64-powerpc" ;;
9937f480 MD	184	s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
9937f480 MD	185	s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
2699970a	186	armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
9937f480 MD	187	arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
9937f480 MD	188	mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
6fa0d97f	189	*) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
9441df61 PMF	190	esac
	191	AC_SUBST(LIBFORMAT)
	192	AC_MSG_RESULT($LIBFORMAT)
ed452f03	193
2699970a JW	194	if test "x$host_cpu" = "xarm" ; then
2699970a JW	195	AC_MSG_CHECKING([checking for armv5])
31b07350	196	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2699970a JW	197	#ifndef __ARM_ARCH_5TEJ__
	198	#error "no arm5 here"
	199	#endif
727bb6cb	200	]])],[
2699970a JW	201	AC_MSG_RESULT([yes])
2699970a JW	202	NO_UNALIGNED_ACCESS=1
727bb6cb MD	203
727bb6cb MD	204	],[
2699970a	205	AC_MSG_RESULT([no])
727bb6cb MD	206
727bb6cb MD	207	])
2699970a JW	208	fi
2699970a JW	209	if test x$NO_UNALIGNED_ACCESS = x ; then
562c813a	210	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
2699970a JW	211	fi
2699970a JW	212
2b6f8df9	213	# Set compile flags to java include files if given
b2263155 AM	214	AC_ARG_WITH([java-jdk],
	215	[AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
	216	[JAVA_JDK=$withval],
	217	[JAVA_JDK=""]
	218	)
	219	AS_IF([test $JAVA_JDK],[
	220	AS_IF([test -d $JAVA_JDK],[
	221	AC_MSG_RESULT([using Java includes in $JAVA_SDK])
	222	SUBDIRS=`find $JAVA_JDK/include -type d`
135987a5 MD	223	CPPFLAGS+=" "
	224	CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
	225	CPPFLAGS+=" "
b2263155 AM	226	],[
	227	AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
	228	])
	229	])
2b6f8df9 MD	230
2b6f8df9 MD	231	# Check for JNI header files if requested
b2263155 AM	232	AC_ARG_WITH([jni-interface],
	233	[AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	234	[jni_interface=$withval],
	235	[jni_interface=no]
	236	)
2b6f8df9	237
b2263155 AM	238	AS_IF([test "x$jni_interface" = "xyes"],[
	239	AC_CHECK_HEADERS([jni.h],[],[
	240	AC_MSG_ERROR([missing jni.h
	241	Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
	242	Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
	243	])
	244	])
	245	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
2b6f8df9	246
4846fadc AM	247	# sdt.h integration
4846fadc AM	248	AC_ARG_WITH([sdt],
02120ddf	249	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
4846fadc AM	250	[with_sdt=$withval],
	251	[with_sdt="no"]
	252	)
	253
	254	AS_IF([test "x$with_sdt" = "xyes"],[
491f30fe MD	255	AC_MSG_CHECKING([STAP_PROBEV()])
	256	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	257	#define SDT_USE_VARIADIC
	258	#include <sys/sdt.h>
	259	void fct(void)
	260	{
	261	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	262	}
	263	]])],[
	264	AC_MSG_RESULT([yes])
562c813a	265	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
4846fadc	266	],[
491f30fe	267	AC_MSG_RESULT([no])
135987a5	268	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
4846fadc AM	269	])
	270	])
	271
36385b6e	272	#currently disabled.
36385b6e MD	273	#tests/hello2/Makefile
	274	#tests/basic/Makefile
	275	#tests/simple_include/Makefile
	276	#tests/snprintf/Makefile
	277	#tests/test-nevents/Makefile
	278	#tests/test-libustinstr-malloc/Makefile
	279	#tests/dlopen/Makefile
	280	#tests/same_line_marker/Makefile
	281	#tests/trace_event/Makefile
	282	#tests/tracepoint/Makefile
	283	#tests/tracepoint/benchmark/Makefile
	284	#tests/register_test/Makefile
	285	#tests/libustctl_function_#tests/Makefile
	286	#tests/exit-fast/Makefile
	287	#tests/basic_long/Makefile
	288
55355fa5 JB	289	AC_CONFIG_FILES([
55355fa5 JB	290	Makefile
7ccf75d3 MD	291	doc/Makefile
7ccf75d3 MD	292	doc/examples/Makefile
69400ac4	293	include/Makefile
b728d87e	294	include/lttng/ust-version.h
69400ac4	295	snprintf/Makefile
4931a13e	296	libringbuffer/Makefile
69400ac4 MD	297	liblttng-ust-comm/Makefile
	298	liblttng-ust/Makefile
	299	liblttng-ust-ctl/Makefile
	300	liblttng-ust-fork/Makefile
	301	liblttng-ust-java/Makefile
476037d9	302	liblttng-ust-libc-wrapper/Makefile
b25c5b37	303	tools/Makefile
6dd969b5 PMF	304	tests/Makefile
6dd969b5 PMF	305	tests/hello/Makefile
246e1625	306	tests/hello-static-lib/Makefile
6b79f035	307	tests/hello.cxx/Makefile
580d134b	308	tests/demo/Makefile
36385b6e	309	tests/fork/Makefile
5810472c	310	tests/ust-basic-tracing/Makefile
f0966704	311	tests/ust-multi-test/Makefile
74a6d87b	312	lttng-ust.pc
55355fa5	313	])
1f9eff07	314
1304f3df	315	AC_OUTPUT
1f9eff07	316
649282a8 MD	317	AS_ECHO()
	318	AS_ECHO("Version name: $version_name")
	319	AS_ECHO("$version_description")
	320
1f9eff07 AM	321	# Report on the configuration options
	322	AS_ECHO()
	323	AS_ECHO("LTTng-UST will be built with the following options:")
	324	AS_ECHO("Library format: $LIBFORMAT")
	325
	326	AS_ECHO()
	327	AS_ECHO_N("Java support (JNI): ")
	328	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
	329
	330	AS_ECHO_N("sdt.h integration: ")
	331	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
	332
	333	AS_ECHO()
	334	AS_ECHO("Type 'make' to compile.")
	335