configure.ac

   1 dnl -*- Autoconf -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl Version infos
   5 m4_define([V_MAJOR], [2])
   6 m4_define([V_MINOR], [8])
   7 m4_define([V_PATCH], [4])
   8 dnl m4_define([V_EXTRA], [])
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11 m4_define([V_NAME], [[Isseki Nicho]])
  12 m4_define([V_DESC], [[The result of a collaboration between "Dieu du Ciel!" and Nagano-based "Shiga Kogen", Isseki Nicho is a strong Imperial Dark Saison offering a rich roasted malt flavor combined with a complex fruity finish typical of Saison yeasts.]])
  13
  14 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])
  15
  16 # Following the numbering scheme proposed by libtool for the library version
  17 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  18 # This is the library version of liblttng-ust.
  19 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  20 # note: remember to update tracepoint.h dlopen() to match this version
  21 # number. TODO: eventually automate by exporting the major number.
  22
  23 # This is the library version of liblttng-ust-ctl, used internally by
  24 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  25 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  26
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CANONICAL_TARGET
  29 AC_CANONICAL_HOST
  30 AC_CONFIG_MACRO_DIR([config])
  31 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  32 AM_MAINTAINER_MODE([enable])
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  35
  36 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  37
  38 # Configuration options, which will be installed in the config.h
  39 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  40 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  41 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  42 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
  43
  44 dnl Substitute minor/major/patchlevel version numbers
  45 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  46 AC_SUBST([MINOR_VERSION], [V_MINOR])
  47 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  48
  49 AC_PROG_SED
  50 AC_PROG_GREP
  51 AC_PROG_LN_S
  52
  53 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  54 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  55         AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  56 ], [
  57         libtool_fixup=$enableval
  58 ], [
  59         libtool_fixup=yes
  60 ])
  61
  62 AS_IF([test "x$libtool_fixup" = "xyes"], [
  63         libtool_m4="$srcdir/config/libtool.m4"
  64         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  65         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  66         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  67
  68         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  69         AC_MSG_RESULT([$libtool_flag_pattern_count])
  70         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  71                 sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  72         ], [
  73                 AC_MSG_RESULT([none])
  74         ])
  75 ])
  76
  77 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  78
  79 # Checks for programs.
  80 AC_PROG_CC
  81 AC_PROG_CXX
  82 AC_PROG_MAKE_SET
  83 LT_INIT
  84
  85 # rw_PROG_CXX_WORKS
  86 # Check whether the C++ compiler works.
  87 AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
  88         AC_LANG_PUSH([C++])
  89
  90         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
  91                 check_cxx_designated_initializers=yes
  92         ], [
  93                 rw_cv_prog_cxx_works=no
  94         ])
  95
  96         AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
  97                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  98                         struct foo { int a; int b; };
  99                         void fct(void)
 100                         {
 101                                 struct foo f = { .a = 0, .b = 1 };
 102                         }
 103                 ]])], [
 104                         rw_cv_prog_cxx_works=yes
 105                 ], [
 106                         rw_cv_prog_cxx_works=no
 107                 ])
 108         ])
 109
 110         AC_LANG_POP([C++])
 111 ])
 112
 113 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 114
 115 # Check if the compiler support weak symbols
 116 AX_SYS_WEAK_ALIAS
 117
 118 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
 119         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
 120 ])
 121
 122 # Checks for libraries.
 123 AC_CHECK_LIB([dl], [dlopen], [
 124         have_libdl=yes
 125 ], [
 126         #libdl not found, check for dlopen in libc.
 127         AC_CHECK_LIB([c], [dlopen], [
 128                 have_libc_dl=yes
 129         ], [
 130                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 131         ])
 132 ])
 133
 134 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 135 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 136
 137 AC_CHECK_LIB([pthread], [pthread_create])
 138
 139 # Check for dlfcn.h
 140 AC_CHECK_HEADER([dlfcn.h])
 141 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 142         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 143                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 144                 #include <dlfcn.h>
 145         ])
 146 ], [
 147         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 148 ])
 149
 150 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 151
 152 # Checks for header files.
 153 dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 154
 155 # Checks for typedefs, structures, and compiler characteristics.
 156 AC_C_INLINE
 157 dnl AC_TYPE_INT16_T
 158 dnl AC_TYPE_INT32_T
 159 dnl AC_TYPE_INT64_T
 160 dnl AC_TYPE_INT8_T
 161 dnl AC_TYPE_PID_T
 162 dnl AC_TYPE_SIZE_T
 163 dnl AC_TYPE_SSIZE_T
 164 dnl AC_TYPE_UINT16_T
 165 dnl AC_TYPE_UINT32_T
 166 dnl AC_TYPE_UINT64_T
 167 dnl AC_TYPE_UINT8_T
 168 dnl AC_CHECK_TYPES([ptrdiff_t])
 169
 170 # Checks for library functions.
 171 AC_FUNC_MALLOC
 172 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 173
 174 # URCU
 175
 176 # urcu - check if we just find the headers it out of the box.
 177 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 178 This error can also occur when the liburcu package's configure script has not been run.])])
 179
 180 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 181 # Part of Userspace RCU library 0.7.2 or better.
 182 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 183 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 184
 185 AC_MSG_CHECKING([caa_likely()])
 186 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 187         #include <urcu/compiler.h>
 188         void fct(void)
 189         {
 190                 if (caa_likely(1)) {
 191                 }
 192         }
 193 ]])], [
 194         AC_MSG_RESULT([yes])
 195 ], [
 196         AC_MSG_RESULT([no])
 197         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 198 ])
 199
 200 # urcu - check that URCU lib is available to compilation
 201 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 202
 203 # urcu - check that URCU lib is at least version 0.6
 204 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 205
 206 # optional linux/perf_event.h
 207 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 208
 209 # Perf event counters are only supported on x86 so far.
 210 AC_MSG_CHECKING([UST support for architecture perf event counters])
 211 AS_CASE([$host_cpu],
 212         [i[[3456]]86], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
 213         [x86_64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
 214         [amd64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
 215         [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no])
 216 AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
 217
 218 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
 219
 220 AS_IF([test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"], [
 221         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 222 ])
 223
 224 AC_MSG_CHECKING([host system alignment requirements])
 225 AS_CASE([$host_cpu],
 226         [i[[3456]]86], [],
 227         [x86_64], [],
 228         [amd64], [],
 229         [powerpc], [],
 230         [ppc64], [],
 231         [ppc64le], [],
 232         [powerpc64], [],
 233         [powerpc64le], [],
 234         [s390], [NO_UNALIGNED_ACCESS=1],
 235         [s390x], [NO_UNALIGNED_ACCESS=1],
 236         [arm*], [NO_UNALIGNED_ACCESS=1],
 237         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 238         [mips*], [NO_UNALIGNED_ACCESS=1],
 239         [tile*], [NO_UNALIGNED_ACCESS=1],
 240         [
 241                 UNSUPPORTED_ARCH=1
 242                 NO_UNALIGNED_ACCESS=1
 243         ])
 244 AC_MSG_RESULT([$host_cpu])
 245
 246 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 247         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 248 ])
 249
 250 # Check for JNI header files if requested
 251 AC_ARG_ENABLE([jni-interface], [
 252         AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 253 ], [
 254         jni_interface=$enableval
 255 ], [
 256         jni_interface=no
 257 ])
 258
 259 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 260
 261
 262 AC_ARG_ENABLE([java-agent-jul], [
 263         AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 264 ], [
 265         java_agent_jul=$enableval
 266 ], [
 267         java_agent_jul=no
 268 ])
 269
 270 AC_ARG_ENABLE([java-agent-log4j], [
 271         AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 272 ], [
 273         java_agent_log4j=$enableval
 274 ], [
 275         java_agent_log4j=no
 276 ])
 277
 278 AC_ARG_ENABLE([java-agent-all], [
 279         AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 280 ], [
 281         java_agent_jul=$enableval
 282         java_agent_log4j=$enableval
 283 ], [:])
 284
 285 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 286 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 287 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 288
 289 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 290         AX_JAVA_OPTIONS
 291         AX_PROG_JAVAC
 292         AX_PROG_JAVA
 293         AX_PROG_JAR
 294
 295         AX_JNI_INCLUDE_DIR
 296         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 297         do
 298                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 299         done
 300
 301         saved_CPPFLAGS="$CPPFLAGS"
 302         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 303         AX_PROG_JAVAH
 304         CPPFLAGS="$saved_CPPFLAGS"
 305 ])
 306
 307 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 308         AX_CHECK_CLASSPATH
 309         AX_CHECK_CLASS([org.apache.log4j.Logger])
 310         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 311                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 312         ])
 313 ])
 314
 315 # Option to build the python agent
 316 AC_ARG_ENABLE([python-agent], [
 317         AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 318 ], [
 319         python_agent=$enableval
 320 ], [:])
 321 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 322 AS_IF([test "x$python_agent" = "xyes"], [
 323         AM_PATH_PYTHON([2.7])
 324 ])
 325
 326 # sdt.h integration
 327 AC_ARG_WITH([sdt], [
 328         AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 329 ], [
 330         with_sdt=$withval
 331 ], [
 332         with_sdt="no"
 333 ])
 334
 335 AS_IF([test "x$with_sdt" = "xyes"], [
 336         AC_MSG_CHECKING([STAP_PROBEV()])
 337         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 338                 #define SDT_USE_VARIADIC
 339                 #include <sys/sdt.h>
 340                 void fct(void)
 341                 {
 342                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 343                 }
 344         ]])], [
 345                 AC_MSG_RESULT([yes])
 346                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 347         ], [
 348                 AC_MSG_RESULT([no])
 349                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 350         ])
 351 ])
 352
 353 AC_MSG_CHECKING([whether shared libraries are enabled])
 354 AS_IF([test "x$enable_shared" = "xyes"], [
 355         AC_MSG_RESULT([yes])
 356 ], [
 357         AC_MSG_RESULT([no])
 358         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 359 ])
 360
 361 AC_ARG_WITH([lttng-system-rundir], [
 362         AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 363 ], [
 364         lttng_system_rundir="$withval"
 365 ], [
 366         lttng_system_rundir="/var/run/lttng"
 367 ])
 368 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 369                 [LTTng system runtime directory])
 370
 371 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 372 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 373
 374 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 375 # is not distributed in tarballs.
 376 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 377 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 378
 379 # Enable building man pages (user's intention).
 380 AC_ARG_ENABLE(
 381         man-pages,
 382         AS_HELP_STRING(
 383                 [--disable-man-pages],
 384                 [Do not build and install man pages (already built in a distributed tarball)]
 385         ),
 386         [man_pages_opt=$enableval],
 387         [man_pages_opt=yes]
 388 )
 389
 390 # Check for asciidoc and xmlto if we enabled building the man pages.
 391 have_asciidoc_xmlto=no
 392
 393 AS_IF([test "x$man_pages_opt" = "xyes"], [
 394         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 395         AC_PATH_PROG([XMLTO], [xmlto], [no])
 396
 397         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 398                 AS_IF([test "x$in_git_repo" = "xyes"], [
 399                         # This is an error because we're in the Git repo, which
 400                         # means the man pages are not already generated for us,
 401                         # thus asciidoc/xmlto are required because we were asked
 402                         # to build the man pages.
 403                         AC_MSG_ERROR([
 404 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 405 --disable-man-pages to disable building the man pages, in which case
 406 they will not be installed.
 407                         ])
 408                 ], [
 409                         # Only warn here: since we're in the tarball, the man
 410                         # pages should already be generated at this point, thus
 411                         # asciidoc/xmlto are not strictly required.
 412                         AC_MSG_WARN([
 413 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 414 Note that the man pages are already built in this distribution tarball,
 415 so asciidoc and xmlto are only needed if you intend to modify their
 416 sources. Use --disable-man-pages to completely disable building
 417 and installing the man pages.
 418                         ])
 419                 ])
 420         ], [
 421                 have_asciidoc_xmlto=yes
 422         ])
 423 ])
 424
 425 # Export man page build condition: build the man pages if the user
 426 # asked for it, and if the tools are available.
 427 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 428 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 429
 430 # Default values
 431 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 432         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 433         $1="$2"
 434         AC_SUBST([$1])
 435 ])
 436
 437 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 438
 439 AM_CFLAGS="-Wall"
 440 AC_SUBST(AM_CFLAGS)
 441 AC_SUBST(JNI_CPPFLAGS)
 442
 443 AC_CONFIG_FILES([
 444         Makefile
 445         doc/Makefile
 446         doc/examples/Makefile
 447         doc/man/Makefile
 448         include/Makefile
 449         include/lttng/ust-version.h
 450         snprintf/Makefile
 451         libringbuffer/Makefile
 452         liblttng-ust-comm/Makefile
 453         liblttng-ust/Makefile
 454         liblttng-ust-ctl/Makefile
 455         liblttng-ust-fork/Makefile
 456         liblttng-ust-dl/Makefile
 457         liblttng-ust-java/Makefile
 458         liblttng-ust-java-agent/Makefile
 459         liblttng-ust-java-agent/java/Makefile
 460         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 461         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 462         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 463         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 464         liblttng-ust-java-agent/jni/Makefile
 465         liblttng-ust-java-agent/jni/common/Makefile
 466         liblttng-ust-java-agent/jni/jul/Makefile
 467         liblttng-ust-java-agent/jni/log4j/Makefile
 468         liblttng-ust-libc-wrapper/Makefile
 469         liblttng-ust-cyg-profile/Makefile
 470         liblttng-ust-python-agent/Makefile
 471         python-lttngust/Makefile
 472         python-lttngust/setup.py
 473         python-lttngust/lttngust/__init__.py
 474         tools/Makefile
 475         tests/Makefile
 476         tests/ctf-types/Makefile
 477         tests/hello/Makefile
 478         tests/hello.cxx/Makefile
 479         tests/same_line_tracepoint/Makefile
 480         tests/snprintf/Makefile
 481         tests/ust-elf/Makefile
 482         tests/benchmark/Makefile
 483         tests/utils/Makefile
 484         tests/test-app-ctx/Makefile
 485         tests/gcc-weak-hidden/Makefile
 486         lttng-ust.pc
 487 ])
 488
 489 # Create link for python agent for the VPATH guru.
 490 AC_CONFIG_LINKS([
 491         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 492         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 493         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 494         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 495 ])
 496
 497 AC_OUTPUT
 498
 499 AS_ECHO
 500 AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
 501 AS_ECHO
 502 AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])
 503
 504 # Report on the configuration options
 505 AS_ECHO
 506 AS_ECHO(["LTTng-UST will be built with the following options:"])
 507
 508 AS_ECHO
 509
 510 AS_ECHO_N(["Java agent (JUL support): "])
 511 AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 512
 513 AS_ECHO_N(["Java agent (Log4j support): "])
 514 AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 515
 516 AS_ECHO_N(["JNI interface (JNI): "])
 517 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 518
 519 AS_ECHO_N(["Python ($PYTHON) agent: "])
 520 AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 521
 522 AS_ECHO_N(["sdt.h integration: "])
 523 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
 524
 525 AS_ECHO(["Architecture: $host_cpu"])
 526 AS_ECHO_N(["Efficient unaligned memory access: "])
 527 AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
 528 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
 529 AS_ECHO
 530
 531 AS_ECHO(["Type 'make' to compile."])
 532