configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.6],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Annedd'ale"
  38 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], [$version_name], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], [$version_description], [UST version description])
  41
  42 AC_PROG_GREP
  43 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  44 AC_ARG_ENABLE(libtool-linkdep-fixup,
  45         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  46                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  47         libtool_fixup=$enableval,
  48         libtool_fixup=yes)
  49
  50 AS_IF([test "x$libtool_fixup" = "xyes"],
  51             [
  52             libtool_m4="$srcdir/config/libtool.m4"
  53             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  54             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  55             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  56             AS_IF([test $libtool_flag_pattern_count -ne 0],
  57             [
  58                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  59                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  60                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  61                   ],
  62                   [
  63                   AC_MSG_RESULT([none])
  64                   ])
  65             ])
  66
  67 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  68
  69 # Checks for programs.
  70 AC_PROG_CC
  71 AC_PROG_CXX
  72 AC_PROG_MAKE_SET
  73 LT_INIT
  74
  75 ## Checks for libraries.
  76 AC_CHECK_LIB([dl], [dlopen])
  77 AC_CHECK_LIB([pthread], [pthread_create])
  78
  79 # Check for libuuid
  80 AC_CHECK_LIB([uuid], [uuid_generate], [],
  81         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  82 )
  83
  84 # Checks for header files.
  85 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  86
  87 # Checks for typedefs, structures, and compiler characteristics.
  88 AC_C_INLINE
  89 #AC_TYPE_INT16_T
  90 #AC_TYPE_INT32_T
  91 #AC_TYPE_INT64_T
  92 #AC_TYPE_INT8_T
  93 #AC_TYPE_PID_T
  94 #AC_TYPE_SIZE_T
  95 #AC_TYPE_SSIZE_T
  96 #AC_TYPE_UINT16_T
  97 #AC_TYPE_UINT32_T
  98 #AC_TYPE_UINT64_T
  99 #AC_TYPE_UINT8_T
 100 #AC_CHECK_TYPES([ptrdiff_t])
 101
 102 # Checks for library functions.
 103 AC_FUNC_MALLOC
 104 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 105
 106 CFLAGS="-Wall $CFLAGS"
 107
 108 # URCU
 109
 110 # urcu - check if we just find the headers it out of the box.
 111 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 112 This error can also occur when the liburcu package's configure script has not been run.])])
 113
 114 AC_MSG_CHECKING([caa_likely()])
 115 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 116 #include <urcu/compiler.h>
 117 void fct(void)
 118 {
 119         if (caa_likely(1)) {
 120         }
 121 }
 122 ]])],[
 123         AC_MSG_RESULT([yes])
 124 ],[
 125         AC_MSG_RESULT([no])
 126         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 127
 128 ])
 129
 130 # urcu - check that URCU lib is available to compilation
 131 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 132
 133 # urcu - check that URCU lib is at least version 0.6
 134 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 135
 136
 137 # Check for various supplementary host information (beyond the
 138 # triplet) which might affect the library format choices.  E.g., we
 139 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 140
 141 case "${host}" in
 142 changequote(,)dnl
 143   i[34567]86-*-linux*)
 144 changequote([,])dnl
 145     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 146                     [save_CPPFLAGS="$CPPFLAGS"
 147                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 148                     AC_EGREP_CPP([got it], [
 149 #if __x86_64__
 150 got it
 151 #endif
 152                  ], [ust_cv_i386_is_x86_64=yes],
 153                     [ust_cv_i386_is_x86_64=no])
 154                     CPPFLAGS="$save_CPPFLAGS"])
 155     ;;
 156 esac
 157
 158 AC_MSG_CHECKING([library format for the host system])
 159 case $host_cpu in
 160 changequote(,)dnl
 161         i[3456]86)
 162 changequote([,])dnl
 163           if test "$ust_cv_i386_is_x86_64" = yes ; then
 164              LIBFORMAT="elf64-x86-64"
 165           else
 166              LIBFORMAT="elf32-i386"
 167           fi
 168           ;;
 169         x86_64) LIBFORMAT="elf64-x86-64" ;;
 170         powerpc) LIBFORMAT="elf32-powerpc" ;;
 171         ppc64) LIBFORMAT="elf64-powerpc" ;;
 172         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 173         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 174         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 175         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 176         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 177         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 178         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 179 esac
 180 AC_SUBST(LIBFORMAT)
 181 AC_MSG_RESULT($LIBFORMAT)
 182
 183 if test "x$host_cpu" = "xarm" ; then
 184 AC_MSG_CHECKING([checking for armv5])
 185 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 186 #ifndef __ARM_ARCH_5TEJ__
 187 #error "no arm5 here"
 188 #endif
 189 ]])],[
 190         AC_MSG_RESULT([yes])
 191         NO_UNALIGNED_ACCESS=1
 192
 193 ],[
 194         AC_MSG_RESULT([no])
 195
 196 ])
 197 fi
 198 if test x$NO_UNALIGNED_ACCESS = x ; then
 199 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 200 fi
 201
 202 # Set compile flags to java include files if given
 203 AC_ARG_WITH([java-jdk],
 204         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 205         [JAVA_JDK=$withval],
 206         [JAVA_JDK=""]
 207 )
 208 AS_IF([test $JAVA_JDK],[
 209         AS_IF([test -d $JAVA_JDK],[
 210                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 211                 SUBDIRS=`find $JAVA_JDK/include -type d`
 212                 CPPFLAGS+=" "
 213                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 214                 CPPFLAGS+=" "
 215         ],[
 216                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 217         ])
 218 ])
 219
 220 # sdt.h integration
 221 AC_ARG_WITH([sdt],
 222         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 223         [with_sdt=$withval],
 224         [with_sdt="no"]
 225 )
 226
 227 AS_IF([test "x$with_sdt" = "xyes"],[
 228         AC_MSG_CHECKING([STAP_PROBEV()])
 229         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 230         #define SDT_USE_VARIADIC
 231         #include <sys/sdt.h>
 232         void fct(void)
 233         {
 234                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 235         }
 236         ]])],[
 237                 AC_MSG_RESULT([yes])
 238                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 239         ],[
 240                 AC_MSG_RESULT([no])
 241                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 242         ])
 243 ])
 244
 245 #currently disabled.
 246         #tests/hello2/Makefile
 247         #tests/basic/Makefile
 248         #tests/simple_include/Makefile
 249         #tests/snprintf/Makefile
 250         #tests/test-nevents/Makefile
 251         #tests/test-libustinstr-malloc/Makefile
 252         #tests/dlopen/Makefile
 253         #tests/same_line_marker/Makefile
 254         #tests/trace_event/Makefile
 255         #tests/tracepoint/Makefile
 256         #tests/tracepoint/benchmark/Makefile
 257         #tests/register_test/Makefile
 258         #tests/libustctl_function_#tests/Makefile
 259         #tests/exit-fast/Makefile
 260         #tests/basic_long/Makefile
 261
 262 #       liblttng-ust-java/Makefile
 263
 264 AC_CONFIG_FILES([
 265         Makefile
 266         doc/Makefile
 267         doc/examples/Makefile
 268         include/Makefile
 269         include/lttng/ust-version.h
 270         snprintf/Makefile
 271         libringbuffer/Makefile
 272         liblttng-ust-comm/Makefile
 273         liblttng-ust/Makefile
 274         liblttng-ust-ctl/Makefile
 275         liblttng-ust-fork/Makefile
 276         liblttng-ust-libc-wrapper/Makefile
 277         tools/Makefile
 278         tests/Makefile
 279         tests/hello/Makefile
 280         tests/hello-static-lib/Makefile
 281         tests/hello.cxx/Makefile
 282         tests/demo/Makefile
 283         tests/fork/Makefile
 284         tests/ust-basic-tracing/Makefile
 285         tests/ust-multi-test/Makefile
 286         lttng-ust.pc
 287 ])
 288
 289 AC_OUTPUT
 290
 291 AS_ECHO()
 292 AS_ECHO("Version name: $version_name")
 293 AS_ECHO("$version_description")
 294
 295 # Report on the configuration options
 296 AS_ECHO()
 297 AS_ECHO("LTTng-UST will be built with the following options:")
 298 AS_ECHO("Library format: $LIBFORMAT")
 299
 300 AS_ECHO()
 301 AS_ECHO_N("sdt.h integration:  ")
 302 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 303
 304 AS_ECHO()
 305 AS_ECHO("Type 'make' to compile.")
 306