configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7
   8 # Project version information
   9 m4_define([ust_version_major], [2])
  10 m4_define([ust_version_minor], [13])
  11 m4_define([ust_version_patch], [0])
  12 m4_define([ust_version_dev_stage], [-pre])
  13 m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
  14 m4_define([ust_version_name], [[Codename TBD]])
  15 m4_define([ust_version_description], [[Description TBD]])
  16
  17 # Library version information of "liblttng-ust"
  18 # Following the numbering scheme proposed by libtool for the library version
  19 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  20 m4_define([ust_lib_version_current], [1])
  21 m4_define([ust_lib_version_revision], [0])
  22 m4_define([ust_lib_version_age], [0])
  23 m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
  24
  25 # Library version information of "liblttng-ust-ctl"
  26 # Following the numbering scheme proposed by libtool for the library version
  27 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  28 m4_define([ust_ctl_lib_version_current], [5])
  29 m4_define([ust_ctl_lib_version_revision], [0])
  30 m4_define([ust_ctl_lib_version_age], [0])
  31 m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
  32
  33
  34 ##                     ##
  35 ## Autoconf base setup ##
  36 ##                     ##
  37
  38 AC_PREREQ([2.69])
  39 AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
  40
  41 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
  42 AC_CONFIG_AUX_DIR([config])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  45
  46 AC_CANONICAL_TARGET
  47 AC_CANONICAL_HOST
  48
  49
  50 ##                     ##
  51 ## Automake base setup ##
  52 ##                     ##
  53
  54 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  55 AM_MAINTAINER_MODE([enable])
  56
  57 # Enable silent rules by default
  58 AM_SILENT_RULES([yes])
  59
  60 # Checks for C compiler
  61 AC_USE_SYSTEM_EXTENSIONS
  62 AC_SYS_LARGEFILE
  63 AC_PROG_CC
  64 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  65 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  66 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
  67 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
  68
  69 # Check if the compiler support weak symbols
  70 AX_SYS_WEAK_ALIAS
  71
  72 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  73         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  74 ])
  75
  76 # Checks for programs.
  77 AM_PROG_AR
  78 AC_PROG_SED
  79 AC_PROG_GREP
  80 AC_PROG_LN_S
  81 AC_PROG_MKDIR_P
  82 AC_PROG_MAKE_SET
  83 AC_CHECK_PROG([CMAKE], [cmake])
  84 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
  85
  86 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  87 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  88 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  89 ], [
  90         libtool_fixup=$enableval
  91 ], [
  92         libtool_fixup=yes
  93 ])
  94
  95 AS_IF([test "x$libtool_fixup" = "xyes"], [
  96         libtool_m4="$srcdir/m4/libtool.m4"
  97         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  98         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  99         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 100
 101         AS_IF([test $libtool_flag_pattern_count -ne 0], [
 102         AC_MSG_RESULT([$libtool_flag_pattern_count])
 103         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 104                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 105         ], [
 106                 AC_MSG_RESULT([none])
 107         ])
 108 ])
 109 LT_INIT([disable-static])
 110
 111 AC_MSG_CHECKING([whether shared libraries are enabled])
 112 AS_IF([test "x$enable_shared" = "xyes"], [
 113         AC_MSG_RESULT([yes])
 114 ], [
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 117 ])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_TYPE_INT8_T
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_MODE_T
 126 AC_TYPE_OFF_T
 127 AC_TYPE_PID_T
 128 AC_TYPE_SIZE_T
 129 AC_TYPE_SSIZE_T
 130 AC_TYPE_UID_T
 131 AC_TYPE_UINT8_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_CHECK_TYPES([ptrdiff_t])
 136
 137 AX_C___ATTRIBUTE__
 138 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 139         [:],
 140         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 141
 142 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 143
 144 # Checks for library functions.
 145 AC_FUNC_CHOWN
 146 AC_FUNC_FORK
 147 AC_FUNC_MMAP
 148 AC_FUNC_REALLOC
 149 AC_FUNC_STRERROR_R
 150 AC_FUNC_STRNLEN
 151 AC_CHECK_FUNCS([ \
 152         atexit \
 153         clock_gettime \
 154         ftruncate \
 155         getpagesize \
 156         gettimeofday \
 157         localeconv \
 158         memchr \
 159         memmove \
 160         memset \
 161         mkdir \
 162         munmap \
 163         realpath \
 164         sched_getcpu \
 165         socket \
 166         strchr \
 167         strdup \
 168         strerror \
 169         strtol \
 170         strtoul \
 171         sysconf \
 172 ])
 173
 174 # Check for pthread_setname_np and its signature
 175 LTTNG_PTHREAD_SETNAME_NP
 176 LTTNG_PTHREAD_GETNAME_NP
 177
 178 # AC_FUNC_MALLOC causes problems when cross-compiling.
 179 #AC_FUNC_MALLOC
 180
 181 # Checks for header files.
 182 AC_HEADER_STDBOOL
 183 AC_CHECK_HEADERS([ \
 184         arpa/inet.h \
 185         fcntl.h \
 186         float.h \
 187         limits.h \
 188         locale.h \
 189         stddef.h \
 190         sys/socket.h \
 191         sys/time.h \
 192         wchar.h \
 193 ])
 194
 195 # Set architecture specific options
 196 AS_CASE([$host_cpu],
 197         [i[[3456]]86], [],
 198         [x86_64], [],
 199         [amd64], [],
 200         [powerpc], [],
 201         [ppc64], [],
 202         [ppc64le], [],
 203         [powerpc64], [],
 204         [powerpc64le], [],
 205         [s390], [],
 206         [s390x], [],
 207         [arm*], [
 208                 NO_NUMA=1
 209                 ],
 210         [aarch64*], [],
 211         [mips*], [],
 212         [tile*], [],
 213         [
 214                 UNSUPPORTED_ARCH=1
 215         ])
 216
 217 # Set os specific options
 218 AS_CASE([$host_os],
 219         [freebsd*], [NO_NUMA=1]
 220 )
 221
 222 # Configuration options, which will be installed in the config.h
 223 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 224
 225 # Checks for libraries.
 226 AC_CHECK_LIB([dl], [dlopen], [
 227         libdl_name=dl
 228         DL_LIBS="-ldl"
 229 ], [
 230         #libdl not found, check for dlopen in libc.
 231         AC_CHECK_LIB([c], [dlopen], [
 232                 libdl_name=c
 233                 DL_LIBS="-lc"
 234         ], [
 235                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 236         ])
 237 ])
 238 AC_SUBST(DL_LIBS)
 239
 240 # Check if libdl has dlmopen support.
 241 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 242 AC_CHECK_LIB([$libdl_name], [dlmopen],
 243         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 244 )
 245
 246 # Check for dlfcn.h
 247 AC_CHECK_HEADER([dlfcn.h])
 248 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 249         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 250                 #include <dlfcn.h>
 251         ])
 252 ], [
 253         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 254 ])
 255
 256 AM_CONDITIONAL([ENABLE_UST_DL], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 257
 258 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 259 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 260
 261 # numa.h integration
 262 AS_IF([test "x$NO_NUMA" = "x1"],[
 263       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 264 ])
 265
 266 AC_ARG_ENABLE([numa], [
 267 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 268 ], [
 269         enable_numa=$enableval
 270 ], [
 271         enable_numa=yes
 272 ])
 273
 274 AS_IF([test "x$enable_numa" = "xyes"], [
 275         # numa - check that numa lib is available
 276         AC_CHECK_LIB([numa], [numa_available], [],
 277 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 278         have_libnuma=yes
 279 ])
 280 AM_CONDITIONAL([ENABLE_NUMA], [test "x$have_libnuma" = "xyes"])
 281
 282 # optional linux/perf_event.h
 283 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 284
 285 # Perf event counters are supported on all architectures supported by
 286 # perf, using the read system call as fallback.
 287 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 288
 289 AH_TEMPLATE([HAVE_PERF_EVENT], ["Perf event integration via perf_event.h"])
 290 AS_IF([test "x$have_perf_event" = "xyes"], [
 291         AC_DEFINE([HAVE_PERF_EVENT], [1])
 292 ])
 293
 294 # Check for JNI header files if requested
 295 AC_ARG_ENABLE([jni-interface], [
 296 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 297 ], [
 298         jni_interface=$enableval
 299 ], [
 300         jni_interface=no
 301 ])
 302
 303 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 304
 305
 306 AC_ARG_ENABLE([java-agent-jul], [
 307 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 308 ], [
 309         java_agent_jul=$enableval
 310 ], [
 311         java_agent_jul=no
 312 ])
 313
 314 AC_ARG_ENABLE([java-agent-log4j], [
 315 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 316 ], [
 317         java_agent_log4j=$enableval
 318 ], [
 319         java_agent_log4j=no
 320 ])
 321
 322 AC_ARG_ENABLE([java-agent-all], [
 323 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 324 ], [
 325         java_agent_jul=$enableval
 326         java_agent_log4j=$enableval
 327 ], [:])
 328
 329 AM_CONDITIONAL([ENABLE_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 330 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 331 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 332
 333 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 334         AX_JAVA_OPTIONS
 335         AX_PROG_JAVAC
 336         AX_PROG_JAVA
 337         AX_PROG_JAR
 338         AC_ARG_VAR([CLASSPATH], [Java class path])
 339
 340         AX_JNI_INCLUDE_DIR
 341         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 342         do
 343                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 344         done
 345
 346         saved_CPPFLAGS="$CPPFLAGS"
 347         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 348         AX_PROG_JAVAH
 349         CPPFLAGS="$saved_CPPFLAGS"
 350 ])
 351
 352 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 353
 354 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 355         AX_CHECK_CLASSPATH
 356         AX_CHECK_CLASS([org.apache.log4j.Logger])
 357         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 358                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 359         ])
 360 ])
 361
 362 # Option to build the python agent
 363 AC_ARG_ENABLE([python-agent], [
 364 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 365 ], [
 366         python_agent=$enableval
 367 ], [:])
 368 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 369 AS_IF([test "x$python_agent" = "xyes"], [
 370         AM_PATH_PYTHON([2.7])
 371 ])
 372
 373 # sdt.h integration
 374 AC_ARG_WITH([sdt], [
 375 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 376 ], [
 377         with_sdt=$withval
 378 ], [
 379         with_sdt="no"
 380 ])
 381
 382 AS_IF([test "x$with_sdt" = "xyes"], [
 383         AC_MSG_CHECKING([STAP_PROBEV()])
 384         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 385                 #define SDT_USE_VARIADIC
 386                 #include <sys/sdt.h>
 387                 void fct(void)
 388                 {
 389                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 390                 }
 391         ]])], [
 392                 AC_MSG_RESULT([yes])
 393                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 394         ], [
 395                 AC_MSG_RESULT([no])
 396                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 397         ])
 398 ])
 399
 400 AC_ARG_WITH([lttng-system-rundir], [
 401 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 402 ], [
 403         lttng_system_rundir="$withval"
 404 ], [
 405         lttng_system_rundir="/var/run/lttng"
 406 ])
 407 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 408                 [LTTng system runtime directory])
 409
 410 AC_CHECK_PROG([ENABLE_GEN_TP_EXAMPLES], [python], ["yes"])
 411 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$ENABLE_GEN_TP_EXAMPLES" = "xyes"])
 412
 413 # Enable building examples
 414 AC_ARG_ENABLE(
 415         examples,
 416         AS_HELP_STRING(
 417                 [--disable-examples],
 418                 [Do not build and install examples]
 419         ),
 420         [enable_examples=$enableval],
 421         [enable_examples=yes]
 422 )
 423
 424 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 425
 426 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 427 # is not distributed in tarballs.
 428 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 429 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 430
 431 # Enable building man pages (user's intention).
 432 AC_ARG_ENABLE(
 433         man-pages,
 434         AS_HELP_STRING(
 435                 [--disable-man-pages],
 436                 [Do not build and install man pages (already built in a distributed tarball)]
 437         ),
 438         [man_pages_opt=$enableval],
 439         [man_pages_opt=yes]
 440 )
 441
 442 # Check for asciidoc and xmlto if we enabled building the man pages.
 443 have_asciidoc_xmlto=no
 444 warn_prebuilt_man_pages=no
 445
 446 AS_IF([test "x$man_pages_opt" = "xyes"], [
 447         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 448         AC_PATH_PROG([XMLTO], [xmlto], [no])
 449
 450         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 451                 AS_IF([test "x$in_git_repo" = "xyes"], [
 452                         # This is an error because we're in the Git repo, which
 453                         # means the man pages are not already generated for us,
 454                         # thus asciidoc/xmlto are required because we were asked
 455                         # to build the man pages.
 456                         AC_MSG_ERROR([
 457 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 458 --disable-man-pages to disable building the man pages, in which case
 459 they will not be installed.
 460                         ])
 461                 ], [
 462                         # Only warn here: since we're in the tarball, the man
 463                         # pages should already be generated at this point, thus
 464                         # asciidoc/xmlto are not strictly required.
 465                         warn_prebuilt_man_pages=yes
 466                 ])
 467         ], [
 468                 have_asciidoc_xmlto=yes
 469         ])
 470 ])
 471
 472 # Export man page build condition: build the man pages if the user
 473 # asked for it, and if the tools are available.
 474 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$man_pages_opt" != "xno"])
 475 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 476
 477
 478 # Defined in include/lttng/ust-version.h
 479 AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
 480 AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
 481 AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
 482 AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
 483 AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
 484 AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
 485
 486
 487 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
 488 AC_SUBST(AM_CFLAGS)
 489
 490 AM_CXXFLAGS="$AM_CFLAGS"
 491 AC_SUBST(AM_CXXFLAGS)
 492
 493 # The order in which the include folders are searched is important.
 494 # The top_builddir should always be searched first in the event that a build
 495 # time generated file is included.
 496 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 497 AC_SUBST(AM_CPPFLAGS)
 498
 499 AC_SUBST(JNI_CPPFLAGS)
 500
 501
 502 ##                                     ##
 503 ## Output files generated by configure ##
 504 ##                                     ##
 505
 506 # List of files to be generated from '.in' templates by AC_OUTPUT
 507 AC_CONFIG_FILES([
 508         Makefile
 509         doc/Makefile
 510         doc/examples/Makefile
 511         doc/man/Makefile
 512         include/Makefile
 513         snprintf/Makefile
 514         libcounter/Makefile
 515         libmsgpack/Makefile
 516         libringbuffer/Makefile
 517         liblttng-ust-comm/Makefile
 518         liblttng-ust/Makefile
 519         liblttng-ust-ctl/Makefile
 520         liblttng-ust-fork/Makefile
 521         liblttng-ust-dl/Makefile
 522         liblttng-ust-fd/Makefile
 523         liblttng-ust-java/Makefile
 524         liblttng-ust-java-agent/Makefile
 525         liblttng-ust-java-agent/java/Makefile
 526         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 527         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 528         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 529         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 530         liblttng-ust-java-agent/jni/Makefile
 531         liblttng-ust-java-agent/jni/common/Makefile
 532         liblttng-ust-java-agent/jni/jul/Makefile
 533         liblttng-ust-java-agent/jni/log4j/Makefile
 534         liblttng-ust-libc-wrapper/Makefile
 535         liblttng-ust-cyg-profile/Makefile
 536         liblttng-ust-python-agent/Makefile
 537         python-lttngust/Makefile
 538         python-lttngust/setup.py
 539         python-lttngust/lttngust/__init__.py
 540         tools/Makefile
 541         tests/Makefile
 542         tests/compile/Makefile
 543         tests/compile/ctf-types/Makefile
 544         tests/compile/hello.cxx/Makefile
 545         tests/compile/hello/Makefile
 546         tests/compile/hello-many/Makefile
 547         tests/compile/same_line_tracepoint/Makefile
 548         tests/compile/test-app-ctx/Makefile
 549         tests/benchmark/Makefile
 550         tests/unit/gcc-weak-hidden/Makefile
 551         tests/unit/libmsgpack/Makefile
 552         tests/unit/Makefile
 553         tests/unit/libringbuffer/Makefile
 554         tests/unit/pthread_name/Makefile
 555         tests/unit/snprintf/Makefile
 556         tests/unit/ust-elf/Makefile
 557         tests/utils/Makefile
 558         lttng-ust.pc
 559         lttng-ust-ctl.pc
 560 ])
 561
 562 AC_OUTPUT
 563
 564
 565 ##                                    ##
 566 ## Mini-report on what will be built. ##
 567 ##                                    ##
 568
 569 PPRINT_INIT
 570 PPRINT_SET_INDENT(1)
 571 PPRINT_SET_TS(38)
 572
 573 AS_ECHO
 574 AS_IF([test -n "ust_version_name"], [
 575   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
 576 ], [
 577   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
 578 ])
 579
 580 AS_ECHO
 581
 582 AS_IF([test -n "ust_version_description"], [
 583   AS_IF([test -n "$FOLD"], [
 584     AS_ECHO("`AS_ECHO("ust_version_description") | $FOLD -s`")
 585   ], [
 586     AS_ECHO("ust_version_description")
 587   ])
 588   AS_ECHO
 589 ])
 590
 591 PPRINT_SUBTITLE([System])
 592
 593 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 594
 595 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 596        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 597 ])
 598
 599 AS_ECHO
 600 PPRINT_SUBTITLE([Features])
 601 PPRINT_SET_INDENT(1)
 602
 603 test "x$with_sdt" = "xyes" && value=1 || value=0
 604 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 605
 606 test "x$java_agent_jul" = xyes && value=1 || value=0
 607 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 608
 609 test "x$java_agent_log4j" = xyes && value=1 || value=0
 610 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 611
 612 test "x$jni_interface" = xyes && value=1 || value=0
 613 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 614
 615 test "x$python_agent" = xyes && value=1 || value=0
 616 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 617
 618 test "x$have_perf_event" = "xyes" && value=1 || value=0
 619 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 620
 621 test "x$enable_numa" = xyes && value=1 || value=0
 622 PPRINT_PROP_BOOL([NUMA], $value)
 623
 624 AS_ECHO
 625 PPRINT_SET_INDENT(0)
 626
 627 test "x$enable_examples" = xyes && value=1 || value=0
 628 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 629
 630 # man pages build enabled/disabled
 631 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 632
 633 AS_IF([test "x$man_pages_opt" != "xno"], [
 634         AS_IF([test "x$in_git_repo" = "xyes"], [
 635                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 636         ], [
 637                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 638                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 639                 ], [
 640                         PPRINT_PROP_STRING([build_man_pages_msg],
 641                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 642                                 $PPRINT_COLOR_SUBTITLE)
 643                 ])
 644         ])
 645 ], [
 646         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 647 ])
 648
 649 m4_popdef([build_man_pages_msg])
 650
 651 PPRINT_SET_INDENT(1)
 652
 653 report_bindir="`eval eval echo $bindir`"
 654 report_libdir="`eval eval echo $libdir`"
 655
 656 # Print the bindir and libdir this `make install' will install into.
 657 AS_ECHO
 658 PPRINT_SUBTITLE([Install directories])
 659 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 660 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 661
 662 AS_ECHO
 663 PPRINT_SUBTITLE([System directories])
 664
 665 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 666
 667 PPRINT_SET_INDENT(0)
 668
 669 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 670         AS_ECHO
 671         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 672
 673 Note that the man pages are already built in this distribution tarball,
 674 therefore asciidoc and xmlto are only needed if you intend to modify
 675 their sources.
 676
 677 Use --disable-man-pages to completely disable building and installing
 678 the man pages.])
 679 ])