configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.0-rc1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_MAKE_SET
  42 LT_INIT
  43
  44 ## Checks for libraries.
  45 AC_CHECK_LIB([dl], [dlopen])
  46 AC_CHECK_LIB([pthread], [pthread_create])
  47
  48 # Check for libuuid
  49 AC_CHECK_LIB([uuid], [uuid_generate],
  50 [
  51         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
  52 ],
  53 [
  54         # libuuid not found, check for uuid_create in libc.
  55         AC_CHECK_LIB([c], [uuid_create],
  56         [
  57                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  58         ],
  59         [
  60                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify its location.])
  61         ])
  62 ]
  63 )
  64
  65 # Checks for header files.
  66 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  67
  68 # Checks for typedefs, structures, and compiler characteristics.
  69 AC_C_INLINE
  70 #AC_TYPE_INT16_T
  71 #AC_TYPE_INT32_T
  72 #AC_TYPE_INT64_T
  73 #AC_TYPE_INT8_T
  74 #AC_TYPE_PID_T
  75 #AC_TYPE_SIZE_T
  76 #AC_TYPE_SSIZE_T
  77 #AC_TYPE_UINT16_T
  78 #AC_TYPE_UINT32_T
  79 #AC_TYPE_UINT64_T
  80 #AC_TYPE_UINT8_T
  81 #AC_CHECK_TYPES([ptrdiff_t])
  82
  83 # Checks for library functions.
  84 AC_FUNC_MALLOC
  85 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
  86
  87 CFLAGS="-Wall $CFLAGS"
  88
  89 # Check for texinfo, required for building the documentation
  90 # TODO: make this (and building the documentation) optional
  91 AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
  92 AS_IF([test "x$TEXINFO" != "xyes"],[
  93         AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
  94 ])
  95
  96 # URCU
  97
  98 # urcu - check if we just find the headers it out of the box.
  99 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CFLAGS]=-Idir to specify their location.
 100 This error can also occur when the liburcu package's configure script has not been run.])])
 101
 102 AC_MSG_CHECKING([caa_likely()])
 103 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 104 #include <urcu/compiler.h>
 105 void fct(void)
 106 {
 107         if (caa_likely(1)) {
 108         }
 109 }
 110 ]])],[
 111         AC_MSG_RESULT([yes])
 112 ],[
 113         AC_MSG_RESULT([no])
 114         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 115
 116 ])
 117
 118 # urcu - check that URCU lib is available to compilation
 119 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 120
 121 # urcu - check that URCU lib is at least version 0.6
 122 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 123
 124
 125 # Check for various supplementary host information (beyond the
 126 # triplet) which might affect the library format choices.  E.g., we
 127 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 128
 129 case "${host}" in
 130 changequote(,)dnl
 131   i[34567]86-*-linux*)
 132 changequote([,])dnl
 133     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 134                     [save_CPPFLAGS="$CPPFLAGS"
 135                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 136                     AC_EGREP_CPP([got it], [
 137 #if __x86_64__
 138 got it
 139 #endif
 140                  ], [ust_cv_i386_is_x86_64=yes],
 141                     [ust_cv_i386_is_x86_64=no])
 142                     CPPFLAGS="$save_CPPFLAGS"])
 143     ;;
 144 esac
 145
 146 AC_MSG_CHECKING([library format for the host system])
 147 case $host_cpu in
 148 changequote(,)dnl
 149         i[3456]86)
 150 changequote([,])dnl
 151           if test "$ust_cv_i386_is_x86_64" = yes ; then
 152              LIBFORMAT="elf64-x86-64"
 153           else
 154              LIBFORMAT="elf32-i386"
 155           fi
 156           ;;
 157         x86_64) LIBFORMAT="elf64-x86-64" ;;
 158         powerpc) LIBFORMAT="elf32-powerpc" ;;
 159         ppc64) LIBFORMAT="elf64-powerpc" ;;
 160         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 161         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 162         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 163         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 164         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 165         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 166         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 167 esac
 168 AC_SUBST(LIBFORMAT)
 169 AC_MSG_RESULT($LIBFORMAT)
 170
 171 if test "x$host_cpu" = "xarm" ; then
 172 AC_MSG_CHECKING([checking for armv5])
 173 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 174 #ifndef __ARM_ARCH_5TEJ__
 175 #error "no arm5 here"
 176 #endif
 177 ]])],[
 178         AC_MSG_RESULT([yes])
 179         NO_UNALIGNED_ACCESS=1
 180
 181 ],[
 182         AC_MSG_RESULT([no])
 183
 184 ])
 185 fi
 186 if test x$NO_UNALIGNED_ACCESS = x ; then
 187 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 188 fi
 189
 190 # Set compile flags to java include files if given
 191 AC_ARG_WITH([java-jdk],
 192         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 193         [JAVA_JDK=$withval],
 194         [JAVA_JDK=""]
 195 )
 196 AS_IF([test $JAVA_JDK],[
 197         AS_IF([test -d $JAVA_JDK],[
 198                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 199                 SUBDIRS=`find $JAVA_JDK/include -type d`
 200                 CFLAGS+=" "
 201                 CFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 202                 CFLAGS+=" "
 203         ],[
 204                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 205         ])
 206 ])
 207
 208 # Check for JNI header files if requested
 209 AC_ARG_WITH([jni-interface],
 210         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 211         [jni_interface=$withval],
 212         [jni_interface=no]
 213 )
 214
 215 AS_IF([test "x$jni_interface" = "xyes"],[
 216         AC_CHECK_HEADERS([jni.h],[],[
 217         AC_MSG_ERROR([missing jni.h
 218 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 219 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 220         ])
 221 ])
 222 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 223
 224 # sdt.h integration
 225 AC_ARG_WITH([sdt],
 226         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 227         [with_sdt=$withval],
 228         [with_sdt="no"]
 229 )
 230
 231 AS_IF([test "x$with_sdt" = "xyes"],[
 232         AC_MSG_CHECKING([STAP_PROBEV()])
 233         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 234         #define SDT_USE_VARIADIC
 235         #include <sys/sdt.h>
 236         void fct(void)
 237         {
 238                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 239         }
 240         ]])],[
 241                 AC_MSG_RESULT([yes])
 242                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 243         ],[
 244                 AC_MSG_RESULT([no])
 245                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 246         ])
 247 ])
 248
 249 #currently disabled.
 250         #tests/hello2/Makefile
 251         #tests/basic/Makefile
 252         #tests/simple_include/Makefile
 253         #tests/snprintf/Makefile
 254         #tests/test-nevents/Makefile
 255         #tests/test-libustinstr-malloc/Makefile
 256         #tests/dlopen/Makefile
 257         #tests/same_line_marker/Makefile
 258         #tests/trace_event/Makefile
 259         #tests/tracepoint/Makefile
 260         #tests/tracepoint/benchmark/Makefile
 261         #tests/register_test/Makefile
 262         #tests/libustctl_function_#tests/Makefile
 263         #tests/exit-fast/Makefile
 264         #tests/basic_long/Makefile
 265
 266 AC_CONFIG_FILES([
 267         Makefile
 268         doc/Makefile
 269         doc/examples/Makefile
 270         include/Makefile
 271         include/lttng/ust-version.h
 272         snprintf/Makefile
 273         libringbuffer/Makefile
 274         liblttng-ust-comm/Makefile
 275         liblttng-ust/Makefile
 276         liblttng-ust-ctl/Makefile
 277         liblttng-ust-fork/Makefile
 278         liblttng-ust-java/Makefile
 279         liblttng-ust-libc-wrapper/Makefile
 280         tools/Makefile
 281         tests/Makefile
 282         tests/hello/Makefile
 283         tests/hello-static-lib/Makefile
 284         tests/hello.cxx/Makefile
 285         tests/demo/Makefile
 286         tests/fork/Makefile
 287         tests/ust-basic-tracing/Makefile
 288         tests/ust-multi-test/Makefile
 289         lttng-ust.pc
 290 ])
 291
 292 AC_OUTPUT
 293
 294 # Report on the configuration options
 295 AS_ECHO()
 296 AS_ECHO("LTTng-UST will be built with the following options:")
 297 AS_ECHO("Library format: $LIBFORMAT")
 298
 299 AS_ECHO()
 300 AS_ECHO_N("Java support (JNI): ")
 301 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 302
 303 AS_ECHO_N("sdt.h integration:  ")
 304 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 305
 306 AS_ECHO()
 307 AS_ECHO("Type 'make' to compile.")
 308