| | 1 | dnl SPDX-License-Identifier: GPL-2.0-only |
| | 2 | AC_PREREQ([2.64]) |
| | 3 | AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 4 | |
| | 5 | AC_CONFIG_HEADERS([include/config.h]) |
| | 6 | AC_CONFIG_AUX_DIR([config]) |
| | 7 | AC_CONFIG_MACRO_DIR([m4]) |
| | 8 | |
| | 9 | AC_CANONICAL_TARGET |
| | 10 | AC_CANONICAL_HOST |
| | 11 | |
| | 12 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 13 | AM_MAINTAINER_MODE([enable]) |
| | 14 | |
| | 15 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 16 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 17 | |
| | 18 | |
| | 19 | ## ## |
| | 20 | ## C compiler checks ## |
| | 21 | ## ## |
| | 22 | |
| | 23 | # Choose the C compiler |
| | 24 | AC_PROG_CC |
| | 25 | # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70 |
| | 26 | m4_version_prereq([2.70], [], [AC_PROG_CC_STDC]) |
| | 27 | |
| | 28 | # Make sure the C compiler supports C99 |
| | 29 | AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])]) |
| | 30 | |
| | 31 | # Enable available system extensions and LFS support |
| | 32 | AC_USE_SYSTEM_EXTENSIONS |
| | 33 | AC_SYS_LARGEFILE |
| | 34 | |
| | 35 | # Make sure the C compiler supports __attribute__ |
| | 36 | AX_C___ATTRIBUTE__ |
| | 37 | AS_IF([test "x$ax_cv___attribute__" != "xyes"], |
| | 38 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 39 | |
| | 40 | # Make sure we have pthread support |
| | 41 | AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])]) |
| | 42 | |
| | 43 | # Checks for typedefs, structures, and compiler characteristics. |
| | 44 | AC_C_INLINE |
| | 45 | AC_TYPE_INT32_T |
| | 46 | AC_TYPE_INT64_T |
| | 47 | AC_TYPE_MODE_T |
| | 48 | AC_TYPE_OFF_T |
| | 49 | AC_TYPE_PID_T |
| | 50 | AC_TYPE_SIZE_T |
| | 51 | AC_TYPE_SSIZE_T |
| | 52 | AC_TYPE_UID_T |
| | 53 | AC_TYPE_UINT16_T |
| | 54 | AC_TYPE_UINT32_T |
| | 55 | AC_TYPE_UINT64_T |
| | 56 | AC_TYPE_UINT8_T |
| | 57 | |
| | 58 | # Detect warning flags supported by the C and C++ compilers and append them to |
| | 59 | # WARN_CFLAGS and WARN_CXXFLAGS. |
| | 60 | m4_define([WARN_FLAGS_COMMON_LIST], [ dnl |
| | 61 | -Wall dnl |
| | 62 | -Wextra dnl |
| | 63 | -Wmissing-declarations dnl |
| | 64 | -Wnull-dereference dnl |
| | 65 | -Wundef dnl |
| | 66 | -Wredundant-decls dnl |
| | 67 | -Wshadow dnl |
| | 68 | -Wsuggest-attribute=format dnl |
| | 69 | -Wtautological-constant-out-of-range-compare dnl Clang specific |
| | 70 | -Wwrite-strings dnl |
| | 71 | -Wformat=2 dnl |
| | 72 | -Wstrict-aliasing dnl |
| | 73 | -Wmissing-noreturn dnl |
| | 74 | -Wduplicated-cond dnl |
| | 75 | -Wduplicated-branches dnl |
| | 76 | -Wlogical-op dnl |
| | 77 | -Winit-self dnl |
| | 78 | dnl We currently get this warning when building with Clang: |
| | 79 | dnl |
| | 80 | dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration] |
| | 81 | dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL; |
| | 82 | dnl ^ |
| | 83 | -Wno-incomplete-setjmp-declaration dnl |
| | 84 | -Wno-gnu-folding-constant dnl Clang specific |
| | 85 | ]) |
| | 86 | |
| | 87 | # Detect warning flags specific to the C compiler and append them to |
| | 88 | # WARN_CFLAGS. |
| | 89 | m4_define([WARN_FLAGS_C_LIST], [ dnl |
| | 90 | -Wdiscarded-qualifiers dnl |
| | 91 | -Wmissing-prototypes dnl |
| | 92 | -Wmissing-parameter-type dnl |
| | 93 | -Wsuggest-final-types dnl |
| | 94 | -Wsuggest-final-methods dnl |
| | 95 | -Wsuggest-override dnl |
| | 96 | ]) |
| | 97 | |
| | 98 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 99 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 100 | AC_LANG_PUSH([C]) |
| | 101 | AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_C_LIST], [WARN_CFLAGS], [-Werror]) |
| | 102 | AC_LANG_POP([C]) |
| | 103 | |
| | 104 | # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is |
| | 105 | # written in such a way that it triggers warnings with the following warning |
| | 106 | # flags. So they would always end up disabled if we put them there, because |
| | 107 | # the test program would not build. |
| | 108 | # |
| | 109 | # Enable them here unconditionally. They are supported by GCC >= 4.8 and by |
| | 110 | # Clang >= 3.3 (required by the project) and are only valid for C code. |
| | 111 | WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes" |
| | 112 | |
| | 113 | # Disable 'strict aliasing' if the C compiler supports it. |
| | 114 | AC_LANG_PUSH([C]) |
| | 115 | AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror]) |
| | 116 | AC_LANG_POP([C]) |
| | 117 | |
| | 118 | |
| | 119 | ## ## |
| | 120 | ## C++ compiler checks ## |
| | 121 | ## ## |
| | 122 | |
| | 123 | # Find a C++11 compiler with GNU extensions (-std=gnu++11) |
| | 124 | AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory]) |
| | 125 | |
| | 126 | # Detect warning flags specific to the C++ compiler and append them to |
| | 127 | # WARN_CXXFLAGS. |
| | 128 | m4_define([WARN_FLAGS_CXX_LIST], [ dnl |
| | 129 | dnl GCC enables this with -Wall in C++, and that generates a |
| | 130 | dnl lot of warnings that have on average a low value to fix. |
| | 131 | -Wno-sign-compare dnl |
| | 132 | ]) |
| | 133 | |
| | 134 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 135 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 136 | AC_LANG_PUSH([C++]) |
| | 137 | AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_COMMON_LIST WARN_FLAGS_CXX_LIST], [WARN_CXXFLAGS], [-Werror]) |
| | 138 | AC_LANG_POP([C++]) |
| | 139 | |
| | 140 | # Disable 'strict aliasing' if the C++ compiler supports it. |
| | 141 | AC_LANG_PUSH([C++]) |
| | 142 | AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror]) |
| | 143 | AC_LANG_POP([C++]) |
| | 144 | |
| | 145 | |
| | 146 | # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS. |
| | 147 | AC_ARG_ENABLE([Werror],[ |
| | 148 | AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.]) |
| | 149 | ]) |
| | 150 | |
| | 151 | AS_IF([test "x$enable_Werror" = "xyes"], [ |
| | 152 | WARN_CFLAGS="${WARN_CFLAGS} -Werror" |
| | 153 | WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror" |
| | 154 | ]) |
| | 155 | |
| | 156 | # Checks for programs. |
| | 157 | AC_PROG_GREP |
| | 158 | AC_PROG_MAKE_SET |
| | 159 | AC_PROG_SED |
| | 160 | AC_PATH_PROG([report_fold], [fold]) |
| | 161 | LT_INIT |
| | 162 | |
| | 163 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 164 | AC_CHECK_TOOL([OBJCOPY], [objcopy]) |
| | 165 | AS_IF([test "x$OBJCOPY" = "x"], |
| | 166 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 167 | ) |
| | 168 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != "x"]) |
| | 169 | |
| | 170 | # check for pgrep |
| | 171 | AC_PATH_PROG([PGREP], [pgrep]) |
| | 172 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "x"]) |
| | 173 | |
| | 174 | AC_PATH_PROG([SHELLCHECK], [shellcheck]) |
| | 175 | AM_CONDITIONAL([HAVE_SHELLCHECK], [test "x$SHELLCHECK" != "x"]) |
| | 176 | |
| | 177 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 178 | # is not distributed in tarballs |
| | 179 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 180 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 181 | |
| | 182 | # check for bison |
| | 183 | AC_PROG_YACC |
| | 184 | BISON=$YACC |
| | 185 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 186 | |
| | 187 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 188 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 189 | AC_MSG_FAILURE([ |
| | 190 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 191 | set the YACC variable to override automatic detection. |
| | 192 | ]) |
| | 193 | ], [ |
| | 194 | AC_MSG_WARN([ |
| | 195 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 196 | this distribution tarball, so Bison is only needed if you intend to |
| | 197 | modify their sources. You can set the YACC variable to override automatic |
| | 198 | detection. |
| | 199 | ]) |
| | 200 | ]) |
| | 201 | ]) |
| | 202 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 203 | |
| | 204 | # check for flex |
| | 205 | # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a |
| | 206 | # problem since the argument is silently ignored by older versions. |
| | 207 | AC_PROG_LEX([noyywrap]) |
| | 208 | FLEX=$LEX |
| | 209 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 210 | |
| | 211 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 212 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 213 | AC_MSG_FAILURE([ |
| | 214 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 215 | set the LEX variable to override automatic detection. |
| | 216 | ]) |
| | 217 | ], [ |
| | 218 | AC_MSG_WARN([ |
| | 219 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 220 | this distribution tarball, so Flex is only needed if you intend to |
| | 221 | modify their sources. You can set the LEX variable to override automatic |
| | 222 | detection. |
| | 223 | ]) |
| | 224 | ]) |
| | 225 | ]) |
| | 226 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 227 | |
| | 228 | |
| | 229 | |
| | 230 | # Check if linker has the -no-pie option. |
| | 231 | AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes]) |
| | 232 | AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"]) |
| | 233 | |
| | 234 | AX_LIB_SOCKET_NSL |
| | 235 | |
| | 236 | LT_NO_UNDEFINED="" |
| | 237 | AS_CASE([$host_os], |
| | 238 | [cygwin*], |
| | 239 | [ |
| | 240 | LT_NO_UNDEFINED="-no-undefined" |
| | 241 | ], |
| | 242 | [cygwin*|darwin*|mingw*|solaris*], |
| | 243 | [ |
| | 244 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 245 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 246 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 247 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 248 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 249 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 250 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 251 | ] |
| | 252 | ) |
| | 253 | |
| | 254 | AC_SUBST(LT_NO_UNDEFINED) |
| | 255 | |
| | 256 | # Compute minor/major/patchlevel version numbers |
| | 257 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 258 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 259 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 260 | |
| | 261 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 262 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 263 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 264 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 265 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 266 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 267 | |
| | 268 | version_name="O-Beer" |
| | 269 | version_description="An alcoholic drink made from yeast-fermented malt flavored with hops." |
| | 270 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 271 | |
| | 272 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 273 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 274 | |
| | 275 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 276 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 277 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 278 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 279 | libtool_fixup=$enableval, |
| | 280 | libtool_fixup=yes) |
| | 281 | |
| | 282 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 283 | [ |
| | 284 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 285 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 286 | AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 287 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 288 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 289 | [ |
| | 290 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 291 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 292 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 293 | ], |
| | 294 | [ |
| | 295 | AC_MSG_RESULT([none]) |
| | 296 | ]) |
| | 297 | ]) |
| | 298 | |
| | 299 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 300 | |
| | 301 | AC_CHECK_HEADERS([ \ |
| | 302 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 303 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 304 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 305 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 306 | sys/mount.h sys/param.h sys/time.h elf.h sys/random.h sys/syscall.h |
| | 307 | ]) |
| | 308 | |
| | 309 | AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes]) |
| | 310 | |
| | 311 | # Basic functions check |
| | 312 | AC_CHECK_FUNCS([ \ |
| | 313 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 314 | gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \ |
| | 315 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 316 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 317 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 318 | sched_getcpu sysconf sync_file_range getrandom posix_fadvise \ |
| | 319 | arc4random |
| | 320 | ]) |
| | 321 | |
| | 322 | # Check for pthread_setname_np and pthread_getname_np |
| | 323 | LTTNG_PTHREAD_SETNAME_NP |
| | 324 | LTTNG_PTHREAD_GETNAME_NP |
| | 325 | |
| | 326 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 327 | # add -lrt to LIBS |
| | 328 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 329 | |
| | 330 | # Checks for dl. |
| | 331 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 332 | have_libdl=yes |
| | 333 | libdl_name=dl |
| | 334 | DL_LIBS="-ldl" |
| | 335 | ], [ |
| | 336 | # libdl not found, check for dlopen in libc. |
| | 337 | AC_CHECK_LIB([c], [dlopen], [ |
| | 338 | have_libc_dl=yes |
| | 339 | libdl_name=c |
| | 340 | DL_LIBS="-lc" |
| | 341 | ], [ |
| | 342 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 343 | ]) |
| | 344 | ]) |
| | 345 | AC_SUBST(DL_LIBS) |
| | 346 | |
| | 347 | # Check if libdl has dlmopen support. |
| | 348 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 349 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 350 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 351 | HAVE_DLMOPEN=1 |
| | 352 | ], [ |
| | 353 | HAVE_DLMOPEN=0 |
| | 354 | ]) |
| | 355 | AC_SUBST(HAVE_DLMOPEN) |
| | 356 | |
| | 357 | # Babeltrace viewer check |
| | 358 | AC_ARG_WITH([babeltrace-bin], |
| | 359 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 360 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 361 | [BABELTRACE_BIN="$withval"], |
| | 362 | [BABELTRACE_BIN='']) |
| | 363 | AC_SUBST([BABELTRACE_BIN]) |
| | 364 | |
| | 365 | AC_ARG_WITH([babeltrace2-bin], |
| | 366 | AS_HELP_STRING([--with-babeltrace2-bin], |
| | 367 | [Location of the babeltrace2 viewer executable (including the filename)]), |
| | 368 | [BABELTRACE2_BIN="$withval"], |
| | 369 | [BABELTRACE2_BIN='']) |
| | 370 | AC_SUBST([BABELTRACE2_BIN]) |
| | 371 | |
| | 372 | AC_ARG_WITH([consumerd32-bin], |
| | 373 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 374 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 375 | [CONSUMERD32_BIN="$withval"], |
| | 376 | [CONSUMERD32_BIN='']) |
| | 377 | AC_SUBST([CONSUMERD32_BIN]) |
| | 378 | |
| | 379 | AC_ARG_WITH([consumerd64-bin], |
| | 380 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 381 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 382 | [CONSUMERD64_BIN="$withval"], |
| | 383 | [CONSUMERD64_BIN='']) |
| | 384 | AC_SUBST([CONSUMERD64_BIN]) |
| | 385 | |
| | 386 | AC_ARG_WITH([consumerd32-libdir], |
| | 387 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 388 | [Directory containing the 32-bit consumerd libraries]), |
| | 389 | [CONSUMERD32_LIBDIR="$withval"], |
| | 390 | [CONSUMERD32_LIBDIR='']) |
| | 391 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 392 | |
| | 393 | AC_ARG_WITH([consumerd64-libdir], |
| | 394 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 395 | [Directory containing the 64-bit consumerd libraries]), |
| | 396 | [CONSUMERD64_LIBDIR="$withval"], |
| | 397 | [CONSUMERD64_LIBDIR='']) |
| | 398 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 399 | |
| | 400 | AC_ARG_WITH([sessiond-bin], |
| | 401 | AS_HELP_STRING([--with-sessiond-bin], |
| | 402 | [Location of the sessiond executable (including the filename)]), |
| | 403 | [SESSIOND_BIN="$withval"], |
| | 404 | [SESSIOND_BIN='']) |
| | 405 | AC_SUBST([SESSIOND_BIN]) |
| | 406 | |
| | 407 | AC_ARG_WITH([lttng-system-rundir], |
| | 408 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 409 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 410 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 411 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 412 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 413 | |
| | 414 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 415 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 416 | [test_java_agent_jul=$enableval], |
| | 417 | [test_java_agent_jul=no] |
| | 418 | ) |
| | 419 | |
| | 420 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 421 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])], |
| | 422 | [test_java_agent_log4j=$enableval], |
| | 423 | [test_java_agent_log4j=no] |
| | 424 | ) |
| | 425 | |
| | 426 | AC_ARG_ENABLE([test-java-agent-log4j2], |
| | 427 | [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])], |
| | 428 | [test_java_agent_log4j2=$enableval], |
| | 429 | [test_java_agent_log4j2=no] |
| | 430 | ) |
| | 431 | |
| | 432 | AC_ARG_ENABLE([test-java-agent-all], |
| | 433 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 434 | [test_java_agent_jul=$enableval |
| | 435 | test_java_agent_log4j=$enableval |
| | 436 | test_java_agent_log4j2=$enableval], |
| | 437 | [:] |
| | 438 | ) |
| | 439 | |
| | 440 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 441 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 442 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 443 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 444 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 445 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.]) |
| | 446 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 447 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 448 | |
| | 449 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 450 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 451 | $1="$2" |
| | 452 | AC_SUBST([$1]) |
| | 453 | ]) |
| | 454 | |
| | 455 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 456 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 457 | $1="$2" |
| | 458 | AC_SUBST([$1]) |
| | 459 | ]) |
| | 460 | |
| | 461 | # Default values |
| | 462 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 463 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 464 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 465 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 466 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 467 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 468 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 469 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 470 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 471 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 472 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 473 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 474 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 475 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 476 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 477 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 478 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 479 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 480 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 481 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 482 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 483 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 484 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 485 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 486 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 487 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 488 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 489 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 490 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 491 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 492 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 493 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 494 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 495 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 496 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 497 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 498 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 499 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 500 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 501 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 502 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 503 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 504 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 505 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 506 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 507 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 508 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 509 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 510 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000]) |
| | 511 | _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096]) |
| | 512 | |
| | 513 | # Command short descriptions |
| | 514 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded]) |
| | 515 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger]) |
| | 516 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session]) |
| | 517 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session]) |
| | 518 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions]) |
| | 519 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels]) |
| | 520 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules]) |
| | 521 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule]) |
| | 522 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel]) |
| | 523 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules]) |
| | 524 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule]) |
| | 525 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command]) |
| | 526 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points]) |
| | 527 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers]) |
| | 528 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations]) |
| | 529 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data]) |
| | 530 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger]) |
| | 531 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session]) |
| | 532 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations]) |
| | 533 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session]) |
| | 534 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot]) |
| | 535 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session]) |
| | 536 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session]) |
| | 537 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session]) |
| | 538 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events]) |
| | 539 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events]) |
| | 540 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information]) |
| | 541 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader]) |
| | 542 | |
| | 543 | if test "x$prefix" = "xNONE"; then |
| | 544 | prefix=$ac_default_prefix |
| | 545 | fi |
| | 546 | CONFDIR=`eval echo $sysconfdir` |
| | 547 | AC_SUBST(CONFDIR) |
| | 548 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 549 | |
| | 550 | AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.]) |
| | 551 | |
| | 552 | # Check libpopt |
| | 553 | PKG_CHECK_MODULES([POPT], [popt], |
| | 554 | [ |
| | 555 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 556 | ], |
| | 557 | [ |
| | 558 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 559 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 560 | AC_CHECK_LIB([popt], |
| | 561 | [poptGetContext], |
| | 562 | [POPT_LIBS="-lpopt"], |
| | 563 | [ |
| | 564 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 565 | ] |
| | 566 | ) |
| | 567 | ] |
| | 568 | ) |
| | 569 | AC_SUBST(POPT_LIBS) |
| | 570 | |
| | 571 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 572 | |
| | 573 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 574 | |
| | 575 | # URCU library version needed or newer |
| | 576 | PKG_CHECK_MODULES([URCU], [liburcu >= 0.14]) |
| | 577 | PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.14]) |
| | 578 | AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS" |
| | 579 | |
| | 580 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 581 | # it can be explicitly disabled with --without-kmod |
| | 582 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 583 | AC_ARG_WITH([kmod], |
| | 584 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 585 | [], |
| | 586 | [with_kmod=check] |
| | 587 | ) |
| | 588 | |
| | 589 | AS_IF([test "x$with_kmod" != "xno"], |
| | 590 | [ |
| | 591 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 592 | [ |
| | 593 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 594 | KMOD_LIBS="-lkmod" |
| | 595 | ], |
| | 596 | [ |
| | 597 | if test "x$with_kmod" != xcheck; then |
| | 598 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 599 | else |
| | 600 | with_kmod=no |
| | 601 | fi |
| | 602 | ] |
| | 603 | ) |
| | 604 | ] |
| | 605 | ) |
| | 606 | AC_SUBST(KMOD_LIBS) |
| | 607 | |
| | 608 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 609 | # it can be explicitly disabled with --without-lttng-ust |
| | 610 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 611 | AC_ARG_WITH([lttng-ust], |
| | 612 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 613 | [], |
| | 614 | [with_lttng_ust=yes] |
| | 615 | ) |
| | 616 | |
| | 617 | AS_IF([test "x$with_lttng_ust" = "xyes"], [ |
| | 618 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 619 | |
| | 620 | # Check for liblttng-ust |
| | 621 | PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version]) |
| | 622 | |
| | 623 | # Check for liblttng-ust-ctl |
| | 624 | PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version]) |
| | 625 | |
| | 626 | AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS" |
| | 627 | ]) |
| | 628 | |
| | 629 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 630 | |
| | 631 | |
| | 632 | # Check for fmemopen |
| | 633 | AC_CHECK_LIB([c], [fmemopen], |
| | 634 | [ |
| | 635 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 636 | ] |
| | 637 | ) |
| | 638 | |
| | 639 | # check for libpfm |
| | 640 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 641 | [ |
| | 642 | have_libpfm=yes |
| | 643 | ]) |
| | 644 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 645 | |
| | 646 | # For Python |
| | 647 | # SWIG version needed or newer: |
| | 648 | swig_version=2.0.0 |
| | 649 | |
| | 650 | AC_ARG_ENABLE([python-bindings], |
| | 651 | [AS_HELP_STRING([--enable-python-bindings], |
| | 652 | [compile Python bindings])], |
| | 653 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 654 | |
| | 655 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 656 | |
| | 657 | if test "x$enable_python_binding" = xyes; then |
| | 658 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 659 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 660 | AM_PATH_PYTHON([3.4]) |
| | 661 | |
| | 662 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 663 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 664 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 665 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 666 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 667 | [python$PYTHON_VERSION-config python-config], |
| | 668 | [], |
| | 669 | [`dirname $PYTHON`]) |
| | 670 | AS_IF([test "x$PYTHON_CONFIG" = "x"], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 671 | ]) |
| | 672 | AC_MSG_CHECKING([python include flags]) |
| | 673 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 674 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 675 | ]) |
| | 676 | |
| | 677 | else |
| | 678 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 679 | [if you want Python bindings.]) |
| | 680 | |
| | 681 | fi |
| | 682 | |
| | 683 | # Epoll check. If not present, the build will fallback on poll() API |
| | 684 | AX_HAVE_EPOLL( |
| | 685 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 686 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 687 | ) |
| | 688 | AX_CONFIG_FEATURE( |
| | 689 | [epoll], [This platform supports epoll(7)], |
| | 690 | [HAVE_EPOLL], [This platform supports epoll(7).] |
| | 691 | ) |
| | 692 | |
| | 693 | AS_IF([test "x$ac_cv_func_dirfd" = "xyes"], |
| | 694 | [AX_CONFIG_FEATURE_ENABLE(dirfd)], |
| | 695 | [AX_CONFIG_FEATURE_DISABLE(dirfd)] |
| | 696 | ) |
| | 697 | AX_CONFIG_FEATURE( |
| | 698 | [dirfd], [Use directory file descriptors], |
| | 699 | [HAVE_DIRFD], [This platform supports directory file descriptors.] |
| | 700 | ) |
| | 701 | |
| | 702 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 703 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 704 | AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"]) |
| | 705 | |
| | 706 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then |
| | 707 | AX_JAVA_OPTIONS |
| | 708 | AX_PROG_JAVAC |
| | 709 | AX_PROG_JAVA |
| | 710 | AX_PROG_JAR |
| | 711 | |
| | 712 | AX_CHECK_CLASSPATH |
| | 713 | |
| | 714 | # Check for Java UST agent common class first |
| | 715 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 716 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 717 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 718 | fi |
| | 719 | |
| | 720 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 721 | # Check for JUL agent class |
| | 722 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 723 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 724 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 725 | fi |
| | 726 | fi |
| | 727 | |
| | 728 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 729 | # Check for Log4j agent class |
| | 730 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 731 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 732 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 733 | fi |
| | 734 | |
| | 735 | # Check for Log4j class |
| | 736 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 737 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 738 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 739 | fi |
| | 740 | fi |
| | 741 | |
| | 742 | if test "x$test_java_agent_log4j2" = "xyes"; then |
| | 743 | # Check for Log4j2 agent class |
| | 744 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender) |
| | 745 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then |
| | 746 | AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"]) |
| | 747 | fi |
| | 748 | |
| | 749 | # Check for Log4j 2.x classes |
| | 750 | AX_CHECK_CLASS([org.apache.logging.log4j.Logger]) |
| | 751 | AX_CHECK_CLASS([org.apache.logging.log4j.core.Core]) |
| | 752 | if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then |
| | 753 | AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"]) |
| | 754 | fi |
| | 755 | fi |
| | 756 | fi |
| | 757 | |
| | 758 | # enable building man pages (user's intention) |
| | 759 | AC_ARG_ENABLE( |
| | 760 | man-pages, |
| | 761 | AS_HELP_STRING( |
| | 762 | [--disable-man-pages], |
| | 763 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 764 | ), |
| | 765 | [man_pages_opt=$enableval], |
| | 766 | [man_pages_opt=yes] |
| | 767 | ) |
| | 768 | |
| | 769 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 770 | have_asciidoc_xmlto=no |
| | 771 | warn_prebuilt_man_pages=no |
| | 772 | |
| | 773 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 774 | AC_PATH_PROG([ASCIIDOC], [asciidoc]) |
| | 775 | AC_PATH_PROG([XMLTO], [xmlto]) |
| | 776 | |
| | 777 | AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [ |
| | 778 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 779 | # this is an error because we're in the Git repo, which |
| | 780 | # means the man pages are not already generated for us, |
| | 781 | # thus asciidoc/xmlto are required because we were asked |
| | 782 | # to build the man pages |
| | 783 | AC_MSG_ERROR([ |
| | 784 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 785 | --disable-man-pages to disable building the man pages, in which case |
| | 786 | they will not be installed. |
| | 787 | ]) |
| | 788 | ], [ |
| | 789 | # only warn here: since we're in the tarball, the man |
| | 790 | # pages should already be generated at this point, thus |
| | 791 | # asciidoc/xmlto are not strictly required |
| | 792 | warn_prebuilt_man_pages=yes |
| | 793 | ]) |
| | 794 | ], [ |
| | 795 | have_asciidoc_xmlto=yes |
| | 796 | ]) |
| | 797 | ]) |
| | 798 | |
| | 799 | # export man page build condition: build the man pages if the user |
| | 800 | # asked for it, and if the tools are available |
| | 801 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 802 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 803 | |
| | 804 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 805 | |
| | 806 | # embedded --help message |
| | 807 | AC_ARG_ENABLE( |
| | 808 | [embedded-help], |
| | 809 | AS_HELP_STRING( |
| | 810 | [--enable-embedded-help], |
| | 811 | [Embed the --help messages in the executable files] |
| | 812 | ), |
| | 813 | [embedded_help=$enableval], |
| | 814 | [embedded_help=no] |
| | 815 | ) |
| | 816 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 817 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 818 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 819 | ]) |
| | 820 | AC_PATH_PROG([man_prog_path], [man]) |
| | 821 | AS_IF([test "x$man_prog_path" = "x"], [ |
| | 822 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 823 | ]) |
| | 824 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 825 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 826 | ]) |
| | 827 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 828 | |
| | 829 | # Python agent test |
| | 830 | UST_PYTHON_AGENT="lttngust" |
| | 831 | |
| | 832 | AC_ARG_ENABLE(test-python2-agent, |
| | 833 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 834 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 835 | ),[:],[test_python2_agent_autodetect=yes] |
| | 836 | ) |
| | 837 | |
| | 838 | AC_ARG_ENABLE(test-python3-agent, |
| | 839 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 840 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 841 | ),[:],[test_python3_agent_autodetect=yes] |
| | 842 | ) |
| | 843 | |
| | 844 | AC_ARG_ENABLE(test-python-agent-all, |
| | 845 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 846 | [enable test for all python{2/3} agent.] |
| | 847 | ), |
| | 848 | ) |
| | 849 | |
| | 850 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 851 | unset test_python2_agent_autodetect |
| | 852 | unset test_python3_agent_autodetect |
| | 853 | ]) |
| | 854 | |
| | 855 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 856 | enable_test_python2_agent=yes |
| | 857 | enable_test_python3_agent=yes |
| | 858 | ]) |
| | 859 | |
| | 860 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 861 | enable_test_python2_agent=no |
| | 862 | enable_test_python3_agent=no |
| | 863 | ]) |
| | 864 | |
| | 865 | |
| | 866 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 867 | AS_IF([test -z "$PYTHON2"], [ |
| | 868 | PYTHON2=python2 |
| | 869 | ], [ |
| | 870 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 871 | ]) |
| | 872 | |
| | 873 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 874 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 875 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 876 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 877 | ]) |
| | 878 | ], [ |
| | 879 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 880 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 881 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 882 | AC_MSG_RESULT([yes]) |
| | 883 | RUN_PYTHON_AGENT_TEST=yes |
| | 884 | ], [ |
| | 885 | AC_MSG_RESULT([no]) |
| | 886 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 887 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 888 | ]) |
| | 889 | ]) |
| | 890 | |
| | 891 | ]) |
| | 892 | |
| | 893 | ]) |
| | 894 | |
| | 895 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 896 | AS_IF([test -z "$PYTHON3"], [ |
| | 897 | PYTHON3=python3 |
| | 898 | ], [ |
| | 899 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 900 | ]) |
| | 901 | |
| | 902 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 903 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 904 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 905 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 906 | ]) |
| | 907 | ], [ |
| | 908 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 909 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 910 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 911 | AC_MSG_RESULT([yes]) |
| | 912 | RUN_PYTHON_AGENT_TEST=yes |
| | 913 | ], [ |
| | 914 | AC_MSG_RESULT([no]) |
| | 915 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 916 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 917 | ]) |
| | 918 | ]) |
| | 919 | |
| | 920 | ]) |
| | 921 | ]) |
| | 922 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 923 | AC_SUBST([PYTHON2_AGENT]) |
| | 924 | AC_SUBST([PYTHON3_AGENT]) |
| | 925 | |
| | 926 | AC_ARG_ENABLE([test-sdt-uprobe], |
| | 927 | [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])], |
| | 928 | [test_sdt_uprobe="$enableval"], |
| | 929 | [test_sdt_uprobe=autodetect] |
| | 930 | ) |
| | 931 | |
| | 932 | AS_IF([test "$test_sdt_uprobe" != "no"], [ |
| | 933 | LTTNG_CHECK_SDT_WORKS |
| | 934 | AC_PATH_PROG([DTRACE], [dtrace]) |
| | 935 | ]) |
| | 936 | |
| | 937 | AS_IF([test "$test_sdt_uprobe" = "yes"], [ |
| | 938 | AS_IF([test "$lttng_cv_sdt_works" = "no"], [ |
| | 939 | AC_MSG_ERROR([Cannot find 'sys/sdt.h'.]) |
| | 940 | ]) |
| | 941 | AS_IF([test "x$DTRACE" = "x"], [ |
| | 942 | AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.]) |
| | 943 | ]) |
| | 944 | ]) |
| | 945 | |
| | 946 | AS_IF([test "$test_sdt_uprobe" = "autodetect"], [ |
| | 947 | AS_IF([test "$lttng_cv_sdt_works" = "yes"], [ |
| | 948 | AS_IF([test "x$DTRACE" != "x"], [ |
| | 949 | test_sdt_uprobe=yes |
| | 950 | ]) |
| | 951 | ]) |
| | 952 | ]) |
| | 953 | |
| | 954 | AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"]) |
| | 955 | |
| | 956 | # Arguments for binaries build exclusion |
| | 957 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 958 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 959 | [Disable the build of lttng-consumerd binaries])) |
| | 960 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 961 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 962 | [Disable the build of lttng-relayd binaries])) |
| | 963 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 964 | [Disable the build of lttng-sessiond binaries])) |
| | 965 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 966 | [Disable the build of the extra components])) |
| | 967 | |
| | 968 | |
| | 969 | build_lib_consumer=no |
| | 970 | build_lib_health=no |
| | 971 | build_lib_index=no |
| | 972 | build_lib_kernel_consumer=no |
| | 973 | build_lib_kernel_ctl=no |
| | 974 | build_lib_lttng_ctl=no |
| | 975 | build_lib_relayd=no |
| | 976 | build_lib_sessiond_comm=no |
| | 977 | build_lib_testpoint=no |
| | 978 | build_lib_ust_consumer=no |
| | 979 | |
| | 980 | # There is an overlap for enabled dependencies, but this makes everything |
| | 981 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 982 | # here. |
| | 983 | |
| | 984 | # Enable binary dependencies. |
| | 985 | AS_IF([test x$enable_bin_lttng != xno], |
| | 986 | [ |
| | 987 | build_lib_lttng_ctl=yes |
| | 988 | ] |
| | 989 | ) |
| | 990 | |
| | 991 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 992 | [ |
| | 993 | build_lib_consumer=yes |
| | 994 | build_lib_sessiond_comm=yes |
| | 995 | build_lib_index=yes |
| | 996 | build_lib_health=yes |
| | 997 | build_lib_testpoint=yes |
| | 998 | ] |
| | 999 | ) |
| | 1000 | |
| | 1001 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 1002 | # Do nothing since libconfig and libcommon are built by default. |
| | 1003 | [] |
| | 1004 | ) |
| | 1005 | |
| | 1006 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 1007 | [ |
| | 1008 | build_lib_sessiond_comm=yes |
| | 1009 | build_lib_index=yes |
| | 1010 | build_lib_health=yes |
| | 1011 | build_lib_testpoint=yes |
| | 1012 | ] |
| | 1013 | ) |
| | 1014 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 1015 | [ |
| | 1016 | build_lib_lttng_ctl=yes |
| | 1017 | build_lib_sessiond_comm=yes |
| | 1018 | build_lib_kernel_ctl=yes |
| | 1019 | build_lib_relayd=yes |
| | 1020 | build_lib_testpoint=yes |
| | 1021 | build_lib_health=yes |
| | 1022 | ] |
| | 1023 | ) |
| | 1024 | |
| | 1025 | # Libraries dependencies enabling |
| | 1026 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 1027 | [ |
| | 1028 | build_lib_sessiond_comm=yes |
| | 1029 | ] |
| | 1030 | ) |
| | 1031 | |
| | 1032 | AS_IF([test x$build_lib_consumer = xyes], |
| | 1033 | [ |
| | 1034 | build_lib_sessiond_comm=yes |
| | 1035 | build_lib_kernel_consumer=yes |
| | 1036 | build_lib_relayd=yes |
| | 1037 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 1038 | ] |
| | 1039 | ) |
| | 1040 | |
| | 1041 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 1042 | [ |
| | 1043 | build_lib_kernel_ctl=yes |
| | 1044 | build_lib_relayd=yes |
| | 1045 | ] |
| | 1046 | ) |
| | 1047 | |
| | 1048 | AS_IF([test x$build_lib_relayd = xyes], |
| | 1049 | [ |
| | 1050 | build_lib_sessiond_comm=yes |
| | 1051 | ] |
| | 1052 | ) |
| | 1053 | |
| | 1054 | # Find arch type |
| | 1055 | AS_CASE([$host_cpu], |
| | 1056 | [k1om], [ARCHTYPE="x86"], |
| | 1057 | [i386], [ARCHTYPE="x86"], |
| | 1058 | [i486], [ARCHTYPE="x86"], |
| | 1059 | [i586], [ARCHTYPE="x86"], |
| | 1060 | [i686], [ARCHTYPE="x86"], |
| | 1061 | [amd64], [ARCHTYPE="x86"], |
| | 1062 | [x86_64], [ARCHTYPE="x86"], |
| | 1063 | [powerpc], [ARCHTYPE="ppc"], |
| | 1064 | [ppc64], [ARCHTYPE="ppc"], |
| | 1065 | [powerpc64], [ARCHTYPE="ppc"], |
| | 1066 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 1067 | [ppc], [ARCHTYPE="ppc"], |
| | 1068 | [s390], [ARCHTYPE="s390"], |
| | 1069 | [s390x], [ARCHTYPE="s390"], |
| | 1070 | [sparc], [ARCHTYPE="sparc64"], |
| | 1071 | [sparc64], [ARCHTYPE="sparc64"], |
| | 1072 | [alpha*], [ARCHTYPE="alpha"], |
| | 1073 | [ia64], [ARCHTYPE="ia64"], |
| | 1074 | [arm*], [ARCHTYPE="arm"], |
| | 1075 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 1076 | [mips*], [ARCHTYPE="mips"], |
| | 1077 | [nios2*], [ARCHTYPE="nios2"], |
| | 1078 | [tile*], [ARCHTYPE="tile"], |
| | 1079 | [hppa*], [ARCHTYPE="hppa"], |
| | 1080 | [m68k], [ARCHTYPE="m68k"], |
| | 1081 | [riscv*], [ARCHTYPE="riscv"], |
| | 1082 | [ARCHTYPE="unknown"] |
| | 1083 | ) |
| | 1084 | |
| | 1085 | AC_SUBST(ARCHTYPE) |
| | 1086 | |
| | 1087 | AS_CASE([$host_os], |
| | 1088 | [linux*], [OSTYPE="linux"], |
| | 1089 | [freebsd*], [OSTYPE="freebsd"], |
| | 1090 | [solaris*], [OSTYPE="solaris"], |
| | 1091 | [cygwin*], [OSTYPE="cygwin"], |
| | 1092 | [mingw*], [OSTYPE="mingw"], |
| | 1093 | [OSTYPE="unknown"] |
| | 1094 | ) |
| | 1095 | AC_SUBST(OSTYPE) |
| | 1096 | AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"]) |
| | 1097 | |
| | 1098 | |
| | 1099 | |
| | 1100 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 1101 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 1102 | AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[ |
| | 1103 | have_modules_userspace_callstack_context=yes |
| | 1104 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 1105 | ]) |
| | 1106 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes]) |
| | 1107 | |
| | 1108 | # Export binaries build conditions. |
| | 1109 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1110 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1111 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1112 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1113 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1114 | |
| | 1115 | # Export the tests and extras build conditions. |
| | 1116 | AS_IF([\ |
| | 1117 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1118 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1119 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1120 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1121 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1122 | [build_tests=yes], |
| | 1123 | [build_tests=no] |
| | 1124 | ) |
| | 1125 | |
| | 1126 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1127 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1128 | |
| | 1129 | # Export libraries build conditions. |
| | 1130 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1131 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1132 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1133 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1134 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1135 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1136 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1137 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1138 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1139 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1140 | |
| | 1141 | AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS" |
| | 1142 | AC_SUBST(AM_CFLAGS) |
| | 1143 | |
| | 1144 | AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS" |
| | 1145 | AC_SUBST(AM_CXXFLAGS) |
| | 1146 | |
| | 1147 | # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...". |
| | 1148 | AM_LDFLAGS="" |
| | 1149 | AC_SUBST(AM_LDFLAGS) |
| | 1150 | |
| | 1151 | # The order in which the include folders are searched is important. |
| | 1152 | # The top_builddir should always be searched first in the event that a build |
| | 1153 | # time generated file is included. An example of this is the "version.i" file. |
| | 1154 | # In a scenario where lttng-tools is built from a distribution tarball and in a |
| | 1155 | # out-of-tree manner, the generated "version.i" has priority on the one from |
| | 1156 | # the source (distribution tarball) and must be found first. |
| | 1157 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1158 | AC_SUBST(AM_CPPFLAGS) |
| | 1159 | |
| | 1160 | lttngincludedir="${includedir}/lttng" |
| | 1161 | AC_SUBST(lttngincludedir) |
| | 1162 | |
| | 1163 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1164 | AC_SUBST(lttngactionincludedir) |
| | 1165 | |
| | 1166 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1167 | AC_SUBST(lttngconditionincludedir) |
| | 1168 | |
| | 1169 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1170 | AC_SUBST(lttngnotificationincludedir) |
| | 1171 | |
| | 1172 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1173 | AC_SUBST(lttngtriggerincludedir) |
| | 1174 | |
| | 1175 | lttngeventruleincludedir="${includedir}/lttng/event-rule" |
| | 1176 | AC_SUBST(lttngeventruleincludedir) |
| | 1177 | |
| | 1178 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1179 | AC_SUBST(lttnglibexecdir) |
| | 1180 | |
| | 1181 | AC_CONFIG_FILES([ |
| | 1182 | Makefile |
| | 1183 | doc/Makefile |
| | 1184 | doc/examples/Makefile |
| | 1185 | doc/examples/rotation/Makefile |
| | 1186 | doc/examples/trigger-condition-event-matches/Makefile |
| | 1187 | doc/man/Makefile |
| | 1188 | doc/man/asciidoc-attrs.conf |
| | 1189 | include/Makefile |
| | 1190 | extras/Makefile |
| | 1191 | extras/bindings/Makefile |
| | 1192 | extras/bindings/swig/Makefile |
| | 1193 | extras/bindings/swig/python/Makefile |
| | 1194 | extras/core-handler/Makefile |
| | 1195 | src/Makefile |
| | 1196 | src/common/Makefile |
| | 1197 | src/lib/Makefile |
| | 1198 | src/lib/lttng-ctl/Makefile |
| | 1199 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1200 | src/bin/Makefile |
| | 1201 | src/bin/lttng-consumerd/Makefile |
| | 1202 | src/bin/lttng-sessiond/Makefile |
| | 1203 | src/bin/lttng-relayd/Makefile |
| | 1204 | src/bin/lttng/Makefile |
| | 1205 | src/bin/lttng-crash/Makefile |
| | 1206 | src/vendor/Makefile |
| | 1207 | src/vendor/msgpack/Makefile |
| | 1208 | tests/Makefile |
| | 1209 | tests/destructive/Makefile |
| | 1210 | tests/meta/Makefile |
| | 1211 | tests/regression/Makefile |
| | 1212 | tests/regression/kernel/Makefile |
| | 1213 | tests/regression/tools/Makefile |
| | 1214 | tests/regression/tools/streaming/Makefile |
| | 1215 | tests/regression/tools/filtering/Makefile |
| | 1216 | tests/regression/tools/health/Makefile |
| | 1217 | tests/regression/tools/tracefile-limits/Makefile |
| | 1218 | tests/regression/tools/snapshots/Makefile |
| | 1219 | tests/regression/tools/live/Makefile |
| | 1220 | tests/regression/tools/exclusion/Makefile |
| | 1221 | tests/regression/tools/save-load/Makefile |
| | 1222 | tests/regression/tools/save-load/configuration/Makefile |
| | 1223 | tests/regression/tools/mi/Makefile |
| | 1224 | tests/regression/tools/wildcard/Makefile |
| | 1225 | tests/regression/tools/channel/Makefile |
| | 1226 | tests/regression/tools/crash/Makefile |
| | 1227 | tests/regression/tools/regen-metadata/Makefile |
| | 1228 | tests/regression/tools/regen-statedump/Makefile |
| | 1229 | tests/regression/tools/notification/Makefile |
| | 1230 | tests/regression/tools/rotation/Makefile |
| | 1231 | tests/regression/tools/base-path/Makefile |
| | 1232 | tests/regression/tools/metadata/Makefile |
| | 1233 | tests/regression/tools/tracker/Makefile |
| | 1234 | tests/regression/tools/working-directory/Makefile |
| | 1235 | tests/regression/tools/relayd-grouping/Makefile |
| | 1236 | tests/regression/tools/clear/Makefile |
| | 1237 | tests/regression/tools/trigger/Makefile |
| | 1238 | tests/regression/tools/trigger/rate-policy/Makefile |
| | 1239 | tests/regression/tools/trigger/start-stop/Makefile |
| | 1240 | tests/regression/tools/trigger/utils/Makefile |
| | 1241 | tests/regression/tools/trigger/name/Makefile |
| | 1242 | tests/regression/tools/trigger/hidden/Makefile |
| | 1243 | tests/regression/tools/context/Makefile |
| | 1244 | tests/regression/tools/client/Makefile |
| | 1245 | tests/regression/ust/Makefile |
| | 1246 | tests/regression/ust/nprocesses/Makefile |
| | 1247 | tests/regression/ust/high-throughput/Makefile |
| | 1248 | tests/regression/ust/low-throughput/Makefile |
| | 1249 | tests/regression/ust/before-after/Makefile |
| | 1250 | tests/regression/ust/buffers-pid/Makefile |
| | 1251 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1252 | tests/regression/ust/multi-session/Makefile |
| | 1253 | tests/regression/ust/multi-lib/Makefile |
| | 1254 | tests/regression/ust/overlap/Makefile |
| | 1255 | tests/regression/ust/overlap/demo/Makefile |
| | 1256 | tests/regression/ust/linking/Makefile |
| | 1257 | tests/regression/ust/daemon/Makefile |
| | 1258 | tests/regression/ust/exit-fast/Makefile |
| | 1259 | tests/regression/ust/fork/Makefile |
| | 1260 | tests/regression/ust/libc-wrapper/Makefile |
| | 1261 | tests/regression/ust/baddr-statedump/Makefile |
| | 1262 | tests/regression/ust/ust-dl/Makefile |
| | 1263 | tests/regression/ust/java-jul/Makefile |
| | 1264 | tests/regression/ust/java-log4j/Makefile |
| | 1265 | tests/regression/ust/java-log4j2/Makefile |
| | 1266 | tests/regression/ust/getcpu-override/Makefile |
| | 1267 | tests/regression/ust/clock-override/Makefile |
| | 1268 | tests/regression/ust/type-declarations/Makefile |
| | 1269 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1270 | tests/regression/ust/blocking/Makefile |
| | 1271 | tests/regression/ust/namespaces/Makefile |
| | 1272 | tests/regression/ust/ust-constructor/Makefile |
| | 1273 | tests/stress/Makefile |
| | 1274 | tests/unit/Makefile |
| | 1275 | tests/unit/ini_config/Makefile |
| | 1276 | tests/perf/Makefile |
| | 1277 | tests/utils/Makefile |
| | 1278 | tests/utils/lttngtest/Makefile |
| | 1279 | tests/utils/tap/Makefile |
| | 1280 | tests/utils/testapp/Makefile |
| | 1281 | tests/utils/testapp/gen-ns-events/Makefile |
| | 1282 | tests/utils/testapp/gen-kernel-test-events/Makefile |
| | 1283 | tests/utils/testapp/gen-py-events/Makefile |
| | 1284 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1285 | tests/utils/testapp/gen-ust-events-constructor/Makefile |
| | 1286 | tests/utils/testapp/gen-ust-events-ns/Makefile |
| | 1287 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1288 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1289 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1290 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1291 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1292 | tests/utils/testapp/userspace-probe-elf-binary/Makefile |
| | 1293 | tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile |
| | 1294 | tests/utils/testapp/userspace-probe-sdt-binary/Makefile |
| | 1295 | tests/utils/xml-utils/Makefile |
| | 1296 | ]) |
| | 1297 | |
| | 1298 | # Inject variable into python test script. |
| | 1299 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1300 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1301 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1302 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1303 | AC_CONFIG_FILES([pre-inst-env],[chmod +x pre-inst-env]) |
| | 1304 | |
| | 1305 | AC_OUTPUT |
| | 1306 | |
| | 1307 | # |
| | 1308 | # Mini-report on what will be built. |
| | 1309 | # |
| | 1310 | |
| | 1311 | PPRINT_INIT |
| | 1312 | PPRINT_SET_INDENT(1) |
| | 1313 | PPRINT_SET_TS(38) |
| | 1314 | |
| | 1315 | AS_ECHO |
| | 1316 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1317 | AS_ECHO |
| | 1318 | |
| | 1319 | AS_IF([test -n "$report_fold"], [ |
| | 1320 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1321 | ], [ |
| | 1322 | AS_ECHO("$version_description") |
| | 1323 | ]) |
| | 1324 | |
| | 1325 | AS_ECHO |
| | 1326 | PPRINT_SUBTITLE([Features]) |
| | 1327 | |
| | 1328 | # Target architecture we're building for. |
| | 1329 | target_arch=$host_cpu |
| | 1330 | [ |
| | 1331 | for f in $CFLAGS; do |
| | 1332 | if test $f = "-m32"; then |
| | 1333 | target_arch="32-bit" |
| | 1334 | elif test $f = "-m64"; then |
| | 1335 | target_arch="64-bit" |
| | 1336 | fi |
| | 1337 | done |
| | 1338 | ] |
| | 1339 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1340 | |
| | 1341 | # kmod enabled/disabled |
| | 1342 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1343 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1344 | |
| | 1345 | # LTTng-UST enabled/disabled |
| | 1346 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1347 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1348 | |
| | 1349 | AS_ECHO |
| | 1350 | PPRINT_SUBTITLE([Binaries]) |
| | 1351 | |
| | 1352 | # List binaries to be built |
| | 1353 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1354 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1355 | |
| | 1356 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1357 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1358 | |
| | 1359 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1360 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1361 | |
| | 1362 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1363 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1364 | |
| | 1365 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1366 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1367 | |
| | 1368 | # Extras |
| | 1369 | test x$enable_extras != xno && value=1 || value=0 |
| | 1370 | AS_ECHO |
| | 1371 | PPRINT_SET_INDENT(0) |
| | 1372 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1373 | PPRINT_SET_INDENT(1) |
| | 1374 | |
| | 1375 | AS_ECHO |
| | 1376 | PPRINT_SUBTITLE([Tests]) |
| | 1377 | |
| | 1378 | # Print clear message that tests won't be built |
| | 1379 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1380 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1381 | ]) |
| | 1382 | |
| | 1383 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1384 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1385 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1386 | |
| | 1387 | # LTTng UST Java agent Log4j 1.x tests enabled/disabled |
| | 1388 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1389 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value) |
| | 1390 | |
| | 1391 | # LTTng UST Java agent Log4j 2.x tests enabled/disabled |
| | 1392 | test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0 |
| | 1393 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value) |
| | 1394 | |
| | 1395 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1396 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1397 | |
| | 1398 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1399 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1400 | |
| | 1401 | # userspace-probe SDT instrumentation tests enabled/disabled |
| | 1402 | test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0 |
| | 1403 | PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value) |
| | 1404 | |
| | 1405 | #Python binding enabled/disabled |
| | 1406 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1407 | AS_ECHO |
| | 1408 | PPRINT_SET_INDENT(0) |
| | 1409 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1410 | |
| | 1411 | # man pages build enabled/disabled |
| | 1412 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1413 | |
| | 1414 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1415 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1416 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1417 | ], [ |
| | 1418 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1419 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1420 | ], [ |
| | 1421 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1422 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1423 | $PPRINT_COLOR_SUBTITLE) |
| | 1424 | ]) |
| | 1425 | ]) |
| | 1426 | ], [ |
| | 1427 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1428 | ]) |
| | 1429 | |
| | 1430 | m4_popdef([build_man_pages_msg]) |
| | 1431 | |
| | 1432 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1433 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1434 | |
| | 1435 | PPRINT_SET_INDENT(1) |
| | 1436 | |
| | 1437 | report_bindir="`eval eval echo $bindir`" |
| | 1438 | report_libdir="`eval eval echo $libdir`" |
| | 1439 | |
| | 1440 | # Print the bindir and libdir this `make install' will install into. |
| | 1441 | AS_ECHO |
| | 1442 | PPRINT_SUBTITLE([Install directories]) |
| | 1443 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1444 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1445 | |
| | 1446 | AS_ECHO |
| | 1447 | PPRINT_SUBTITLE([Search directories]) |
| | 1448 | |
| | 1449 | # If we build the sessiond, print the paths it will use |
| | 1450 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1451 | path="$report_bindir/lttng-sessiond" |
| | 1452 | ],[ |
| | 1453 | path="$SESSIOND_BIN" |
| | 1454 | ]) |
| | 1455 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1456 | |
| | 1457 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1458 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1459 | ],[ |
| | 1460 | path="$CONSUMERD32_BIN" |
| | 1461 | ]) |
| | 1462 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1463 | |
| | 1464 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1465 | path="`eval eval echo $libdir`" |
| | 1466 | ],[ |
| | 1467 | path="$CONSUMERD32_LIBDIR" |
| | 1468 | ]) |
| | 1469 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1470 | |
| | 1471 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1472 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1473 | ],[ |
| | 1474 | path="$CONSUMERD64_BIN" |
| | 1475 | ]) |
| | 1476 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1477 | |
| | 1478 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1479 | path="`eval eval echo $libdir`" |
| | 1480 | ],[ |
| | 1481 | path="$CONSUMERD64_LIBDIR" |
| | 1482 | ]) |
| | 1483 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1484 | PPRINT_SET_INDENT(0) |
| | 1485 | |
| | 1486 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1487 | AS_ECHO |
| | 1488 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1489 | |
| | 1490 | Note that the man pages are already built in this distribution tarball, |
| | 1491 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1492 | their sources. |
| | 1493 | |
| | 1494 | Also note that the installed man pages will contain the project's |
| | 1495 | default command-line option and environment variable values. |
| | 1496 | |
| | 1497 | Use --disable-man-pages to completely disable building and installing |
| | 1498 | the man pages.]) |
| | 1499 | ]) |
projects / lttng-tools.git / blame_incremental