configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.0-rc1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_MAKE_SET
  42 LT_INIT
  43
  44 ## Checks for libraries.
  45 AC_CHECK_LIB([dl], [dlopen],
  46 [
  47         have_libdl=yes
  48 ],
  49 [
  50         #libdl not found, check for dlopen in libc.
  51         AC_CHECK_LIB([c], [dlopen],
  52         [
  53                 have_libc_dl=yes
  54         ],
  55         [
  56                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
  57         ])
  58 ])
  59 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
  60 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
  61
  62 AC_CHECK_LIB([pthread], [pthread_create])
  63
  64 # Check for libuuid
  65 AC_CHECK_LIB([uuid], [uuid_generate],
  66 [
  67         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
  68         have_libuuid=yes
  69 ],
  70 [
  71         # libuuid not found, check for uuid_create in libc.
  72         AC_CHECK_LIB([c], [uuid_create],
  73         [
  74                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  75                 have_libc_uuid=yes
  76         ],
  77         [
  78                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  79         ])
  80 ]
  81 )
  82 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  83 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  84
  85 # Checks for header files.
  86 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 #AC_TYPE_INT16_T
  91 #AC_TYPE_INT32_T
  92 #AC_TYPE_INT64_T
  93 #AC_TYPE_INT8_T
  94 #AC_TYPE_PID_T
  95 #AC_TYPE_SIZE_T
  96 #AC_TYPE_SSIZE_T
  97 #AC_TYPE_UINT16_T
  98 #AC_TYPE_UINT32_T
  99 #AC_TYPE_UINT64_T
 100 #AC_TYPE_UINT8_T
 101 #AC_CHECK_TYPES([ptrdiff_t])
 102
 103 # Checks for library functions.
 104 AC_FUNC_MALLOC
 105 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 106
 107 CFLAGS="-Wall $CFLAGS"
 108
 109 # Check for texinfo, required for building the documentation
 110 # TODO: make this (and building the documentation) optional
 111 AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
 112 AS_IF([test "x$TEXINFO" != "xyes"],[
 113         AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
 114 ])
 115
 116 # URCU
 117
 118 # urcu - check if we just find the headers it out of the box.
 119 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CFLAGS]=-Idir to specify their location.
 120 This error can also occur when the liburcu package's configure script has not been run.])])
 121
 122 AC_MSG_CHECKING([caa_likely()])
 123 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 124 #include <urcu/compiler.h>
 125 void fct(void)
 126 {
 127         if (caa_likely(1)) {
 128         }
 129 }
 130 ]])],[
 131         AC_MSG_RESULT([yes])
 132 ],[
 133         AC_MSG_RESULT([no])
 134         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 135
 136 ])
 137
 138 # urcu - check that URCU lib is available to compilation
 139 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 140
 141 # urcu - check that URCU lib is at least version 0.6
 142 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 143
 144
 145 # Check for various supplementary host information (beyond the
 146 # triplet) which might affect the library format choices.  E.g., we
 147 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 148
 149 case "${host}" in
 150 changequote(,)dnl
 151   i[34567]86-*-linux*)
 152 changequote([,])dnl
 153     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 154                     [save_CPPFLAGS="$CPPFLAGS"
 155                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 156                     AC_EGREP_CPP([got it], [
 157 #if __x86_64__
 158 got it
 159 #endif
 160                  ], [ust_cv_i386_is_x86_64=yes],
 161                     [ust_cv_i386_is_x86_64=no])
 162                     CPPFLAGS="$save_CPPFLAGS"])
 163     ;;
 164 esac
 165
 166 AC_MSG_CHECKING([library format for the host system])
 167 case $host_cpu in
 168 changequote(,)dnl
 169         i[3456]86)
 170 changequote([,])dnl
 171           if test "$ust_cv_i386_is_x86_64" = yes ; then
 172              LIBFORMAT="elf64-x86-64"
 173           else
 174              LIBFORMAT="elf32-i386"
 175           fi
 176           ;;
 177         x86_64) LIBFORMAT="elf64-x86-64" ;;
 178         powerpc) LIBFORMAT="elf32-powerpc" ;;
 179         ppc64) LIBFORMAT="elf64-powerpc" ;;
 180         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 181         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 182         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 183         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 184         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 185         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 186         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 187 esac
 188 AC_SUBST(LIBFORMAT)
 189 AC_MSG_RESULT($LIBFORMAT)
 190
 191 if test "x$host_cpu" = "xarm" ; then
 192 AC_MSG_CHECKING([checking for armv5])
 193 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 194 #ifndef __ARM_ARCH_5TEJ__
 195 #error "no arm5 here"
 196 #endif
 197 ]])],[
 198         AC_MSG_RESULT([yes])
 199         NO_UNALIGNED_ACCESS=1
 200
 201 ],[
 202         AC_MSG_RESULT([no])
 203
 204 ])
 205 fi
 206 if test x$NO_UNALIGNED_ACCESS = x ; then
 207 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 208 fi
 209
 210 # Set compile flags to java include files if given
 211 AC_ARG_WITH([java-jdk],
 212         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 213         [JAVA_JDK=$withval],
 214         [JAVA_JDK=""]
 215 )
 216 AS_IF([test $JAVA_JDK],[
 217         AS_IF([test -d $JAVA_JDK],[
 218                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 219                 SUBDIRS=`find $JAVA_JDK/include -type d`
 220                 CFLAGS+=" "
 221                 CFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 222                 CFLAGS+=" "
 223         ],[
 224                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 225         ])
 226 ])
 227
 228 # Check for JNI header files if requested
 229 AC_ARG_WITH([jni-interface],
 230         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 231         [jni_interface=$withval],
 232         [jni_interface=no]
 233 )
 234
 235 AS_IF([test "x$jni_interface" = "xyes"],[
 236         AC_CHECK_HEADERS([jni.h],[],[
 237         AC_MSG_ERROR([missing jni.h
 238 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 239 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 240         ])
 241 ])
 242 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 243
 244 # sdt.h integration
 245 AC_ARG_WITH([sdt],
 246         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 247         [with_sdt=$withval],
 248         [with_sdt="no"]
 249 )
 250
 251 AS_IF([test "x$with_sdt" = "xyes"],[
 252         AC_MSG_CHECKING([STAP_PROBEV()])
 253         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 254         #define SDT_USE_VARIADIC
 255         #include <sys/sdt.h>
 256         void fct(void)
 257         {
 258                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 259         }
 260         ]])],[
 261                 AC_MSG_RESULT([yes])
 262                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 263         ],[
 264                 AC_MSG_RESULT([no])
 265                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 266         ])
 267 ])
 268
 269 #currently disabled.
 270         #tests/hello2/Makefile
 271         #tests/basic/Makefile
 272         #tests/simple_include/Makefile
 273         #tests/snprintf/Makefile
 274         #tests/test-nevents/Makefile
 275         #tests/test-libustinstr-malloc/Makefile
 276         #tests/dlopen/Makefile
 277         #tests/same_line_marker/Makefile
 278         #tests/trace_event/Makefile
 279         #tests/tracepoint/Makefile
 280         #tests/tracepoint/benchmark/Makefile
 281         #tests/register_test/Makefile
 282         #tests/libustctl_function_#tests/Makefile
 283         #tests/exit-fast/Makefile
 284         #tests/basic_long/Makefile
 285
 286 AC_CONFIG_FILES([
 287         Makefile
 288         doc/Makefile
 289         doc/examples/Makefile
 290         include/Makefile
 291         include/lttng/ust-version.h
 292         snprintf/Makefile
 293         libringbuffer/Makefile
 294         liblttng-ust-comm/Makefile
 295         liblttng-ust/Makefile
 296         liblttng-ust-ctl/Makefile
 297         liblttng-ust-fork/Makefile
 298         liblttng-ust-java/Makefile
 299         liblttng-ust-libc-wrapper/Makefile
 300         tools/Makefile
 301         tests/Makefile
 302         tests/hello/Makefile
 303         tests/hello-static-lib/Makefile
 304         tests/hello.cxx/Makefile
 305         tests/demo/Makefile
 306         tests/fork/Makefile
 307         tests/ust-basic-tracing/Makefile
 308         tests/ust-multi-test/Makefile
 309         lttng-ust.pc
 310 ])
 311
 312 AC_OUTPUT
 313
 314 # Report on the configuration options
 315 AS_ECHO()
 316 AS_ECHO("LTTng-UST will be built with the following options:")
 317 AS_ECHO("Library format: $LIBFORMAT")
 318
 319 AS_ECHO()
 320 AS_ECHO_N("Java support (JNI): ")
 321 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 322
 323 AS_ECHO_N("sdt.h integration:  ")
 324 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 325
 326 AS_ECHO()
 327 AS_ECHO("Type 'make' to compile.")
 328