configure.ac

   1 # SPDX-License-Identifier: LGPL-2.1-only
   2
   3 dnl Version infos
   4 m4_define([V_MAJOR], [2])
   5 m4_define([V_MINOR], [13])
   6 m4_define([V_PATCH], [0])
   7 m4_define([V_EXTRA], [pre])
   8 m4_define([V_NAME], [[Codename TBD]])
   9 m4_define([V_DESC], [[Description TBD]])
  10
  11 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  12 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  13
  14 AC_PREREQ([2.69])
  15 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  16
  17 dnl Substitute minor/major/patchlevel version numbers
  18 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  19 AC_SUBST([MINOR_VERSION], [V_MINOR])
  20 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  21
  22 # Following the numbering scheme proposed by libtool for the library version
  23 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  24 # This is the library version of liblttng-ust.
  25 m4_define([UST_LIB_V_MAJOR], [1])
  26 m4_define([UST_LIB_V_MINOR], [0])
  27 m4_define([UST_LIB_V_PATCH], [0])
  28
  29 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  30 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  31 # note: remember to update tracepoint.h dlopen() to match this version
  32 # number. TODO: eventually automate by exporting the major number.
  33
  34 # This is the library version of liblttng-ust-ctl, used internally by
  35 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  36 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  37
  38 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h])
  39 AC_CONFIG_AUX_DIR([config])
  40 AC_CONFIG_MACRO_DIR([m4])
  41 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  42
  43 AC_CANONICAL_TARGET
  44 AC_CANONICAL_HOST
  45
  46 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 # Enable silent rules by default
  50 AM_SILENT_RULES([yes])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  57 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  58 AC_PROG_CXX
  59 AX_CXX_COMPILE_STDCXX([11])
  60 RW_PROG_CXX_WORKS
  61 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  62
  63 # Check if the compiler support weak symbols
  64 AX_SYS_WEAK_ALIAS
  65
  66 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  67         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  68 ])
  69
  70 # Checks for programs.
  71 AM_PROG_AR
  72 AC_PROG_SED
  73 AC_PROG_GREP
  74 AC_PROG_LN_S
  75 AC_PROG_MKDIR_P
  76 AC_PROG_MAKE_SET
  77 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  78 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  79
  80 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  81 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  82 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  83 ], [
  84         libtool_fixup=$enableval
  85 ], [
  86         libtool_fixup=yes
  87 ])
  88
  89 AS_IF([test "x$libtool_fixup" = "xyes"], [
  90         libtool_m4="$srcdir/m4/libtool.m4"
  91         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  92         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  93         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  94
  95         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  96         AC_MSG_RESULT([$libtool_flag_pattern_count])
  97         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  98                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  99         ], [
 100                 AC_MSG_RESULT([none])
 101         ])
 102 ])
 103 LT_INIT([disable-static])
 104
 105 AC_MSG_CHECKING([whether shared libraries are enabled])
 106 AS_IF([test "x$enable_shared" = "xyes"], [
 107         AC_MSG_RESULT([yes])
 108 ], [
 109         AC_MSG_RESULT([no])
 110         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 111 ])
 112
 113 # Checks for typedefs, structures, and compiler characteristics.
 114 AC_C_INLINE
 115 AC_TYPE_INT8_T
 116 AC_TYPE_INT16_T
 117 AC_TYPE_INT32_T
 118 AC_TYPE_INT64_T
 119 AC_TYPE_MODE_T
 120 AC_TYPE_OFF_T
 121 AC_TYPE_PID_T
 122 AC_TYPE_SIZE_T
 123 AC_TYPE_SSIZE_T
 124 AC_TYPE_UID_T
 125 AC_TYPE_UINT8_T
 126 AC_TYPE_UINT16_T
 127 AC_TYPE_UINT32_T
 128 AC_TYPE_UINT64_T
 129 AC_CHECK_TYPES([ptrdiff_t])
 130
 131 AX_C___ATTRIBUTE__
 132 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 133         [:],
 134         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 135
 136 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 137
 138 # Checks for library functions.
 139 AC_FUNC_CHOWN
 140 AC_FUNC_FORK
 141 AC_FUNC_MMAP
 142 AC_FUNC_REALLOC
 143 AC_FUNC_STRERROR_R
 144 AC_FUNC_STRNLEN
 145 AC_CHECK_FUNCS([ \
 146         atexit \
 147         clock_gettime \
 148         ftruncate \
 149         getpagesize \
 150         gettimeofday \
 151         localeconv \
 152         memchr \
 153         memmove \
 154         memset \
 155         mkdir \
 156         munmap \
 157         realpath \
 158         sched_getcpu \
 159         socket \
 160         strchr \
 161         strdup \
 162         strerror \
 163         strtol \
 164         strtoul \
 165         sysconf \
 166 ])
 167
 168 # Check for pthread_setname_np and its signature
 169 LTTNG_PTHREAD_SETNAME_NP
 170
 171 # AC_FUNC_MALLOC causes problems when cross-compiling.
 172 #AC_FUNC_MALLOC
 173
 174 # Checks for header files.
 175 AC_HEADER_STDBOOL
 176 AC_CHECK_HEADERS([ \
 177         arpa/inet.h \
 178         fcntl.h \
 179         float.h \
 180         limits.h \
 181         locale.h \
 182         stddef.h \
 183         sys/socket.h \
 184         sys/time.h \
 185         wchar.h \
 186 ])
 187
 188 # Set architecture specific options
 189 AS_CASE([$host_cpu],
 190         [i[[3456]]86], [],
 191         [x86_64], [],
 192         [amd64], [],
 193         [powerpc], [],
 194         [ppc64], [],
 195         [ppc64le], [],
 196         [powerpc64], [],
 197         [powerpc64le], [],
 198         [s390], [NO_UNALIGNED_ACCESS=1],
 199         [s390x], [NO_UNALIGNED_ACCESS=1],
 200         [arm*], [
 201                 NO_UNALIGNED_ACCESS=1
 202                 NO_NUMA=1
 203                 ],
 204         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 205         [mips*], [NO_UNALIGNED_ACCESS=1],
 206         [tile*], [NO_UNALIGNED_ACCESS=1],
 207         [
 208                 UNSUPPORTED_ARCH=1
 209                 NO_UNALIGNED_ACCESS=1
 210         ])
 211
 212 # Set os specific options
 213 AS_CASE([$host_os],
 214         [freebsd*], [NO_NUMA=1]
 215 )
 216
 217 # Configuration options, which will be installed in the config.h
 218 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 219 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 220 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 221
 222 # Checks for libraries.
 223 AC_CHECK_LIB([dl], [dlopen], [
 224         libdl_name=dl
 225         DL_LIBS="-ldl"
 226 ], [
 227         #libdl not found, check for dlopen in libc.
 228         AC_CHECK_LIB([c], [dlopen], [
 229                 libdl_name=c
 230                 DL_LIBS="-lc"
 231         ], [
 232                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 233         ])
 234 ])
 235 AC_SUBST(DL_LIBS)
 236
 237 # Check if libdl has dlmopen support.
 238 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 239 AC_CHECK_LIB([$libdl_name], [dlmopen],
 240         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 241 )
 242
 243 # Check for dlfcn.h
 244 AC_CHECK_HEADER([dlfcn.h])
 245 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 246         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 247                 #include <dlfcn.h>
 248         ])
 249 ], [
 250         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 251 ])
 252
 253 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 254
 255 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 256 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 257
 258 # numa.h integration
 259 AS_IF([test "x$NO_NUMA" = "x1"],[
 260       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 261 ])
 262
 263 AC_ARG_ENABLE([numa], [
 264 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 265 ], [
 266         enable_numa=$enableval
 267 ], [
 268         enable_numa=yes
 269 ])
 270
 271 AS_IF([test "x$enable_numa" = "xyes"], [
 272         # numa - check that numa lib is available
 273         AC_CHECK_LIB([numa], [numa_available], [],
 274 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 275         have_libnuma=yes
 276 ])
 277 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 278
 279 # optional linux/perf_event.h
 280 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 281
 282 # Perf event counters are supported on all architectures supported by
 283 # perf, using the read system call as fallback.
 284 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 285
 286 AS_IF([test "x$have_perf_event" = "xyes"], [
 287         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 288 ])
 289
 290 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 291         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 292 ])
 293
 294 # Check for JNI header files if requested
 295 AC_ARG_ENABLE([jni-interface], [
 296 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 297 ], [
 298         jni_interface=$enableval
 299 ], [
 300         jni_interface=no
 301 ])
 302
 303 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 304
 305
 306 AC_ARG_ENABLE([java-agent-jul], [
 307 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 308 ], [
 309         java_agent_jul=$enableval
 310 ], [
 311         java_agent_jul=no
 312 ])
 313
 314 AC_ARG_ENABLE([java-agent-log4j], [
 315 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 316 ], [
 317         java_agent_log4j=$enableval
 318 ], [
 319         java_agent_log4j=no
 320 ])
 321
 322 AC_ARG_ENABLE([java-agent-all], [
 323 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 324 ], [
 325         java_agent_jul=$enableval
 326         java_agent_log4j=$enableval
 327 ], [:])
 328
 329 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 330 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 331 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 332
 333 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 334         AX_JAVA_OPTIONS
 335         AX_PROG_JAVAC
 336         AX_PROG_JAVA
 337         AX_PROG_JAR
 338         AC_ARG_VAR([CLASSPATH], [Java class path])
 339
 340         AX_JNI_INCLUDE_DIR
 341         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 342         do
 343                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 344         done
 345
 346         saved_CPPFLAGS="$CPPFLAGS"
 347         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 348         AX_PROG_JAVAH
 349         CPPFLAGS="$saved_CPPFLAGS"
 350 ])
 351
 352 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 353
 354 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 355         AX_CHECK_CLASSPATH
 356         AX_CHECK_CLASS([org.apache.log4j.Logger])
 357         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 358                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 359         ])
 360 ])
 361
 362 # Option to build the python agent
 363 AC_ARG_ENABLE([python-agent], [
 364 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 365 ], [
 366         python_agent=$enableval
 367 ], [:])
 368 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 369 AS_IF([test "x$python_agent" = "xyes"], [
 370         AM_PATH_PYTHON([2.7])
 371 ])
 372
 373 # sdt.h integration
 374 AC_ARG_WITH([sdt], [
 375 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 376 ], [
 377         with_sdt=$withval
 378 ], [
 379         with_sdt="no"
 380 ])
 381
 382 AS_IF([test "x$with_sdt" = "xyes"], [
 383         AC_MSG_CHECKING([STAP_PROBEV()])
 384         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 385                 #define SDT_USE_VARIADIC
 386                 #include <sys/sdt.h>
 387                 void fct(void)
 388                 {
 389                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 390                 }
 391         ]])], [
 392                 AC_MSG_RESULT([yes])
 393                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 394         ], [
 395                 AC_MSG_RESULT([no])
 396                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 397         ])
 398 ])
 399
 400 AC_ARG_WITH([lttng-system-rundir], [
 401 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 402 ], [
 403         lttng_system_rundir="$withval"
 404 ], [
 405         lttng_system_rundir="/var/run/lttng"
 406 ])
 407 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 408                 [LTTng system runtime directory])
 409
 410 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 411 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 412
 413 # Enable building examples
 414 AC_ARG_ENABLE(
 415         examples,
 416         AS_HELP_STRING(
 417                 [--disable-examples],
 418                 [Do not build and install examples]
 419         ),
 420         [enable_examples=$enableval],
 421         [enable_examples=yes]
 422 )
 423
 424 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 425
 426 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 427 # is not distributed in tarballs.
 428 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 429 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 430
 431 # Enable building man pages (user's intention).
 432 AC_ARG_ENABLE(
 433         man-pages,
 434         AS_HELP_STRING(
 435                 [--disable-man-pages],
 436                 [Do not build and install man pages (already built in a distributed tarball)]
 437         ),
 438         [man_pages_opt=$enableval],
 439         [man_pages_opt=yes]
 440 )
 441
 442 # Check for asciidoc and xmlto if we enabled building the man pages.
 443 have_asciidoc_xmlto=no
 444 warn_prebuilt_man_pages=no
 445
 446 AS_IF([test "x$man_pages_opt" = "xyes"], [
 447         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 448         AC_PATH_PROG([XMLTO], [xmlto], [no])
 449
 450         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 451                 AS_IF([test "x$in_git_repo" = "xyes"], [
 452                         # This is an error because we're in the Git repo, which
 453                         # means the man pages are not already generated for us,
 454                         # thus asciidoc/xmlto are required because we were asked
 455                         # to build the man pages.
 456                         AC_MSG_ERROR([
 457 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 458 --disable-man-pages to disable building the man pages, in which case
 459 they will not be installed.
 460                         ])
 461                 ], [
 462                         # Only warn here: since we're in the tarball, the man
 463                         # pages should already be generated at this point, thus
 464                         # asciidoc/xmlto are not strictly required.
 465                         warn_prebuilt_man_pages=yes
 466                 ])
 467         ], [
 468                 have_asciidoc_xmlto=yes
 469         ])
 470 ])
 471
 472 # Export man page build condition: build the man pages if the user
 473 # asked for it, and if the tools are available.
 474 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 475 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 476
 477 # Default values
 478 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 479         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 480         $1="$2"
 481         AC_SUBST([$1])
 482 ])
 483
 484 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 485
 486 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
 487 AC_SUBST(AM_CFLAGS)
 488
 489 AM_CXXFLAGS="$AM_CFLAGS"
 490 AC_SUBST(AM_CXXFLAGS)
 491
 492 # The order in which the include folders are searched is important.
 493 # The top_builddir should always be searched first in the event that a build
 494 # time generated file is included.
 495 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 496 AC_SUBST(AM_CPPFLAGS)
 497
 498 AC_SUBST(JNI_CPPFLAGS)
 499
 500 AC_CONFIG_FILES([
 501         Makefile
 502         doc/Makefile
 503         doc/examples/Makefile
 504         doc/man/Makefile
 505         include/Makefile
 506         include/lttng/ust-version.h
 507         snprintf/Makefile
 508         libcounter/Makefile
 509         libmsgpack/Makefile
 510         libringbuffer/Makefile
 511         liblttng-ust-comm/Makefile
 512         liblttng-ust/Makefile
 513         liblttng-ust-ctl/Makefile
 514         liblttng-ust-fork/Makefile
 515         liblttng-ust-dl/Makefile
 516         liblttng-ust-fd/Makefile
 517         liblttng-ust-java/Makefile
 518         liblttng-ust-java-agent/Makefile
 519         liblttng-ust-java-agent/java/Makefile
 520         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 521         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 522         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 523         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 524         liblttng-ust-java-agent/jni/Makefile
 525         liblttng-ust-java-agent/jni/common/Makefile
 526         liblttng-ust-java-agent/jni/jul/Makefile
 527         liblttng-ust-java-agent/jni/log4j/Makefile
 528         liblttng-ust-libc-wrapper/Makefile
 529         liblttng-ust-cyg-profile/Makefile
 530         liblttng-ust-python-agent/Makefile
 531         python-lttngust/Makefile
 532         python-lttngust/setup.py
 533         python-lttngust/lttngust/__init__.py
 534         tools/Makefile
 535         tests/Makefile
 536         tests/compile/Makefile
 537         tests/compile/ctf-types/Makefile
 538         tests/compile/hello.cxx/Makefile
 539         tests/compile/hello/Makefile
 540         tests/compile/hello-many/Makefile
 541         tests/compile/same_line_tracepoint/Makefile
 542         tests/compile/test-app-ctx/Makefile
 543         tests/benchmark/Makefile
 544         tests/unit/gcc-weak-hidden/Makefile
 545         tests/unit/libmsgpack/Makefile
 546         tests/unit/Makefile
 547         tests/unit/libringbuffer/Makefile
 548         tests/unit/pthread_name/Makefile
 549         tests/unit/snprintf/Makefile
 550         tests/unit/ust-elf/Makefile
 551         tests/utils/Makefile
 552         lttng-ust.pc
 553         lttng-ust-ctl.pc
 554 ])
 555
 556 # Create link for python agent for the VPATH guru.
 557 AC_CONFIG_LINKS([
 558         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 559         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 560         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 561         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 562         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 563 ])
 564
 565 AC_CONFIG_FILES([tests/unit/ust-elf/test_ust_elf],[chmod +x tests/unit/ust-elf/test_ust_elf])
 566
 567 AC_OUTPUT
 568
 569
 570 #
 571 # Mini-report on what will be built.
 572 #
 573
 574 PPRINT_INIT
 575 PPRINT_SET_INDENT(1)
 576 PPRINT_SET_TS(38)
 577
 578 AS_ECHO
 579 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 580 AS_ECHO
 581
 582 AS_ECHO("V_DESC")
 583
 584 AS_ECHO
 585 PPRINT_SUBTITLE([System])
 586
 587 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 588
 589 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 590 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 591
 592 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 593        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 594 ])
 595
 596 AS_ECHO
 597 PPRINT_SUBTITLE([Features])
 598 PPRINT_SET_INDENT(1)
 599
 600 test "x$with_sdt" = "xyes" && value=1 || value=0
 601 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 602
 603 test "x$java_agent_jul" = xyes && value=1 || value=0
 604 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 605
 606 test "x$java_agent_log4j" = xyes && value=1 || value=0
 607 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 608
 609 test "x$jni_interface" = xyes && value=1 || value=0
 610 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 611
 612 test "x$python_agent" = xyes && value=1 || value=0
 613 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 614
 615 test "x$have_perf_event" = "xyes" && value=1 || value=0
 616 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 617
 618 test "x$enable_numa" = xyes && value=1 || value=0
 619 PPRINT_PROP_BOOL([NUMA], $value)
 620
 621 AS_ECHO
 622 PPRINT_SET_INDENT(0)
 623
 624 test "x$enable_examples" = xyes && value=1 || value=0
 625 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 626
 627 # man pages build enabled/disabled
 628 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 629
 630 AS_IF([test "x$man_pages_opt" != "xno"], [
 631         AS_IF([test "x$in_git_repo" = "xyes"], [
 632                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 633         ], [
 634                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 635                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 636                 ], [
 637                         PPRINT_PROP_STRING([build_man_pages_msg],
 638                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 639                                 $PPRINT_COLOR_SUBTITLE)
 640                 ])
 641         ])
 642 ], [
 643         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 644 ])
 645
 646 m4_popdef([build_man_pages_msg])
 647
 648 PPRINT_SET_INDENT(1)
 649
 650 report_bindir="`eval eval echo $bindir`"
 651 report_libdir="`eval eval echo $libdir`"
 652
 653 # Print the bindir and libdir this `make install' will install into.
 654 AS_ECHO
 655 PPRINT_SUBTITLE([Install directories])
 656 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 657 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 658
 659 AS_ECHO
 660 PPRINT_SUBTITLE([System directories])
 661
 662 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 663
 664 PPRINT_SET_INDENT(0)
 665
 666 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 667         AS_ECHO
 668         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 669
 670 Note that the man pages are already built in this distribution tarball,
 671 therefore asciidoc and xmlto are only needed if you intend to modify
 672 their sources.
 673
 674 Use --disable-man-pages to completely disable building and installing
 675 the man pages.])
 676 ])