configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust], [1.9.0], [mathieu dot desnoyers at efficios dot com])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CANONICAL_TARGET
   7 AC_CANONICAL_HOST
   8 AC_CONFIG_MACRO_DIR([config])
   9 AM_INIT_AUTOMAKE([foreign])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  12 AC_CONFIG_HEADERS([config.h include/lttng/config.h])
  13 AH_TEMPLATE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  14 # Compute minor/major/patchlevel version numbers
  15 major_version=$(echo AC_PACKAGE_VERSION | sed 's/\([^.]\)*\.\([^.]*\)\.\([^.]*\)/\1/)')
  16 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/\([^.]\)*\.\([^.]*\)\.\([^.]*\)/\2/)')
  17 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/\([^.]\)*\.\([^.]*\)\.\([^.]*\)/\3/)')
  18 AC_SUBST([MAJOR_VERSION], [$major_version])
  19 AC_SUBST([MINOR_VERSION], [$minor_version])
  20 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  21 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  22 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  23 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  24
  25
  26 # Checks for programs.
  27 AC_PROG_CC
  28 AC_PROG_MAKE_SET
  29 AC_PROG_LIBTOOL
  30
  31 ## Checks for libraries.
  32 AC_CHECK_LIB([dl], [dlopen])
  33 AC_CHECK_LIB([pthread], [pthread_create])
  34
  35 # Check for libuuid
  36 AC_CHECK_LIB([uuid], [uuid_generate], [],
  37         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  38 )
  39
  40 # Checks for header files.
  41 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 #AC_TYPE_INT16_T
  46 #AC_TYPE_INT32_T
  47 #AC_TYPE_INT64_T
  48 #AC_TYPE_INT8_T
  49 #AC_TYPE_PID_T
  50 #AC_TYPE_SIZE_T
  51 #AC_TYPE_SSIZE_T
  52 #AC_TYPE_UINT16_T
  53 #AC_TYPE_UINT32_T
  54 #AC_TYPE_UINT64_T
  55 #AC_TYPE_UINT8_T
  56 #AC_CHECK_TYPES([ptrdiff_t])
  57
  58 # Checks for library functions.
  59 AC_FUNC_MALLOC
  60 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol])
  61
  62 CFLAGS="-Wall $CFLAGS"
  63
  64 # URCU
  65
  66 # urcu - check if we just find the headers it out of the box.
  67 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CFLAGS]=-Idir to specify their location.
  68 This error can also occur when the liburcu package's configure script has not been run.])])
  69
  70 AC_MSG_CHECKING([caa_likely()])
  71 AC_TRY_COMPILE(
  72 [
  73 #include <urcu/compiler.h>
  74 ],
  75 [
  76 void fct(void)
  77 {
  78         if (caa_likely(1)) {
  79         }
  80 }
  81 ],
  82 [
  83         AC_MSG_RESULT([yes])
  84 ],
  85 [
  86         AC_MSG_RESULT([no])
  87         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
  88 ]
  89 )
  90
  91 # urcu - check that URCU lib is available to compilation
  92 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
  93
  94 # urcu - check that URCU lib is at least version 0.6
  95 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
  96
  97
  98 # Check for various supplementary host information (beyond the
  99 # triplet) which might affect the library format choices.  E.g., we
 100 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 101
 102 case "${host}" in
 103 changequote(,)dnl
 104   i[34567]86-*-linux*)
 105 changequote([,])dnl
 106     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 107                     [save_CPPFLAGS="$CPPFLAGS"
 108                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 109                     AC_EGREP_CPP([got it], [
 110 #if __x86_64__
 111 got it
 112 #endif
 113                  ], [ust_cv_i386_is_x86_64=yes],
 114                     [ust_cv_i386_is_x86_64=no])
 115                     CPPFLAGS="$save_CPPFLAGS"])
 116     ;;
 117 esac
 118
 119 AC_MSG_CHECKING([library format for the host system])
 120 case $host_cpu in
 121 changequote(,)dnl
 122         i[3456]86)
 123 changequote([,])dnl
 124           if test "$ust_cv_i386_is_x86_64" = yes ; then
 125              LIBFORMAT="elf64-x86-64"
 126           else
 127              LIBFORMAT="elf32-i386"
 128           fi
 129           ;;
 130         x86_64) LIBFORMAT="elf64-x86-64" ;;
 131         powerpc) LIBFORMAT="elf32-powerpc" ;;
 132         ppc64) LIBFORMAT="elf64-powerpc" ;;
 133         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 134         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 135         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 136         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 137         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 138         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 139         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 140 esac
 141 AC_SUBST(LIBFORMAT)
 142 AC_MSG_RESULT($LIBFORMAT)
 143
 144 if test "x$host_cpu" = "xarm" ; then
 145 AC_MSG_CHECKING([checking for armv5])
 146 AC_TRY_COMPILE(
 147 [
 148 ],
 149 [
 150 #ifndef __ARM_ARCH_5TEJ__
 151 #error "no arm5 here"
 152 #endif
 153 ],
 154 [
 155         AC_MSG_RESULT([yes])
 156         NO_UNALIGNED_ACCESS=1
 157 ]
 158 ,
 159 [
 160         AC_MSG_RESULT([no])
 161 ]
 162 )
 163 fi
 164 if test x$NO_UNALIGNED_ACCESS = x ; then
 165 AC_DEFINE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 166 fi
 167
 168 # Set compile flags to java include files if given
 169 AC_ARG_WITH(java_jdk, [  --with-java-jdk=DIR     use java jdk from DIR. Ex : $JAVA_HOME.], JAVA_SDK=$withval,)
 170 if test $JAVA_SDK; then
 171         if test -d $JAVA_SDK; then
 172                 AC_MSG_RESULT([using java include in $JAVA_SDK])
 173                 SUBDIRS=`find $JAVA_SDK/include -type d`
 174                 CFLAGS+=" "
 175                 CFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 176                 CFLAGS+=" "
 177         else
 178                 AC_MSG_ERROR(Unable to find java include file in $JAVA_JDK)
 179         fi
 180 fi
 181
 182 # Check for JNI header files if requested
 183 AC_ARG_WITH(jni-interface, [  --with-jni-interface    build JNI interface between C and java. Need java include files.
 184                           [[default=no]]])
 185
 186 if test -z "$with_jni_interface"; then
 187         with_jni_interface=${with_jni_interface_default-no}
 188 fi
 189
 190 if test "$with_jni_interface" = "yes"; then
 191         AC_CHECK_HEADERS([jni.h],,AC_MSG_ERROR([
 192 missing jni.h
 193 Make sure Sun Java or OpenJDK or GCJ is installed and that this header file exists in the system path.
 194 Use --with-java-jdk=DIR flag to point to your java include files or desactivate the JNI interface.]))
 195 fi
 196 AM_CONDITIONAL(BUILD_JNI_INTERFACE, test "$with_jni_interface" = "yes")
 197
 198 #currently disabled.
 199         #liblttng-ust-malloc/Makefile
 200         #tests/hello2/Makefile
 201         #tests/basic/Makefile
 202         #tests/simple_include/Makefile
 203         #tests/snprintf/Makefile
 204         #tests/test-nevents/Makefile
 205         #tests/test-libustinstr-malloc/Makefile
 206         #tests/dlopen/Makefile
 207         #tests/same_line_marker/Makefile
 208         #tests/trace_event/Makefile
 209         #tests/tracepoint/Makefile
 210         #tests/tracepoint/benchmark/Makefile
 211         #tests/register_test/Makefile
 212         #tests/libustctl_function_#tests/Makefile
 213         #tests/exit-fast/Makefile
 214         #tests/basic_long/Makefile
 215
 216 AC_CONFIG_FILES([
 217         Makefile
 218         include/Makefile
 219         include/lttng/ust-version.h
 220         doc/Makefile
 221         doc/man/Makefile
 222         doc/info/Makefile
 223         snprintf/Makefile
 224         libringbuffer/Makefile
 225         liblttng-ust-comm/Makefile
 226         liblttng-ust/Makefile
 227         liblttng-ust-ctl/Makefile
 228         liblttng-ust-fork/Makefile
 229         liblttng-ust-java/Makefile
 230         tests/Makefile
 231         tests/hello/Makefile
 232         tests/demo/Makefile
 233         tests/fork/Makefile
 234         tests/ust-basic-tracing/Makefile
 235         tests/ust-multi-test/Makefile
 236         lttng-ust.pc
 237 ])
 238 AC_OUTPUT