configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.4],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Annedd'ale"
  38 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], [$version_name], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], [$version_description], [UST version description])
  41
  42 AC_PROG_GREP
  43 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  44 AC_ARG_ENABLE(libtool-linkdep-fixup,
  45         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  46                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  47         libtool_fixup=$enableval,
  48         libtool_fixup=yes)
  49
  50 AS_IF([test "x$libtool_fixup" = "xyes"],
  51             [
  52             libtool_m4="$srcdir/config/libtool.m4"
  53             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  54             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  55             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  56             AS_IF([test $libtool_flag_pattern_count -ne 0],
  57             [
  58                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  59                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  60                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  61                   ],
  62                   [
  63                   AC_MSG_RESULT([none])
  64                   ])
  65             ])
  66
  67 # Checks for programs.
  68 AC_PROG_CC
  69 AC_PROG_CXX
  70 AC_PROG_MAKE_SET
  71 LT_INIT
  72
  73 ## Checks for libraries.
  74 AC_CHECK_LIB([dl], [dlopen])
  75 AC_CHECK_LIB([pthread], [pthread_create])
  76
  77 # Check for libuuid
  78 AC_CHECK_LIB([uuid], [uuid_generate], [],
  79         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  80 )
  81
  82 # Checks for header files.
  83 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  84
  85 # Checks for typedefs, structures, and compiler characteristics.
  86 AC_C_INLINE
  87 #AC_TYPE_INT16_T
  88 #AC_TYPE_INT32_T
  89 #AC_TYPE_INT64_T
  90 #AC_TYPE_INT8_T
  91 #AC_TYPE_PID_T
  92 #AC_TYPE_SIZE_T
  93 #AC_TYPE_SSIZE_T
  94 #AC_TYPE_UINT16_T
  95 #AC_TYPE_UINT32_T
  96 #AC_TYPE_UINT64_T
  97 #AC_TYPE_UINT8_T
  98 #AC_CHECK_TYPES([ptrdiff_t])
  99
 100 # Checks for library functions.
 101 AC_FUNC_MALLOC
 102 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 103
 104 CFLAGS="-Wall $CFLAGS"
 105
 106 # URCU
 107
 108 # urcu - check if we just find the headers it out of the box.
 109 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 110 This error can also occur when the liburcu package's configure script has not been run.])])
 111
 112 AC_MSG_CHECKING([caa_likely()])
 113 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 114 #include <urcu/compiler.h>
 115 void fct(void)
 116 {
 117         if (caa_likely(1)) {
 118         }
 119 }
 120 ]])],[
 121         AC_MSG_RESULT([yes])
 122 ],[
 123         AC_MSG_RESULT([no])
 124         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 125
 126 ])
 127
 128 # urcu - check that URCU lib is available to compilation
 129 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 130
 131 # urcu - check that URCU lib is at least version 0.6
 132 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 133
 134
 135 # Check for various supplementary host information (beyond the
 136 # triplet) which might affect the library format choices.  E.g., we
 137 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 138
 139 case "${host}" in
 140 changequote(,)dnl
 141   i[34567]86-*-linux*)
 142 changequote([,])dnl
 143     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 144                     [save_CPPFLAGS="$CPPFLAGS"
 145                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 146                     AC_EGREP_CPP([got it], [
 147 #if __x86_64__
 148 got it
 149 #endif
 150                  ], [ust_cv_i386_is_x86_64=yes],
 151                     [ust_cv_i386_is_x86_64=no])
 152                     CPPFLAGS="$save_CPPFLAGS"])
 153     ;;
 154 esac
 155
 156 AC_MSG_CHECKING([library format for the host system])
 157 case $host_cpu in
 158 changequote(,)dnl
 159         i[3456]86)
 160 changequote([,])dnl
 161           if test "$ust_cv_i386_is_x86_64" = yes ; then
 162              LIBFORMAT="elf64-x86-64"
 163           else
 164              LIBFORMAT="elf32-i386"
 165           fi
 166           ;;
 167         x86_64) LIBFORMAT="elf64-x86-64" ;;
 168         powerpc) LIBFORMAT="elf32-powerpc" ;;
 169         ppc64) LIBFORMAT="elf64-powerpc" ;;
 170         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 171         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 172         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 173         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 174         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 175         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 176         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 177 esac
 178 AC_SUBST(LIBFORMAT)
 179 AC_MSG_RESULT($LIBFORMAT)
 180
 181 if test "x$host_cpu" = "xarm" ; then
 182 AC_MSG_CHECKING([checking for armv5])
 183 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 184 #ifndef __ARM_ARCH_5TEJ__
 185 #error "no arm5 here"
 186 #endif
 187 ]])],[
 188         AC_MSG_RESULT([yes])
 189         NO_UNALIGNED_ACCESS=1
 190
 191 ],[
 192         AC_MSG_RESULT([no])
 193
 194 ])
 195 fi
 196 if test x$NO_UNALIGNED_ACCESS = x ; then
 197 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 198 fi
 199
 200 # Set compile flags to java include files if given
 201 AC_ARG_WITH([java-jdk],
 202         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 203         [JAVA_JDK=$withval],
 204         [JAVA_JDK=""]
 205 )
 206 AS_IF([test $JAVA_JDK],[
 207         AS_IF([test -d $JAVA_JDK],[
 208                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 209                 SUBDIRS=`find $JAVA_JDK/include -type d`
 210                 CPPFLAGS+=" "
 211                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 212                 CPPFLAGS+=" "
 213         ],[
 214                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 215         ])
 216 ])
 217
 218 # sdt.h integration
 219 AC_ARG_WITH([sdt],
 220         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 221         [with_sdt=$withval],
 222         [with_sdt="no"]
 223 )
 224
 225 AS_IF([test "x$with_sdt" = "xyes"],[
 226         AC_MSG_CHECKING([STAP_PROBEV()])
 227         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 228         #define SDT_USE_VARIADIC
 229         #include <sys/sdt.h>
 230         void fct(void)
 231         {
 232                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 233         }
 234         ]])],[
 235                 AC_MSG_RESULT([yes])
 236                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 237         ],[
 238                 AC_MSG_RESULT([no])
 239                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 240         ])
 241 ])
 242
 243 #currently disabled.
 244         #tests/hello2/Makefile
 245         #tests/basic/Makefile
 246         #tests/simple_include/Makefile
 247         #tests/snprintf/Makefile
 248         #tests/test-nevents/Makefile
 249         #tests/test-libustinstr-malloc/Makefile
 250         #tests/dlopen/Makefile
 251         #tests/same_line_marker/Makefile
 252         #tests/trace_event/Makefile
 253         #tests/tracepoint/Makefile
 254         #tests/tracepoint/benchmark/Makefile
 255         #tests/register_test/Makefile
 256         #tests/libustctl_function_#tests/Makefile
 257         #tests/exit-fast/Makefile
 258         #tests/basic_long/Makefile
 259
 260 #       liblttng-ust-java/Makefile
 261
 262 AC_CONFIG_FILES([
 263         Makefile
 264         doc/Makefile
 265         doc/examples/Makefile
 266         include/Makefile
 267         include/lttng/ust-version.h
 268         snprintf/Makefile
 269         libringbuffer/Makefile
 270         liblttng-ust-comm/Makefile
 271         liblttng-ust/Makefile
 272         liblttng-ust-ctl/Makefile
 273         liblttng-ust-fork/Makefile
 274         liblttng-ust-libc-wrapper/Makefile
 275         tools/Makefile
 276         tests/Makefile
 277         tests/hello/Makefile
 278         tests/hello-static-lib/Makefile
 279         tests/hello.cxx/Makefile
 280         tests/demo/Makefile
 281         tests/fork/Makefile
 282         tests/ust-basic-tracing/Makefile
 283         tests/ust-multi-test/Makefile
 284         lttng-ust.pc
 285 ])
 286
 287 AC_OUTPUT
 288
 289 AS_ECHO()
 290 AS_ECHO("Version name: $version_name")
 291 AS_ECHO("$version_description")
 292
 293 # Report on the configuration options
 294 AS_ECHO()
 295 AS_ECHO("LTTng-UST will be built with the following options:")
 296 AS_ECHO("Library format: $LIBFORMAT")
 297
 298 AS_ECHO()
 299 AS_ECHO_N("sdt.h integration:  ")
 300 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 301
 302 AS_ECHO()
 303 AS_ECHO("Type 'make' to compile.")
 304