configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [10])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [rc1])
   6 m4_define([V_NAME], [[KeKriek]])
   7 m4_define([V_DESC], [[From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  24 # note: remember to update tracepoint.h dlopen() to match this version
  25 # number. TODO: eventually automate by exporting the major number.
  26
  27 # This is the library version of liblttng-ust-ctl, used internally by
  28 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  29 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  30
  31 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  32 AC_CONFIG_AUX_DIR([config])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38
  39 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  40 AM_MAINTAINER_MODE([enable])
  41
  42 # Enable silent rules if available (Introduced in AM 1.11)
  43 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  44
  45 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  46
  47 # Checks for C compiler
  48 AC_USE_SYSTEM_EXTENSIONS
  49 AC_SYS_LARGEFILE
  50 AC_PROG_CC
  51 AC_PROG_CC_STDC
  52 AC_PROG_CXX
  53 rw_PROG_CXX_WORKS
  54 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  55
  56 # Check if the compiler support weak symbols
  57 AX_SYS_WEAK_ALIAS
  58
  59 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  60         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  61 ])
  62
  63 # Checks for programs.
  64 AC_PROG_SED
  65 AC_PROG_GREP
  66 AC_PROG_LN_S
  67 AC_PROG_MKDIR_P
  68 AC_PROG_MAKE_SET
  69 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  70 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  71
  72 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  73 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  74 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  75 ], [
  76         libtool_fixup=$enableval
  77 ], [
  78         libtool_fixup=yes
  79 ])
  80
  81 AS_IF([test "x$libtool_fixup" = "xyes"], [
  82         libtool_m4="$srcdir/m4/libtool.m4"
  83         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  84         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  85         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  86
  87         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  88         AC_MSG_RESULT([$libtool_flag_pattern_count])
  89         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  90                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  91         ], [
  92                 AC_MSG_RESULT([none])
  93         ])
  94 ])
  95 LT_INIT([disable-static])
  96
  97 AC_MSG_CHECKING([whether shared libraries are enabled])
  98 AS_IF([test "x$enable_shared" = "xyes"], [
  99         AC_MSG_RESULT([yes])
 100 ], [
 101         AC_MSG_RESULT([no])
 102         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 103 ])
 104
 105 # Checks for typedefs, structures, and compiler characteristics.
 106 AC_C_INLINE
 107 AC_TYPE_INT8_T
 108 AC_TYPE_INT16_T
 109 AC_TYPE_INT32_T
 110 AC_TYPE_INT64_T
 111 AC_TYPE_MODE_T
 112 AC_TYPE_OFF_T
 113 AC_TYPE_PID_T
 114 AC_TYPE_SIZE_T
 115 AC_TYPE_SSIZE_T
 116 AC_TYPE_UID_T
 117 AC_TYPE_UINT8_T
 118 AC_TYPE_UINT16_T
 119 AC_TYPE_UINT32_T
 120 AC_TYPE_UINT64_T
 121 AC_CHECK_TYPES([ptrdiff_t])
 122
 123 AX_C___ATTRIBUTE__
 124 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 125         [:],
 126         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 127
 128 # Checks for library functions.
 129 AC_FUNC_CHOWN
 130 AC_FUNC_FORK
 131 AC_FUNC_MMAP
 132 AC_FUNC_REALLOC
 133 AC_FUNC_STRERROR_R
 134 AC_FUNC_STRNLEN
 135 AC_CHECK_FUNCS([ \
 136         atexit \
 137         clock_gettime \
 138         ftruncate \
 139         getpagesize \
 140         gettimeofday \
 141         localeconv \
 142         memchr \
 143         memmove \
 144         memset \
 145         mkdir \
 146         munmap \
 147         realpath \
 148         sched_getcpu \
 149         socket \
 150         strchr \
 151         strdup \
 152         strerror \
 153         strtol \
 154         sysconf \
 155 ])
 156
 157 # AC_FUNC_MALLOC causes problems when cross-compiling.
 158 #AC_FUNC_MALLOC
 159
 160 # Checks for header files.
 161 AC_HEADER_STDBOOL
 162 AC_CHECK_HEADERS([ \
 163         arpa/inet.h \
 164         fcntl.h \
 165         float.h \
 166         limits.h \
 167         locale.h \
 168         stddef.h \
 169         sys/socket.h \
 170         sys/time.h \
 171         wchar.h \
 172 ])
 173
 174 # Configuration options, which will be installed in the config.h
 175 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 176 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 177 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 178
 179 # Checks for libraries.
 180 AC_CHECK_LIB([dl], [dlopen], [
 181         have_libdl=yes
 182         libdl_name=dl
 183 ], [
 184         #libdl not found, check for dlopen in libc.
 185         AC_CHECK_LIB([c], [dlopen], [
 186                 have_libc_dl=yes
 187                 libdl_name=c
 188         ], [
 189                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 190         ])
 191 ])
 192
 193 # Check if libdl has dlmopen support.
 194 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 195 AC_CHECK_LIB([$libdl_name], [dlmopen],
 196         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 197 )
 198
 199 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 200 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 201
 202 AC_CHECK_LIB([pthread], [pthread_create])
 203 AC_CHECK_LIB([pthread], [pthread_setname_np],
 204         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 205         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 206                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 207                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 208
 209 # Check for dlfcn.h
 210 AC_CHECK_HEADER([dlfcn.h])
 211 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 212         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 213                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 214                 #include <dlfcn.h>
 215         ])
 216 ], [
 217         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 218 ])
 219
 220 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 221
 222 # URCU
 223
 224 # urcu - check if we just find the headers it out of the box.
 225 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 226 This error can also occur when the liburcu package's configure script has not been run.])])
 227
 228 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 229 # Part of Userspace RCU library 0.7.2 or better.
 230 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 231 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 232
 233 AC_MSG_CHECKING([caa_likely()])
 234 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 235         #include <urcu/compiler.h>
 236         void fct(void)
 237         {
 238                 if (caa_likely(1)) {
 239                 }
 240         }
 241 ]])], [
 242         AC_MSG_RESULT([yes])
 243 ], [
 244         AC_MSG_RESULT([no])
 245         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 246 ])
 247
 248 # urcu - check that URCU lib is available to compilation
 249 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 250
 251 # urcu - check that URCU lib is at least version 0.6
 252 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 253
 254 # optional linux/perf_event.h
 255 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 256
 257 # Perf event counters are supported on all architectures supported by
 258 # perf, using the read system call as fallback.
 259 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 260
 261 AS_IF([test "x$have_perf_event" = "xyes"], [
 262         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 263 ])
 264
 265 AC_MSG_CHECKING([host system alignment requirements])
 266 AS_CASE([$host_cpu],
 267         [i[[3456]]86], [],
 268         [x86_64], [],
 269         [amd64], [],
 270         [powerpc], [],
 271         [ppc64], [],
 272         [ppc64le], [],
 273         [powerpc64], [],
 274         [powerpc64le], [],
 275         [s390], [NO_UNALIGNED_ACCESS=1],
 276         [s390x], [NO_UNALIGNED_ACCESS=1],
 277         [arm*], [NO_UNALIGNED_ACCESS=1],
 278         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 279         [mips*], [NO_UNALIGNED_ACCESS=1],
 280         [tile*], [NO_UNALIGNED_ACCESS=1],
 281         [
 282                 UNSUPPORTED_ARCH=1
 283                 NO_UNALIGNED_ACCESS=1
 284         ])
 285 AC_MSG_RESULT([$host_cpu])
 286
 287 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 288         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 289 ])
 290
 291 # Check for JNI header files if requested
 292 AC_ARG_ENABLE([jni-interface], [
 293 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 294 ], [
 295         jni_interface=$enableval
 296 ], [
 297         jni_interface=no
 298 ])
 299
 300 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 301
 302
 303 AC_ARG_ENABLE([java-agent-jul], [
 304 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 305 ], [
 306         java_agent_jul=$enableval
 307 ], [
 308         java_agent_jul=no
 309 ])
 310
 311 AC_ARG_ENABLE([java-agent-log4j], [
 312 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 313 ], [
 314         java_agent_log4j=$enableval
 315 ], [
 316         java_agent_log4j=no
 317 ])
 318
 319 AC_ARG_ENABLE([java-agent-all], [
 320 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 321 ], [
 322         java_agent_jul=$enableval
 323         java_agent_log4j=$enableval
 324 ], [:])
 325
 326 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 327 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 328 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 329
 330 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 331         AX_JAVA_OPTIONS
 332         AX_PROG_JAVAC
 333         AX_PROG_JAVA
 334         AX_PROG_JAR
 335
 336         AX_JNI_INCLUDE_DIR
 337         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 338         do
 339                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 340         done
 341
 342         saved_CPPFLAGS="$CPPFLAGS"
 343         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 344         AX_PROG_JAVAH
 345         CPPFLAGS="$saved_CPPFLAGS"
 346 ])
 347
 348 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 349         AX_CHECK_CLASSPATH
 350         AX_CHECK_CLASS([org.apache.log4j.Logger])
 351         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 352                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 353         ])
 354 ])
 355
 356 # Option to build the python agent
 357 AC_ARG_ENABLE([python-agent], [
 358 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 359 ], [
 360         python_agent=$enableval
 361 ], [:])
 362 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 363 AS_IF([test "x$python_agent" = "xyes"], [
 364         AM_PATH_PYTHON([2.7])
 365 ])
 366
 367 # sdt.h integration
 368 AC_ARG_WITH([sdt], [
 369 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 370 ], [
 371         with_sdt=$withval
 372 ], [
 373         with_sdt="no"
 374 ])
 375
 376 AS_IF([test "x$with_sdt" = "xyes"], [
 377         AC_MSG_CHECKING([STAP_PROBEV()])
 378         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 379                 #define SDT_USE_VARIADIC
 380                 #include <sys/sdt.h>
 381                 void fct(void)
 382                 {
 383                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 384                 }
 385         ]])], [
 386                 AC_MSG_RESULT([yes])
 387                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 388         ], [
 389                 AC_MSG_RESULT([no])
 390                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 391         ])
 392 ])
 393
 394 AC_ARG_WITH([lttng-system-rundir], [
 395 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 396 ], [
 397         lttng_system_rundir="$withval"
 398 ], [
 399         lttng_system_rundir="/var/run/lttng"
 400 ])
 401 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 402                 [LTTng system runtime directory])
 403
 404 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 405 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 406
 407 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 408 # is not distributed in tarballs.
 409 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 410 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 411
 412 # Enable building man pages (user's intention).
 413 AC_ARG_ENABLE(
 414         man-pages,
 415         AS_HELP_STRING(
 416                 [--disable-man-pages],
 417                 [Do not build and install man pages (already built in a distributed tarball)]
 418         ),
 419         [man_pages_opt=$enableval],
 420         [man_pages_opt=yes]
 421 )
 422
 423 # Check for asciidoc and xmlto if we enabled building the man pages.
 424 have_asciidoc_xmlto=no
 425 warn_prebuilt_man_pages=no
 426
 427 AS_IF([test "x$man_pages_opt" = "xyes"], [
 428         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 429         AC_PATH_PROG([XMLTO], [xmlto], [no])
 430
 431         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 432                 AS_IF([test "x$in_git_repo" = "xyes"], [
 433                         # This is an error because we're in the Git repo, which
 434                         # means the man pages are not already generated for us,
 435                         # thus asciidoc/xmlto are required because we were asked
 436                         # to build the man pages.
 437                         AC_MSG_ERROR([
 438 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 439 --disable-man-pages to disable building the man pages, in which case
 440 they will not be installed.
 441                         ])
 442                 ], [
 443                         # Only warn here: since we're in the tarball, the man
 444                         # pages should already be generated at this point, thus
 445                         # asciidoc/xmlto are not strictly required.
 446                         warn_prebuilt_man_pages=yes
 447                 ])
 448         ], [
 449                 have_asciidoc_xmlto=yes
 450         ])
 451 ])
 452
 453 # Export man page build condition: build the man pages if the user
 454 # asked for it, and if the tools are available.
 455 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 456 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 457
 458 # Default values
 459 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 460         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 461         $1="$2"
 462         AC_SUBST([$1])
 463 ])
 464
 465 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 466
 467 AM_CFLAGS="-Wall"
 468 AC_SUBST(AM_CFLAGS)
 469 AC_SUBST(JNI_CPPFLAGS)
 470
 471 AC_CONFIG_FILES([
 472         Makefile
 473         doc/Makefile
 474         doc/examples/Makefile
 475         doc/man/Makefile
 476         include/Makefile
 477         include/lttng/ust-version.h
 478         snprintf/Makefile
 479         libringbuffer/Makefile
 480         liblttng-ust-comm/Makefile
 481         liblttng-ust/Makefile
 482         liblttng-ust-ctl/Makefile
 483         liblttng-ust-fork/Makefile
 484         liblttng-ust-dl/Makefile
 485         liblttng-ust-fd/Makefile
 486         liblttng-ust-java/Makefile
 487         liblttng-ust-java-agent/Makefile
 488         liblttng-ust-java-agent/java/Makefile
 489         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 490         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 491         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 492         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 493         liblttng-ust-java-agent/jni/Makefile
 494         liblttng-ust-java-agent/jni/common/Makefile
 495         liblttng-ust-java-agent/jni/jul/Makefile
 496         liblttng-ust-java-agent/jni/log4j/Makefile
 497         liblttng-ust-libc-wrapper/Makefile
 498         liblttng-ust-cyg-profile/Makefile
 499         liblttng-ust-python-agent/Makefile
 500         python-lttngust/Makefile
 501         python-lttngust/setup.py
 502         python-lttngust/lttngust/__init__.py
 503         tools/Makefile
 504         tests/Makefile
 505         tests/ctf-types/Makefile
 506         tests/hello/Makefile
 507         tests/hello.cxx/Makefile
 508         tests/same_line_tracepoint/Makefile
 509         tests/snprintf/Makefile
 510         tests/ust-elf/Makefile
 511         tests/benchmark/Makefile
 512         tests/utils/Makefile
 513         tests/test-app-ctx/Makefile
 514         tests/gcc-weak-hidden/Makefile
 515         lttng-ust.pc
 516 ])
 517
 518 # Create link for python agent for the VPATH guru.
 519 AC_CONFIG_LINKS([
 520         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 521         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 522         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 523         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 524 ])
 525
 526 AC_OUTPUT
 527
 528
 529 #
 530 # Mini-report on what will be built.
 531 #
 532
 533 PPRINT_INIT
 534 PPRINT_SET_INDENT(1)
 535 PPRINT_SET_TS(38)
 536
 537 AS_ECHO
 538 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 539 AS_ECHO
 540
 541 AS_ECHO("V_DESC")
 542
 543 AS_ECHO
 544 PPRINT_SUBTITLE([System])
 545
 546 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 547
 548 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 549 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 550
 551 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 552        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 553 ])
 554
 555 AS_ECHO
 556 PPRINT_SUBTITLE([Features])
 557 PPRINT_SET_INDENT(1)
 558
 559 test "x$with_sdt" = "xyes" && value=1 || value=0
 560 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 561
 562 test "x$java_agent_jul" = xyes && value=1 || value=0
 563 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 564
 565 test "x$java_agent_log4j" = xyes && value=1 || value=0
 566 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 567
 568 test "x$jni_interface" = xyes && value=1 || value=0
 569 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 570
 571 test "x$python_agent" = xyes && value=1 || value=0
 572 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 573
 574 AS_ECHO
 575 PPRINT_SET_INDENT(0)
 576
 577 # man pages build enabled/disabled
 578 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 579
 580 AS_IF([test "x$man_pages_opt" != "xno"], [
 581         AS_IF([test "x$in_git_repo" = "xyes"], [
 582                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 583         ], [
 584                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 585                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 586                 ], [
 587                         PPRINT_PROP_STRING([build_man_pages_msg],
 588                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 589                                 $PPRINT_COLOR_SUBTITLE)
 590                 ])
 591         ])
 592 ], [
 593         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 594 ])
 595
 596 m4_popdef([build_man_pages_msg])
 597
 598 PPRINT_SET_INDENT(1)
 599
 600 report_bindir="`eval eval echo $bindir`"
 601 report_libdir="`eval eval echo $libdir`"
 602
 603 # Print the bindir and libdir this `make install' will install into.
 604 AS_ECHO
 605 PPRINT_SUBTITLE([Install directories])
 606 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 607 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 608
 609 AS_ECHO
 610 PPRINT_SUBTITLE([System directories])
 611
 612 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 613
 614 PPRINT_SET_INDENT(0)
 615
 616 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 617         AS_ECHO
 618         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 619
 620 Note that the man pages are already built in this distribution tarball,
 621 therefore asciidoc and xmlto are only needed if you intend to modify
 622 their sources.
 623
 624 Use --disable-man-pages to completely disable building and installing
 625 the man pages.])
 626 ])