configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7
   8 # Project version information
   9 m4_define([ust_version_major], [2])
  10 m4_define([ust_version_minor], [13])
  11 m4_define([ust_version_patch], [0])
  12 m4_define([ust_version_dev_stage], [-pre])
  13 m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
  14 m4_define([ust_version_name], [[Codename TBD]])
  15 m4_define([ust_version_description], [[Description TBD]])
  16
  17 # Library version information of "liblttng-ust"
  18 # Following the numbering scheme proposed by libtool for the library version
  19 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  20 m4_define([ust_lib_version_current], [1])
  21 m4_define([ust_lib_version_revision], [0])
  22 m4_define([ust_lib_version_age], [0])
  23 m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
  24
  25 # Library version information of "liblttng-ust-ctl"
  26 # Following the numbering scheme proposed by libtool for the library version
  27 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  28 m4_define([ust_ctl_lib_version_current], [5])
  29 m4_define([ust_ctl_lib_version_revision], [0])
  30 m4_define([ust_ctl_lib_version_age], [0])
  31 m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
  32
  33
  34 ##                     ##
  35 ## Autoconf base setup ##
  36 ##                     ##
  37
  38 AC_PREREQ([2.69])
  39 AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
  40
  41 AC_CONFIG_HEADERS([src/common/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
  42 AC_CONFIG_AUX_DIR([config])
  43 AC_CONFIG_MACRO_DIR([m4])
  44
  45 AC_CANONICAL_TARGET
  46 AC_CANONICAL_HOST
  47
  48
  49 ##                     ##
  50 ## Automake base setup ##
  51 ##                     ##
  52
  53 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  54 AM_MAINTAINER_MODE([enable])
  55
  56 # Enable silent rules by default
  57 AM_SILENT_RULES([yes])
  58
  59
  60 ##                               ##
  61 ## OS and Arch specific defaults ##
  62 ##                               ##
  63
  64 # Set os specific options
  65 AS_CASE([$host_os],
  66   [freebsd*], [AE_FEATURE_DISABLE([numa])]
  67 )
  68
  69 # Set architecture specific options
  70 AS_CASE([$host_cpu],
  71   [i[[3456]]86], [],
  72   [x86_64], [],
  73   [amd64], [],
  74   [powerpc], [],
  75   [ppc64], [],
  76   [ppc64le], [],
  77   [powerpc64], [],
  78   [powerpc64le], [],
  79   [s390], [],
  80   [s390x], [],
  81   [arm*], [AE_FEATURE_DISABLE([numa])],
  82   [aarch64*], [],
  83   [mips*], [],
  84   [tile*], [],
  85   [
  86     unsupported_arch="yes"
  87   ])
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 # Choose the C compiler
  95 AC_PROG_CC
  96 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  97 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  98
  99 # Make sure the C compiler supports C99
 100 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
 101
 102 # Enable available system extensions and LFS support
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Make sure the C compiler supports __attribute__
 107 AX_C___ATTRIBUTE__
 108 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 109   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 110
 111 # Make sure we have pthread support
 112 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 113
 114 # Make sure the C compiler supports weak symbols
 115 AX_SYS_WEAK_ALIAS
 116 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
 117   [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_C_TYPEOF
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_INT8_T
 126 AC_TYPE_MODE_T
 127 AC_TYPE_OFF_T
 128 AC_TYPE_PID_T
 129 AC_TYPE_SIZE_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UID_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136 AC_CHECK_TYPES([ptrdiff_t])
 137
 138 # Detect warning flags supported by the C compiler and append them to
 139 # WARN_CFLAGS.
 140 m4_define([WARN_FLAGS_LIST], [ dnl
 141   -Wall dnl
 142   -Wextra dnl
 143   -Wmissing-prototypes dnl
 144   -Wmissing-declarations dnl
 145   -Wnull-dereference dnl
 146   -Wundef dnl
 147   -Wshadow dnl
 148   -Wjump-misses-init dnl
 149   -Wsuggest-attribute=format dnl
 150   -Wtautological-constant-out-of-range-compare dnl
 151   -Wnested-externs dnl
 152   -Wwrite-strings dnl
 153   -Wformat=2 dnl
 154   -Wstrict-aliasing dnl
 155   -Wmissing-noreturn dnl
 156   -Winit-self dnl
 157   -Wduplicated-cond dnl
 158   -Wduplicated-branches dnl
 159   -Wlogical-op dnl
 160   dnl These would require reworking the tracepoint macros
 161   dnl-Wredundant-decls dnl
 162   -Wno-sign-compare dnl
 163   -Wno-missing-field-initializers dnl
 164   -Wno-null-dereference dnl
 165 ])
 166
 167 # Pass -Werror as an extra flag during the test: this is needed to make the
 168 # -Wunknown-warning-option diagnostic fatal with clang.
 169 AC_LANG_PUSH([C])
 170 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
 171 AC_LANG_POP([C])
 172
 173 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 174 # written in such a way that it triggers warnings with the following warning
 175 # flags.  So they would always end up disabled if we put them there, because
 176 # the test program would not build.
 177 #
 178 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 179 # Clang >= 3.3 (required by the project) and are only valid for C code.
 180 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 181
 182 # Disable 'strict aliasing' if the compiler supports it.
 183 AC_LANG_PUSH([C])
 184 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 185 AC_LANG_POP([C])
 186
 187
 188 ##                     ##
 189 ## C++ compiler checks ##
 190 ##                     ##
 191
 192 # Find an optional C++11 compiler without GNU extensions (-std=c++11)
 193 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 194
 195 AS_IF([test "$HAVE_CXX11" = "1"], [
 196   # Pass -Werror as an extra flag during the test: this is needed to make the
 197   # -Wunknown-warning-option diagnostic fatal with clang.
 198   AC_LANG_PUSH([C++])
 199   AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST -Wno-undef -Wno-duplicated-branches], [WARN_CXXFLAGS], [-Werror])
 200   AC_LANG_POP([C++])
 201 ])
 202
 203
 204 ##               ##
 205 ## Header checks ##
 206 ##               ##
 207
 208 AC_HEADER_STDBOOL
 209 AC_CHECK_HEADERS([ \
 210   arpa/inet.h \
 211   dlfcn.h \
 212   fcntl.h \
 213   float.h \
 214   limits.h \
 215   linux/perf_event.h \
 216   locale.h \
 217   stddef.h \
 218   sys/socket.h \
 219   sys/time.h \
 220   wchar.h \
 221 ])
 222
 223 # Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
 224 AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
 225   AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
 226 ])
 227
 228
 229 ##                 ##
 230 ## Programs checks ##
 231 ##                 ##
 232
 233 AM_PROG_AR
 234 AC_PROG_SED
 235 AC_PROG_GREP
 236 AC_PROG_LN_S
 237 AC_PROG_MKDIR_P
 238 AC_PROG_MAKE_SET
 239 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 240 AC_CHECK_PROGS([CMAKE], [cmake])
 241 AC_CHECK_PROGS([FOLD], [fold])
 242 AC_CHECK_PROGS([XMLTO], [xmlto])
 243
 244 AM_PATH_PYTHON([2.7], [], [PYTHON=""])
 245
 246 # Initialize and configure libtool
 247 LT_INIT([disable-static])
 248
 249
 250 ##                ##
 251 ## Library checks ##
 252 ##                ##
 253
 254 AC_FUNC_CHOWN
 255 AC_FUNC_FORK
 256 AC_FUNC_MMAP
 257 AC_FUNC_STRERROR_R
 258 AC_FUNC_STRNLEN
 259 AC_CHECK_FUNCS([ \
 260   atexit \
 261   clock_gettime \
 262   ftruncate \
 263   getpagesize \
 264   gettimeofday \
 265   localeconv \
 266   memchr \
 267   memmove \
 268   memset \
 269   mkdir \
 270   munmap \
 271   realpath \
 272   sched_getcpu \
 273   socket \
 274   strchr \
 275   strdup \
 276   strerror \
 277   strtol \
 278   strtoul \
 279   sysconf \
 280 ])
 281
 282 # AC_FUNC_MALLOC causes problems when cross-compiling.
 283 #AC_FUNC_MALLOC
 284 #AC_FUNC_REALLOC
 285
 286 # Check for pthread_setname_np and its signature
 287 LTTNG_PTHREAD_SETNAME_NP
 288 LTTNG_PTHREAD_GETNAME_NP
 289
 290 # Check dor dlopen() in -ldl or -lc
 291 AC_CHECK_LIB([dl], [dlopen], [
 292   libdl_name=dl
 293   DL_LIBS="-ldl"
 294 ], [
 295   # dlopen not found in libdl, check in libc
 296   AC_CHECK_LIB([c], [dlopen], [
 297     libdl_name=c
 298     DL_LIBS="-lc"
 299   ], [
 300     AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 301   ])
 302 ])
 303 AC_SUBST(DL_LIBS)
 304
 305 # Check if libdl has dlmopen()
 306 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 307   AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
 308 ])
 309
 310 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 311 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 312
 313
 314 ##                 ##
 315 ## User variables  ##
 316 ##                 ##
 317
 318 # Additional variables captured during ./configure
 319
 320 AC_ARG_VAR([CLASSPATH], [Java class path])
 321
 322
 323 ##                              ##
 324 ## Optionnal features selection ##
 325 ##                              ##
 326
 327 # numa integration
 328 # Enabled by default, except on some platforms
 329 AE_FEATURE_DEFAULT_ENABLE
 330 AE_FEATURE([numa],[disable NUMA support])
 331
 332 # Java JNI interface library
 333 # Disabled by default
 334 AE_FEATURE_DEFAULT_DISABLE
 335 AE_FEATURE([jni-interface], [build JNI interface between C and Java])
 336
 337 # Build the Java Logging API agent
 338 # Disabled by default
 339 AE_FEATURE_DEFAULT_DISABLE
 340 AE_FEATURE([java-agent-jul],[build the LTTng UST Java agent with JUL support])
 341
 342 # Build the Java Log4j agent
 343 # Disabled by default
 344 AE_FEATURE_DEFAULT_DISABLE
 345 AE_FEATURE([java-agent-log4j],[build the LTTng UST Java agent with Log4j support])
 346
 347 # Build both Java agents
 348 # Disabled by default
 349 AE_FEATURE_DEFAULT_DISABLE
 350 AE_FEATURE([java-agent-all],[build the LTTng UST Java agent with all supported backends])
 351
 352 # Build the Python agent
 353 # Disabled by default
 354 AE_FEATURE_DEFAULT_DISABLE
 355 AE_FEATURE([python-agent],[build the LTTng UST Python agent])
 356
 357 # Build the examples
 358 # Disabled by default
 359 AE_FEATURE_DEFAULT_ENABLE
 360 AE_FEATURE([examples],[Do not build and install examples])
 361
 362 # Man pages
 363 # Enabled by default
 364 AE_FEATURE_DEFAULT_ENABLE
 365 AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball)])
 366
 367 # Systemtap sdt.h integration
 368 # Disabled by default
 369 AC_ARG_WITH([sdt],
 370   [AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])]
 371 )
 372
 373 # Override the default runtime directory
 374 AC_ARG_WITH([lttng-system-rundir], [
 375 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 376 ], [
 377   lttng_system_rundir="$withval"
 378 ], [
 379   lttng_system_rundir="/var/run/lttng"
 380 ])
 381
 382 # Add the java command line arguments like '--wit-java-prefix'
 383 AX_JAVA_OPTIONS
 384
 385
 386 ##                                          ##
 387 ## Check for conflicting features selection ##
 388 ##                                          ##
 389
 390 AE_IF_FEATURE_DISABLED([shared], [
 391   AC_MSG_ERROR(LTTng-UST requires shared libraries to be enabled)
 392 ])
 393
 394 AE_IF_FEATURE_ENABLED([java-agent-all], [
 395   AE_FEATURE_ENABLE([java-agent-jul])
 396   AE_FEATURE_ENABLE([java-agent-log4j])
 397 ])
 398
 399
 400 ##                                          ##
 401 ## Check for optional features dependencies ##
 402 ##                                          ##
 403
 404 # The numa integration requires libnuma
 405 AE_IF_FEATURE_ENABLED([numa], [
 406   AC_CHECK_LIB([numa], [numa_available], [], [
 407     AC_MSG_ERROR([dnl
 408 libnuma is not available. Please either install it (e.g. libnuma-dev) or use
 409 [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure
 410 argument to disable NUMA support.
 411     ])
 412   ])
 413 ])
 414
 415 # The JNI interface and Java Agents require a working Java JDK
 416 AS_IF([AE_IS_FEATURE_ENABLED([jni-interface]) || AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j])], [
 417   AX_PROG_JAVAC
 418   AX_PROG_JAVA
 419   AX_PROG_JAR
 420
 421   # Get the CPPFLAGS required to build jni libaries
 422   AX_JNI_INCLUDE_DIR
 423   for jni_include_dir in $JNI_INCLUDE_DIRS; do
 424     JNI_CPPFLAGS="$JNI_CPPFLAGS -I$jni_include_dir"
 425   done
 426
 427   # Check for javah and jni.h
 428   saved_CPPFLAGS="$CPPFLAGS"
 429   CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 430   AX_PROG_JAVAH
 431   CPPFLAGS="$saved_CPPFLAGS"
 432 ])
 433
 434 # The log4j agent requires the log4j jar in the classpath
 435 AE_IF_FEATURE_ENABLED([java-agent-log4j], [
 436   AX_CHECK_CLASS([org.apache.log4j.Logger])
 437   AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 438     AC_MSG_ERROR([dnl
 439 The UST Java agent support for log4j was requested but the Log4j classes were
 440 not found. Please specify the location of the Log4j jar via the Java CLASSPATH
 441 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j.jar"
 442
 443 Current CLASSPATH: "$CLASSPATH"
 444     ])
 445   ])
 446 ])
 447
 448 # The python agent requires a python interpreter
 449 AE_IF_FEATURE_ENABLED([python-agent], [
 450   AS_IF([test "x$PYTHON" = "x"], [
 451     AC_MSG_ERROR([dnl
 452 Cannot find a suitable python interpreter. You can override it with the PYTHON
 453 environment variable.
 454     ])
 455   ])
 456 ])
 457
 458 # Check for asciidoc and xmlto if we enabled building the man pages.
 459 AE_IF_FEATURE_ENABLED([man-pages], [
 460   AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 461     AE_IF_IN_GIT_REPO([
 462       # This is an error because we're in the Git repo, which
 463       # means the man pages are not already generated for us,
 464       # thus asciidoc/xmlto are required because we were asked
 465       # to build the man pages.
 466       AC_MSG_ERROR([dnl
 467 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 468 --disable-man-pages to disable building the man pages, in which case
 469 they will not be installed.
 470       ])
 471     ], [
 472       # Only warn here: since we're in the tarball, the man
 473       # pages should already be generated at this point, thus
 474       # asciidoc/xmlto are not strictly required.
 475       warn_prebuilt_man_pages=yes
 476     ])
 477   ], [
 478     have_asciidoc_xmlto=yes
 479   ])
 480 ])
 481
 482 AS_IF([test "x$with_sdt" = "xyes"], [
 483   AC_MSG_CHECKING([STAP_PROBEV()])
 484   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 485     #define SDT_USE_VARIADIC
 486     #include <sys/sdt.h>
 487     void fct(void)
 488     {
 489       STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 490     }
 491   ]])], [
 492     AC_MSG_RESULT([yes])
 493     AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1], [SystemTap integration via sdt.h])
 494   ], [
 495     AC_MSG_RESULT([no])
 496     AC_MSG_ERROR([dnl
 497 The sdt.h integration was requested but the STAP_PROBEV define cannot be used.
 498 Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify
 499 a non-standard path to sys/sdt.h
 500     ])
 501   ])
 502 ])
 503
 504
 505 ##                                                                    ##
 506 ## Set defines for optional features conditionnals in the source code ##
 507 ##                                                                    ##
 508
 509 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], [LTTng system runtime directory])
 510
 511 # Defined in include/lttng/ust-version.h
 512 AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
 513 AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
 514 AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
 515 AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
 516 AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
 517 AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
 518
 519
 520 ##                                                                          ##
 521 ## Set automake variables for optional feature conditionnals in Makefile.am ##
 522 ##                                                                          ##
 523
 524 AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([examples]))
 525 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
 526 AM_CONDITIONAL([ENABLE_JAVA_AGENT], AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j]))
 527 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], AE_IS_FEATURE_ENABLED([java-agent-jul]))
 528 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], AE_IS_FEATURE_ENABLED([java-agent-log4j]))
 529 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], AE_IS_FEATURE_ENABLED([jni-interface]))
 530 AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
 531 AM_CONDITIONAL([ENABLE_NUMA], AE_IS_FEATURE_ENABLED([numa]))
 532 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], AE_IS_FEATURE_ENABLED([python-agent]))
 533 AM_CONDITIONAL([ENABLE_UST_DL], [test "x$ac_cv_have_decl_RTLD_DI_LINKMAP" = "xyes"])
 534 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 535 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
 536 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
 537 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 538 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
 539
 540
 541 ##                                             ##
 542 ## Substitute variables for use in Makefile.am ##
 543 ##                                             ##
 544
 545 # Library versions for libtool
 546 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], ust_lib_version)
 547 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], ust_ctl_lib_version)
 548
 549 # Major soname for python-lttngust
 550 AC_SUBST([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current])
 551
 552 AM_CFLAGS="$OPT_CFLAGS $WARN_CFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 553 AC_SUBST(AM_CFLAGS)
 554
 555 AM_CXXFLAGS="$WARN_CXXFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 556 AC_SUBST(AM_CXXFLAGS)
 557
 558 # The order in which the include folders are searched is important.
 559 # The top_builddir should always be searched first in the event that a build
 560 # time generated file is included.
 561 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 562 AC_SUBST(AM_CPPFLAGS)
 563
 564 AC_SUBST(JNI_CPPFLAGS)
 565
 566
 567 ##                                     ##
 568 ## Output files generated by configure ##
 569 ##                                     ##
 570
 571 # List of files to be generated from '.in' templates by AC_OUTPUT
 572 AC_CONFIG_FILES([
 573   Makefile
 574   doc/examples/Makefile
 575   doc/Makefile
 576   doc/man/Makefile
 577   include/Makefile
 578   src/common/Makefile
 579   src/lib/lttng-ust-common/Makefile
 580   src/lib/lttng-ust-ctl/Makefile
 581   src/lib/lttng-ust-cyg-profile/Makefile
 582   src/lib/lttng-ust-dl/Makefile
 583   src/lib/lttng-ust-fd/Makefile
 584   src/lib/lttng-ust-fork/Makefile
 585   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 586   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 587   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 588   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 589   src/lib/lttng-ust-java-agent/java/Makefile
 590   src/lib/lttng-ust-java-agent/jni/common/Makefile
 591   src/lib/lttng-ust-java-agent/jni/jul/Makefile
 592   src/lib/lttng-ust-java-agent/jni/log4j/Makefile
 593   src/lib/lttng-ust-java-agent/jni/Makefile
 594   src/lib/lttng-ust-java-agent/Makefile
 595   src/lib/lttng-ust-java/Makefile
 596   src/lib/lttng-ust-libc-wrapper/Makefile
 597   src/lib/lttng-ust-pthread-wrapper/Makefile
 598   src/lib/lttng-ust-tracepoint/Makefile
 599   src/lib/lttng-ust/Makefile
 600   src/lib/lttng-ust-python-agent/Makefile
 601   src/lib/Makefile
 602   src/lttng-ust-ctl.pc
 603   src/lttng-ust.pc
 604   src/Makefile
 605   src/python-lttngust/lttngust/version.py
 606   src/python-lttngust/Makefile
 607   src/python-lttngust/setup.py
 608   tests/benchmark/Makefile
 609   tests/compile/ctf-types/Makefile
 610   tests/compile/hello.cxx/Makefile
 611   tests/compile/hello/Makefile
 612   tests/compile/hello-many/Makefile
 613   tests/compile/Makefile
 614   tests/compile/same_line_tracepoint/Makefile
 615   tests/compile/test-app-ctx/Makefile
 616   tests/Makefile
 617   tests/unit/gcc-weak-hidden/Makefile
 618   tests/unit/libmsgpack/Makefile
 619   tests/unit/libringbuffer/Makefile
 620   tests/unit/Makefile
 621   tests/unit/pthread_name/Makefile
 622   tests/unit/snprintf/Makefile
 623   tests/unit/ust-elf/Makefile
 624   tests/unit/ust-error/Makefile
 625   tests/unit/ust-utils/Makefile
 626   tests/utils/Makefile
 627   tools/Makefile
 628 ])
 629
 630 AC_OUTPUT
 631
 632
 633 ##                                    ##
 634 ## Mini-report on what will be built. ##
 635 ##                                    ##
 636
 637 PPRINT_INIT
 638 PPRINT_SET_INDENT(1)
 639 PPRINT_SET_TS(38)
 640
 641 AS_ECHO
 642 AS_IF([test -n "ust_version_name"], [
 643   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
 644 ], [
 645   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
 646 ])
 647
 648 AS_ECHO
 649
 650 AS_IF([test -n "ust_version_description"], [
 651   AS_IF([test -n "$FOLD"], [
 652     AS_ECHO("`AS_ECHO("ust_version_description") | $FOLD -s`")
 653   ], [
 654     AS_ECHO("ust_version_description")
 655   ])
 656   AS_ECHO
 657 ])
 658
 659 PPRINT_SUBTITLE([System])
 660
 661 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 662
 663 AS_IF([test "x$unsupported_arch" = "xyes"],[
 664        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 665 ])
 666
 667 AS_ECHO
 668 PPRINT_SUBTITLE([Features])
 669 PPRINT_SET_INDENT(1)
 670
 671 test "x$with_sdt" = "xyes" && value=1 || value=0
 672 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 673
 674 AE_IS_FEATURE_ENABLED([java-agent-jul]) && value=1 || value=0
 675 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 676
 677 AE_IS_FEATURE_ENABLED([java-agent-log4j]) && value=1 || value=0
 678 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 679
 680 AE_IS_FEATURE_ENABLED([jni-interface]) && value=1 || value=0
 681 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 682
 683 AE_IS_FEATURE_ENABLED([python-agent]) && value=1 || value=0
 684 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 685
 686 test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
 687 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 688
 689 AE_IS_FEATURE_ENABLED([numa]) && value=1 || value=0
 690 PPRINT_PROP_BOOL([NUMA], $value)
 691
 692 AS_ECHO
 693 PPRINT_SET_INDENT(0)
 694
 695 AE_IS_FEATURE_ENABLED([examples]) && value=1 || value=0
 696 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 697
 698 # man pages build enabled/disabled
 699 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 700
 701 AE_IF_FEATURE_ENABLED([man-pages], [
 702   AE_IF_IN_GIT_REPO([
 703     PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 704   ], [
 705     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 706       PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 707     ], [
 708       PPRINT_PROP_STRING([build_man_pages_msg],
 709         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 710         $PPRINT_COLOR_SUBTITLE)
 711     ])
 712   ])
 713 ], [
 714   PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 715 ])
 716
 717 m4_popdef([build_man_pages_msg])
 718
 719 PPRINT_SET_INDENT(1)
 720
 721 report_bindir="`eval eval echo $bindir`"
 722 report_libdir="`eval eval echo $libdir`"
 723
 724 # Print the bindir and libdir this `make install' will install into.
 725 AS_ECHO
 726 PPRINT_SUBTITLE([Install directories])
 727 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 728 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 729
 730 AS_ECHO
 731 PPRINT_SUBTITLE([System directories])
 732
 733 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 734
 735 PPRINT_SET_INDENT(0)
 736
 737 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 738   AS_ECHO
 739   PPRINT_WARN([dnl
 740 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 741
 742 Note that the man pages are already built in this distribution tarball,
 743 therefore asciidoc and xmlto are only needed if you intend to modify
 744 their sources.
 745
 746 Use --disable-man-pages to completely disable building and installing
 747 the man pages.])
 748 ])
 749
 750 # vim: shiftwidth=2 softtabstop=2 expandtab