configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.1.4],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [1:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  24
  25 # Configuration options, which will be installed in the config.h
  26 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  27 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  29
  30 # Compute minor/major/patchlevel version numbers
  31 AC_PROG_SED
  32 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  33 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  34 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  35 AC_SUBST([MAJOR_VERSION], [$major_version])
  36 AC_SUBST([MINOR_VERSION], [$minor_version])
  37 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  38 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  39 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  40 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  41
  42 version_name="Basse Messe"
  43 version_description="Light coloured German ale whose style was named after the city Cologne (Koln) where it was first brewed. It is a rather simple beer with lightly fruity aromas and a delicate hoppy fragrance. The beer has a pronounced malty taste with a subtle bitter aftertaste"
  44 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  45 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  46
  47 AC_PROG_GREP
  48 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  49 AC_ARG_ENABLE(libtool-linkdep-fixup,
  50         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  51                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  52         libtool_fixup=$enableval,
  53         libtool_fixup=yes)
  54
  55 AS_IF([test "x$libtool_fixup" = "xyes"],
  56             [
  57             libtool_m4="$srcdir/config/libtool.m4"
  58             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  59             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  60             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  61             AS_IF([test $libtool_flag_pattern_count -ne 0],
  62             [
  63                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  64                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  65                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  66                   ],
  67                   [
  68                   AC_MSG_RESULT([none])
  69                   ])
  70             ])
  71
  72 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  73
  74 # Checks for programs.
  75 AC_PROG_CC
  76 AC_PROG_CXX
  77 AC_PROG_MAKE_SET
  78 LT_INIT
  79
  80 # rw_PROG_CXX_WORKS
  81 # Check whether the C++ compiler works.
  82 AC_CACHE_CHECK([whether the C++ compiler works],
  83                 [rw_cv_prog_cxx_works],
  84                 [AC_LANG_PUSH([C++])
  85                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  86                                 [rw_cv_prog_cxx_works=yes],
  87                                 [rw_cv_prog_cxx_works=no])
  88                 AC_LANG_POP([C++])])
  89
  90 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  91
  92 ## Checks for libraries.
  93 AC_CHECK_LIB([dl], [dlopen],
  94 [
  95         have_libdl=yes
  96 ],
  97 [
  98         #libdl not found, check for dlopen in libc.
  99         AC_CHECK_LIB([c], [dlopen],
 100         [
 101                 have_libc_dl=yes
 102         ],
 103         [
 104                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 105         ])
 106 ])
 107 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 108 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 109
 110 AC_CHECK_LIB([pthread], [pthread_create])
 111
 112 # Check for libuuid
 113 AC_CHECK_LIB([uuid], [uuid_generate],
 114 [
 115         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
 116         have_libuuid=yes
 117 ],
 118 [
 119         # libuuid not found, check for uuid_create in libc.
 120         AC_CHECK_LIB([c], [uuid_create],
 121         [
 122                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 123                 have_libc_uuid=yes
 124         ],
 125         [
 126                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 127         ])
 128 ]
 129 )
 130 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 131 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 132
 133 # Checks for header files.
 134 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 135
 136 # Checks for typedefs, structures, and compiler characteristics.
 137 AC_C_INLINE
 138 #AC_TYPE_INT16_T
 139 #AC_TYPE_INT32_T
 140 #AC_TYPE_INT64_T
 141 #AC_TYPE_INT8_T
 142 #AC_TYPE_PID_T
 143 #AC_TYPE_SIZE_T
 144 #AC_TYPE_SSIZE_T
 145 #AC_TYPE_UINT16_T
 146 #AC_TYPE_UINT32_T
 147 #AC_TYPE_UINT64_T
 148 #AC_TYPE_UINT8_T
 149 #AC_CHECK_TYPES([ptrdiff_t])
 150
 151 # Checks for library functions.
 152 AC_FUNC_MALLOC
 153 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 154
 155 CFLAGS="-Wall $CFLAGS"
 156
 157 # URCU
 158
 159 # urcu - check if we just find the headers it out of the box.
 160 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 161 This error can also occur when the liburcu package's configure script has not been run.])])
 162
 163 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 164 # Part of Userspace RCU library 0.7.2 or better.
 165 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 166 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 167
 168 AC_MSG_CHECKING([caa_likely()])
 169 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 170 #include <urcu/compiler.h>
 171 void fct(void)
 172 {
 173         if (caa_likely(1)) {
 174         }
 175 }
 176 ]])],[
 177         AC_MSG_RESULT([yes])
 178 ],[
 179         AC_MSG_RESULT([no])
 180         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 181
 182 ])
 183
 184 # urcu - check that URCU lib is available to compilation
 185 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 186
 187 # urcu - check that URCU lib is at least version 0.6
 188 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 189
 190 AC_MSG_CHECKING([host system alignment requirements])
 191 case $host_cpu in
 192 changequote(,)dnl
 193         i[3456]86)
 194 changequote([,])dnl
 195           ;;
 196         x86_64) ;;
 197         amd64) ;;
 198         powerpc) ;;
 199         ppc64) ;;
 200         powerpc64) ;;
 201         s390) NO_UNALIGNED_ACCESS=1 ;;
 202         s390x) NO_UNALIGNED_ACCESS=1 ;;
 203         arm*) NO_UNALIGNED_ACCESS=1 ;;
 204         mips*) NO_UNALIGNED_ACCESS=1;;
 205         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 206 esac
 207
 208 if test x$NO_UNALIGNED_ACCESS = x ; then
 209 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 210 fi
 211
 212 # Set compile flags to java include files if given
 213 AC_ARG_WITH([java-jdk],
 214         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 215         [JAVA_JDK=$withval],
 216         [JAVA_JDK=""]
 217 )
 218 AS_IF([test $JAVA_JDK],[
 219         AS_IF([test -d $JAVA_JDK],[
 220                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 221                 SUBDIRS=`find $JAVA_JDK/include -type d`
 222                 CPPFLAGS+=" "
 223                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 224                 CPPFLAGS+=" "
 225         ],[
 226                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 227         ])
 228 ])
 229
 230 # Check for JNI header files if requested
 231 AC_ARG_WITH([jni-interface],
 232         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 233         [jni_interface=$withval],
 234         [jni_interface=no]
 235 )
 236
 237 AS_IF([test "x$jni_interface" = "xyes"],[
 238         AC_CHECK_HEADERS([jni.h],[],[
 239         AC_MSG_ERROR([missing jni.h
 240 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 241 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 242         ])
 243 ])
 244 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 245
 246 # sdt.h integration
 247 AC_ARG_WITH([sdt],
 248         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 249         [with_sdt=$withval],
 250         [with_sdt="no"]
 251 )
 252
 253 AS_IF([test "x$with_sdt" = "xyes"],[
 254         AC_MSG_CHECKING([STAP_PROBEV()])
 255         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 256         #define SDT_USE_VARIADIC
 257         #include <sys/sdt.h>
 258         void fct(void)
 259         {
 260                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 261         }
 262         ]])],[
 263                 AC_MSG_RESULT([yes])
 264                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 265         ],[
 266                 AC_MSG_RESULT([no])
 267                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 268         ])
 269 ])
 270
 271 #currently disabled.
 272         #tests/hello2/Makefile
 273         #tests/basic/Makefile
 274         #tests/simple_include/Makefile
 275         #tests/snprintf/Makefile
 276         #tests/test-nevents/Makefile
 277         #tests/test-libustinstr-malloc/Makefile
 278         #tests/dlopen/Makefile
 279         #tests/same_line_marker/Makefile
 280         #tests/trace_event/Makefile
 281         #tests/tracepoint/Makefile
 282         #tests/tracepoint/benchmark/Makefile
 283         #tests/register_test/Makefile
 284         #tests/libustctl_function_#tests/Makefile
 285         #tests/exit-fast/Makefile
 286         #tests/basic_long/Makefile
 287
 288 AC_CONFIG_FILES([
 289         Makefile
 290         doc/Makefile
 291         doc/examples/Makefile
 292         include/Makefile
 293         include/lttng/ust-version.h
 294         snprintf/Makefile
 295         libringbuffer/Makefile
 296         liblttng-ust-comm/Makefile
 297         liblttng-ust/Makefile
 298         liblttng-ust-ctl/Makefile
 299         liblttng-ust-fork/Makefile
 300         liblttng-ust-java/Makefile
 301         liblttng-ust-libc-wrapper/Makefile
 302         tools/Makefile
 303         tests/Makefile
 304         tests/hello/Makefile
 305         tests/hello-static-lib/Makefile
 306         tests/hello.cxx/Makefile
 307         tests/daemon/Makefile
 308         tests/demo/Makefile
 309         tests/fork/Makefile
 310         tests/ust-basic-tracing/Makefile
 311         tests/ust-multi-test/Makefile
 312         lttng-ust.pc
 313 ])
 314
 315 AC_OUTPUT
 316
 317 AS_ECHO()
 318 AS_ECHO("Version name: $version_name")
 319 AS_ECHO("$version_description")
 320
 321 # Report on the configuration options
 322 AS_ECHO()
 323 AS_ECHO("LTTng-UST will be built with the following options:")
 324 AS_ECHO("Library format: $LIBFORMAT")
 325
 326 AS_ECHO()
 327 AS_ECHO_N("Java support (JNI): ")
 328 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 329
 330 AS_ECHO_N("sdt.h integration:  ")
 331 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 332
 333 AS_ECHO()
 334 AS_ECHO("Type 'make' to compile.")
 335