configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[1.9.0],[mathieu dot desnoyers at efficios dot com])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CANONICAL_TARGET
   7 AC_CANONICAL_HOST
   8 AC_CONFIG_MACRO_DIR([config])
   9 AM_INIT_AUTOMAKE([foreign])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  12 AC_CONFIG_HEADERS([config.h include/lttng/config.h])
  13 AH_TEMPLATE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  14
  15 # Compute minor/major/patchlevel version numbers
  16 AC_PROG_SED
  17 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*$/\1/')
  18 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*$/\1/')
  19 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\)$/\1/')
  20 AC_SUBST([MAJOR_VERSION], [$major_version])
  21 AC_SUBST([MINOR_VERSION], [$minor_version])
  22 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  23 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  24 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  25 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  26
  27
  28 # Checks for programs.
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31 AC_PROG_MAKE_SET
  32 LT_INIT
  33
  34 ## Checks for libraries.
  35 AC_CHECK_LIB([dl], [dlopen])
  36 AC_CHECK_LIB([pthread], [pthread_create])
  37
  38 # Check for libuuid
  39 AC_CHECK_LIB([uuid], [uuid_generate], [],
  40         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  41 )
  42
  43 # Checks for header files.
  44 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  45
  46 # Checks for typedefs, structures, and compiler characteristics.
  47 AC_C_INLINE
  48 #AC_TYPE_INT16_T
  49 #AC_TYPE_INT32_T
  50 #AC_TYPE_INT64_T
  51 #AC_TYPE_INT8_T
  52 #AC_TYPE_PID_T
  53 #AC_TYPE_SIZE_T
  54 #AC_TYPE_SSIZE_T
  55 #AC_TYPE_UINT16_T
  56 #AC_TYPE_UINT32_T
  57 #AC_TYPE_UINT64_T
  58 #AC_TYPE_UINT8_T
  59 #AC_CHECK_TYPES([ptrdiff_t])
  60
  61 # Checks for library functions.
  62 AC_FUNC_MALLOC
  63 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol])
  64
  65 CFLAGS="-Wall $CFLAGS"
  66
  67 # URCU
  68
  69 # urcu - check if we just find the headers it out of the box.
  70 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CFLAGS]=-Idir to specify their location.
  71 This error can also occur when the liburcu package's configure script has not been run.])])
  72
  73 AC_MSG_CHECKING([caa_likely()])
  74 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  75 #include <urcu/compiler.h>
  76 ]], [[
  77 void fct(void)
  78 {
  79         if (caa_likely(1)) {
  80         }
  81 }
  82 ]])],[
  83         AC_MSG_RESULT([yes])
  84 ],[
  85         AC_MSG_RESULT([no])
  86         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
  87
  88 ])
  89
  90 # urcu - check that URCU lib is available to compilation
  91 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
  92
  93 # urcu - check that URCU lib is at least version 0.6
  94 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
  95
  96
  97 # Check for various supplementary host information (beyond the
  98 # triplet) which might affect the library format choices.  E.g., we
  99 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 100
 101 case "${host}" in
 102 changequote(,)dnl
 103   i[34567]86-*-linux*)
 104 changequote([,])dnl
 105     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 106                     [save_CPPFLAGS="$CPPFLAGS"
 107                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 108                     AC_EGREP_CPP([got it], [
 109 #if __x86_64__
 110 got it
 111 #endif
 112                  ], [ust_cv_i386_is_x86_64=yes],
 113                     [ust_cv_i386_is_x86_64=no])
 114                     CPPFLAGS="$save_CPPFLAGS"])
 115     ;;
 116 esac
 117
 118 AC_MSG_CHECKING([library format for the host system])
 119 case $host_cpu in
 120 changequote(,)dnl
 121         i[3456]86)
 122 changequote([,])dnl
 123           if test "$ust_cv_i386_is_x86_64" = yes ; then
 124              LIBFORMAT="elf64-x86-64"
 125           else
 126              LIBFORMAT="elf32-i386"
 127           fi
 128           ;;
 129         x86_64) LIBFORMAT="elf64-x86-64" ;;
 130         powerpc) LIBFORMAT="elf32-powerpc" ;;
 131         ppc64) LIBFORMAT="elf64-powerpc" ;;
 132         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 133         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 134         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 135         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 136         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 137         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 138         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 139 esac
 140 AC_SUBST(LIBFORMAT)
 141 AC_MSG_RESULT($LIBFORMAT)
 142
 143 if test "x$host_cpu" = "xarm" ; then
 144 AC_MSG_CHECKING([checking for armv5])
 145 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 146 ]], [[
 147 #ifndef __ARM_ARCH_5TEJ__
 148 #error "no arm5 here"
 149 #endif
 150 ]])],[
 151         AC_MSG_RESULT([yes])
 152         NO_UNALIGNED_ACCESS=1
 153
 154 ],[
 155         AC_MSG_RESULT([no])
 156
 157 ])
 158 fi
 159 if test x$NO_UNALIGNED_ACCESS = x ; then
 160 AC_DEFINE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 161 fi
 162
 163 # Set compile flags to java include files if given
 164 AC_ARG_WITH(java_jdk, [  --with-java-jdk=DIR     use java jdk from DIR. Ex : $JAVA_HOME.], JAVA_SDK=$withval,)
 165 if test $JAVA_SDK; then
 166         if test -d $JAVA_SDK; then
 167                 AC_MSG_RESULT([using java include in $JAVA_SDK])
 168                 SUBDIRS=`find $JAVA_SDK/include -type d`
 169                 CFLAGS+=" "
 170                 CFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 171                 CFLAGS+=" "
 172         else
 173                 AC_MSG_ERROR(Unable to find java include file in $JAVA_JDK)
 174         fi
 175 fi
 176
 177 # Check for JNI header files if requested
 178 AC_ARG_WITH(jni-interface, [  --with-jni-interface    build JNI interface between C and java. Need java include files.
 179                           [[default=no]]])
 180
 181 if test -z "$with_jni_interface"; then
 182         with_jni_interface=${with_jni_interface_default-no}
 183 fi
 184
 185 if test "$with_jni_interface" = "yes"; then
 186         AC_CHECK_HEADERS([jni.h],,AC_MSG_ERROR([
 187 missing jni.h
 188 Make sure Sun Java or OpenJDK or GCJ is installed and that this header file exists in the system path.
 189 Use --with-java-jdk=DIR flag to point to your java include files or desactivate the JNI interface.]))
 190 fi
 191 AM_CONDITIONAL(BUILD_JNI_INTERFACE, test "$with_jni_interface" = "yes")
 192
 193 #currently disabled.
 194         #liblttng-ust-malloc/Makefile
 195         #tests/hello2/Makefile
 196         #tests/basic/Makefile
 197         #tests/simple_include/Makefile
 198         #tests/snprintf/Makefile
 199         #tests/test-nevents/Makefile
 200         #tests/test-libustinstr-malloc/Makefile
 201         #tests/dlopen/Makefile
 202         #tests/same_line_marker/Makefile
 203         #tests/trace_event/Makefile
 204         #tests/tracepoint/Makefile
 205         #tests/tracepoint/benchmark/Makefile
 206         #tests/register_test/Makefile
 207         #tests/libustctl_function_#tests/Makefile
 208         #tests/exit-fast/Makefile
 209         #tests/basic_long/Makefile
 210
 211 AC_CONFIG_FILES([
 212         Makefile
 213         include/Makefile
 214         include/lttng/ust-version.h
 215         doc/Makefile
 216         doc/man/Makefile
 217         doc/info/Makefile
 218         snprintf/Makefile
 219         libringbuffer/Makefile
 220         liblttng-ust-comm/Makefile
 221         liblttng-ust/Makefile
 222         liblttng-ust-ctl/Makefile
 223         liblttng-ust-fork/Makefile
 224         liblttng-ust-java/Makefile
 225         tests/Makefile
 226         tests/hello/Makefile
 227         tests/hello.cxx/Makefile
 228         tests/demo/Makefile
 229         tests/fork/Makefile
 230         tests/ust-basic-tracing/Makefile
 231         tests/ust-multi-test/Makefile
 232         lttng-ust.pc
 233 ])
 234 AC_OUTPUT