configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7
   8 # Project version information
   9 m4_define([ust_version_major], [2])
  10 m4_define([ust_version_minor], [13])
  11 m4_define([ust_version_patch], [0])
  12 m4_define([ust_version_dev_stage], [-pre])
  13 m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
  14 m4_define([ust_version_name], [[Codename TBD]])
  15 m4_define([ust_version_description], [[Description TBD]])
  16
  17 # Library version information of "liblttng-ust"
  18 # Following the numbering scheme proposed by libtool for the library version
  19 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  20 m4_define([ust_lib_version_current], [1])
  21 m4_define([ust_lib_version_revision], [0])
  22 m4_define([ust_lib_version_age], [0])
  23 m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
  24
  25 # Library version information of "liblttng-ust-ctl"
  26 # Following the numbering scheme proposed by libtool for the library version
  27 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  28 m4_define([ust_ctl_lib_version_current], [5])
  29 m4_define([ust_ctl_lib_version_revision], [0])
  30 m4_define([ust_ctl_lib_version_age], [0])
  31 m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
  32
  33
  34 ##                     ##
  35 ## Autoconf base setup ##
  36 ##                     ##
  37
  38 AC_PREREQ([2.69])
  39 AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
  40
  41 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
  42 AC_CONFIG_AUX_DIR([config])
  43 AC_CONFIG_MACRO_DIR([m4])
  44
  45 AC_CANONICAL_TARGET
  46 AC_CANONICAL_HOST
  47
  48
  49 ##                     ##
  50 ## Automake base setup ##
  51 ##                     ##
  52
  53 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  54 AM_MAINTAINER_MODE([enable])
  55
  56 # Enable silent rules by default
  57 AM_SILENT_RULES([yes])
  58
  59
  60 ##                               ##
  61 ## OS and Arch specific defaults ##
  62 ##                               ##
  63
  64 # Set os specific options
  65 AS_CASE([$host_os],
  66   [freebsd*], [AE_FEATURE_DISABLE([numa])]
  67 )
  68
  69 # Set architecture specific options
  70 AS_CASE([$host_cpu],
  71   [i[[3456]]86], [],
  72   [x86_64], [],
  73   [amd64], [],
  74   [powerpc], [],
  75   [ppc64], [],
  76   [ppc64le], [],
  77   [powerpc64], [],
  78   [powerpc64le], [],
  79   [s390], [],
  80   [s390x], [],
  81   [arm*], [AE_FEATURE_DISABLE([numa])],
  82   [aarch64*], [],
  83   [mips*], [],
  84   [tile*], [],
  85   [
  86     unsupported_arch="yes"
  87   ])
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 # Choose the C compiler
  95 AC_PROG_CC
  96 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  97 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  98
  99 # Make sure the C compiler supports C99
 100 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
 101
 102 # Enable available system extensions and LFS support
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Make sure the C compiler supports __attribute__
 107 AX_C___ATTRIBUTE__
 108 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 109   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 110
 111 # Make sure we have pthread support
 112 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 113
 114 # Make sure the C compiler supports weak symbols
 115 AX_SYS_WEAK_ALIAS
 116 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
 117   [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_C_TYPEOF
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_INT8_T
 126 AC_TYPE_MODE_T
 127 AC_TYPE_OFF_T
 128 AC_TYPE_PID_T
 129 AC_TYPE_SIZE_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UID_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136 AC_CHECK_TYPES([ptrdiff_t])
 137
 138
 139 ##                     ##
 140 ## C++ compiler checks ##
 141 ##                     ##
 142
 143 # Find an optional C++11 compiler without GNU extensions (-std=c++11)
 144 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 145 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
 146
 147
 148 ##               ##
 149 ## Header checks ##
 150 ##               ##
 151
 152 AC_HEADER_STDBOOL
 153 AC_CHECK_HEADERS([ \
 154   arpa/inet.h \
 155   dlfcn.h \
 156   fcntl.h \
 157   float.h \
 158   limits.h \
 159   linux/perf_event.h \
 160   locale.h \
 161   stddef.h \
 162   sys/socket.h \
 163   sys/time.h \
 164   wchar.h \
 165 ])
 166
 167 # Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
 168 AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
 169   AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
 170 ])
 171
 172
 173 ##                 ##
 174 ## Programs checks ##
 175 ##                 ##
 176
 177 AM_PROG_AR
 178 AC_PROG_SED
 179 AC_PROG_GREP
 180 AC_PROG_LN_S
 181 AC_PROG_MKDIR_P
 182 AC_PROG_MAKE_SET
 183 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 184 AC_CHECK_PROGS([CMAKE], [cmake])
 185 AC_CHECK_PROGS([FOLD], [fold])
 186 AC_CHECK_PROGS([XMLTO], [xmlto])
 187
 188 AM_PATH_PYTHON([2.7], [], [PYTHON=""])
 189
 190 AX_PROG_JAVAC
 191 AX_PROG_JAVA
 192 AX_PROG_JAR
 193
 194 # Initialize and configure libtool
 195 LT_INIT([disable-static])
 196
 197
 198 ##                ##
 199 ## Library checks ##
 200 ##                ##
 201
 202 AC_FUNC_CHOWN
 203 AC_FUNC_FORK
 204 AC_FUNC_MMAP
 205 AC_FUNC_STRERROR_R
 206 AC_FUNC_STRNLEN
 207 AC_CHECK_FUNCS([ \
 208   atexit \
 209   clock_gettime \
 210   ftruncate \
 211   getpagesize \
 212   gettimeofday \
 213   localeconv \
 214   memchr \
 215   memmove \
 216   memset \
 217   mkdir \
 218   munmap \
 219   realpath \
 220   sched_getcpu \
 221   socket \
 222   strchr \
 223   strdup \
 224   strerror \
 225   strtol \
 226   strtoul \
 227   sysconf \
 228 ])
 229
 230 # AC_FUNC_MALLOC causes problems when cross-compiling.
 231 #AC_FUNC_MALLOC
 232 #AC_FUNC_REALLOC
 233
 234 # Check for pthread_setname_np and its signature
 235 LTTNG_PTHREAD_SETNAME_NP
 236 LTTNG_PTHREAD_GETNAME_NP
 237
 238 # Check dor dlopen() in -ldl or -lc
 239 AC_CHECK_LIB([dl], [dlopen], [
 240   libdl_name=dl
 241   DL_LIBS="-ldl"
 242 ], [
 243   # dlopen not found in libdl, check in libc
 244   AC_CHECK_LIB([c], [dlopen], [
 245     libdl_name=c
 246     DL_LIBS="-lc"
 247   ], [
 248     AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 249   ])
 250 ])
 251 AC_SUBST(DL_LIBS)
 252
 253 # Check if libdl has dlmopen()
 254 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 255   AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
 256 ])
 257
 258 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 259 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 260
 261
 262 ##                 ##
 263 ## User variables  ##
 264 ##                 ##
 265
 266 # Additional variables captured during ./configure
 267
 268 AC_ARG_VAR([CLASSPATH], [Java class path])
 269
 270
 271 ##                              ##
 272 ## Optionnal features selection ##
 273 ##                              ##
 274
 275 # numa integration
 276 # Enabled by default, except on some platforms
 277 AE_FEATURE_DEFAULT_ENABLE
 278 AE_FEATURE([numa],[disable NUMA support])
 279
 280 # Java JNI interface library
 281 # Disabled by default
 282 AE_FEATURE_DEFAULT_DISABLE
 283 AE_FEATURE([jni-interface], [build JNI interface between C and Java])
 284
 285 # Build the Java Logging API agent
 286 # Disabled by default
 287 AE_FEATURE_DEFAULT_DISABLE
 288 AE_FEATURE([java-agent-jul],[build the LTTng UST Java agent with JUL support])
 289
 290 # Build the Java Log4j agent
 291 # Disabled by default
 292 AE_FEATURE_DEFAULT_DISABLE
 293 AE_FEATURE([java-agent-log4j],[build the LTTng UST Java agent with Log4j support])
 294
 295 # Build both Java agents
 296 # Disabled by default
 297 AE_FEATURE_DEFAULT_DISABLE
 298 AE_FEATURE([java-agent-all],[build the LTTng UST Java agent with all supported backends])
 299
 300 # Build the Python agent
 301 # Disabled by default
 302 AE_FEATURE_DEFAULT_DISABLE
 303 AE_FEATURE([python-agent],[build the LTTng UST Python agent])
 304
 305 # Build the examples
 306 # Disabled by default
 307 AE_FEATURE_DEFAULT_ENABLE
 308 AE_FEATURE([examples],[Do not build and install examples])
 309
 310 # Man pages
 311 # Enabled by default
 312 AE_FEATURE_DEFAULT_ENABLE
 313 AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball)])
 314
 315 # Systemtap sdt.h integration
 316 # Disabled by default
 317 AC_ARG_WITH([sdt],
 318   [AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])]
 319 )
 320
 321 # Override the default runtime directory
 322 AC_ARG_WITH([lttng-system-rundir], [
 323 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 324 ], [
 325   lttng_system_rundir="$withval"
 326 ], [
 327   lttng_system_rundir="/var/run/lttng"
 328 ])
 329
 330 # Add the java command line arguments like '--wit-java-prefix'
 331 AX_JAVA_OPTIONS
 332
 333
 334 ##                                          ##
 335 ## Check for conflicting features selection ##
 336 ##                                          ##
 337
 338 AE_IF_FEATURE_DISABLED([shared], [
 339   AC_MSG_ERROR(LTTng-UST requires shared libraries to be enabled)
 340 ])
 341
 342 AE_IF_FEATURE_ENABLED([java-agent-all], [
 343   AE_FEATURE_ENABLE([java-agent-jul])
 344   AE_FEATURE_ENABLE([java-agent-log4j])
 345 ])
 346
 347
 348 ##                                          ##
 349 ## Check for optional features dependencies ##
 350 ##                                          ##
 351
 352 # The numa integration requires libnuma
 353 AE_IF_FEATURE_ENABLED([numa], [
 354   AC_CHECK_LIB([numa], [numa_available], [], [
 355     AC_MSG_ERROR([dnl
 356 libnuma is not available. Please either install it (e.g. libnuma-dev) or use
 357 [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure
 358 argument to disable NUMA support.
 359     ])
 360   ])
 361 ])
 362
 363 # The JNI interface and Java Agents require a working Java JDK
 364 AS_IF([AE_IS_FEATURE_ENABLED([jni-interface]) || AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j])], [
 365   # We detected a java compiler earlier, make sure it works
 366   AX_PROG_JAVAC_WORKS
 367
 368   # Get the CPPFLAGS required to build jni libaries
 369   AX_JNI_INCLUDE_DIR
 370   for jni_include_dir in $JNI_INCLUDE_DIRS; do
 371     JNI_CPPFLAGS="$JNI_CPPFLAGS -I$jni_include_dir"
 372   done
 373
 374   # Check for javah and jni.h
 375   saved_CPPFLAGS="$CPPFLAGS"
 376   CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 377   AX_PROG_JAVAH
 378   CPPFLAGS="$saved_CPPFLAGS"
 379 ])
 380
 381 # The log4j agent requires the log4j jar in the classpath
 382 AE_IF_FEATURE_ENABLED([java-agent-log4j], [
 383   AX_CHECK_CLASS([org.apache.log4j.Logger])
 384   AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 385     AC_MSG_ERROR([dnl
 386 The UST Java agent support for log4j was requested but the Log4j classes were
 387 not found. Please specify the location of the Log4j jar via the Java CLASSPATH
 388 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j.jar"
 389
 390 Current CLASSPATH: "$CLASSPATH"
 391     ])
 392   ])
 393 ])
 394
 395 # The python agent requires a python interpreter
 396 AE_IF_FEATURE_ENABLED([python-agent], [
 397   AS_IF([test "x$PYTHON" = "x"], [
 398     AC_MSG_ERROR([dnl
 399 Cannot find a suitable python interpreter. You can override it with the PYTHON
 400 environment variable.
 401     ])
 402   ])
 403 ])
 404
 405 # Check for asciidoc and xmlto if we enabled building the man pages.
 406 AE_IF_FEATURE_ENABLED([man-pages], [
 407   AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 408     AE_IF_IN_GIT_REPO([
 409       # This is an error because we're in the Git repo, which
 410       # means the man pages are not already generated for us,
 411       # thus asciidoc/xmlto are required because we were asked
 412       # to build the man pages.
 413       AC_MSG_ERROR([dnl
 414 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 415 --disable-man-pages to disable building the man pages, in which case
 416 they will not be installed.
 417       ])
 418     ], [
 419       # Only warn here: since we're in the tarball, the man
 420       # pages should already be generated at this point, thus
 421       # asciidoc/xmlto are not strictly required.
 422       warn_prebuilt_man_pages=yes
 423     ])
 424   ], [
 425     have_asciidoc_xmlto=yes
 426   ])
 427 ])
 428
 429 AS_IF([test "x$with_sdt" = "xyes"], [
 430   AC_MSG_CHECKING([STAP_PROBEV()])
 431   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 432     #define SDT_USE_VARIADIC
 433     #include <sys/sdt.h>
 434     void fct(void)
 435     {
 436       STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 437     }
 438   ]])], [
 439     AC_MSG_RESULT([yes])
 440     AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1], [SystemTap integration via sdt.h])
 441   ], [
 442     AC_MSG_RESULT([no])
 443     AC_MSG_ERROR([dnl
 444 The sdt.h integration was requested but the STAP_PROBEV define cannot be used.
 445 Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify
 446 a non-standard path to sys/sdt.h
 447     ])
 448   ])
 449 ])
 450
 451
 452 ##                                                                    ##
 453 ## Set defines for optional features conditionnals in the source code ##
 454 ##                                                                    ##
 455
 456 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], [LTTng system runtime directory])
 457
 458 # Defined in include/lttng/ust-version.h
 459 AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
 460 AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
 461 AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
 462 AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
 463 AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
 464 AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
 465
 466
 467 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
 468
 469 # Configuration options, which will be installed in the config.h
 470 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 471
 472
 473 AM_CONDITIONAL([ENABLE_UST_DL], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 474
 475
 476 AM_CONDITIONAL([ENABLE_NUMA], [test "x$have_libnuma" = "xyes"])
 477
 478 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
 479
 480 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 481 AM_CONDITIONAL([ENABLE_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 482 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 483 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 484
 485 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 486
 487 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 488
 489 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
 490
 491
 492 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 493
 494 # Export man page build condition: build the man pages if the user
 495 # asked for it, and if the tools are available.
 496 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$man_pages_opt" != "xno"])
 497 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 498
 499 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
 500 AC_SUBST(AM_CFLAGS)
 501
 502 AM_CXXFLAGS="$AM_CFLAGS"
 503 AC_SUBST(AM_CXXFLAGS)
 504
 505 # The order in which the include folders are searched is important.
 506 # The top_builddir should always be searched first in the event that a build
 507 # time generated file is included.
 508 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 509 AC_SUBST(AM_CPPFLAGS)
 510
 511 AC_SUBST(JNI_CPPFLAGS)
 512
 513
 514 ##                                     ##
 515 ## Output files generated by configure ##
 516 ##                                     ##
 517
 518 # List of files to be generated from '.in' templates by AC_OUTPUT
 519 AC_CONFIG_FILES([
 520         Makefile
 521         doc/Makefile
 522         doc/examples/Makefile
 523         doc/man/Makefile
 524         include/Makefile
 525         snprintf/Makefile
 526         libcounter/Makefile
 527         libmsgpack/Makefile
 528         libringbuffer/Makefile
 529         liblttng-ust-comm/Makefile
 530         liblttng-ust/Makefile
 531         liblttng-ust-ctl/Makefile
 532         liblttng-ust-fork/Makefile
 533         liblttng-ust-dl/Makefile
 534         liblttng-ust-fd/Makefile
 535         liblttng-ust-java/Makefile
 536         liblttng-ust-java-agent/Makefile
 537         liblttng-ust-java-agent/java/Makefile
 538         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 539         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 540         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 541         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 542         liblttng-ust-java-agent/jni/Makefile
 543         liblttng-ust-java-agent/jni/common/Makefile
 544         liblttng-ust-java-agent/jni/jul/Makefile
 545         liblttng-ust-java-agent/jni/log4j/Makefile
 546         liblttng-ust-libc-wrapper/Makefile
 547         liblttng-ust-cyg-profile/Makefile
 548         liblttng-ust-python-agent/Makefile
 549         python-lttngust/Makefile
 550         python-lttngust/setup.py
 551         python-lttngust/lttngust/__init__.py
 552         tools/Makefile
 553         tests/Makefile
 554         tests/compile/Makefile
 555         tests/compile/ctf-types/Makefile
 556         tests/compile/hello.cxx/Makefile
 557         tests/compile/hello/Makefile
 558         tests/compile/hello-many/Makefile
 559         tests/compile/same_line_tracepoint/Makefile
 560         tests/compile/test-app-ctx/Makefile
 561         tests/benchmark/Makefile
 562         tests/unit/gcc-weak-hidden/Makefile
 563         tests/unit/libmsgpack/Makefile
 564         tests/unit/Makefile
 565         tests/unit/libringbuffer/Makefile
 566         tests/unit/pthread_name/Makefile
 567         tests/unit/snprintf/Makefile
 568         tests/unit/ust-elf/Makefile
 569         tests/utils/Makefile
 570         lttng-ust.pc
 571         lttng-ust-ctl.pc
 572 ])
 573
 574 AC_OUTPUT
 575
 576
 577 ##                                    ##
 578 ## Mini-report on what will be built. ##
 579 ##                                    ##
 580
 581 PPRINT_INIT
 582 PPRINT_SET_INDENT(1)
 583 PPRINT_SET_TS(38)
 584
 585 AS_ECHO
 586 AS_IF([test -n "ust_version_name"], [
 587   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
 588 ], [
 589   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
 590 ])
 591
 592 AS_ECHO
 593
 594 AS_IF([test -n "ust_version_description"], [
 595   AS_IF([test -n "$FOLD"], [
 596     AS_ECHO("`AS_ECHO("ust_version_description") | $FOLD -s`")
 597   ], [
 598     AS_ECHO("ust_version_description")
 599   ])
 600   AS_ECHO
 601 ])
 602
 603 PPRINT_SUBTITLE([System])
 604
 605 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 606
 607 AS_IF([test "x$unsupported_arch" = "xyes"],[
 608        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 609 ])
 610
 611 AS_ECHO
 612 PPRINT_SUBTITLE([Features])
 613 PPRINT_SET_INDENT(1)
 614
 615 test "x$with_sdt" = "xyes" && value=1 || value=0
 616 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 617
 618 AE_IS_FEATURE_ENABLED([java-agent-jul]) && value=1 || value=0
 619 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 620
 621 AE_IS_FEATURE_ENABLED([java-agent-log4j]) && value=1 || value=0
 622 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 623
 624 AE_IS_FEATURE_ENABLED([jni-interface]) && value=1 || value=0
 625 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 626
 627 AE_IS_FEATURE_ENABLED([python-agent]) && value=1 || value=0
 628 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 629
 630 test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
 631 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 632
 633 AE_IS_FEATURE_ENABLED([numa]) && value=1 || value=0
 634 PPRINT_PROP_BOOL([NUMA], $value)
 635
 636 AS_ECHO
 637 PPRINT_SET_INDENT(0)
 638
 639 AE_IS_FEATURE_ENABLED([examples]) && value=1 || value=0
 640 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 641
 642 # man pages build enabled/disabled
 643 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 644
 645 AE_IF_FEATURE_ENABLED([man-pages], [
 646   AE_IF_IN_GIT_REPO([
 647     PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 648   ], [
 649     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 650       PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 651     ], [
 652       PPRINT_PROP_STRING([build_man_pages_msg],
 653         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 654         $PPRINT_COLOR_SUBTITLE)
 655     ])
 656   ])
 657 ], [
 658   PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 659 ])
 660
 661 m4_popdef([build_man_pages_msg])
 662
 663 PPRINT_SET_INDENT(1)
 664
 665 report_bindir="`eval eval echo $bindir`"
 666 report_libdir="`eval eval echo $libdir`"
 667
 668 # Print the bindir and libdir this `make install' will install into.
 669 AS_ECHO
 670 PPRINT_SUBTITLE([Install directories])
 671 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 672 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 673
 674 AS_ECHO
 675 PPRINT_SUBTITLE([System directories])
 676
 677 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 678
 679 PPRINT_SET_INDENT(0)
 680
 681 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 682   AS_ECHO
 683   PPRINT_WARN([dnl
 684 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 685
 686 Note that the man pages are already built in this distribution tarball,
 687 therefore asciidoc and xmlto are only needed if you intend to modify
 688 their sources.
 689
 690 Use --disable-man-pages to completely disable building and installing
 691 the man pages.])
 692 ])