configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [13])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [pre])
   6 m4_define([V_NAME], [[Codename TBD]])
   7 m4_define([V_DESC], [[Description TBD]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ([2.69])
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules by default
  48 AM_SILENT_RULES([yes])
  49
  50 # Checks for C compiler
  51 AC_USE_SYSTEM_EXTENSIONS
  52 AC_SYS_LARGEFILE
  53 AC_PROG_CC
  54 AC_PROG_CC_STDC
  55 AC_PROG_CXX
  56 AX_CXX_COMPILE_STDCXX([11])
  57 RW_PROG_CXX_WORKS
  58 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  59
  60 # Check if the compiler support weak symbols
  61 AX_SYS_WEAK_ALIAS
  62
  63 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  64         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  65 ])
  66
  67 # Checks for programs.
  68 AM_PROG_AR
  69 AC_PROG_SED
  70 AC_PROG_GREP
  71 AC_PROG_LN_S
  72 AC_PROG_MKDIR_P
  73 AC_PROG_MAKE_SET
  74 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  75 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  76
  77 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  78 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  79 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  80 ], [
  81         libtool_fixup=$enableval
  82 ], [
  83         libtool_fixup=yes
  84 ])
  85
  86 AS_IF([test "x$libtool_fixup" = "xyes"], [
  87         libtool_m4="$srcdir/m4/libtool.m4"
  88         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  89         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  90         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  91
  92         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  93         AC_MSG_RESULT([$libtool_flag_pattern_count])
  94         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  95                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  96         ], [
  97                 AC_MSG_RESULT([none])
  98         ])
  99 ])
 100 LT_INIT([disable-static])
 101
 102 AC_MSG_CHECKING([whether shared libraries are enabled])
 103 AS_IF([test "x$enable_shared" = "xyes"], [
 104         AC_MSG_RESULT([yes])
 105 ], [
 106         AC_MSG_RESULT([no])
 107         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 108 ])
 109
 110 # Checks for typedefs, structures, and compiler characteristics.
 111 AC_C_INLINE
 112 AC_TYPE_INT8_T
 113 AC_TYPE_INT16_T
 114 AC_TYPE_INT32_T
 115 AC_TYPE_INT64_T
 116 AC_TYPE_MODE_T
 117 AC_TYPE_OFF_T
 118 AC_TYPE_PID_T
 119 AC_TYPE_SIZE_T
 120 AC_TYPE_SSIZE_T
 121 AC_TYPE_UID_T
 122 AC_TYPE_UINT8_T
 123 AC_TYPE_UINT16_T
 124 AC_TYPE_UINT32_T
 125 AC_TYPE_UINT64_T
 126 AC_CHECK_TYPES([ptrdiff_t])
 127
 128 AX_C___ATTRIBUTE__
 129 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 130         [:],
 131         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 132
 133 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 134
 135 # Checks for library functions.
 136 AC_FUNC_CHOWN
 137 AC_FUNC_FORK
 138 AC_FUNC_MMAP
 139 AC_FUNC_REALLOC
 140 AC_FUNC_STRERROR_R
 141 AC_FUNC_STRNLEN
 142 AC_CHECK_FUNCS([ \
 143         atexit \
 144         clock_gettime \
 145         ftruncate \
 146         getpagesize \
 147         gettimeofday \
 148         localeconv \
 149         memchr \
 150         memmove \
 151         memset \
 152         mkdir \
 153         munmap \
 154         realpath \
 155         sched_getcpu \
 156         socket \
 157         strchr \
 158         strdup \
 159         strerror \
 160         strtol \
 161         strtoul \
 162         sysconf \
 163 ])
 164
 165 # Check for pthread_setname_np and its signature
 166 LTTNG_PTHREAD_SETNAME_NP
 167
 168 # AC_FUNC_MALLOC causes problems when cross-compiling.
 169 #AC_FUNC_MALLOC
 170
 171 # Checks for header files.
 172 AC_HEADER_STDBOOL
 173 AC_CHECK_HEADERS([ \
 174         arpa/inet.h \
 175         fcntl.h \
 176         float.h \
 177         limits.h \
 178         locale.h \
 179         stddef.h \
 180         sys/socket.h \
 181         sys/time.h \
 182         wchar.h \
 183 ])
 184
 185 # Set architecture specific options
 186 AS_CASE([$host_cpu],
 187         [i[[3456]]86], [],
 188         [x86_64], [],
 189         [amd64], [],
 190         [powerpc], [],
 191         [ppc64], [],
 192         [ppc64le], [],
 193         [powerpc64], [],
 194         [powerpc64le], [],
 195         [s390], [NO_UNALIGNED_ACCESS=1],
 196         [s390x], [NO_UNALIGNED_ACCESS=1],
 197         [arm*], [
 198                 NO_UNALIGNED_ACCESS=1
 199                 NO_NUMA=1
 200                 ],
 201         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 202         [mips*], [NO_UNALIGNED_ACCESS=1],
 203         [tile*], [NO_UNALIGNED_ACCESS=1],
 204         [
 205                 UNSUPPORTED_ARCH=1
 206                 NO_UNALIGNED_ACCESS=1
 207         ])
 208
 209 # Set os specific options
 210 AS_CASE([$host_os],
 211         [freebsd*], [NO_NUMA=1]
 212 )
 213
 214 # Configuration options, which will be installed in the config.h
 215 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 216 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 217 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 218
 219 # Checks for libraries.
 220 AC_CHECK_LIB([dl], [dlopen], [
 221         libdl_name=dl
 222         DL_LIBS="-ldl"
 223 ], [
 224         #libdl not found, check for dlopen in libc.
 225         AC_CHECK_LIB([c], [dlopen], [
 226                 libdl_name=c
 227                 DL_LIBS="-lc"
 228         ], [
 229                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 230         ])
 231 ])
 232 AC_SUBST(DL_LIBS)
 233
 234 # Check if libdl has dlmopen support.
 235 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 236 AC_CHECK_LIB([$libdl_name], [dlmopen],
 237         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 238 )
 239
 240 # Check for dlfcn.h
 241 AC_CHECK_HEADER([dlfcn.h])
 242 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 243         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 244                 #include <dlfcn.h>
 245         ])
 246 ], [
 247         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 248 ])
 249
 250 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 251
 252 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 253 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 254
 255 # numa.h integration
 256 AS_IF([test "x$NO_NUMA" = "x1"],[
 257       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 258 ])
 259
 260 AC_ARG_ENABLE([numa], [
 261 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 262 ], [
 263         enable_numa=$enableval
 264 ], [
 265         enable_numa=yes
 266 ])
 267
 268 AS_IF([test "x$enable_numa" = "xyes"], [
 269         # numa - check that numa lib is available
 270         AC_CHECK_LIB([numa], [numa_available], [],
 271 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 272         have_libnuma=yes
 273 ])
 274 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 275
 276 # optional linux/perf_event.h
 277 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 278
 279 # Perf event counters are supported on all architectures supported by
 280 # perf, using the read system call as fallback.
 281 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 282
 283 AS_IF([test "x$have_perf_event" = "xyes"], [
 284         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 285 ])
 286
 287 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 288         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 289 ])
 290
 291 # Check for JNI header files if requested
 292 AC_ARG_ENABLE([jni-interface], [
 293 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 294 ], [
 295         jni_interface=$enableval
 296 ], [
 297         jni_interface=no
 298 ])
 299
 300 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 301
 302
 303 AC_ARG_ENABLE([java-agent-jul], [
 304 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 305 ], [
 306         java_agent_jul=$enableval
 307 ], [
 308         java_agent_jul=no
 309 ])
 310
 311 AC_ARG_ENABLE([java-agent-log4j], [
 312 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 313 ], [
 314         java_agent_log4j=$enableval
 315 ], [
 316         java_agent_log4j=no
 317 ])
 318
 319 AC_ARG_ENABLE([java-agent-all], [
 320 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 321 ], [
 322         java_agent_jul=$enableval
 323         java_agent_log4j=$enableval
 324 ], [:])
 325
 326 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 327 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 328 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 329
 330 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 331         AX_JAVA_OPTIONS
 332         AX_PROG_JAVAC
 333         AX_PROG_JAVA
 334         AX_PROG_JAR
 335         AC_ARG_VAR([CLASSPATH], [Java class path])
 336
 337         AX_JNI_INCLUDE_DIR
 338         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 339         do
 340                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 341         done
 342
 343         saved_CPPFLAGS="$CPPFLAGS"
 344         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 345         AX_PROG_JAVAH
 346         CPPFLAGS="$saved_CPPFLAGS"
 347 ])
 348
 349 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 350
 351 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 352         AX_CHECK_CLASSPATH
 353         AX_CHECK_CLASS([org.apache.log4j.Logger])
 354         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 355                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 356         ])
 357 ])
 358
 359 # Option to build the python agent
 360 AC_ARG_ENABLE([python-agent], [
 361 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 362 ], [
 363         python_agent=$enableval
 364 ], [:])
 365 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 366 AS_IF([test "x$python_agent" = "xyes"], [
 367         AM_PATH_PYTHON([2.7])
 368 ])
 369
 370 # sdt.h integration
 371 AC_ARG_WITH([sdt], [
 372 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 373 ], [
 374         with_sdt=$withval
 375 ], [
 376         with_sdt="no"
 377 ])
 378
 379 AS_IF([test "x$with_sdt" = "xyes"], [
 380         AC_MSG_CHECKING([STAP_PROBEV()])
 381         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 382                 #define SDT_USE_VARIADIC
 383                 #include <sys/sdt.h>
 384                 void fct(void)
 385                 {
 386                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 387                 }
 388         ]])], [
 389                 AC_MSG_RESULT([yes])
 390                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 391         ], [
 392                 AC_MSG_RESULT([no])
 393                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 394         ])
 395 ])
 396
 397 AC_ARG_WITH([lttng-system-rundir], [
 398 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 399 ], [
 400         lttng_system_rundir="$withval"
 401 ], [
 402         lttng_system_rundir="/var/run/lttng"
 403 ])
 404 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 405                 [LTTng system runtime directory])
 406
 407 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 408 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 409
 410 # Enable building examples
 411 AC_ARG_ENABLE(
 412         examples,
 413         AS_HELP_STRING(
 414                 [--disable-examples],
 415                 [Do not build and install examples]
 416         ),
 417         [enable_examples=$enableval],
 418         [enable_examples=yes]
 419 )
 420
 421 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 422
 423 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 424 # is not distributed in tarballs.
 425 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 426 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 427
 428 # Enable building man pages (user's intention).
 429 AC_ARG_ENABLE(
 430         man-pages,
 431         AS_HELP_STRING(
 432                 [--disable-man-pages],
 433                 [Do not build and install man pages (already built in a distributed tarball)]
 434         ),
 435         [man_pages_opt=$enableval],
 436         [man_pages_opt=yes]
 437 )
 438
 439 # Check for asciidoc and xmlto if we enabled building the man pages.
 440 have_asciidoc_xmlto=no
 441 warn_prebuilt_man_pages=no
 442
 443 AS_IF([test "x$man_pages_opt" = "xyes"], [
 444         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 445         AC_PATH_PROG([XMLTO], [xmlto], [no])
 446
 447         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 448                 AS_IF([test "x$in_git_repo" = "xyes"], [
 449                         # This is an error because we're in the Git repo, which
 450                         # means the man pages are not already generated for us,
 451                         # thus asciidoc/xmlto are required because we were asked
 452                         # to build the man pages.
 453                         AC_MSG_ERROR([
 454 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 455 --disable-man-pages to disable building the man pages, in which case
 456 they will not be installed.
 457                         ])
 458                 ], [
 459                         # Only warn here: since we're in the tarball, the man
 460                         # pages should already be generated at this point, thus
 461                         # asciidoc/xmlto are not strictly required.
 462                         warn_prebuilt_man_pages=yes
 463                 ])
 464         ], [
 465                 have_asciidoc_xmlto=yes
 466         ])
 467 ])
 468
 469 # Export man page build condition: build the man pages if the user
 470 # asked for it, and if the tools are available.
 471 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 472 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 473
 474 # Default values
 475 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 476         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 477         $1="$2"
 478         AC_SUBST([$1])
 479 ])
 480
 481 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 482
 483 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
 484 AC_SUBST(AM_CFLAGS)
 485
 486 AM_CXXFLAGS="$AM_CFLAGS"
 487 AC_SUBST(AM_CXXFLAGS)
 488
 489 # The order in which the include folders are searched is important.
 490 # The top_builddir should always be searched first in the event that a build
 491 # time generated file is included.
 492 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 493 AC_SUBST(AM_CPPFLAGS)
 494
 495 AC_SUBST(JNI_CPPFLAGS)
 496
 497 AC_CONFIG_FILES([
 498         Makefile
 499         doc/Makefile
 500         doc/examples/Makefile
 501         doc/man/Makefile
 502         include/Makefile
 503         include/lttng/ust-version.h
 504         snprintf/Makefile
 505         libcounter/Makefile
 506         libmsgpack/Makefile
 507         libringbuffer/Makefile
 508         liblttng-ust-comm/Makefile
 509         liblttng-ust/Makefile
 510         liblttng-ust-ctl/Makefile
 511         liblttng-ust-fork/Makefile
 512         liblttng-ust-dl/Makefile
 513         liblttng-ust-fd/Makefile
 514         liblttng-ust-java/Makefile
 515         liblttng-ust-java-agent/Makefile
 516         liblttng-ust-java-agent/java/Makefile
 517         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 518         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 519         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 520         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 521         liblttng-ust-java-agent/jni/Makefile
 522         liblttng-ust-java-agent/jni/common/Makefile
 523         liblttng-ust-java-agent/jni/jul/Makefile
 524         liblttng-ust-java-agent/jni/log4j/Makefile
 525         liblttng-ust-libc-wrapper/Makefile
 526         liblttng-ust-cyg-profile/Makefile
 527         liblttng-ust-python-agent/Makefile
 528         python-lttngust/Makefile
 529         python-lttngust/setup.py
 530         python-lttngust/lttngust/__init__.py
 531         tools/Makefile
 532         tests/Makefile
 533         tests/compile/Makefile
 534         tests/compile/ctf-types/Makefile
 535         tests/compile/hello.cxx/Makefile
 536         tests/compile/hello/Makefile
 537         tests/compile/hello-many/Makefile
 538         tests/compile/same_line_tracepoint/Makefile
 539         tests/compile/test-app-ctx/Makefile
 540         tests/benchmark/Makefile
 541         tests/unit/gcc-weak-hidden/Makefile
 542         tests/unit/libmsgpack/Makefile
 543         tests/unit/Makefile
 544         tests/unit/libringbuffer/Makefile
 545         tests/unit/pthread_name/Makefile
 546         tests/unit/snprintf/Makefile
 547         tests/unit/ust-elf/Makefile
 548         tests/utils/Makefile
 549         lttng-ust.pc
 550         lttng-ust-ctl.pc
 551 ])
 552
 553 # Create link for python agent for the VPATH guru.
 554 AC_CONFIG_LINKS([
 555         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 556         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 557         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 558         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 559         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 560 ])
 561
 562 AC_CONFIG_FILES([tests/unit/ust-elf/test_ust_elf],[chmod +x tests/unit/ust-elf/test_ust_elf])
 563
 564 AC_OUTPUT
 565
 566
 567 #
 568 # Mini-report on what will be built.
 569 #
 570
 571 PPRINT_INIT
 572 PPRINT_SET_INDENT(1)
 573 PPRINT_SET_TS(38)
 574
 575 AS_ECHO
 576 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 577 AS_ECHO
 578
 579 AS_ECHO("V_DESC")
 580
 581 AS_ECHO
 582 PPRINT_SUBTITLE([System])
 583
 584 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 585
 586 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 587 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 588
 589 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 590        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 591 ])
 592
 593 AS_ECHO
 594 PPRINT_SUBTITLE([Features])
 595 PPRINT_SET_INDENT(1)
 596
 597 test "x$with_sdt" = "xyes" && value=1 || value=0
 598 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 599
 600 test "x$java_agent_jul" = xyes && value=1 || value=0
 601 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 602
 603 test "x$java_agent_log4j" = xyes && value=1 || value=0
 604 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 605
 606 test "x$jni_interface" = xyes && value=1 || value=0
 607 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 608
 609 test "x$python_agent" = xyes && value=1 || value=0
 610 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 611
 612 test "x$have_perf_event" = "xyes" && value=1 || value=0
 613 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 614
 615 test "x$enable_numa" = xyes && value=1 || value=0
 616 PPRINT_PROP_BOOL([NUMA], $value)
 617
 618 AS_ECHO
 619 PPRINT_SET_INDENT(0)
 620
 621 test "x$enable_examples" = xyes && value=1 || value=0
 622 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 623
 624 # man pages build enabled/disabled
 625 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 626
 627 AS_IF([test "x$man_pages_opt" != "xno"], [
 628         AS_IF([test "x$in_git_repo" = "xyes"], [
 629                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 630         ], [
 631                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 632                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 633                 ], [
 634                         PPRINT_PROP_STRING([build_man_pages_msg],
 635                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 636                                 $PPRINT_COLOR_SUBTITLE)
 637                 ])
 638         ])
 639 ], [
 640         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 641 ])
 642
 643 m4_popdef([build_man_pages_msg])
 644
 645 PPRINT_SET_INDENT(1)
 646
 647 report_bindir="`eval eval echo $bindir`"
 648 report_libdir="`eval eval echo $libdir`"
 649
 650 # Print the bindir and libdir this `make install' will install into.
 651 AS_ECHO
 652 PPRINT_SUBTITLE([Install directories])
 653 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 654 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 655
 656 AS_ECHO
 657 PPRINT_SUBTITLE([System directories])
 658
 659 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 660
 661 PPRINT_SET_INDENT(0)
 662
 663 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 664         AS_ECHO
 665         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 666
 667 Note that the man pages are already built in this distribution tarball,
 668 therefore asciidoc and xmlto are only needed if you intend to modify
 669 their sources.
 670
 671 Use --disable-man-pages to completely disable building and installing
 672 the man pages.])
 673 ])