configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.0],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Annedd'ale"
  38 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], [$version_name], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], [$version_description], [UST version description])
  41
  42 # Checks for programs.
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 AC_PROG_MAKE_SET
  46 LT_INIT
  47
  48 ## Checks for libraries.
  49 AC_CHECK_LIB([dl], [dlopen])
  50 AC_CHECK_LIB([pthread], [pthread_create])
  51
  52 # Check for libuuid
  53 AC_CHECK_LIB([uuid], [uuid_generate], [],
  54         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  55 )
  56
  57 # Checks for header files.
  58 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  59
  60 # Checks for typedefs, structures, and compiler characteristics.
  61 AC_C_INLINE
  62 #AC_TYPE_INT16_T
  63 #AC_TYPE_INT32_T
  64 #AC_TYPE_INT64_T
  65 #AC_TYPE_INT8_T
  66 #AC_TYPE_PID_T
  67 #AC_TYPE_SIZE_T
  68 #AC_TYPE_SSIZE_T
  69 #AC_TYPE_UINT16_T
  70 #AC_TYPE_UINT32_T
  71 #AC_TYPE_UINT64_T
  72 #AC_TYPE_UINT8_T
  73 #AC_CHECK_TYPES([ptrdiff_t])
  74
  75 # Checks for library functions.
  76 AC_FUNC_MALLOC
  77 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
  78
  79 CFLAGS="-Wall $CFLAGS"
  80
  81 # Check for texinfo, required for building the documentation
  82 # TODO: make this (and building the documentation) optional
  83 AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
  84 AS_IF([test "x$TEXINFO" != "xyes"],[
  85         AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
  86 ])
  87
  88 # URCU
  89
  90 # urcu - check if we just find the headers it out of the box.
  91 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
  92 This error can also occur when the liburcu package's configure script has not been run.])])
  93
  94 AC_MSG_CHECKING([caa_likely()])
  95 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  96 #include <urcu/compiler.h>
  97 void fct(void)
  98 {
  99         if (caa_likely(1)) {
 100         }
 101 }
 102 ]])],[
 103         AC_MSG_RESULT([yes])
 104 ],[
 105         AC_MSG_RESULT([no])
 106         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 107
 108 ])
 109
 110 # urcu - check that URCU lib is available to compilation
 111 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 112
 113 # urcu - check that URCU lib is at least version 0.6
 114 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 115
 116
 117 # Check for various supplementary host information (beyond the
 118 # triplet) which might affect the library format choices.  E.g., we
 119 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 120
 121 case "${host}" in
 122 changequote(,)dnl
 123   i[34567]86-*-linux*)
 124 changequote([,])dnl
 125     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 126                     [save_CPPFLAGS="$CPPFLAGS"
 127                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 128                     AC_EGREP_CPP([got it], [
 129 #if __x86_64__
 130 got it
 131 #endif
 132                  ], [ust_cv_i386_is_x86_64=yes],
 133                     [ust_cv_i386_is_x86_64=no])
 134                     CPPFLAGS="$save_CPPFLAGS"])
 135     ;;
 136 esac
 137
 138 AC_MSG_CHECKING([library format for the host system])
 139 case $host_cpu in
 140 changequote(,)dnl
 141         i[3456]86)
 142 changequote([,])dnl
 143           if test "$ust_cv_i386_is_x86_64" = yes ; then
 144              LIBFORMAT="elf64-x86-64"
 145           else
 146              LIBFORMAT="elf32-i386"
 147           fi
 148           ;;
 149         x86_64) LIBFORMAT="elf64-x86-64" ;;
 150         powerpc) LIBFORMAT="elf32-powerpc" ;;
 151         ppc64) LIBFORMAT="elf64-powerpc" ;;
 152         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 153         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 154         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 155         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 156         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 157         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 158         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 159 esac
 160 AC_SUBST(LIBFORMAT)
 161 AC_MSG_RESULT($LIBFORMAT)
 162
 163 if test "x$host_cpu" = "xarm" ; then
 164 AC_MSG_CHECKING([checking for armv5])
 165 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 166 #ifndef __ARM_ARCH_5TEJ__
 167 #error "no arm5 here"
 168 #endif
 169 ]])],[
 170         AC_MSG_RESULT([yes])
 171         NO_UNALIGNED_ACCESS=1
 172
 173 ],[
 174         AC_MSG_RESULT([no])
 175
 176 ])
 177 fi
 178 if test x$NO_UNALIGNED_ACCESS = x ; then
 179 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 180 fi
 181
 182 # Set compile flags to java include files if given
 183 AC_ARG_WITH([java-jdk],
 184         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 185         [JAVA_JDK=$withval],
 186         [JAVA_JDK=""]
 187 )
 188 AS_IF([test $JAVA_JDK],[
 189         AS_IF([test -d $JAVA_JDK],[
 190                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 191                 SUBDIRS=`find $JAVA_JDK/include -type d`
 192                 CPPFLAGS+=" "
 193                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 194                 CPPFLAGS+=" "
 195         ],[
 196                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 197         ])
 198 ])
 199
 200 # Check for JNI header files if requested
 201 AC_ARG_WITH([jni-interface],
 202         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 203         [jni_interface=$withval],
 204         [jni_interface=no]
 205 )
 206
 207 AS_IF([test "x$jni_interface" = "xyes"],[
 208         AC_CHECK_HEADERS([jni.h],[],[
 209         AC_MSG_ERROR([missing jni.h
 210 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 211 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 212         ])
 213 ])
 214 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 215
 216 # sdt.h integration
 217 AC_ARG_WITH([sdt],
 218         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 219         [with_sdt=$withval],
 220         [with_sdt="no"]
 221 )
 222
 223 AS_IF([test "x$with_sdt" = "xyes"],[
 224         AC_MSG_CHECKING([STAP_PROBEV()])
 225         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 226         #define SDT_USE_VARIADIC
 227         #include <sys/sdt.h>
 228         void fct(void)
 229         {
 230                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 231         }
 232         ]])],[
 233                 AC_MSG_RESULT([yes])
 234                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 235         ],[
 236                 AC_MSG_RESULT([no])
 237                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 238         ])
 239 ])
 240
 241 #currently disabled.
 242         #tests/hello2/Makefile
 243         #tests/basic/Makefile
 244         #tests/simple_include/Makefile
 245         #tests/snprintf/Makefile
 246         #tests/test-nevents/Makefile
 247         #tests/test-libustinstr-malloc/Makefile
 248         #tests/dlopen/Makefile
 249         #tests/same_line_marker/Makefile
 250         #tests/trace_event/Makefile
 251         #tests/tracepoint/Makefile
 252         #tests/tracepoint/benchmark/Makefile
 253         #tests/register_test/Makefile
 254         #tests/libustctl_function_#tests/Makefile
 255         #tests/exit-fast/Makefile
 256         #tests/basic_long/Makefile
 257
 258 AC_CONFIG_FILES([
 259         Makefile
 260         doc/Makefile
 261         doc/examples/Makefile
 262         include/Makefile
 263         include/lttng/ust-version.h
 264         snprintf/Makefile
 265         libringbuffer/Makefile
 266         liblttng-ust-comm/Makefile
 267         liblttng-ust/Makefile
 268         liblttng-ust-ctl/Makefile
 269         liblttng-ust-fork/Makefile
 270         liblttng-ust-java/Makefile
 271         liblttng-ust-libc-wrapper/Makefile
 272         tools/Makefile
 273         tests/Makefile
 274         tests/hello/Makefile
 275         tests/hello-static-lib/Makefile
 276         tests/hello.cxx/Makefile
 277         tests/demo/Makefile
 278         tests/fork/Makefile
 279         tests/ust-basic-tracing/Makefile
 280         tests/ust-multi-test/Makefile
 281         lttng-ust.pc
 282 ])
 283
 284 AC_OUTPUT
 285
 286 AS_ECHO()
 287 AS_ECHO("Version name: $version_name")
 288 AS_ECHO("$version_description")
 289
 290 # Report on the configuration options
 291 AS_ECHO()
 292 AS_ECHO("LTTng-UST will be built with the following options:")
 293 AS_ECHO("Library format: $LIBFORMAT")
 294
 295 AS_ECHO()
 296 AS_ECHO_N("Java support (JNI): ")
 297 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 298
 299 AS_ECHO_N("sdt.h integration:  ")
 300 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 301
 302 AS_ECHO()
 303 AS_ECHO("Type 'make' to compile.")
 304