configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Annedd'ale"
  38 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  41
  42 # Checks for programs.
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 AC_PROG_MAKE_SET
  46 LT_INIT
  47
  48 ## Checks for libraries.
  49 AC_CHECK_LIB([dl], [dlopen],
  50 [
  51         have_libdl=yes
  52 ],
  53 [
  54         #libdl not found, check for dlopen in libc.
  55         AC_CHECK_LIB([c], [dlopen],
  56         [
  57                 have_libc_dl=yes
  58         ],
  59         [
  60                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
  61         ])
  62 ])
  63 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
  64 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
  65
  66 AC_CHECK_LIB([pthread], [pthread_create])
  67
  68 # Check for libuuid
  69 AC_CHECK_LIB([uuid], [uuid_generate],
  70 [
  71         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
  72         have_libuuid=yes
  73 ],
  74 [
  75         # libuuid not found, check for uuid_create in libc.
  76         AC_CHECK_LIB([c], [uuid_create],
  77         [
  78                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  79                 have_libc_uuid=yes
  80         ],
  81         [
  82                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  83         ])
  84 ]
  85 )
  86 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  87 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  88
  89 # Checks for header files.
  90 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  91
  92 # Checks for typedefs, structures, and compiler characteristics.
  93 AC_C_INLINE
  94 #AC_TYPE_INT16_T
  95 #AC_TYPE_INT32_T
  96 #AC_TYPE_INT64_T
  97 #AC_TYPE_INT8_T
  98 #AC_TYPE_PID_T
  99 #AC_TYPE_SIZE_T
 100 #AC_TYPE_SSIZE_T
 101 #AC_TYPE_UINT16_T
 102 #AC_TYPE_UINT32_T
 103 #AC_TYPE_UINT64_T
 104 #AC_TYPE_UINT8_T
 105 #AC_CHECK_TYPES([ptrdiff_t])
 106
 107 # Checks for library functions.
 108 AC_FUNC_MALLOC
 109 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 110
 111 CFLAGS="-Wall $CFLAGS"
 112
 113 # URCU
 114
 115 # urcu - check if we just find the headers it out of the box.
 116 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 117 This error can also occur when the liburcu package's configure script has not been run.])])
 118
 119 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 120 # Part of Userspace RCU library 0.7.2 or better.
 121 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 122 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 123
 124 AC_MSG_CHECKING([caa_likely()])
 125 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 126 #include <urcu/compiler.h>
 127 void fct(void)
 128 {
 129         if (caa_likely(1)) {
 130         }
 131 }
 132 ]])],[
 133         AC_MSG_RESULT([yes])
 134 ],[
 135         AC_MSG_RESULT([no])
 136         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 137
 138 ])
 139
 140 # urcu - check that URCU lib is available to compilation
 141 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 142
 143 # urcu - check that URCU lib is at least version 0.6
 144 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 145
 146
 147 # Check for various supplementary host information (beyond the
 148 # triplet) which might affect the library format choices.  E.g., we
 149 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 150
 151 case "${host}" in
 152 changequote(,)dnl
 153   i[34567]86-*-linux*)
 154 changequote([,])dnl
 155     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 156                     [save_CPPFLAGS="$CPPFLAGS"
 157                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 158                     AC_EGREP_CPP([got it], [
 159 #if __x86_64__
 160 got it
 161 #endif
 162                  ], [ust_cv_i386_is_x86_64=yes],
 163                     [ust_cv_i386_is_x86_64=no])
 164                     CPPFLAGS="$save_CPPFLAGS"])
 165     ;;
 166 esac
 167
 168 AC_MSG_CHECKING([library format for the host system])
 169 case $host_cpu in
 170 changequote(,)dnl
 171         i[3456]86)
 172 changequote([,])dnl
 173           if test "$ust_cv_i386_is_x86_64" = yes ; then
 174              LIBFORMAT="elf64-x86-64"
 175           else
 176              LIBFORMAT="elf32-i386"
 177           fi
 178           ;;
 179         x86_64) LIBFORMAT="elf64-x86-64" ;;
 180         amd64) LIBFORMAT="elf64-x86-64" ;;
 181         powerpc) LIBFORMAT="elf32-powerpc" ;;
 182         ppc64) LIBFORMAT="elf64-powerpc" ;;
 183         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 184         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 185         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 186         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 187         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 188         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 189         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 190 esac
 191 AC_SUBST(LIBFORMAT)
 192 AC_MSG_RESULT($LIBFORMAT)
 193
 194 if test "x$host_cpu" = "xarm" ; then
 195 AC_MSG_CHECKING([checking for armv5])
 196 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 197 #ifndef __ARM_ARCH_5TEJ__
 198 #error "no arm5 here"
 199 #endif
 200 ]])],[
 201         AC_MSG_RESULT([yes])
 202         NO_UNALIGNED_ACCESS=1
 203
 204 ],[
 205         AC_MSG_RESULT([no])
 206
 207 ])
 208 fi
 209 if test x$NO_UNALIGNED_ACCESS = x ; then
 210 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 211 fi
 212
 213 # Set compile flags to java include files if given
 214 AC_ARG_WITH([java-jdk],
 215         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 216         [JAVA_JDK=$withval],
 217         [JAVA_JDK=""]
 218 )
 219 AS_IF([test $JAVA_JDK],[
 220         AS_IF([test -d $JAVA_JDK],[
 221                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 222                 SUBDIRS=`find $JAVA_JDK/include -type d`
 223                 CPPFLAGS+=" "
 224                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 225                 CPPFLAGS+=" "
 226         ],[
 227                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 228         ])
 229 ])
 230
 231 # Check for JNI header files if requested
 232 AC_ARG_WITH([jni-interface],
 233         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 234         [jni_interface=$withval],
 235         [jni_interface=no]
 236 )
 237
 238 AS_IF([test "x$jni_interface" = "xyes"],[
 239         AC_CHECK_HEADERS([jni.h],[],[
 240         AC_MSG_ERROR([missing jni.h
 241 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 242 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 243         ])
 244 ])
 245 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 246
 247 # sdt.h integration
 248 AC_ARG_WITH([sdt],
 249         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 250         [with_sdt=$withval],
 251         [with_sdt="no"]
 252 )
 253
 254 AS_IF([test "x$with_sdt" = "xyes"],[
 255         AC_MSG_CHECKING([STAP_PROBEV()])
 256         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 257         #define SDT_USE_VARIADIC
 258         #include <sys/sdt.h>
 259         void fct(void)
 260         {
 261                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 262         }
 263         ]])],[
 264                 AC_MSG_RESULT([yes])
 265                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 266         ],[
 267                 AC_MSG_RESULT([no])
 268                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 269         ])
 270 ])
 271
 272 #currently disabled.
 273         #tests/hello2/Makefile
 274         #tests/basic/Makefile
 275         #tests/simple_include/Makefile
 276         #tests/snprintf/Makefile
 277         #tests/test-nevents/Makefile
 278         #tests/test-libustinstr-malloc/Makefile
 279         #tests/dlopen/Makefile
 280         #tests/same_line_marker/Makefile
 281         #tests/trace_event/Makefile
 282         #tests/tracepoint/Makefile
 283         #tests/tracepoint/benchmark/Makefile
 284         #tests/register_test/Makefile
 285         #tests/libustctl_function_#tests/Makefile
 286         #tests/exit-fast/Makefile
 287         #tests/basic_long/Makefile
 288
 289 AC_CONFIG_FILES([
 290         Makefile
 291         doc/Makefile
 292         doc/examples/Makefile
 293         include/Makefile
 294         include/lttng/ust-version.h
 295         snprintf/Makefile
 296         libringbuffer/Makefile
 297         liblttng-ust-comm/Makefile
 298         liblttng-ust/Makefile
 299         liblttng-ust-ctl/Makefile
 300         liblttng-ust-fork/Makefile
 301         liblttng-ust-java/Makefile
 302         liblttng-ust-libc-wrapper/Makefile
 303         tools/Makefile
 304         tests/Makefile
 305         tests/hello/Makefile
 306         tests/hello-static-lib/Makefile
 307         tests/hello.cxx/Makefile
 308         tests/demo/Makefile
 309         tests/fork/Makefile
 310         tests/ust-basic-tracing/Makefile
 311         tests/ust-multi-test/Makefile
 312         lttng-ust.pc
 313 ])
 314
 315 AC_OUTPUT
 316
 317 AS_ECHO()
 318 AS_ECHO("Version name: $version_name")
 319 AS_ECHO("$version_description")
 320
 321 # Report on the configuration options
 322 AS_ECHO()
 323 AS_ECHO("LTTng-UST will be built with the following options:")
 324 AS_ECHO("Library format: $LIBFORMAT")
 325
 326 AS_ECHO()
 327 AS_ECHO_N("Java support (JNI): ")
 328 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 329
 330 AS_ECHO_N("sdt.h integration:  ")
 331 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 332
 333 AS_ECHO()
 334 AS_ECHO("Type 'make' to compile.")
 335