configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.0-rc1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_MAKE_SET
  42 LT_INIT
  43
  44 ## Checks for libraries.
  45 AC_CHECK_LIB([dl], [dlopen])
  46 AC_CHECK_LIB([pthread], [pthread_create])
  47
  48 # Check for libuuid
  49 AC_CHECK_LIB([uuid], [uuid_generate],
  50 [
  51         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
  52         have_libuuid=yes
  53 ],
  54 [
  55         # libuuid not found, check for uuid_create in libc.
  56         AC_CHECK_LIB([c], [uuid_create],
  57         [
  58                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  59                 have_libc_uuid=yes
  60         ],
  61         [
  62                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify its location.])
  63         ])
  64 ]
  65 )
  66 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  67 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  68
  69 # Checks for header files.
  70 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  71
  72 # Checks for typedefs, structures, and compiler characteristics.
  73 AC_C_INLINE
  74 #AC_TYPE_INT16_T
  75 #AC_TYPE_INT32_T
  76 #AC_TYPE_INT64_T
  77 #AC_TYPE_INT8_T
  78 #AC_TYPE_PID_T
  79 #AC_TYPE_SIZE_T
  80 #AC_TYPE_SSIZE_T
  81 #AC_TYPE_UINT16_T
  82 #AC_TYPE_UINT32_T
  83 #AC_TYPE_UINT64_T
  84 #AC_TYPE_UINT8_T
  85 #AC_CHECK_TYPES([ptrdiff_t])
  86
  87 # Checks for library functions.
  88 AC_FUNC_MALLOC
  89 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
  90
  91 CFLAGS="-Wall $CFLAGS"
  92
  93 # Check for texinfo, required for building the documentation
  94 # TODO: make this (and building the documentation) optional
  95 AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
  96 AS_IF([test "x$TEXINFO" != "xyes"],[
  97         AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
  98 ])
  99
 100 # URCU
 101
 102 # urcu - check if we just find the headers it out of the box.
 103 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 104 This error can also occur when the liburcu package's configure script has not been run.])])
 105
 106 AC_MSG_CHECKING([caa_likely()])
 107 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 108 #include <urcu/compiler.h>
 109 void fct(void)
 110 {
 111         if (caa_likely(1)) {
 112         }
 113 }
 114 ]])],[
 115         AC_MSG_RESULT([yes])
 116 ],[
 117         AC_MSG_RESULT([no])
 118         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 119
 120 ])
 121
 122 # urcu - check that URCU lib is available to compilation
 123 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 124
 125 # urcu - check that URCU lib is at least version 0.6
 126 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 127
 128
 129 # Check for various supplementary host information (beyond the
 130 # triplet) which might affect the library format choices.  E.g., we
 131 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 132
 133 case "${host}" in
 134 changequote(,)dnl
 135   i[34567]86-*-linux*)
 136 changequote([,])dnl
 137     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 138                     [save_CPPFLAGS="$CPPFLAGS"
 139                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 140                     AC_EGREP_CPP([got it], [
 141 #if __x86_64__
 142 got it
 143 #endif
 144                  ], [ust_cv_i386_is_x86_64=yes],
 145                     [ust_cv_i386_is_x86_64=no])
 146                     CPPFLAGS="$save_CPPFLAGS"])
 147     ;;
 148 esac
 149
 150 AC_MSG_CHECKING([library format for the host system])
 151 case $host_cpu in
 152 changequote(,)dnl
 153         i[3456]86)
 154 changequote([,])dnl
 155           if test "$ust_cv_i386_is_x86_64" = yes ; then
 156              LIBFORMAT="elf64-x86-64"
 157           else
 158              LIBFORMAT="elf32-i386"
 159           fi
 160           ;;
 161         x86_64) LIBFORMAT="elf64-x86-64" ;;
 162         powerpc) LIBFORMAT="elf32-powerpc" ;;
 163         ppc64) LIBFORMAT="elf64-powerpc" ;;
 164         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 165         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 166         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 167         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 168         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 169         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 170         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 171 esac
 172 AC_SUBST(LIBFORMAT)
 173 AC_MSG_RESULT($LIBFORMAT)
 174
 175 if test "x$host_cpu" = "xarm" ; then
 176 AC_MSG_CHECKING([checking for armv5])
 177 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 178 #ifndef __ARM_ARCH_5TEJ__
 179 #error "no arm5 here"
 180 #endif
 181 ]])],[
 182         AC_MSG_RESULT([yes])
 183         NO_UNALIGNED_ACCESS=1
 184
 185 ],[
 186         AC_MSG_RESULT([no])
 187
 188 ])
 189 fi
 190 if test x$NO_UNALIGNED_ACCESS = x ; then
 191 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 192 fi
 193
 194 # Set compile flags to java include files if given
 195 AC_ARG_WITH([java-jdk],
 196         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 197         [JAVA_JDK=$withval],
 198         [JAVA_JDK=""]
 199 )
 200 AS_IF([test $JAVA_JDK],[
 201         AS_IF([test -d $JAVA_JDK],[
 202                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 203                 SUBDIRS=`find $JAVA_JDK/include -type d`
 204                 CPPFLAGS+=" "
 205                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 206                 CPPFLAGS+=" "
 207         ],[
 208                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 209         ])
 210 ])
 211
 212 # Check for JNI header files if requested
 213 AC_ARG_WITH([jni-interface],
 214         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 215         [jni_interface=$withval],
 216         [jni_interface=no]
 217 )
 218
 219 AS_IF([test "x$jni_interface" = "xyes"],[
 220         AC_CHECK_HEADERS([jni.h],[],[
 221         AC_MSG_ERROR([missing jni.h
 222 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 223 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 224         ])
 225 ])
 226 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 227
 228 # sdt.h integration
 229 AC_ARG_WITH([sdt],
 230         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 231         [with_sdt=$withval],
 232         [with_sdt="no"]
 233 )
 234
 235 AS_IF([test "x$with_sdt" = "xyes"],[
 236         AC_MSG_CHECKING([STAP_PROBEV()])
 237         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 238         #define SDT_USE_VARIADIC
 239         #include <sys/sdt.h>
 240         void fct(void)
 241         {
 242                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 243         }
 244         ]])],[
 245                 AC_MSG_RESULT([yes])
 246                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 247         ],[
 248                 AC_MSG_RESULT([no])
 249                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 250         ])
 251 ])
 252
 253 #currently disabled.
 254         #tests/hello2/Makefile
 255         #tests/basic/Makefile
 256         #tests/simple_include/Makefile
 257         #tests/snprintf/Makefile
 258         #tests/test-nevents/Makefile
 259         #tests/test-libustinstr-malloc/Makefile
 260         #tests/dlopen/Makefile
 261         #tests/same_line_marker/Makefile
 262         #tests/trace_event/Makefile
 263         #tests/tracepoint/Makefile
 264         #tests/tracepoint/benchmark/Makefile
 265         #tests/register_test/Makefile
 266         #tests/libustctl_function_#tests/Makefile
 267         #tests/exit-fast/Makefile
 268         #tests/basic_long/Makefile
 269
 270 AC_CONFIG_FILES([
 271         Makefile
 272         doc/Makefile
 273         doc/examples/Makefile
 274         include/Makefile
 275         include/lttng/ust-version.h
 276         snprintf/Makefile
 277         libringbuffer/Makefile
 278         liblttng-ust-comm/Makefile
 279         liblttng-ust/Makefile
 280         liblttng-ust-ctl/Makefile
 281         liblttng-ust-fork/Makefile
 282         liblttng-ust-java/Makefile
 283         liblttng-ust-libc-wrapper/Makefile
 284         tools/Makefile
 285         tests/Makefile
 286         tests/hello/Makefile
 287         tests/hello-static-lib/Makefile
 288         tests/hello.cxx/Makefile
 289         tests/demo/Makefile
 290         tests/fork/Makefile
 291         tests/ust-basic-tracing/Makefile
 292         tests/ust-multi-test/Makefile
 293         lttng-ust.pc
 294 ])
 295
 296 AC_OUTPUT
 297
 298 # Report on the configuration options
 299 AS_ECHO()
 300 AS_ECHO("LTTng-UST will be built with the following options:")
 301 AS_ECHO("Library format: $LIBFORMAT")
 302
 303 AS_ECHO()
 304 AS_ECHO_N("Java support (JNI): ")
 305 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 306
 307 AS_ECHO_N("sdt.h integration:  ")
 308 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 309
 310 AS_ECHO()
 311 AS_ECHO("Type 'make' to compile.")
 312