configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7
   8 # Project version information
   9 m4_define([ust_version_major], [2])
  10 m4_define([ust_version_minor], [13])
  11 m4_define([ust_version_patch], [0])
  12 m4_define([ust_version_dev_stage], [-pre])
  13 m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
  14 m4_define([ust_version_name], [[Codename TBD]])
  15 m4_define([ust_version_description], [[Description TBD]])
  16
  17 # Library version information of "liblttng-ust"
  18 # Following the numbering scheme proposed by libtool for the library version
  19 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  20 m4_define([ust_lib_version_current], [1])
  21 m4_define([ust_lib_version_revision], [0])
  22 m4_define([ust_lib_version_age], [0])
  23 m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
  24
  25 # Library version information of "liblttng-ust-ctl"
  26 # Following the numbering scheme proposed by libtool for the library version
  27 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  28 m4_define([ust_ctl_lib_version_current], [5])
  29 m4_define([ust_ctl_lib_version_revision], [0])
  30 m4_define([ust_ctl_lib_version_age], [0])
  31 m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
  32
  33
  34 ##                     ##
  35 ## Autoconf base setup ##
  36 ##                     ##
  37
  38 AC_PREREQ([2.69])
  39 AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
  40
  41 AC_CONFIG_HEADERS([src/common/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
  42 AC_CONFIG_AUX_DIR([config])
  43 AC_CONFIG_MACRO_DIR([m4])
  44
  45 AC_CANONICAL_TARGET
  46 AC_CANONICAL_HOST
  47
  48
  49 ##                     ##
  50 ## Automake base setup ##
  51 ##                     ##
  52
  53 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  54 AM_MAINTAINER_MODE([enable])
  55
  56 # Enable silent rules by default
  57 AM_SILENT_RULES([yes])
  58
  59
  60 ##                               ##
  61 ## OS and Arch specific defaults ##
  62 ##                               ##
  63
  64 # Set os specific options
  65 AS_CASE([$host_os],
  66   [freebsd*], [AE_FEATURE_DISABLE([numa])]
  67 )
  68
  69 # Set architecture specific options
  70 AS_CASE([$host_cpu],
  71   [i[[3456]]86], [],
  72   [x86_64], [],
  73   [amd64], [],
  74   [powerpc], [],
  75   [ppc64], [],
  76   [ppc64le], [],
  77   [powerpc64], [],
  78   [powerpc64le], [],
  79   [s390], [],
  80   [s390x], [],
  81   [arm*], [AE_FEATURE_DISABLE([numa])],
  82   [aarch64*], [],
  83   [mips*], [],
  84   [tile*], [],
  85   [
  86     unsupported_arch="yes"
  87   ])
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 # Choose the C compiler
  95 AC_PROG_CC
  96 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  97 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  98
  99 # Make sure the C compiler supports C99
 100 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
 101
 102 # Enable available system extensions and LFS support
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Make sure the C compiler supports __attribute__
 107 AX_C___ATTRIBUTE__
 108 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 109   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 110
 111 # Make sure we have pthread support
 112 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 113
 114 # Make sure the C compiler supports weak symbols
 115 AX_SYS_WEAK_ALIAS
 116 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
 117   [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_C_TYPEOF
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_INT8_T
 126 AC_TYPE_MODE_T
 127 AC_TYPE_OFF_T
 128 AC_TYPE_PID_T
 129 AC_TYPE_SIZE_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UID_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136 AC_CHECK_TYPES([ptrdiff_t])
 137
 138
 139 ##                     ##
 140 ## C++ compiler checks ##
 141 ##                     ##
 142
 143 # Find an optional C++11 compiler without GNU extensions (-std=c++11)
 144 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 145
 146
 147 ##               ##
 148 ## Header checks ##
 149 ##               ##
 150
 151 AC_HEADER_STDBOOL
 152 AC_CHECK_HEADERS([ \
 153   arpa/inet.h \
 154   dlfcn.h \
 155   fcntl.h \
 156   float.h \
 157   limits.h \
 158   linux/perf_event.h \
 159   locale.h \
 160   stddef.h \
 161   sys/socket.h \
 162   sys/time.h \
 163   wchar.h \
 164 ])
 165
 166 # Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
 167 AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
 168   AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
 169 ])
 170
 171
 172 ##                 ##
 173 ## Programs checks ##
 174 ##                 ##
 175
 176 AM_PROG_AR
 177 AC_PROG_SED
 178 AC_PROG_GREP
 179 AC_PROG_LN_S
 180 AC_PROG_MKDIR_P
 181 AC_PROG_MAKE_SET
 182 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 183 AC_CHECK_PROGS([CMAKE], [cmake])
 184 AC_CHECK_PROGS([FOLD], [fold])
 185 AC_CHECK_PROGS([XMLTO], [xmlto])
 186
 187 AM_PATH_PYTHON([2.7], [], [PYTHON=""])
 188
 189 # Initialize and configure libtool
 190 LT_INIT([disable-static])
 191
 192
 193 ##                ##
 194 ## Library checks ##
 195 ##                ##
 196
 197 AC_FUNC_CHOWN
 198 AC_FUNC_FORK
 199 AC_FUNC_MMAP
 200 AC_FUNC_STRERROR_R
 201 AC_FUNC_STRNLEN
 202 AC_CHECK_FUNCS([ \
 203   atexit \
 204   clock_gettime \
 205   ftruncate \
 206   getpagesize \
 207   gettimeofday \
 208   localeconv \
 209   memchr \
 210   memmove \
 211   memset \
 212   mkdir \
 213   munmap \
 214   realpath \
 215   sched_getcpu \
 216   socket \
 217   strchr \
 218   strdup \
 219   strerror \
 220   strtol \
 221   strtoul \
 222   sysconf \
 223 ])
 224
 225 # AC_FUNC_MALLOC causes problems when cross-compiling.
 226 #AC_FUNC_MALLOC
 227 #AC_FUNC_REALLOC
 228
 229 # Check for pthread_setname_np and its signature
 230 LTTNG_PTHREAD_SETNAME_NP
 231 LTTNG_PTHREAD_GETNAME_NP
 232
 233 # Check dor dlopen() in -ldl or -lc
 234 AC_CHECK_LIB([dl], [dlopen], [
 235   libdl_name=dl
 236   DL_LIBS="-ldl"
 237 ], [
 238   # dlopen not found in libdl, check in libc
 239   AC_CHECK_LIB([c], [dlopen], [
 240     libdl_name=c
 241     DL_LIBS="-lc"
 242   ], [
 243     AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 244   ])
 245 ])
 246 AC_SUBST(DL_LIBS)
 247
 248 # Check if libdl has dlmopen()
 249 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 250   AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
 251 ])
 252
 253 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 254 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 255
 256
 257 ##                 ##
 258 ## User variables  ##
 259 ##                 ##
 260
 261 # Additional variables captured during ./configure
 262
 263 AC_ARG_VAR([CLASSPATH], [Java class path])
 264
 265
 266 ##                              ##
 267 ## Optionnal features selection ##
 268 ##                              ##
 269
 270 # numa integration
 271 # Enabled by default, except on some platforms
 272 AE_FEATURE_DEFAULT_ENABLE
 273 AE_FEATURE([numa],[disable NUMA support])
 274
 275 # Java JNI interface library
 276 # Disabled by default
 277 AE_FEATURE_DEFAULT_DISABLE
 278 AE_FEATURE([jni-interface], [build JNI interface between C and Java])
 279
 280 # Build the Java Logging API agent
 281 # Disabled by default
 282 AE_FEATURE_DEFAULT_DISABLE
 283 AE_FEATURE([java-agent-jul],[build the LTTng UST Java agent with JUL support])
 284
 285 # Build the Java Log4j agent
 286 # Disabled by default
 287 AE_FEATURE_DEFAULT_DISABLE
 288 AE_FEATURE([java-agent-log4j],[build the LTTng UST Java agent with Log4j support])
 289
 290 # Build both Java agents
 291 # Disabled by default
 292 AE_FEATURE_DEFAULT_DISABLE
 293 AE_FEATURE([java-agent-all],[build the LTTng UST Java agent with all supported backends])
 294
 295 # Build the Python agent
 296 # Disabled by default
 297 AE_FEATURE_DEFAULT_DISABLE
 298 AE_FEATURE([python-agent],[build the LTTng UST Python agent])
 299
 300 # Build the examples
 301 # Disabled by default
 302 AE_FEATURE_DEFAULT_ENABLE
 303 AE_FEATURE([examples],[Do not build and install examples])
 304
 305 # Man pages
 306 # Enabled by default
 307 AE_FEATURE_DEFAULT_ENABLE
 308 AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball)])
 309
 310 # Systemtap sdt.h integration
 311 # Disabled by default
 312 AC_ARG_WITH([sdt],
 313   [AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])]
 314 )
 315
 316 # Override the default runtime directory
 317 AC_ARG_WITH([lttng-system-rundir], [
 318 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 319 ], [
 320   lttng_system_rundir="$withval"
 321 ], [
 322   lttng_system_rundir="/var/run/lttng"
 323 ])
 324
 325 # Add the java command line arguments like '--wit-java-prefix'
 326 AX_JAVA_OPTIONS
 327
 328
 329 ##                                          ##
 330 ## Check for conflicting features selection ##
 331 ##                                          ##
 332
 333 AE_IF_FEATURE_DISABLED([shared], [
 334   AC_MSG_ERROR(LTTng-UST requires shared libraries to be enabled)
 335 ])
 336
 337 AE_IF_FEATURE_ENABLED([java-agent-all], [
 338   AE_FEATURE_ENABLE([java-agent-jul])
 339   AE_FEATURE_ENABLE([java-agent-log4j])
 340 ])
 341
 342
 343 ##                                          ##
 344 ## Check for optional features dependencies ##
 345 ##                                          ##
 346
 347 # The numa integration requires libnuma
 348 AE_IF_FEATURE_ENABLED([numa], [
 349   AC_CHECK_LIB([numa], [numa_available], [], [
 350     AC_MSG_ERROR([dnl
 351 libnuma is not available. Please either install it (e.g. libnuma-dev) or use
 352 [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure
 353 argument to disable NUMA support.
 354     ])
 355   ])
 356 ])
 357
 358 # The JNI interface and Java Agents require a working Java JDK
 359 AS_IF([AE_IS_FEATURE_ENABLED([jni-interface]) || AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j])], [
 360   AX_PROG_JAVAC
 361   AX_PROG_JAVA
 362   AX_PROG_JAR
 363
 364   # Get the CPPFLAGS required to build jni libaries
 365   AX_JNI_INCLUDE_DIR
 366   for jni_include_dir in $JNI_INCLUDE_DIRS; do
 367     JNI_CPPFLAGS="$JNI_CPPFLAGS -I$jni_include_dir"
 368   done
 369
 370   # Check for javah and jni.h
 371   saved_CPPFLAGS="$CPPFLAGS"
 372   CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 373   AX_PROG_JAVAH
 374   CPPFLAGS="$saved_CPPFLAGS"
 375 ])
 376
 377 # The log4j agent requires the log4j jar in the classpath
 378 AE_IF_FEATURE_ENABLED([java-agent-log4j], [
 379   AX_CHECK_CLASS([org.apache.log4j.Logger])
 380   AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 381     AC_MSG_ERROR([dnl
 382 The UST Java agent support for log4j was requested but the Log4j classes were
 383 not found. Please specify the location of the Log4j jar via the Java CLASSPATH
 384 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j.jar"
 385
 386 Current CLASSPATH: "$CLASSPATH"
 387     ])
 388   ])
 389 ])
 390
 391 # The python agent requires a python interpreter
 392 AE_IF_FEATURE_ENABLED([python-agent], [
 393   AS_IF([test "x$PYTHON" = "x"], [
 394     AC_MSG_ERROR([dnl
 395 Cannot find a suitable python interpreter. You can override it with the PYTHON
 396 environment variable.
 397     ])
 398   ])
 399 ])
 400
 401 # Check for asciidoc and xmlto if we enabled building the man pages.
 402 AE_IF_FEATURE_ENABLED([man-pages], [
 403   AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 404     AE_IF_IN_GIT_REPO([
 405       # This is an error because we're in the Git repo, which
 406       # means the man pages are not already generated for us,
 407       # thus asciidoc/xmlto are required because we were asked
 408       # to build the man pages.
 409       AC_MSG_ERROR([dnl
 410 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 411 --disable-man-pages to disable building the man pages, in which case
 412 they will not be installed.
 413       ])
 414     ], [
 415       # Only warn here: since we're in the tarball, the man
 416       # pages should already be generated at this point, thus
 417       # asciidoc/xmlto are not strictly required.
 418       warn_prebuilt_man_pages=yes
 419     ])
 420   ], [
 421     have_asciidoc_xmlto=yes
 422   ])
 423 ])
 424
 425 AS_IF([test "x$with_sdt" = "xyes"], [
 426   AC_MSG_CHECKING([STAP_PROBEV()])
 427   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 428     #define SDT_USE_VARIADIC
 429     #include <sys/sdt.h>
 430     void fct(void)
 431     {
 432       STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 433     }
 434   ]])], [
 435     AC_MSG_RESULT([yes])
 436     AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1], [SystemTap integration via sdt.h])
 437   ], [
 438     AC_MSG_RESULT([no])
 439     AC_MSG_ERROR([dnl
 440 The sdt.h integration was requested but the STAP_PROBEV define cannot be used.
 441 Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify
 442 a non-standard path to sys/sdt.h
 443     ])
 444   ])
 445 ])
 446
 447
 448 ##                                                                    ##
 449 ## Set defines for optional features conditionnals in the source code ##
 450 ##                                                                    ##
 451
 452 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], [LTTng system runtime directory])
 453
 454 # Defined in include/lttng/ust-version.h
 455 AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
 456 AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
 457 AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
 458 AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
 459 AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
 460 AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
 461
 462
 463 ##                                                                          ##
 464 ## Set automake variables for optional feature conditionnals in Makefile.am ##
 465 ##                                                                          ##
 466
 467 AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([examples]))
 468 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
 469 AM_CONDITIONAL([ENABLE_JAVA_AGENT], AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j]))
 470 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], AE_IS_FEATURE_ENABLED([java-agent-jul]))
 471 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], AE_IS_FEATURE_ENABLED([java-agent-log4j]))
 472 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], AE_IS_FEATURE_ENABLED([jni-interface]))
 473 AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
 474 AM_CONDITIONAL([ENABLE_NUMA], AE_IS_FEATURE_ENABLED([numa]))
 475 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], AE_IS_FEATURE_ENABLED([python-agent]))
 476 AM_CONDITIONAL([ENABLE_UST_DL], [test "x$ac_cv_have_decl_RTLD_DI_LINKMAP" = "xyes"])
 477 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 478 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
 479 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
 480 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 481 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
 482
 483
 484 ##                                             ##
 485 ## Substitute variables for use in Makefile.am ##
 486 ##                                             ##
 487
 488 # Library versions for libtool
 489 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], ust_lib_version)
 490 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], ust_ctl_lib_version)
 491
 492 # Major soname for python-lttngust
 493 AC_SUBST([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current])
 494
 495 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
 496 AC_SUBST(AM_CFLAGS)
 497
 498 AM_CXXFLAGS="$AM_CFLAGS"
 499 AC_SUBST(AM_CXXFLAGS)
 500
 501 # The order in which the include folders are searched is important.
 502 # The top_builddir should always be searched first in the event that a build
 503 # time generated file is included.
 504 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 505 AC_SUBST(AM_CPPFLAGS)
 506
 507 AC_SUBST(JNI_CPPFLAGS)
 508
 509
 510 ##                                     ##
 511 ## Output files generated by configure ##
 512 ##                                     ##
 513
 514 # List of files to be generated from '.in' templates by AC_OUTPUT
 515 AC_CONFIG_FILES([
 516   Makefile
 517   doc/examples/Makefile
 518   doc/Makefile
 519   doc/man/Makefile
 520   include/Makefile
 521   src/common/Makefile
 522   src/libcounter/Makefile
 523   src/liblttng-ust-comm/Makefile
 524   src/liblttng-ust-ctl/Makefile
 525   src/lib/lttng-ust-cyg-profile/Makefile
 526   src/lib/lttng-ust-dl/Makefile
 527   src/lib/lttng-ust-fd/Makefile
 528   src/lib/lttng-ust-fork/Makefile
 529   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 530   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 531   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 532   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 533   src/lib/lttng-ust-java-agent/java/Makefile
 534   src/lib/lttng-ust-java-agent/jni/common/Makefile
 535   src/lib/lttng-ust-java-agent/jni/jul/Makefile
 536   src/lib/lttng-ust-java-agent/jni/log4j/Makefile
 537   src/lib/lttng-ust-java-agent/jni/Makefile
 538   src/lib/lttng-ust-java-agent/Makefile
 539   src/lib/lttng-ust-java/Makefile
 540   src/lib/lttng-ust-libc-wrapper/Makefile
 541   src/liblttng-ust/Makefile
 542   src/lib/lttng-ust-python-agent/Makefile
 543   src/lib/Makefile
 544   src/libringbuffer/Makefile
 545   src/lttng-ust-ctl.pc
 546   src/lttng-ust.pc
 547   src/Makefile
 548   src/python-lttngust/lttngust/version.py
 549   src/python-lttngust/Makefile
 550   src/python-lttngust/setup.py
 551   tests/benchmark/Makefile
 552   tests/compile/ctf-types/Makefile
 553   tests/compile/hello.cxx/Makefile
 554   tests/compile/hello/Makefile
 555   tests/compile/hello-many/Makefile
 556   tests/compile/Makefile
 557   tests/compile/same_line_tracepoint/Makefile
 558   tests/compile/test-app-ctx/Makefile
 559   tests/Makefile
 560   tests/unit/gcc-weak-hidden/Makefile
 561   tests/unit/libmsgpack/Makefile
 562   tests/unit/libringbuffer/Makefile
 563   tests/unit/Makefile
 564   tests/unit/pthread_name/Makefile
 565   tests/unit/snprintf/Makefile
 566   tests/unit/ust-elf/Makefile
 567   tests/unit/ust-error/Makefile
 568   tests/unit/ust-utils/Makefile
 569   tests/utils/Makefile
 570   tools/Makefile
 571 ])
 572
 573 AC_OUTPUT
 574
 575
 576 ##                                    ##
 577 ## Mini-report on what will be built. ##
 578 ##                                    ##
 579
 580 PPRINT_INIT
 581 PPRINT_SET_INDENT(1)
 582 PPRINT_SET_TS(38)
 583
 584 AS_ECHO
 585 AS_IF([test -n "ust_version_name"], [
 586   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
 587 ], [
 588   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
 589 ])
 590
 591 AS_ECHO
 592
 593 AS_IF([test -n "ust_version_description"], [
 594   AS_IF([test -n "$FOLD"], [
 595     AS_ECHO("`AS_ECHO("ust_version_description") | $FOLD -s`")
 596   ], [
 597     AS_ECHO("ust_version_description")
 598   ])
 599   AS_ECHO
 600 ])
 601
 602 PPRINT_SUBTITLE([System])
 603
 604 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 605
 606 AS_IF([test "x$unsupported_arch" = "xyes"],[
 607        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 608 ])
 609
 610 AS_ECHO
 611 PPRINT_SUBTITLE([Features])
 612 PPRINT_SET_INDENT(1)
 613
 614 test "x$with_sdt" = "xyes" && value=1 || value=0
 615 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 616
 617 AE_IS_FEATURE_ENABLED([java-agent-jul]) && value=1 || value=0
 618 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 619
 620 AE_IS_FEATURE_ENABLED([java-agent-log4j]) && value=1 || value=0
 621 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 622
 623 AE_IS_FEATURE_ENABLED([jni-interface]) && value=1 || value=0
 624 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 625
 626 AE_IS_FEATURE_ENABLED([python-agent]) && value=1 || value=0
 627 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 628
 629 test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
 630 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 631
 632 AE_IS_FEATURE_ENABLED([numa]) && value=1 || value=0
 633 PPRINT_PROP_BOOL([NUMA], $value)
 634
 635 AS_ECHO
 636 PPRINT_SET_INDENT(0)
 637
 638 AE_IS_FEATURE_ENABLED([examples]) && value=1 || value=0
 639 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 640
 641 # man pages build enabled/disabled
 642 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 643
 644 AE_IF_FEATURE_ENABLED([man-pages], [
 645   AE_IF_IN_GIT_REPO([
 646     PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 647   ], [
 648     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 649       PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 650     ], [
 651       PPRINT_PROP_STRING([build_man_pages_msg],
 652         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 653         $PPRINT_COLOR_SUBTITLE)
 654     ])
 655   ])
 656 ], [
 657   PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 658 ])
 659
 660 m4_popdef([build_man_pages_msg])
 661
 662 PPRINT_SET_INDENT(1)
 663
 664 report_bindir="`eval eval echo $bindir`"
 665 report_libdir="`eval eval echo $libdir`"
 666
 667 # Print the bindir and libdir this `make install' will install into.
 668 AS_ECHO
 669 PPRINT_SUBTITLE([Install directories])
 670 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 671 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 672
 673 AS_ECHO
 674 PPRINT_SUBTITLE([System directories])
 675
 676 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 677
 678 PPRINT_SET_INDENT(0)
 679
 680 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 681   AS_ECHO
 682   PPRINT_WARN([dnl
 683 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 684
 685 Note that the man pages are already built in this distribution tarball,
 686 therefore asciidoc and xmlto are only needed if you intend to modify
 687 their sources.
 688
 689 Use --disable-man-pages to completely disable building and installing
 690 the man pages.])
 691 ])
 692
 693 # vim: shiftwidth=2 softtabstop=2 expandtab