configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[1.9.6],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/config.h])
  22 AH_TEMPLATE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([HAVE_SDT_INTEGRATION], [DTrace/GDB/SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\)$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_MAKE_SET
  42 LT_INIT
  43
  44 ## Checks for libraries.
  45 AC_CHECK_LIB([dl], [dlopen])
  46 AC_CHECK_LIB([pthread], [pthread_create])
  47
  48 # Check for libuuid
  49 AC_CHECK_LIB([uuid], [uuid_generate], [],
  50         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  51 )
  52
  53 # Checks for header files.
  54 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  55
  56 # Checks for typedefs, structures, and compiler characteristics.
  57 AC_C_INLINE
  58 #AC_TYPE_INT16_T
  59 #AC_TYPE_INT32_T
  60 #AC_TYPE_INT64_T
  61 #AC_TYPE_INT8_T
  62 #AC_TYPE_PID_T
  63 #AC_TYPE_SIZE_T
  64 #AC_TYPE_SSIZE_T
  65 #AC_TYPE_UINT16_T
  66 #AC_TYPE_UINT32_T
  67 #AC_TYPE_UINT64_T
  68 #AC_TYPE_UINT8_T
  69 #AC_CHECK_TYPES([ptrdiff_t])
  70
  71 # Checks for library functions.
  72 AC_FUNC_MALLOC
  73 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol])
  74
  75 CFLAGS="-Wall $CFLAGS"
  76
  77 # Check for texinfo, required for building the documentation
  78 # TODO: make this (and building the documentation) optional
  79 AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
  80 AS_IF([test "x$TEXINFO" != "xyes"],[
  81         AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
  82 ])
  83
  84 # URCU
  85
  86 # urcu - check if we just find the headers it out of the box.
  87 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CFLAGS]=-Idir to specify their location.
  88 This error can also occur when the liburcu package's configure script has not been run.])])
  89
  90 AC_MSG_CHECKING([caa_likely()])
  91 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  92 #include <urcu/compiler.h>
  93 void fct(void)
  94 {
  95         if (caa_likely(1)) {
  96         }
  97 }
  98 ]])],[
  99         AC_MSG_RESULT([yes])
 100 ],[
 101         AC_MSG_RESULT([no])
 102         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 103
 104 ])
 105
 106 # urcu - check that URCU lib is available to compilation
 107 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 108
 109 # urcu - check that URCU lib is at least version 0.6
 110 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 111
 112
 113 # Check for various supplementary host information (beyond the
 114 # triplet) which might affect the library format choices.  E.g., we
 115 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 116
 117 case "${host}" in
 118 changequote(,)dnl
 119   i[34567]86-*-linux*)
 120 changequote([,])dnl
 121     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 122                     [save_CPPFLAGS="$CPPFLAGS"
 123                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 124                     AC_EGREP_CPP([got it], [
 125 #if __x86_64__
 126 got it
 127 #endif
 128                  ], [ust_cv_i386_is_x86_64=yes],
 129                     [ust_cv_i386_is_x86_64=no])
 130                     CPPFLAGS="$save_CPPFLAGS"])
 131     ;;
 132 esac
 133
 134 AC_MSG_CHECKING([library format for the host system])
 135 case $host_cpu in
 136 changequote(,)dnl
 137         i[3456]86)
 138 changequote([,])dnl
 139           if test "$ust_cv_i386_is_x86_64" = yes ; then
 140              LIBFORMAT="elf64-x86-64"
 141           else
 142              LIBFORMAT="elf32-i386"
 143           fi
 144           ;;
 145         x86_64) LIBFORMAT="elf64-x86-64" ;;
 146         powerpc) LIBFORMAT="elf32-powerpc" ;;
 147         ppc64) LIBFORMAT="elf64-powerpc" ;;
 148         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 149         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 150         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 151         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 152         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 153         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 154         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 155 esac
 156 AC_SUBST(LIBFORMAT)
 157 AC_MSG_RESULT($LIBFORMAT)
 158
 159 if test "x$host_cpu" = "xarm" ; then
 160 AC_MSG_CHECKING([checking for armv5])
 161 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 162 #ifndef __ARM_ARCH_5TEJ__
 163 #error "no arm5 here"
 164 #endif
 165 ]])],[
 166         AC_MSG_RESULT([yes])
 167         NO_UNALIGNED_ACCESS=1
 168
 169 ],[
 170         AC_MSG_RESULT([no])
 171
 172 ])
 173 fi
 174 if test x$NO_UNALIGNED_ACCESS = x ; then
 175 AC_DEFINE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 176 fi
 177
 178 # Set compile flags to java include files if given
 179 AC_ARG_WITH([java-jdk],
 180         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 181         [JAVA_JDK=$withval],
 182         [JAVA_JDK=""]
 183 )
 184 AS_IF([test $JAVA_JDK],[
 185         AS_IF([test -d $JAVA_JDK],[
 186                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 187                 SUBDIRS=`find $JAVA_JDK/include -type d`
 188                 CFLAGS+=" "
 189                 CFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 190                 CFLAGS+=" "
 191         ],[
 192                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 193         ])
 194 ])
 195
 196 # Check for JNI header files if requested
 197 AC_ARG_WITH([jni-interface],
 198         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 199         [jni_interface=$withval],
 200         [jni_interface=no]
 201 )
 202
 203 AS_IF([test "x$jni_interface" = "xyes"],[
 204         AC_CHECK_HEADERS([jni.h],[],[
 205         AC_MSG_ERROR([missing jni.h
 206 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 207 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 208         ])
 209 ])
 210 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 211
 212 # sdt.h integration
 213 AC_ARG_WITH([sdt],
 214         [AS_HELP_STRING([--with-sdt],[provide DTrace, GDB and SystemTap integration via sdt.h [default=no]])],
 215         [with_sdt=$withval],
 216         [with_sdt="no"]
 217 )
 218
 219 AS_IF([test "x$with_sdt" = "xyes"],[
 220         AC_CHECK_HEADERS([sys/sdt.h], [
 221                 AC_DEFINE([HAVE_SDT_INTEGRATION], [1])
 222         ],[
 223                 AC_MSG_ERROR([The sdt.h integration was requested
 224 but this header file cannot be found. Make sure it is installed
 225 or use CFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 226         ])
 227 ])
 228
 229 #currently disabled.
 230         #tests/hello2/Makefile
 231         #tests/basic/Makefile
 232         #tests/simple_include/Makefile
 233         #tests/snprintf/Makefile
 234         #tests/test-nevents/Makefile
 235         #tests/test-libustinstr-malloc/Makefile
 236         #tests/dlopen/Makefile
 237         #tests/same_line_marker/Makefile
 238         #tests/trace_event/Makefile
 239         #tests/tracepoint/Makefile
 240         #tests/tracepoint/benchmark/Makefile
 241         #tests/register_test/Makefile
 242         #tests/libustctl_function_#tests/Makefile
 243         #tests/exit-fast/Makefile
 244         #tests/basic_long/Makefile
 245
 246 AC_CONFIG_FILES([
 247         Makefile
 248         include/Makefile
 249         include/lttng/ust-version.h
 250         snprintf/Makefile
 251         libringbuffer/Makefile
 252         liblttng-ust-comm/Makefile
 253         liblttng-ust/Makefile
 254         liblttng-ust-ctl/Makefile
 255         liblttng-ust-fork/Makefile
 256         liblttng-ust-java/Makefile
 257         liblttng-ust-libc-wrapper/Makefile
 258         tests/Makefile
 259         tests/hello/Makefile
 260         tests/hello-static-lib/Makefile
 261         tests/hello.cxx/Makefile
 262         tests/demo/Makefile
 263         tests/fork/Makefile
 264         tests/ust-basic-tracing/Makefile
 265         tests/ust-multi-test/Makefile
 266         lttng-ust.pc
 267 ])
 268
 269 AC_OUTPUT
 270
 271 # Report on the configuration options
 272 AS_ECHO()
 273 AS_ECHO("LTTng-UST will be built with the following options:")
 274 AS_ECHO("Library format: $LIBFORMAT")
 275
 276 AS_ECHO()
 277 AS_ECHO_N("Java support (JNI): ")
 278 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 279
 280 AS_ECHO_N("sdt.h integration:  ")
 281 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 282
 283 AS_ECHO()
 284 AS_ECHO("Type 'make' to compile.")
 285