configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [13])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [pre])
   6 m4_define([V_NAME], [[Codename TBD]])
   7 m4_define([V_DESC], [[Description TBD]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ([2.69])
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [1])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules by default
  48 AM_SILENT_RULES([yes])
  49
  50 # Checks for C compiler
  51 AC_USE_SYSTEM_EXTENSIONS
  52 AC_SYS_LARGEFILE
  53 AC_PROG_CC
  54 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  55 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  56 AC_PROG_CXX
  57 AX_CXX_COMPILE_STDCXX([11])
  58 RW_PROG_CXX_WORKS
  59 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  60
  61 # Check if the compiler support weak symbols
  62 AX_SYS_WEAK_ALIAS
  63
  64 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  65         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  66 ])
  67
  68 # Checks for programs.
  69 AM_PROG_AR
  70 AC_PROG_SED
  71 AC_PROG_GREP
  72 AC_PROG_LN_S
  73 AC_PROG_MKDIR_P
  74 AC_PROG_MAKE_SET
  75 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  76 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  77
  78 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  79 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  80 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  81 ], [
  82         libtool_fixup=$enableval
  83 ], [
  84         libtool_fixup=yes
  85 ])
  86
  87 AS_IF([test "x$libtool_fixup" = "xyes"], [
  88         libtool_m4="$srcdir/m4/libtool.m4"
  89         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  90         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  91         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  92
  93         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  94         AC_MSG_RESULT([$libtool_flag_pattern_count])
  95         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  96                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  97         ], [
  98                 AC_MSG_RESULT([none])
  99         ])
 100 ])
 101 LT_INIT([disable-static])
 102
 103 AC_MSG_CHECKING([whether shared libraries are enabled])
 104 AS_IF([test "x$enable_shared" = "xyes"], [
 105         AC_MSG_RESULT([yes])
 106 ], [
 107         AC_MSG_RESULT([no])
 108         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 109 ])
 110
 111 # Checks for typedefs, structures, and compiler characteristics.
 112 AC_C_INLINE
 113 AC_TYPE_INT8_T
 114 AC_TYPE_INT16_T
 115 AC_TYPE_INT32_T
 116 AC_TYPE_INT64_T
 117 AC_TYPE_MODE_T
 118 AC_TYPE_OFF_T
 119 AC_TYPE_PID_T
 120 AC_TYPE_SIZE_T
 121 AC_TYPE_SSIZE_T
 122 AC_TYPE_UID_T
 123 AC_TYPE_UINT8_T
 124 AC_TYPE_UINT16_T
 125 AC_TYPE_UINT32_T
 126 AC_TYPE_UINT64_T
 127 AC_CHECK_TYPES([ptrdiff_t])
 128
 129 AX_C___ATTRIBUTE__
 130 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 131         [:],
 132         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 133
 134 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 135
 136 # Checks for library functions.
 137 AC_FUNC_CHOWN
 138 AC_FUNC_FORK
 139 AC_FUNC_MMAP
 140 AC_FUNC_REALLOC
 141 AC_FUNC_STRERROR_R
 142 AC_FUNC_STRNLEN
 143 AC_CHECK_FUNCS([ \
 144         atexit \
 145         clock_gettime \
 146         ftruncate \
 147         getpagesize \
 148         gettimeofday \
 149         localeconv \
 150         memchr \
 151         memmove \
 152         memset \
 153         mkdir \
 154         munmap \
 155         realpath \
 156         sched_getcpu \
 157         socket \
 158         strchr \
 159         strdup \
 160         strerror \
 161         strtol \
 162         strtoul \
 163         sysconf \
 164 ])
 165
 166 # Check for pthread_setname_np and its signature
 167 LTTNG_PTHREAD_SETNAME_NP
 168
 169 # AC_FUNC_MALLOC causes problems when cross-compiling.
 170 #AC_FUNC_MALLOC
 171
 172 # Checks for header files.
 173 AC_HEADER_STDBOOL
 174 AC_CHECK_HEADERS([ \
 175         arpa/inet.h \
 176         fcntl.h \
 177         float.h \
 178         limits.h \
 179         locale.h \
 180         stddef.h \
 181         sys/socket.h \
 182         sys/time.h \
 183         wchar.h \
 184 ])
 185
 186 # Set architecture specific options
 187 AS_CASE([$host_cpu],
 188         [i[[3456]]86], [],
 189         [x86_64], [],
 190         [amd64], [],
 191         [powerpc], [],
 192         [ppc64], [],
 193         [ppc64le], [],
 194         [powerpc64], [],
 195         [powerpc64le], [],
 196         [s390], [NO_UNALIGNED_ACCESS=1],
 197         [s390x], [NO_UNALIGNED_ACCESS=1],
 198         [arm*], [
 199                 NO_UNALIGNED_ACCESS=1
 200                 NO_NUMA=1
 201                 ],
 202         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 203         [mips*], [NO_UNALIGNED_ACCESS=1],
 204         [tile*], [NO_UNALIGNED_ACCESS=1],
 205         [
 206                 UNSUPPORTED_ARCH=1
 207                 NO_UNALIGNED_ACCESS=1
 208         ])
 209
 210 # Set os specific options
 211 AS_CASE([$host_os],
 212         [freebsd*], [NO_NUMA=1]
 213 )
 214
 215 # Configuration options, which will be installed in the config.h
 216 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 217 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 218 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 219
 220 # Checks for libraries.
 221 AC_CHECK_LIB([dl], [dlopen], [
 222         libdl_name=dl
 223         DL_LIBS="-ldl"
 224 ], [
 225         #libdl not found, check for dlopen in libc.
 226         AC_CHECK_LIB([c], [dlopen], [
 227                 libdl_name=c
 228                 DL_LIBS="-lc"
 229         ], [
 230                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 231         ])
 232 ])
 233 AC_SUBST(DL_LIBS)
 234
 235 # Check if libdl has dlmopen support.
 236 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 237 AC_CHECK_LIB([$libdl_name], [dlmopen],
 238         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 239 )
 240
 241 # Check for dlfcn.h
 242 AC_CHECK_HEADER([dlfcn.h])
 243 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 244         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 245                 #include <dlfcn.h>
 246         ])
 247 ], [
 248         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 249 ])
 250
 251 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 252
 253 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 254 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 255
 256 # numa.h integration
 257 AS_IF([test "x$NO_NUMA" = "x1"],[
 258       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 259 ])
 260
 261 AC_ARG_ENABLE([numa], [
 262 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 263 ], [
 264         enable_numa=$enableval
 265 ], [
 266         enable_numa=yes
 267 ])
 268
 269 AS_IF([test "x$enable_numa" = "xyes"], [
 270         # numa - check that numa lib is available
 271         AC_CHECK_LIB([numa], [numa_available], [],
 272 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 273         have_libnuma=yes
 274 ])
 275 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 276
 277 # optional linux/perf_event.h
 278 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 279
 280 # Perf event counters are supported on all architectures supported by
 281 # perf, using the read system call as fallback.
 282 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 283
 284 AS_IF([test "x$have_perf_event" = "xyes"], [
 285         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 286 ])
 287
 288 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 289         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 290 ])
 291
 292 # Check for JNI header files if requested
 293 AC_ARG_ENABLE([jni-interface], [
 294 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 295 ], [
 296         jni_interface=$enableval
 297 ], [
 298         jni_interface=no
 299 ])
 300
 301 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 302
 303
 304 AC_ARG_ENABLE([java-agent-jul], [
 305 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 306 ], [
 307         java_agent_jul=$enableval
 308 ], [
 309         java_agent_jul=no
 310 ])
 311
 312 AC_ARG_ENABLE([java-agent-log4j], [
 313 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 314 ], [
 315         java_agent_log4j=$enableval
 316 ], [
 317         java_agent_log4j=no
 318 ])
 319
 320 AC_ARG_ENABLE([java-agent-all], [
 321 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 322 ], [
 323         java_agent_jul=$enableval
 324         java_agent_log4j=$enableval
 325 ], [:])
 326
 327 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 328 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 329 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 330
 331 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 332         AX_JAVA_OPTIONS
 333         AX_PROG_JAVAC
 334         AX_PROG_JAVA
 335         AX_PROG_JAR
 336         AC_ARG_VAR([CLASSPATH], [Java class path])
 337
 338         AX_JNI_INCLUDE_DIR
 339         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 340         do
 341                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 342         done
 343
 344         saved_CPPFLAGS="$CPPFLAGS"
 345         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 346         AX_PROG_JAVAH
 347         CPPFLAGS="$saved_CPPFLAGS"
 348 ])
 349
 350 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 351
 352 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 353         AX_CHECK_CLASSPATH
 354         AX_CHECK_CLASS([org.apache.log4j.Logger])
 355         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 356                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 357         ])
 358 ])
 359
 360 # Option to build the python agent
 361 AC_ARG_ENABLE([python-agent], [
 362 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 363 ], [
 364         python_agent=$enableval
 365 ], [:])
 366 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 367 AS_IF([test "x$python_agent" = "xyes"], [
 368         AM_PATH_PYTHON([2.7])
 369 ])
 370
 371 # sdt.h integration
 372 AC_ARG_WITH([sdt], [
 373 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 374 ], [
 375         with_sdt=$withval
 376 ], [
 377         with_sdt="no"
 378 ])
 379
 380 AS_IF([test "x$with_sdt" = "xyes"], [
 381         AC_MSG_CHECKING([STAP_PROBEV()])
 382         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 383                 #define SDT_USE_VARIADIC
 384                 #include <sys/sdt.h>
 385                 void fct(void)
 386                 {
 387                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 388                 }
 389         ]])], [
 390                 AC_MSG_RESULT([yes])
 391                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 392         ], [
 393                 AC_MSG_RESULT([no])
 394                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 395         ])
 396 ])
 397
 398 AC_ARG_WITH([lttng-system-rundir], [
 399 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 400 ], [
 401         lttng_system_rundir="$withval"
 402 ], [
 403         lttng_system_rundir="/var/run/lttng"
 404 ])
 405 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 406                 [LTTng system runtime directory])
 407
 408 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 409 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 410
 411 # Enable building examples
 412 AC_ARG_ENABLE(
 413         examples,
 414         AS_HELP_STRING(
 415                 [--disable-examples],
 416                 [Do not build and install examples]
 417         ),
 418         [enable_examples=$enableval],
 419         [enable_examples=yes]
 420 )
 421
 422 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 423
 424 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 425 # is not distributed in tarballs.
 426 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 427 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 428
 429 # Enable building man pages (user's intention).
 430 AC_ARG_ENABLE(
 431         man-pages,
 432         AS_HELP_STRING(
 433                 [--disable-man-pages],
 434                 [Do not build and install man pages (already built in a distributed tarball)]
 435         ),
 436         [man_pages_opt=$enableval],
 437         [man_pages_opt=yes]
 438 )
 439
 440 # Check for asciidoc and xmlto if we enabled building the man pages.
 441 have_asciidoc_xmlto=no
 442 warn_prebuilt_man_pages=no
 443
 444 AS_IF([test "x$man_pages_opt" = "xyes"], [
 445         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 446         AC_PATH_PROG([XMLTO], [xmlto], [no])
 447
 448         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 449                 AS_IF([test "x$in_git_repo" = "xyes"], [
 450                         # This is an error because we're in the Git repo, which
 451                         # means the man pages are not already generated for us,
 452                         # thus asciidoc/xmlto are required because we were asked
 453                         # to build the man pages.
 454                         AC_MSG_ERROR([
 455 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 456 --disable-man-pages to disable building the man pages, in which case
 457 they will not be installed.
 458                         ])
 459                 ], [
 460                         # Only warn here: since we're in the tarball, the man
 461                         # pages should already be generated at this point, thus
 462                         # asciidoc/xmlto are not strictly required.
 463                         warn_prebuilt_man_pages=yes
 464                 ])
 465         ], [
 466                 have_asciidoc_xmlto=yes
 467         ])
 468 ])
 469
 470 # Export man page build condition: build the man pages if the user
 471 # asked for it, and if the tools are available.
 472 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 473 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 474
 475 # Default values
 476 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 477         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 478         $1="$2"
 479         AC_SUBST([$1])
 480 ])
 481
 482 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 483
 484 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
 485 AC_SUBST(AM_CFLAGS)
 486
 487 AM_CXXFLAGS="$AM_CFLAGS"
 488 AC_SUBST(AM_CXXFLAGS)
 489
 490 # The order in which the include folders are searched is important.
 491 # The top_builddir should always be searched first in the event that a build
 492 # time generated file is included.
 493 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 494 AC_SUBST(AM_CPPFLAGS)
 495
 496 AC_SUBST(JNI_CPPFLAGS)
 497
 498 AC_CONFIG_FILES([
 499         Makefile
 500         doc/Makefile
 501         doc/examples/Makefile
 502         doc/man/Makefile
 503         include/Makefile
 504         include/lttng/ust-version.h
 505         snprintf/Makefile
 506         libcounter/Makefile
 507         libmsgpack/Makefile
 508         libringbuffer/Makefile
 509         liblttng-ust-comm/Makefile
 510         liblttng-ust/Makefile
 511         liblttng-ust-ctl/Makefile
 512         liblttng-ust-fork/Makefile
 513         liblttng-ust-dl/Makefile
 514         liblttng-ust-fd/Makefile
 515         liblttng-ust-java/Makefile
 516         liblttng-ust-java-agent/Makefile
 517         liblttng-ust-java-agent/java/Makefile
 518         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 519         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 520         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 521         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 522         liblttng-ust-java-agent/jni/Makefile
 523         liblttng-ust-java-agent/jni/common/Makefile
 524         liblttng-ust-java-agent/jni/jul/Makefile
 525         liblttng-ust-java-agent/jni/log4j/Makefile
 526         liblttng-ust-libc-wrapper/Makefile
 527         liblttng-ust-cyg-profile/Makefile
 528         liblttng-ust-python-agent/Makefile
 529         python-lttngust/Makefile
 530         python-lttngust/setup.py
 531         python-lttngust/lttngust/__init__.py
 532         tools/Makefile
 533         tests/Makefile
 534         tests/compile/Makefile
 535         tests/compile/ctf-types/Makefile
 536         tests/compile/hello.cxx/Makefile
 537         tests/compile/hello/Makefile
 538         tests/compile/hello-many/Makefile
 539         tests/compile/same_line_tracepoint/Makefile
 540         tests/compile/test-app-ctx/Makefile
 541         tests/benchmark/Makefile
 542         tests/unit/gcc-weak-hidden/Makefile
 543         tests/unit/libmsgpack/Makefile
 544         tests/unit/Makefile
 545         tests/unit/libringbuffer/Makefile
 546         tests/unit/pthread_name/Makefile
 547         tests/unit/snprintf/Makefile
 548         tests/unit/ust-elf/Makefile
 549         tests/utils/Makefile
 550         lttng-ust.pc
 551         lttng-ust-ctl.pc
 552 ])
 553
 554 # Create link for python agent for the VPATH guru.
 555 AC_CONFIG_LINKS([
 556         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 557         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 558         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 559         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 560         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 561 ])
 562
 563 AC_CONFIG_FILES([tests/unit/ust-elf/test_ust_elf],[chmod +x tests/unit/ust-elf/test_ust_elf])
 564
 565 AC_OUTPUT
 566
 567
 568 #
 569 # Mini-report on what will be built.
 570 #
 571
 572 PPRINT_INIT
 573 PPRINT_SET_INDENT(1)
 574 PPRINT_SET_TS(38)
 575
 576 AS_ECHO
 577 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 578 AS_ECHO
 579
 580 AS_ECHO("V_DESC")
 581
 582 AS_ECHO
 583 PPRINT_SUBTITLE([System])
 584
 585 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 586
 587 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 588 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 589
 590 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 591        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 592 ])
 593
 594 AS_ECHO
 595 PPRINT_SUBTITLE([Features])
 596 PPRINT_SET_INDENT(1)
 597
 598 test "x$with_sdt" = "xyes" && value=1 || value=0
 599 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 600
 601 test "x$java_agent_jul" = xyes && value=1 || value=0
 602 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 603
 604 test "x$java_agent_log4j" = xyes && value=1 || value=0
 605 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 606
 607 test "x$jni_interface" = xyes && value=1 || value=0
 608 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 609
 610 test "x$python_agent" = xyes && value=1 || value=0
 611 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 612
 613 test "x$have_perf_event" = "xyes" && value=1 || value=0
 614 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 615
 616 test "x$enable_numa" = xyes && value=1 || value=0
 617 PPRINT_PROP_BOOL([NUMA], $value)
 618
 619 AS_ECHO
 620 PPRINT_SET_INDENT(0)
 621
 622 test "x$enable_examples" = xyes && value=1 || value=0
 623 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 624
 625 # man pages build enabled/disabled
 626 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 627
 628 AS_IF([test "x$man_pages_opt" != "xno"], [
 629         AS_IF([test "x$in_git_repo" = "xyes"], [
 630                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 631         ], [
 632                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 633                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 634                 ], [
 635                         PPRINT_PROP_STRING([build_man_pages_msg],
 636                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 637                                 $PPRINT_COLOR_SUBTITLE)
 638                 ])
 639         ])
 640 ], [
 641         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 642 ])
 643
 644 m4_popdef([build_man_pages_msg])
 645
 646 PPRINT_SET_INDENT(1)
 647
 648 report_bindir="`eval eval echo $bindir`"
 649 report_libdir="`eval eval echo $libdir`"
 650
 651 # Print the bindir and libdir this `make install' will install into.
 652 AS_ECHO
 653 PPRINT_SUBTITLE([Install directories])
 654 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 655 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 656
 657 AS_ECHO
 658 PPRINT_SUBTITLE([System directories])
 659
 660 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 661
 662 PPRINT_SET_INDENT(0)
 663
 664 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 665         AS_ECHO
 666         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 667
 668 Note that the man pages are already built in this distribution tarball,
 669 therefore asciidoc and xmlto are only needed if you intend to modify
 670 their sources.
 671
 672 Use --disable-man-pages to completely disable building and installing
 673 the man pages.])
 674 ])