configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.8.9],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [2:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 # Allow overriding storage used for TLS variables.
  32 AC_ARG_ENABLE([compiler-tls],
  33         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  34         [def_compiler_tls=$enableval],
  35         [def_compiler_tls="yes"])
  36
  37 # If not overridden, use ax_tls.m4 to check if TLS is available.
  38 AS_IF([test "x$def_compiler_tls" = "xyes"],
  39         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  40         [:])
  41
  42 AS_IF([test "x$def_tls_detect" = "x"],
  43         [:],
  44         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 LT_INIT
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_INLINE
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55
  56 # Checks for library functions.
  57 AC_FUNC_MALLOC
  58 AC_FUNC_MMAP
  59 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  60
  61 # Find arch type
  62 AS_CASE([$host_cpu],
  63         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  64         [i486], [ARCHTYPE="x86"],
  65         [i586], [ARCHTYPE="x86"],
  66         [i686], [ARCHTYPE="x86"],
  67         [amd64], [ARCHTYPE="x86"],
  68         [x86_64], [ARCHTYPE="x86"],
  69         [powerpc], [ARCHTYPE="ppc"],
  70         [ppc64], [ARCHTYPE="ppc"],
  71         [powerpc64], [ARCHTYPE="ppc"],
  72         [powerpc64le], [ARCHTYPE="gcc"],
  73         [ppc], [ARCHTYPE="ppc"],
  74         [s390], [ARCHTYPE="s390"],
  75         [s390x], [ARCHTYPE="s390"],
  76         [sparc], [ARCHTYPE="sparc64"],
  77         [sparc64], [ARCHTYPE="sparc64"],
  78         [alpha*], [ARCHTYPE="alpha"],
  79         [ia64], [ARCHTYPE="gcc"],
  80         [arm*], [ARCHTYPE="arm"],
  81         [aarch64], [ARCHTYPE="gcc"],
  82         [mips*], [ARCHTYPE="mips"],
  83         [tile*], [ARCHTYPE="gcc"],
  84         [ARCHTYPE="unknown"]
  85 )
  86
  87 AC_SUBST(ARCHTYPE)
  88 AC_SUBST(SUBARCHTYPE)
  89
  90 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  91 ARCHSRC=urcu/arch/$ARCHTYPE.h
  92
  93 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  94         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  95 ])
  96
  97 AS_IF([test "$host_cpu" = "armv7l"],[
  98         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
  99 ])
 100
 101 # ARM-specific checks
 102 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 103         AC_MSG_CHECKING([for dmb instruction])
 104         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 105                                 int main()
 106                                 {
 107                                         asm volatile("dmb":::"memory");
 108                                         return 0;
 109                                 }
 110                 ]])
 111         ],[
 112                 AC_MSG_RESULT([yes])
 113                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 114         ],[
 115                 AC_MSG_RESULT([no])
 116         ])
 117 ])
 118
 119 # Tile-specific checks
 120 AS_IF([echo "$host_cpu" | grep "^tile"],[
 121         AC_MSG_CHECKING([for Tile architecture type])
 122         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 123                                 #ifndef __tilegx__
 124                                 #error
 125                                 #endif
 126                 ]])
 127         ],[
 128                 AC_MSG_RESULT([ok])
 129         ],[
 130                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 131         ])
 132 ])
 133
 134 # x86-specific checks
 135 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 136         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 137         #For now, using lock; addl compatibility mode even for i686, because the
 138         #Pentium III is seen as a i686, but lacks mfence instruction.
 139         #Only using fence for x86_64.
 140         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 141                 AC_MSG_RESULT([yes])
 142                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 143         ],[
 144                 AC_MSG_RESULT([no])
 145         ])
 146 ])
 147
 148 # Check if sys_futex() is available
 149 AC_MSG_CHECKING([for sys_futex()])
 150 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 151                 #include <sys/syscall.h>
 152                 #ifndef __NR_futex
 153                 #error "futexes not available"
 154                 #endif
 155         ]])
 156 ],[
 157         AC_MSG_RESULT([yes])
 158         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 159         compat_futex_test=0
 160 ],[
 161         AC_MSG_RESULT([no])
 162         compat_futex_test=1
 163 ])
 164
 165 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 166 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 167 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 168
 169 # smp-support configure option
 170 AC_ARG_ENABLE([smp-support],
 171         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 172         [def_smp_support=$enableval],
 173         [def_smp_support="yes"])
 174 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 175
 176
 177 # From the sched_setaffinity(2)'s man page:
 178 # ~~~~
 179 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 180 # The library interfaces were introduced in glibc 2.3.  Initially, the
 181 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 182 # the cpuset size argument was removed, but this argument was
 183 # restored in glibc 2.3.4.
 184 # ~~~~
 185
 186 # In addition to that, some vendors ported the system call to 2.4
 187 # kernels.
 188
 189 # Furthermore, when the function first appeared, the MASK argument was
 190 # an unsigned long pointer, while later it was made into a cpu_set_t
 191 # pointer.  Systems that have the cpu_set_t version also should have
 192 # the CPU_ZERO, CPU_SET, etc. macros.
 193
 194 # All this mess means we have to cater for at least 3 different
 195 # sched_setaffinity prototypes:
 196
 197 # ~~~~
 198 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 199 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 200 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 201 # ~~~~
 202
 203 # Since we define _GNU_SOURCE in the sources, must do so too in the
 204 # autoconf tests, as defining _GNU_SOURCE or not exposes
 205 # sched_setaffinity bits differently.
 206 saved_CFLAGS=$CFLAGS
 207 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 208
 209 AC_CHECK_TYPES([cpu_set_t],
 210         [have_cpu_set_t="yes"],
 211         [have_cpu_set_t="no"],
 212         [#include <sched.h>])
 213
 214 # Confirm that we have CPU_ZERO, and it actually works.
 215 AC_MSG_CHECKING([whether CPU_ZERO works])
 216 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 217 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 218                 #define _GNU_SOURCE
 219                 #include <sched.h>
 220                 int main()
 221                 {
 222                         cpu_set_t foo; CPU_ZERO(&foo);
 223                         return 0;
 224                 }
 225         ]])
 226 ],[
 227         AC_DEFINE(HAVE_CPU_ZERO, 1)
 228         AC_MSG_RESULT([yes])
 229 ],[
 230         AC_MSG_RESULT([no])
 231 ])
 232
 233 # Confirm that we have CPU_SET, and it actually works.
 234 AC_MSG_CHECKING([whether CPU_SET works])
 235 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 236 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 237                 #define _GNU_SOURCE
 238                 #include <sched.h>
 239                 int main()
 240                 {
 241                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 242                         return 0;
 243                 }
 244         ]])
 245 ],[
 246         AC_DEFINE(HAVE_CPU_SET, 1)
 247         AC_MSG_RESULT([yes])
 248 ],[
 249         AC_MSG_RESULT([no])
 250 ])
 251
 252 # First check if the function is available at all.
 253 AC_CHECK_FUNCS([sched_setaffinity],[
 254         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 255         # then we have the first version using unsigned long, and no
 256         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 257         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 258         # should also be present, but we confirm nonetheless.
 259
 260         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 261                 # We do have it.
 262                 # Check how many arguments does sched_setaffinity take.
 263                 # Should be 3 or 2.
 264                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 265                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 266                                 #include <sched.h>
 267                                 int main()
 268                                 {
 269                                         cpu_set_t foo;
 270                                         sched_setaffinity(0, sizeof (foo), &foo);
 271                                         return 0;
 272                                 }
 273                         ]])
 274                 ],
 275                 [sched_set_affinity_args=3],
 276                 [sched_set_affinity_args=2])
 277                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 278                         $sched_set_affinity_args,
 279                         [Defined to sched_setaffinity's number of arguments.])
 280                 AC_MSG_RESULT([$sched_set_affinity_args])
 281         ],[
 282                 # No cpu_set_t, always 3 args.
 283                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 284         ])
 285 ])
 286
 287 CFLAGS=$saved_CFLAGS
 288
 289 AC_CONFIG_LINKS([
 290         urcu/arch.h:$ARCHSRC
 291         urcu/uatomic.h:$UATOMICSRC
 292 ])
 293 AC_CONFIG_FILES([
 294         Makefile
 295         doc/Makefile
 296         doc/examples/Makefile
 297         tests/Makefile
 298         tests/common/Makefile
 299         tests/unit/Makefile
 300         tests/benchmark/Makefile
 301         tests/regression/Makefile
 302         liburcu.pc
 303         liburcu-bp.pc
 304         liburcu-cds.pc
 305         liburcu-qsbr.pc
 306         liburcu-mb.pc
 307         liburcu-signal.pc
 308 ])
 309 AC_OUTPUT
 310
 311 # Report on selected configure options
 312 AS_IF([test "x$def_smp_support" = "xyes"],[
 313         AS_ECHO("SMP support enabled.")
 314 ],[
 315         AS_ECHO("SMP support disabled.")
 316 ])
 317
 318 AS_IF([test "x$def_tls_detect" = "x"],[
 319         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 320 ],[
 321         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 322 ])